classes/cmake.bbclass

   1 DEPENDS += " cmake-native "
   2
   3 # We need to unset CCACHE otherwise cmake gets too confused
   4 CCACHE = ""
   5
   6 # We want the staging and installing functions from autotools
   7 inherit autotools
   8
   9 # Use in-tree builds by default but allow this to be changed
  10 # since some packages do not support them (e.g. llvm 2.5).
  11 OECMAKE_SOURCEPATH ?= "."
  12
  13 # If declaring this, make sure you also set EXTRA_OEMAKE to
  14 # "-C ${OECMAKE_BUILDPATH}". So it will run the right makefiles.
  15 OECMAKE_BUILDPATH ?= ""
  16
  17 # C/C++ Compiler (without cpu arch/tune arguments)
  18 OECMAKE_C_COMPILER ?= "`echo ${CC} | sed 's/^\([^ ]*\).*/\1/'`"
  19 OECMAKE_CXX_COMPILER ?= "`echo ${CXX} | sed 's/^\([^ ]*\).*/\1/'`"
  20
  21 # Compiler flags
  22 OECMAKE_C_FLAGS ?= "${HOST_CC_ARCH} ${TOOLCHAIN_OPTIONS} ${TARGET_CPPFLAGS}"
  23 OECMAKE_CXX_FLAGS ?= "${HOST_CC_ARCH} ${TOOLCHAIN_OPTIONS} ${TARGET_CPPFLAGS} -fpermissive"
  24 OECMAKE_C_FLAGS_RELEASE ?= "${SELECTED_OPTIMIZATION} -DNDEBUG"
  25 OECMAKE_CXX_FLAGS_RELEASE ?= "${SELECTED_OPTIMIZATION} -DNDEBUG"
  26
  27 OECMAKE_RPATH ?= ""
  28 python __anonymous() {
  29     # Only set OECMAKE_RPATH if we build a native recipe
  30     if bb.data.inherits_class('native', d) and not bb.data.inherits_class('cross', d):
  31         bb.data.setVar('OECMAKE_RPATH', '${libdir}', d)
  32 }
  33
  34 cmake_do_generate_toolchain_file() {
  35 # CMake system name must be something like "Linux".
  36 # This is important for cross-compiling.
  37   echo "set( CMAKE_SYSTEM_NAME" `echo ${SDK_OS} | sed 's/^./\u&/'` ")" > ${WORKDIR}/toolchain.cmake
  38   echo "set( CMAKE_SYSTEM_PROCESSOR ${TARGET_ARCH} )" >> ${WORKDIR}/toolchain.cmake
  39   echo "set( CMAKE_C_COMPILER ${OECMAKE_C_COMPILER} )" >> ${WORKDIR}/toolchain.cmake
  40   echo "set( CMAKE_CXX_COMPILER ${OECMAKE_CXX_COMPILER} )" >> ${WORKDIR}/toolchain.cmake
  41   echo "set( CMAKE_C_FLAGS \"${OECMAKE_C_FLAGS}\" CACHE STRING \"OpenEmbedded CFLAGS\" )" >> ${WORKDIR}/toolchain.cmake
  42   echo "set( CMAKE_CXX_FLAGS \"${OECMAKE_CXX_FLAGS}\" CACHE STRING \"OpenEmbedded CXXFLAGS\" )" >> ${WORKDIR}/toolchain.cmake
  43   echo "set( CMAKE_C_FLAGS_RELEASE \"${OECMAKE_C_FLAGS_RELEASE}\" CACHE STRING \"CFLAGS for release\" )" >> ${WORKDIR}/toolchain.cmake
  44   echo "set( CMAKE_CXX_FLAGS_RELEASE \"${OECMAKE_CXX_FLAGS_RELEASE}\" CACHE STRING \"CXXFLAGS for release\" )" >> ${WORKDIR}/toolchain.cmake
  45
  46 # only search in the paths provided (from openembedded) so cmake doesnt pick
  47 # up libraries and tools from the native build machine
  48   echo "set( CMAKE_FIND_ROOT_PATH ${STAGING_DIR_HOST} ${STAGING_DIR_NATIVE} ${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH} )" >> ${WORKDIR}/toolchain.cmake
  49   echo "set( CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY )" >> ${WORKDIR}/toolchain.cmake
  50   echo "set( CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY )" >> ${WORKDIR}/toolchain.cmake
  51   echo "set( CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY )" >> ${WORKDIR}/toolchain.cmake
  52 # Use qt.conf settings
  53   echo "set( ENV{QT_CONF_PATH} ${WORKDIR}/qt.conf )" >> ${WORKDIR}/toolchain.cmake
  54
  55 # We need to set the rpath to the correct directory as cmake does not provide any
  56 # directory as rpath by default
  57   echo "set( CMAKE_INSTALL_RPATH ${OECMAKE_RPATH} )" >> ${WORKDIR}/toolchain.cmake
  58 }
  59
  60 addtask generate_toolchain_file after do_patch before do_configure
  61
  62 cmake_do_configure() {
  63   if [ ${OECMAKE_BUILDPATH} ]
  64   then
  65     mkdir -p ${OECMAKE_BUILDPATH}
  66     cd ${OECMAKE_BUILDPATH}
  67   fi
  68
  69   # Just like autotools cmake can use a site file to cache result that need generated binaries to run
  70   if [ -e ${WORKDIR}/site-file.cmake ] ; then
  71     OECMAKE_SITEFILE=" -C ${WORKDIR}/site-file.cmake"
  72   else
  73     OECMAKE_SITEFILE=""
  74   fi
  75
  76   cmake \
  77     ${OECMAKE_SITEFILE} \
  78     ${OECMAKE_SOURCEPATH} \
  79     -DCMAKE_INSTALL_PREFIX:PATH=${prefix} \
  80     -DCMAKE_INSTALL_SO_NO_EXE=0 \
  81         -DCMAKE_TOOLCHAIN_FILE=${WORKDIR}/toolchain.cmake \
  82         -DCMAKE_VERBOSE_MAKEFILE=1 \
  83     ${EXTRA_OECMAKE} \
  84     -Wno-dev
  85 }
  86
  87 cmake_do_compile()  {
  88   if [ ${OECMAKE_BUILDPATH} ]
  89   then
  90      cd ${OECMAKE_BUILDPATH}
  91   fi
  92
  93   base_do_compile
  94 }
  95
  96 cmake_do_install() {
  97   if [ ${OECMAKE_BUILDPATH} ];
  98   then
  99      cd ${OECMAKE_BUILDPATH}
 100   fi
 101
 102   autotools_do_install
 103 }
 104
 105 EXPORT_FUNCTIONS do_configure do_compile do_install do_generate_toolchain_file