recipes/freesmartphone/frameworkd_git.bb

   1 DESCRIPTION = "The reference implementation of the freesmartphone.org framework APIs"
   2 HOMEPAGE = "http://www.freesmartphone.org"
   3 AUTHOR = "FreeSmartphone.Org Development Team"
   4 SECTION = "console/network"
   5 DEPENDS = "python-cython-native python-pyrex-native"
   6 LICENSE = "GPL"
   7 SRCREV = "9ec23103c13930062ab35f0fcb31bb6f4c9b011e"
   8 PV = "0.9.5.9+gitr${SRCPV}"
   9 PR = "r3"
  10 PE = "1"
  11
  12 inherit distutils update-rc.d python-dir
  13
  14 INITSCRIPT_NAME = "frameworkd"
  15 INITSCRIPT_PARAMS = "defaults 29"
  16
  17 SRC_URI = "${FREESMARTPHONE_GIT}/framework.git;protocol=git;branch=master \
  18            file://frameworkd \
  19            file://frameworkd.conf \
  20            "
  21 SRC_URI_append_shr = "file://oeventsd-use-opimd-signals.patch;patch=1"
  22
  23 S = "${WORKDIR}/git"
  24
  25 do_configure_append() {
  26         echo "version=\"${PV}\"" >framework/__version__.py
  27 }
  28
  29 do_install_append() {
  30         install -d ${D}${sysconfdir}/init.d/
  31         install -m 0755 ${WORKDIR}/frameworkd ${D}${sysconfdir}/init.d/
  32         install -m 0644 ${WORKDIR}/frameworkd.conf ${D}${sysconfdir}
  33 }
  34
  35 pkg_postinst_${PN} () {
  36         echo "*IMPORTANT NOTICE*: There has been a change in internal opimd database structure as well as in the backend mechanism."
  37         echo "  This change is not backwards compatible so a conversion is needed, furthermore, since new opimd does not (and will not) support working with SIM, importing your SIM data is also required."
  38         echo "  In order to import SIM contacts, please use PISI."
  39         echo "  If you still have old contacts with 'tel:' prefix instead of field types (i.e you haven't upgraded since 26.1.2010) please run the 'remove-tel' script first."
  40         echo "  For the database conversion:"
  41         echo "    1) stop frameworkd '/etc/init.d/frameworkd stop'"
  42         echo "    2) use the conversion script, called: 'opimd_convert_db' which is already installed in your system"
  43         echo "    3) restart your device"
  44 }
  45
  46 RDEPENDS_${PN} += "\
  47   fsousaged \
  48 "
  49
  50 RDEPENDS_${PN} += "\
  51   python-ctypes \
  52   python-dbus \
  53   python-datetime \
  54   python-difflib \
  55   python-logging \
  56   python-pprint \
  57   python-pyalsaaudio \
  58   python-pygobject \
  59   python-pyrtc \
  60   python-pyserial \
  61   python-pyyaml \
  62   python-shell \
  63   python-subprocess \
  64   python-syslog \
  65   python-textutils \
  66   python-multiprocessing \
  67   ${PN}-config \
  68 "
  69
  70 RRECOMMENDS_${PN} += "\
  71   alsa-utils-amixer \
  72   python-gst \
  73   python-phoneutils \
  74   python-vobject \
  75   ppp \
  76 "
  77
  78 PACKAGES =+ "${PN}-config"
  79 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
  80
  81 # machine specific stuff, should ideally be elsewhere
  82 # - recommend MUXer on platforms that require one
  83 RDEPENDS_${PN}-config_append_om-gta01 = " fso-abyss"
  84 RDEPENDS_${PN}-config_append_om-gta02 = " fso-abyss"
  85 # - add wmiconfig for wireless configuration
  86 RDEPENDS_${PN}-config_append_om-gta02 = " wmiconfig"
  87
  88 FILES_${PN}-config = "\
  89   ${sysconfdir}/frameworkd.conf \
  90   ${sysconfdir}/freesmartphone \
  91   "
  92 CONFFILES_${PN}-config = "\
  93   ${sysconfdir}/frameworkd.conf \
  94   ${sysconfdir}/freesmartphone/opreferences/conf/phone/silent.yaml \
  95   ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml \
  96   ${sysconfdir}/freesmartphone/opreferences/conf/profiles/default.yaml \
  97   ${sysconfdir}/freesmartphone/opreferences/conf/rules/silent.yaml \
  98   ${sysconfdir}/freesmartphone/opreferences/conf/rules/default.yaml \
  99   ${sysconfdir}/freesmartphone/oevents/rules.yaml \
 100   ${sysconfdir}/freesmartphone/ogsmd/networks.tab \
 101   "
 102
 103 PACKAGE_ARCH_${PN} = "${BASE_PACKAGE_ARCH}"
 104 FILES_${PN} += "${sysconfdir}/dbus-1 ${sysconfdir}/freesmartphone ${sysconfdir}/init.d ${datadir}"
 105 FILES_${PN}-dbg += "${PYTHON_SITEPACKAGES_DIR}/framework/subsystems/*/.debug"