classes/image.bbclass

   1 inherit rootfs_${IMAGE_PKGTYPE}
   2 inherit kernel-arch
   3
   4 LICENSE = "MIT"
   5 PACKAGES = ""
   6
   7 #
   8 # udev, devfsd, busybox-mdev (from busybox) or none
   9 #
  10 IMAGE_DEV_MANAGER ?= "${@base_contains("MACHINE_FEATURES", "kernel26",  "udev","",d)} "
  11 #
  12 # sysvinit, upstart
  13 #
  14 IMAGE_INIT_MANAGER ?= "sysvinit sysvinit-pidof"
  15 IMAGE_INITSCRIPTS ?= "initscripts"
  16 #
  17 # tinylogin, getty
  18 #
  19 IMAGE_LOGIN_MANAGER ?= "tinylogin"
  20
  21 # set sane default for the SPLASH variable
  22 SPLASH ?= ""
  23
  24 IMAGE_KEEPROOTFS ?= ""
  25 IMAGE_KEEPROOTFS[doc] = "Set to non-empty to keep ${IMAGE_ROOTFS} around after image creation."
  26
  27 IMAGE_BOOT ?= "${IMAGE_INITSCRIPTS} \
  28                ${IMAGE_DEV_MANAGER} \
  29                ${IMAGE_INIT_MANAGER} \
  30                ${IMAGE_LOGIN_MANAGER}"
  31
  32 # some default locales
  33 IMAGE_LINGUAS ?= "de-de fr-fr en-gb"
  34 IMAGE_LINGUAS[type] = "list"
  35
  36 LINGUAS_INSTALL = ""
  37 LINGUAS_INSTALL_linux = "${@base_ifelse(d.getVar('IMAGE_LINGUAS', True), \
  38                                         'glibc-localedata-i18n', '')}"
  39 LINGUAS_INSTALL_linux += "${@' '.join(map(lambda s: 'locale-base-%s' % s, '${IMAGE_LINGUAS}'.split()))}"
  40 LINGUAS_INSTALL_linux-gnueabi = "${LINGUAS_INSTALL_linux}"
  41
  42 PACKAGE_INSTALL = "${@' '.join(oe.packagegroup.required_packages('${IMAGE_FEATURES}'.split(), d))}"
  43 PACKAGE_INSTALL_ATTEMPTONLY = "${@' '.join(oe.packagegroup.optional_packages('${IMAGE_FEATURES}'.split(), d))}"
  44 RDEPENDS += "${@' '.join(oe.packagegroup.active_packages('${IMAGE_FEATURES}'.split(), d))}"
  45
  46
  47 IMAGE_FEATURES ?= ""
  48 IMAGE_FEATURES[type] = "list"
  49 IMAGE_FEATURES_prepend = "image_base "
  50
  51 # Define our always included package group
  52 PACKAGE_GROUP_image_base = "${IMAGE_INSTALL} ${IMAGE_BOOT} ${LINGUAS_INSTALL}"
  53
  54 # The following package groups allow one to add debugging, development, and
  55 # documentation files for all packages installed in the image.
  56
  57 def string_set(iterable):
  58     return ' '.join(set(iterable))
  59
  60 def image_features_noextras(d):
  61     for f in d.getVar("IMAGE_FEATURES", True).split():
  62         if not f in ('dbg', 'dev', 'doc'):
  63             yield f
  64
  65 def dbg_packages(d):
  66     from itertools import chain
  67
  68     features = image_features_noextras(d)
  69     return string_set("%s-dbg" % pkg
  70                       for pkg in chain(oe.packagegroup.active_packages(features, d),
  71                                        oe.packagegroup.active_recipes(features, d)))
  72
  73 PACKAGE_GROUP_dbg = "${@dbg_packages(d)}"
  74 PACKAGE_GROUP_dbg[optional] = "1"
  75 PACKAGE_GROUP_dev = "${@string_set('%s-dev' % pn for pn in oe.packagegroup.active_recipes(image_features_noextras(d), d))}"
  76 PACKAGE_GROUP_dev[optional] = "1"
  77 PACKAGE_GROUP_doc = "${@string_set('%s-doc' % pn for pn in oe.packagegroup.active_recipes(image_features_noextras(d), d))}"
  78 PACKAGE_GROUP_doc[optional] = "1"
  79
  80 # "export IMAGE_BASENAME" not supported at this time
  81 IMAGE_BASENAME[export] = "1"
  82
  83 # We need to recursively follow RDEPENDS and RRECOMMENDS for images
  84 do_rootfs[recrdeptask] += "do_deploy do_populate_sysroot"
  85
  86 # Images are generally built explicitly, do not need to be part of world.
  87 EXCLUDE_FROM_WORLD = "1"
  88
  89 USE_DEVFS ?= "0"
  90 USE_DEVFS[type] = "boolean"
  91
  92 PID = "${@os.getpid()}"
  93
  94 PACKAGE_ARCH = "${MACHINE_ARCH}"
  95
  96 do_rootfs[depends] += "makedevs-native:do_populate_sysroot fakeroot-native:do_populate_sysroot"
  97
  98 python () {
  99     import bb
 100
 101     deps = bb.data.getVarFlag('do_rootfs', 'depends', d) or ""
 102     for type in (bb.data.getVar('IMAGE_FSTYPES', d, True) or "").split():
 103         for dep in ((bb.data.getVar('IMAGE_DEPENDS_%s' % type, d) or "").split() or []):
 104             deps += " %s:do_populate_sysroot" % dep
 105     for dep in (bb.data.getVar('EXTRA_IMAGEDEPENDS', d, True) or "").split():
 106         deps += " %s:do_populate_sysroot" % dep
 107     bb.data.setVarFlag('do_rootfs', 'depends', deps, d)
 108
 109     runtime_mapping_rename("PACKAGE_INSTALL", d)
 110     runtime_mapping_rename("PACKAGE_INSTALL_ATTEMPTONLY", d)
 111 }
 112
 113 #
 114 # Get a list of files containing tables of devices to be created.
 115 # * IMAGE_DEVICE_TABLE is the old name to an absolute path to a device table file
 116 # * IMAGE_DEVICE_TABLES is a new name for a file, or list of files, searched
 117 #   for in the BBPATH
 118 # If neither are specified then the default name of files/device_table-minimal.txt
 119 # is searched for in the BBPATH (same as the old version.)
 120 #
 121 def get_devtable_list(d):
 122     import bb
 123     devtable = bb.data.getVar('IMAGE_DEVICE_TABLE', d, 1)
 124     if devtable != None:
 125         return devtable
 126     devtables = bb.data.getVar('IMAGE_DEVICE_TABLES', d, 1)
 127     if devtables == None:
 128         devtables = 'files/device_table-minimal.txt'
 129     return " ".join([ bb.which(bb.data.getVar('BBPATH', d, 1), devtable)
 130                       for devtable in devtables.split() ])
 131
 132 def get_imagecmds(d):
 133     import bb
 134     cmds = "\n"
 135     old_overrides = bb.data.getVar('OVERRIDES', d, 0)
 136     for type in bb.data.getVar('IMAGE_FSTYPES', d, True).split():
 137         localdata = bb.data.createCopy(d)
 138         bb.data.setVar('OVERRIDES', '%s:%s' % (type, old_overrides), localdata)
 139         bb.data.update_data(localdata)
 140         cmd  = "\t#Code for image type " + type + "\n"
 141         cmd += "\t${IMAGE_CMD_" + type + "}\n"
 142         cmd += "\tcd ${DEPLOY_DIR_IMAGE}/\n"
 143         cmd += "\tif [ -f ${IMAGE_NAME}.rootfs." + type + " ]; then\n"
 144         cmd += "\tln -fs ${IMAGE_NAME}.rootfs." + type + " ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n"
 145         cmd += "\telif [ -f ${IMAGE_NAME}." + type + ".img ]; then\n"
 146         cmd += "\tln -fs ${IMAGE_NAME}." + type + ".img ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}." + type + "\n"
 147         cmd += "\tfi\n\n"
 148         cmds += bb.data.expand(cmd, localdata)
 149     return cmds
 150
 151 IMAGE_POSTPROCESS_COMMAND ?= ""
 152 MACHINE_POSTPROCESS_COMMAND ?= ""
 153 ROOTFS_POSTPROCESS_COMMAND ?= ""
 154
 155 do_rootfs[nostamp] = "1"
 156 do_rootfs[dirs] = "${TOPDIR}"
 157 do_build[nostamp] = "1"
 158
 159 # Must call real_do_rootfs() from inside here, rather than as a separate
 160 # task, so that we have a single fakeroot context for the whole process.
 161 fakeroot do_rootfs () {
 162         set -x
 163         rm -rf ${IMAGE_ROOTFS}
 164         mkdir -p ${IMAGE_ROOTFS}
 165         mkdir -p ${DEPLOY_DIR_IMAGE}
 166
 167         mkdir -p ${IMAGE_ROOTFS}/etc
 168
 169         if [ "${USE_DEVFS}" != "1" ]; then
 170                 rm -rf ${IMAGE_ROOTFS}/etc/device_table
 171                 for devtable in ${@get_devtable_list(d)}; do
 172                         cat $devtable >> ${IMAGE_ROOTFS}/etc/device_table
 173                         makedevs -r ${IMAGE_ROOTFS} -D $devtable
 174                 done
 175         fi
 176
 177         rootfs_${IMAGE_PKGTYPE}_do_rootfs
 178
 179         ${IMAGE_PREPROCESS_COMMAND}
 180
 181         ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = ${IMAGE_EXTRA_SPACE} + $1; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
 182         ${@get_imagecmds(d)}
 183
 184         ${IMAGE_POSTPROCESS_COMMAND}
 185
 186         ${MACHINE_POSTPROCESS_COMMAND}
 187         ${@['rm -rf ${IMAGE_ROOTFS}', ''][bool(d.getVar("IMAGE_KEEPROOTFS", 1))]}
 188 }
 189
 190 do_deploy_to[nostamp] = "1"
 191 do_deploy_to () {
 192         # A standalone task to deploy built image to the location specified
 193         # by DEPLOY_TO variable (likely passed via environment).
 194         # Assumes ${IMAGE_FSTYPES} is a single value!
 195         cp "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.${IMAGE_FSTYPES}" ${DEPLOY_TO}
 196 }
 197
 198 log_check() {
 199         set +x
 200         for target in $*
 201         do
 202                 lf_path="${WORKDIR}/temp/log.do_$target.${PID}"
 203
 204                 echo "log_check: Using $lf_path as logfile"
 205
 206                 if test -e "$lf_path"
 207                 then
 208                         rootfs_${IMAGE_PKGTYPE}_log_check $target $lf_path
 209                 else
 210                         echo "Cannot find logfile [$lf_path]"
 211                 fi
 212                 echo "Logfile is clean"
 213         done
 214
 215         set -x
 216 }
 217
 218 # set '*' as the rootpassword so the images
 219 # can decide if they want it or not
 220
 221 zap_root_password () {
 222         sed 's%^root:[^:]*:%root::%' < ${IMAGE_ROOTFS}/etc/passwd >${IMAGE_ROOTFS}/etc/passwd.new
 223         mv ${IMAGE_ROOTFS}/etc/passwd.new ${IMAGE_ROOTFS}/etc/passwd
 224 }
 225
 226 create_etc_timestamp() {
 227         date +%2m%2d%2H%2M%Y >${IMAGE_ROOTFS}/etc/timestamp
 228 }
 229
 230 # Turn any symbolic /sbin/init link into a file
 231 remove_init_link () {
 232         if [ -h ${IMAGE_ROOTFS}/sbin/init ]; then
 233                 LINKFILE=${IMAGE_ROOTFS}`readlink ${IMAGE_ROOTFS}/sbin/init`
 234                 rm ${IMAGE_ROOTFS}/sbin/init
 235                 cp $LINKFILE ${IMAGE_ROOTFS}/sbin/init
 236         fi
 237 }
 238
 239 make_zimage_symlink_relative () {
 240         if [ -L ${IMAGE_ROOTFS}/boot/zImage ]; then
 241                 (cd ${IMAGE_ROOTFS}/boot/ && for i in `ls zImage-* | sort`; do ln -sf $i zImage; done)
 242         fi
 243 }
 244
 245 # Make login manager(s) enable automatic login.
 246 # Useful for devices where we do not want to log in at all (e.g. phones)
 247 set_image_autologin () {
 248         sed -i 's%^AUTOLOGIN=\"false"%AUTOLOGIN="true"%g' ${IMAGE_ROOTFS}/etc/sysconfig/gpelogin
 249 }
 250
 251 # Can be use to create /etc/timestamp during image construction to give a reasonably
 252 # sane default time setting
 253 rootfs_update_timestamp () {
 254         date "+%m%d%H%M%Y" >${IMAGE_ROOTFS}/etc/timestamp
 255 }
 256
 257 # Install locales into image for every entry in IMAGE_LINGUAS
 258 install_linguas() {
 259 if [ -e ${IMAGE_ROOTFS}/usr/bin/opkg-cl ] ; then
 260         OPKG="opkg-cl ${IPKG_ARGS}"
 261
 262         mkdir -p ${IMAGE_ROOTFS}/tmp-locale
 263
 264         ${OPKG} update || true
 265         ${OPKG} list_installed | awk '{print $1}' |sort | uniq > ${IMAGE_ROOTFS}/tmp-locale/installed-packages
 266
 267         for i in $(cat ${IMAGE_ROOTFS}/tmp-locale/installed-packages | grep -v locale) ; do
 268                 for translation in ${IMAGE_LINGUAS}; do
 269                         translation_split=$(echo ${translation} | awk -F '-' '{print $1}')
 270                         echo ${i}-locale-${translation}
 271                         echo ${i}-locale-${translation_split}
 272                 done
 273         done | sort | uniq > ${IMAGE_ROOTFS}/tmp-locale/wanted-locale-packages
 274
 275         ${OPKG} list | awk '{print $1}' |grep locale |sort | uniq > ${IMAGE_ROOTFS}/tmp-locale/available-locale-packages
 276
 277         cat ${IMAGE_ROOTFS}/tmp-locale/wanted-locale-packages ${IMAGE_ROOTFS}/tmp-locale/available-locale-packages | sort | uniq -d > ${IMAGE_ROOTFS}/tmp-locale/pending-locale-packages
 278
 279         if [ -s ${IMAGE_ROOTFS}/tmp-locale/pending-locale-packages ] ; then
 280                 cat ${IMAGE_ROOTFS}/tmp-locale/pending-locale-packages | xargs ${OPKG} -nodeps install
 281         fi
 282         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/lists/*
 283
 284         rm -rf ${IMAGE_ROOTFS}/tmp-locale
 285
 286     for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.preinst; do
 287         if [ -f $i ] && ! sh $i; then
 288             opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .preinst`
 289         fi
 290     done
 291
 292     for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.postinst; do
 293         if [ -f $i ] && ! sh $i configure; then
 294             opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .postinst`
 295         fi
 296     done
 297
 298 fi
 299 }
 300
 301 # export the zap_root_password, create_etc_timestamp and remote_init_link
 302 EXPORT_FUNCTIONS zap_root_password create_etc_timestamp remove_init_link do_rootfs make_zimage_symlink_relative set_image_autologin rootfs_update_timestamp install_linguas
 303
 304 addtask rootfs before do_build after do_install
 305 addtask deploy_to after do_rootfs