CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.4)
   4
   5 IF(COMMAND CMAKE_POLICY)
   6   CMAKE_POLICY(SET CMP0003 NEW)
   7 ENDIF(COMMAND CMAKE_POLICY)
   8
   9 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
  10
  11 INCLUDE(CheckFunctionExists)
  12 INCLUDE(CheckLibraryExists)
  13 INCLUDE(CheckSharedLibraryExists)
  14 INCLUDE(CheckIncludeFile)
  15 INCLUDE(CheckIncludeFiles)
  16 INCLUDE(CheckSymbolExists)
  17 INCLUDE(CheckCCompilerFlag)
  18 INCLUDE(CheckCSourceCompiles)
  19 INCLUDE(CheckTypeSize)
  20
  21
  22 PROJECT(OpenAL C)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 OPTION(ALSA    "Check for ALSA backend"                ON)
  29 OPTION(OSS     "Check for OSS backend"                 ON)
  30 OPTION(SOLARIS "Check for Solaris backend"             ON)
  31 OPTION(DSOUND  "Check for DirectSound backend"         ON)
  32 OPTION(WINMM   "Check for Windows Multimedia backend"  ON)
  33 OPTION(PORTAUDIO  "Check for PortAudio backend"        ON)
  34 OPTION(PULSEAUDIO "Check for PulseAudio backend"       ON)
  35
  36 OPTION(DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  37
  38 OPTION(WERROR  "Treat compile warnings as errors"      OFF)
  39
  40 OPTION(EXAMPLES  "Build example programs"              ON)
  41
  42 OPTION(ALSOFT_CONFIG "Install alsoft.conf configuration file" OFF)
  43
  44
  45 IF(WIN32)
  46     SET(LIBNAME OpenAL32)
  47     ADD_DEFINITIONS("-D_WIN32")
  48 ELSE()
  49     SET(LIBNAME openal)
  50 ENDIF()
  51
  52 SET(LIB_MAJOR_VERSION "1")
  53 SET(LIB_MINOR_VERSION "12")
  54 SET(LIB_BUILD_VERSION "854")
  55 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_BUILD_VERSION}")
  56
  57
  58 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  59 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  60 CHECK_TYPE_SIZE("unsigned int" SIZEOF_UINT)
  61 CHECK_TYPE_SIZE("void*" SIZEOF_VOIDP)
  62
  63
  64 # Add definitions, compiler switches, etc.
  65 INCLUDE_DIRECTORIES(OpenAL32/Include include "${OpenAL_BINARY_DIR}")
  66
  67 IF(NOT CMAKE_BUILD_TYPE)
  68     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  69         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  70         FORCE)
  71 ENDIF()
  72 IF(NOT CMAKE_DEBUG_POSTFIX)
  73     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  74         "Library postfix for debug builds. Normally left blank."
  75         FORCE)
  76 ENDIF()
  77
  78 IF(MSVC)
  79     # ???
  80     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
  81     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
  82     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
  83     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
  84     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
  85     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
  86
  87     IF(NOT DXSDK_DIR)
  88         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
  89     ELSE()
  90         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
  91     ENDIF()
  92     IF(DXSDK_DIR)
  93         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
  94         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
  95         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
  96         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
  97     ENDIF()
  98
  99 ELSE()
 100     ADD_DEFINITIONS(-Wall)
 101     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 102     IF(HAVE_W_EXTRA)
 103         ADD_DEFINITIONS(-Wextra)
 104     ENDIF()
 105
 106     IF(WERROR)
 107         ADD_DEFINITIONS(-Werror)
 108     ENDIF()
 109
 110     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -funroll-loops -D_DEBUG" CACHE STRING
 111         "Flags used by the compiler during Release with Debug Info builds."
 112         FORCE)
 113     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 114         "Flags used by the compiler during release minsize builds."
 115         FORCE)
 116     SET(CMAKE_C_FLAGS_RELEASE "-O2 -funroll-loops -fomit-frame-pointer -DNDEBUG" CACHE STRING
 117         "Flags used by the compiler during release builds"
 118         FORCE)
 119     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 120         "Flags used by the compiler during debug builds."
 121         FORCE)
 122
 123     # Set visibility options if available
 124     IF(NOT WIN32)
 125         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 126                                  int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 127
 128         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_SWITCH)
 129         IF(HAVE_VISIBILITY_SWITCH)
 130             CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 131                                      int main() {return 0;}" HAVE_GCC_VISIBILITY)
 132             IF(HAVE_GCC_VISIBILITY)
 133                 ADD_DEFINITIONS(-fvisibility=hidden -DHAVE_GCC_VISIBILITY)
 134             ENDIF()
 135         ENDIF()
 136     ENDIF()
 137 ENDIF()
 138
 139 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 140                          int main() {return 0;}" HAVE_GCC_FORMAT)
 141
 142 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 143 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 144
 145 CHECK_LIBRARY_EXISTS(m  powf   "" HAVE_POWF)
 146 CHECK_LIBRARY_EXISTS(m  sqrtf  "" HAVE_SQRTF)
 147 CHECK_LIBRARY_EXISTS(m  acosf  "" HAVE_ACOSF)
 148 CHECK_LIBRARY_EXISTS(m  atanf  "" HAVE_ATANF)
 149 CHECK_LIBRARY_EXISTS(m  fabsf  "" HAVE_FABSF)
 150 IF(HAVE_FENV_H)
 151     CHECK_LIBRARY_EXISTS(m  fesetround  "" HAVE_FESETROUND)
 152 ENDIF()
 153 IF(HAVE_SQRTF OR HAVE_ACOSF OR HAVE_ATANF OR HAVE_FABSF OR HAVE_FESETROUND)
 154     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 155 ENDIF()
 156 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 157 CHECK_FUNCTION_EXISTS(_controlfp HAVE__CONTROLFP)
 158
 159 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 160 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 161 IF(NOT HAVE_STRCASECMP)
 162     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 163     IF(NOT HAVE__STRICMP)
 164         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 165     ENDIF()
 166
 167     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 168 ENDIF()
 169
 170 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 171 IF(NOT HAVE_STRNCASECMP)
 172     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 173     IF(NOT HAVE__STRNICMP)
 174         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 175     ENDIF()
 176
 177     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 178 ENDIF()
 179
 180 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 181 IF(NOT HAVE_SNPRINTF)
 182     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 183     IF(NOT HAVE__SNPRINTF)
 184         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 185     ENDIF()
 186
 187     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 188 ENDIF()
 189
 190 CHECK_FUNCTION_EXISTS(vsnprintf HAVE_VSNPRINTF)
 191 IF(NOT HAVE_VSNPRINTF)
 192     CHECK_FUNCTION_EXISTS(_vsnprintf HAVE__VSNPRINTF)
 193     IF(NOT HAVE__VSNPRINTF)
 194         MESSAGE(FATAL_ERROR "No vsnprintf function found, please report!")
 195     ENDIF()
 196
 197     ADD_DEFINITIONS(-Dvsnprintf=_vsnprintf)
 198 ENDIF()
 199
 200 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 201 IF(NOT HAVE_ISNAN)
 202     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 203     IF(NOT HAVE__ISNAN)
 204         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 205     ENDIF()
 206
 207     ADD_DEFINITIONS(-Disnan=_isnan)
 208 ENDIF()
 209
 210
 211 # Check for the dlopen API (for dynamicly loading backend libs)
 212 IF(DLOPEN)
 213     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 214     IF(HAVE_DLFCN_H)
 215         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 216         IF(HAVE_LIBDL)
 217             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 218         ENDIF()
 219     ENDIF()
 220 ENDIF()
 221
 222 # Check if we have Windows headers
 223 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0500)
 224 IF(NOT HAVE_WINDOWS_H)
 225     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 226     IF(NOT HAVE_GETTIMEOFDAY)
 227         MESSAGE(FATAL_ERROR "No timing function found!")
 228     ENDIF()
 229
 230     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 231     IF(NOT HAVE_NANOSLEEP)
 232         MESSAGE(FATAL_ERROR "No sleep function found!")
 233     ENDIF()
 234
 235     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 236     IF(HAVE_PTHREAD)
 237         ADD_DEFINITIONS(-pthread)
 238         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 239     ENDIF()
 240
 241     # We need pthreads outside of Windows
 242     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 243     IF(NOT HAVE_PTHREAD_H)
 244         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 245     ENDIF()
 246     # Some systems need pthread_np.h to get recursive mutexes
 247     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 248
 249     # _GNU_SOURCE is needed on some systems for extra attributes, and
 250     # _REENTRANT is needed for libc thread-safety
 251     ADD_DEFINITIONS(-D_GNU_SOURCE=1)
 252     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 253     IF(HAVE_LIBPTHREAD)
 254         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 255     ENDIF()
 256
 257     CHECK_LIBRARY_EXISTS(pthread pthread_setschedparam "" HAVE_PTHREAD_SETSCHEDPARAM)
 258
 259     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 260     IF(HAVE_LIBRT)
 261         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 262     ENDIF()
 263 ENDIF()
 264
 265 # Check for a 64-bit type
 266 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 267 IF(NOT HAVE_STDINT_H)
 268     IF(HAVE_WINDOWS_H)
 269         CHECK_C_SOURCE_COMPILES("\#define _WIN32_WINNT 0x0500
 270                                  \#include <windows.h>
 271                                  __int64 foo;
 272                                  int main() {return 0;}" HAVE___INT64)
 273     ENDIF()
 274     IF(NOT HAVE___INT64)
 275         IF(NOT SIZEOF_LONG MATCHES "8")
 276             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 277                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 278             ENDIF()
 279         ENDIF()
 280     ENDIF()
 281 ENDIF()
 282
 283
 284 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 285                  OpenAL32/alBuffer.c
 286                  OpenAL32/alDatabuffer.c
 287                  OpenAL32/alEffect.c
 288                  OpenAL32/alError.c
 289                  OpenAL32/alExtension.c
 290                  OpenAL32/alFilter.c
 291                  OpenAL32/alListener.c
 292                  OpenAL32/alSource.c
 293                  OpenAL32/alState.c
 294                  OpenAL32/alThunk.c
 295 )
 296 SET(ALC_OBJS  Alc/ALc.c
 297               Alc/ALu.c
 298               Alc/alcConfig.c
 299               Alc/alcEcho.c
 300               Alc/alcModulator.c
 301               Alc/alcReverb.c
 302               Alc/alcRing.c
 303               Alc/alcThread.c
 304               Alc/bs2b.c
 305               Alc/wave.c
 306 )
 307
 308 SET(BACKENDS "")
 309
 310 # Check ALSA backend
 311 IF(ALSA)
 312     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 313     IF(HAVE_ALSA_ASOUNDLIB_H)
 314         CHECK_SHARED_LIBRARY_EXISTS(asound snd_pcm_open 4 "" HAVE_LIBASOUND)
 315         IF(HAVE_LIBASOUND OR HAVE_DLFCN_H OR WIN32)
 316             SET(HAVE_ALSA 1)
 317             SET(ALC_OBJS  ${ALC_OBJS} Alc/alsa.c)
 318             IF(HAVE_DLFCN_H OR WIN32)
 319                 SET(BACKENDS  "${BACKENDS} ALSA,")
 320             ELSE()
 321                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 322                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 323             ENDIF()
 324         ENDIF()
 325     ENDIF()
 326 ENDIF()
 327
 328 # Check OSS backend
 329 IF(OSS)
 330     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 331     IF(HAVE_SYS_SOUNDCARD_H)
 332         SET(HAVE_OSS 1)
 333         SET(ALC_OBJS  ${ALC_OBJS} Alc/oss.c)
 334         SET(BACKENDS  "${BACKENDS} OSS,")
 335     ENDIF()
 336 ENDIF()
 337
 338 # Check Solaris backend
 339 IF(SOLARIS)
 340     CHECK_INCLUDE_FILE(sys/audioio.h HAVE_SYS_AUDIOIO_H)
 341     IF(HAVE_SYS_AUDIOIO_H)
 342         SET(HAVE_SOLARIS 1)
 343         SET(ALC_OBJS  ${ALC_OBJS} Alc/solaris.c)
 344         SET(BACKENDS  "${BACKENDS} Solaris,")
 345     ENDIF()
 346 ENDIF()
 347
 348 # Check DSound/MMSystem backend
 349 IF(DSOUND)
 350     CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 351     IF(HAVE_DSOUND_H)
 352         CHECK_SHARED_LIBRARY_EXISTS(dsound DirectSoundCreate 3 "" HAVE_LIBDSOUND)
 353         IF(HAVE_LIBDSOUND OR HAVE_DLFCN_H OR WIN32)
 354             SET(HAVE_DSOUND 1)
 355             SET(ALC_OBJS  ${ALC_OBJS} Alc/dsound.c)
 356
 357             IF(HAVE_DLFCN_H OR WIN32)
 358                 SET(BACKENDS  "${BACKENDS} DirectSound,")
 359             ELSE()
 360                 SET(BACKENDS  "${BACKENDS} DirectSound \(linked\),")
 361                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 362             ENDIF()
 363         ENDIF()
 364     ENDIF()
 365 ENDIF()
 366 IF(HAVE_WINDOWS_H)
 367     IF(WINMM)
 368         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0500)
 369         IF(HAVE_MMSYSTEM_H)
 370             CHECK_SHARED_LIBRARY_EXISTS(winmm waveInOpen 6 "" HAVE_LIBWINMM)
 371             IF(HAVE_LIBWINMM)
 372                 SET(HAVE_WINMM 1)
 373                 SET(ALC_OBJS  ${ALC_OBJS} Alc/winmm.c)
 374                 SET(BACKENDS  "${BACKENDS} WinMM,")
 375
 376                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 377             ENDIF()
 378         ENDIF()
 379     ENDIF()
 380 ENDIF()
 381
 382 # Check PortAudio backend
 383 IF(PORTAUDIO)
 384     CHECK_INCLUDE_FILE(portaudio.h HAVE_PORTAUDIO_H)
 385     IF(HAVE_PORTAUDIO_H)
 386         CHECK_SHARED_LIBRARY_EXISTS(portaudio Pa_Initialize 0 "" HAVE_LIBPORTAUDIO)
 387         IF(HAVE_LIBPORTAUDIO OR HAVE_DLFCN_H OR WIN32)
 388             SET(HAVE_PORTAUDIO 1)
 389             SET(ALC_OBJS  ${ALC_OBJS} Alc/portaudio.c)
 390             IF(HAVE_DLFCN_H OR WIN32)
 391                 SET(BACKENDS  "${BACKENDS} PortAudio,")
 392             ELSE()
 393                 SET(BACKENDS  "${BACKENDS} PortAudio \(linked\),")
 394                 SET(EXTRA_LIBS portaudio ${EXTRA_LIBS})
 395             ENDIF()
 396         ENDIF()
 397     ENDIF()
 398 ENDIF()
 399
 400 # Check PortAudio backend
 401 IF(PULSEAUDIO)
 402     CHECK_INCLUDE_FILE(pulse/pulseaudio.h HAVE_PULSE_PULSEAUDIO_H)
 403     IF(HAVE_PULSE_PULSEAUDIO_H)
 404         CHECK_SHARED_LIBRARY_EXISTS(pulse pa_context_new 2 "" HAVE_LIBPULSE)
 405         IF(HAVE_LIBPULSE OR HAVE_DLFCN_H OR WIN32)
 406             SET(HAVE_PULSEAUDIO 1)
 407             SET(ALC_OBJS  ${ALC_OBJS} Alc/pulseaudio.c)
 408             IF(HAVE_DLFCN_H OR WIN32)
 409                 SET(BACKENDS  "${BACKENDS} PulseAudio,")
 410             ELSE()
 411                 SET(BACKENDS  "${BACKENDS} PulseAudio \(linked\),")
 412                 SET(EXTRA_LIBS pulse ${EXTRA_LIBS})
 413             ENDIF()
 414         ENDIF()
 415     ENDIF()
 416 ENDIF()
 417
 418 # This is always available
 419 SET(BACKENDS  "${BACKENDS} WaveFile")
 420
 421 # Needed for openal.pc.in
 422 SET(prefix ${CMAKE_INSTALL_PREFIX})
 423 SET(exec_prefix "\${prefix}")
 424 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 425 SET(bindir "\${exec_prefix}/bin")
 426 SET(includedir "\${prefix}/include")
 427 SET(PACKAGE_VERSION "${LIB_VERSION}")
 428
 429 # End configuration
 430 CONFIGURE_FILE(
 431     "${OpenAL_SOURCE_DIR}/config.h.in"
 432     "${OpenAL_BINARY_DIR}/config.h")
 433 CONFIGURE_FILE(
 434     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 435     "${OpenAL_BINARY_DIR}/openal.pc"
 436     @ONLY)
 437
 438 # Build a library
 439 IF(NOT LIBTYPE)
 440     SET(LIBTYPE SHARED)
 441 ENDIF()
 442 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 443 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES DEFINE_SYMBOL AL_BUILD_LIBRARY
 444                                             COMPILE_FLAGS -DAL_ALEXT_PROTOTYPES
 445                                             VERSION ${LIB_VERSION}
 446                                             SOVERSION ${LIB_MAJOR_VERSION})
 447 IF(WIN32)
 448     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 449 ENDIF()
 450
 451 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 452
 453 # Add an install target here
 454 INSTALL(TARGETS ${LIBNAME}
 455         RUNTIME DESTINATION bin
 456         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 457         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 458 )
 459 INSTALL(FILES include/AL/al.h
 460               include/AL/alc.h
 461               include/AL/alext.h
 462               include/AL/efx.h
 463         DESTINATION include/AL
 464 )
 465 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 466         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 467
 468 # Install alsoft.conf configuration file
 469 IF(ALSOFT_CONFIG)
 470     INSTALL(FILES alsoftrc.sample
 471             DESTINATION /etc/openal
 472             RENAME alsoft.conf
 473     )
 474 ENDIF()
 475
 476 IF(EXAMPLES)
 477     ADD_EXECUTABLE(openal-info examples/openal-info.c)
 478     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
 479     INSTALL(TARGETS openal-info
 480             RUNTIME DESTINATION bin
 481             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 482             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 483     )
 484 ENDIF()
 485
 486 MESSAGE(STATUS "")
 487 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 488 MESSAGE(STATUS "    ${BACKENDS}")
 489 MESSAGE(STATUS "")
 490
 491 IF(WIN32)
 492     IF(NOT HAVE_DSOUND)
 493         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 494         MESSAGE(STATUS "         This is probably NOT what you want!")
 495         MESSAGE(STATUS "")
 496     ENDIF()
 497 ENDIF()