recipes/udev/udev_162.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.12."
   4 LICENSE = "GPLv2+"
   5
   6 PR = "r10"
   7
   8 # Untested
   9 #DEFAULT_PREFERENCE = "-1"
  10
  11 # Needed for udev-extras
  12 DEPENDS = "gperf-native usbutils acl glib-2.0"
  13 RDEPENDS_${PN} += "module-init-tools-depmod udev-utils"
  14
  15 SRC_URI[md5sum] = "7c537de77442317ef1b93f9dba38fd4e"
  16 SRC_URI[sha256sum] = "f536de7fc0ec231cb793aae9501c648763901d4360c27a864d1bdf3ed8aca00f"
  17
  18 SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
  19            file://mount.blacklist \
  20            file://run.rules \
  21            "
  22 SRC_URI += " \
  23        file://udev.rules \
  24        file://devfs-udev.rules \
  25        file://links.conf \
  26        file://permissions.rules \
  27        file://mount.sh \
  28        file://network.sh \
  29        file://local.rules \
  30        file://default \
  31        file://init \
  32        file://cache \
  33        file://udev-compat-wrapper-patch \
  34 "
  35
  36 SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
  37 PACKAGE_ARCH_h2200 = "h2200"
  38
  39 #buglabs's bug device
  40 SRC_URI_append_bug = " \
  41        file://30-BUG.rules \
  42        file://10-mx31.rules \
  43        file://bmi_eventpipe.sh "
  44
  45 SRC_URI_append_nokia900 = " \
  46        file://10-cmt_speech.rules \
  47        file://70-persistent-net.rules \
  48        file://udev-rules-nokia-n900-hacks.rules \
  49        file://udev-rules-nokia-n900-snd.rules \
  50        file://nokia-n900-mac-hack.sh \
  51 "
  52
  53 PACKAGE_ARCH_bug = "bug"
  54
  55 inherit update-rc.d autotools
  56
  57 EXTRA_OECONF += " --with-udev-prefix= \
  58                   --with-libdir-name=${base_libdir} \
  59                   --with-pci-ids-path=/usr/share/misc \
  60                   --disable-introspection \
  61                   ac_cv_file__usr_share_pci_ids=no \
  62                   ac_cv_file__usr_share_hwdata_pci_ids=no \
  63                   ac_cv_file__usr_share_misc_pci_ids=yes \
  64                   --sbindir=${base_sbindir} \
  65                   --libexecdir=${base_libdir}/udev \
  66                   --with-rootlibdir=${base_libdir} \
  67 "
  68
  69 INITSCRIPT_NAME = "udev"
  70 INITSCRIPT_PARAMS = "start 03 S ."
  71
  72 PACKAGES =+ "libudev libgudev udev-utils"
  73
  74 FILES_libudev = "${base_libdir}/libudev.so.*"
  75 FILES_libgudev = "${libdir}/libgudev*.so.*"
  76
  77 FILES_udev-utils = "${bindir}/udevinfo ${bindir}/udevtest ${base_sbindir}/udevadm"
  78
  79 RPROVIDES_${PN} = "hotplug"
  80 FILES_${PN} += "${usrbindir}/* ${usrsbindir}/udevd"
  81 FILES_${PN}-dbg += "${usrbindir}/.debug ${usrsbindir}/.debug"
  82
  83 # udev installs binaries under $(udev_prefix)/lib/udev, even if ${libdir}
  84 # is ${prefix}/lib64
  85 FILES_${PN} += "/lib/udev* ${libdir}/ConsoleKit"
  86 FILES_${PN}-dbg += "/lib/udev/.debug"
  87
  88 RPROVIDES_udev_append = " udev-compat-wrapper"
  89 RDEPENDS_udev_append_spitz = " udev-compat"
  90 do_unpack_append_spitz() {
  91         bb.build.exec_func('do_apply_compat_wrapper', d)
  92 }
  93 RDEPENDS_udev_append_akita = " udev-compat"
  94 do_unpack_append_akita() {
  95         bb.build.exec_func('do_apply_compat_wrapper', d)
  96 }
  97 RDEPENDS_udev_append_c7x0 = " udev-compat"
  98 do_unpack_append_c7x0() {
  99         bb.build.exec_func('do_apply_compat_wrapper', d)
 100 }
 101 RDEPENDS_udev_append_poodle = " udev-compat"
 102 do_unpack_append_poodle() {
 103         bb.build.exec_func('do_apply_compat_wrapper', d)
 104 }
 105 RDEPENDS_udev_append_palmpre = " udev-compat"
 106 do_unpack_append_palmpre() {
 107         bb.build.exec_func('do_apply_compat_wrapper', d)
 108 }
 109
 110 # Modify init script on platforms that need to boot old kernels:
 111 do_apply_compat_wrapper() {
 112         cd ${WORKDIR}
 113         sed -i "s:/sbin/udevd:\$UDEVD:g;s:/sbin/udevadm:\$UDEVADM:g" init
 114         patch <udev-compat-wrapper-patch
 115         cd -
 116 }
 117
 118 do_install () {
 119         install -d ${D}${usrsbindir} \
 120                    ${D}${sbindir}
 121         oe_runmake 'DESTDIR=${D}' INSTALL=install install
 122         install -d ${D}${sysconfdir}/init.d
 123         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
 124         install -m 0755 ${WORKDIR}/cache ${D}${sysconfdir}/init.d/udev-cache
 125
 126         install -d ${D}${sysconfdir}/default
 127         install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/udev
 128
 129         cp ${S}/rules/rules.d/* ${D}${sysconfdir}/udev/rules.d/
 130
 131         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
 132         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
 133         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
 134         install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
 135         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
 136         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
 137         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
 138                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
 139         fi
 140
 141         touch ${D}${sysconfdir}/udev/saved.uname
 142         touch ${D}${sysconfdir}/udev/saved.cmdline
 143         touch ${D}${sysconfdir}/udev/saved.atags
 144
 145         install -d ${D}${sysconfdir}/udev/scripts/
 146
 147         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
 148         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
 149 }
 150
 151 do_install_append_h2200() {
 152         install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
 153 }
 154
 155 do_install_append_bug() {
 156         install -m 0644 ${WORKDIR}/30-BUG.rules ${D}${sysconfdir}/udev/rules.d/30-BUG.rules
 157         install -m 0644 ${WORKDIR}/10-mx31.rules ${D}${sysconfdir}/udev/rules.d/10-mx31.rules
 158         install -m 0644 ${WORKDIR}/bmi_eventpipe.sh ${D}${sysconfdir}/udev/scripts/bmi_eventpipe.sh
 159 }
 160
 161 do_install_append_nokia900() {
 162         install -m 0644 ${WORKDIR}/10-cmt_speech.rules ${D}${sysconfdir}/udev/rules.d/10-cmt_speech.rules
 163         install -m 0644 ${WORKDIR}/70-persistent-net.rules ${D}${sysconfdir}/udev/rules.d/70-persistent-net.rules
 164         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-hacks.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-hacks.rules
 165         install -m 0644 ${WORKDIR}/udev-rules-nokia-n900-snd.rules ${D}${sysconfdir}/udev/rules.d/udev-rules-nokia-n900-snd.rules
 166         install -m 0755 ${WORKDIR}/nokia-n900-mac-hack.sh ${D}${sysconfdir}/udev/scripts/nokia-n900-mac-hack.sh
 167 }
 168
 169 # Create the cache after checkroot has run
 170 pkg_postinst_udev_append() {
 171         if test "x$D" != "x"; then
 172                 OPT="-r $D"
 173         else
 174                 OPT="-s"
 175         fi
 176         update-rc.d $OPT udev-cache start 12 S .
 177 }