CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 IF(WIN32)
  29     # This option is mainly for static linking OpenAL Soft into another project
  30     # that already defines the IDs. It is up to that project to ensure all
  31     # required IDs are defined.
  32     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  33 ELSE()
  34     # These are needed on non-Windows systems for extra features
  35     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
  36     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
  37 ENDIF()
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48
  49 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  50 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  51
  52
  53 IF(WIN32)
  54     SET(LIBNAME OpenAL32)
  55     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  56 ELSE()
  57     SET(LIBNAME openal)
  58 ENDIF()
  59
  60 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  61 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  62     ADD_DEFINITIONS("-I/usr/include")
  63     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  64 ENDIF()
  65
  66 IF(NOT LIBTYPE)
  67     SET(LIBTYPE SHARED)
  68 ENDIF()
  69
  70 SET(LIB_MAJOR_VERSION "1")
  71 SET(LIB_MINOR_VERSION "15")
  72 SET(LIB_REVISION "1")
  73 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  74
  75 SET(EXPORT_DECL "")
  76 SET(ALIGN_DECL "")
  77
  78
  79 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  80 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  81
  82
  83 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
  84 IF(HAVE_STD_C99)
  85     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
  86 ENDIF()
  87
  88 # MSVC may need workarounds for C99 restrict and inline
  89 IF(MSVC)
  90     # TODO: Once we truly require C99, these restrict and inline checks should go
  91     # away.
  92     CHECK_C_SOURCE_COMPILES("int *restrict foo;
  93                              int main() {return 0;}" HAVE_RESTRICT)
  94     IF(NOT HAVE_RESTRICT)
  95         ADD_DEFINITIONS("-Drestrict=")
  96         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
  97     ENDIF()
  98
  99     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 100                              int main() {return 0;}" HAVE_INLINE)
 101     IF(NOT HAVE_INLINE)
 102         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 103                                  int main() {return 0;}" HAVE___INLINE)
 104         IF(NOT HAVE___INLINE)
 105             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 106         ENDIF()
 107
 108         ADD_DEFINITIONS(-Dinline=__inline)
 109         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 110     ENDIF()
 111 ENDIF()
 112
 113 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 114 IF(CMAKE_COMPILER_IS_GNUCC)
 115     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 116     # Force no inlining for the next test.
 117     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 118
 119     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 120                              int main() {return foo();}" INLINE_IS_C99)
 121     IF(NOT INLINE_IS_C99)
 122         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 123                              Please update your compiler for better C99 compliance.")
 124     ENDIF()
 125
 126     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 127 ENDIF()
 128
 129 # Check if we have C99 variable length arrays
 130 CHECK_C_SOURCE_COMPILES(
 131 "int main(int argc, char *argv[])
 132  {
 133      volatile int tmp[argc];
 134      tmp[0] = argv[0][0];
 135      return tmp[0];
 136  }"
 137 HAVE_C99_VLA)
 138
 139 # Check if we have C11 static_assert
 140 CHECK_C_SOURCE_COMPILES(
 141 "int main()
 142  {
 143      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 144      return 0;
 145  }"
 146 HAVE_C11_STATIC_ASSERT)
 147
 148 # Check if we have C11 alignas
 149 CHECK_C_SOURCE_COMPILES(
 150 "_Alignas(4) int foo;
 151  int main()
 152  {
 153      return 0;
 154  }"
 155 HAVE_C11_ALIGNAS)
 156
 157 # Add definitions, compiler switches, etc.
 158 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 159 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 160     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 161     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 162         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 163     ENDIF()
 164 ENDIF()
 165
 166 IF(NOT CMAKE_BUILD_TYPE)
 167     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 168         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 169         FORCE)
 170 ENDIF()
 171 IF(NOT CMAKE_DEBUG_POSTFIX)
 172     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 173         "Library postfix for debug builds. Normally left blank."
 174         FORCE)
 175 ENDIF()
 176
 177 IF(MSVC)
 178     # ???
 179     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 180     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 181     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 182     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 183     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 184     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 185     ADD_DEFINITIONS("/wd4098")
 186
 187     IF(NOT DXSDK_DIR)
 188         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 189     ELSE()
 190         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 191     ENDIF()
 192     IF(DXSDK_DIR)
 193         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 194         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 195         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 196         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 197     ENDIF()
 198
 199     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 200     IF(FORCE_STATIC_VCRT)
 201         FOREACH(flag_var
 202                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 203                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 204             IF(${flag_var} MATCHES "/MD")
 205                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 206             ENDIF()
 207         ENDFOREACH(flag_var)
 208     ENDIF()
 209 ELSE()
 210     ADD_DEFINITIONS(-Winline -Wall)
 211     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 212     IF(HAVE_W_EXTRA)
 213         ADD_DEFINITIONS(-Wextra)
 214     ENDIF()
 215
 216     IF(ALSOFT_WERROR)
 217         ADD_DEFINITIONS(-Werror)
 218     ENDIF()
 219
 220     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 221         "Flags used by the compiler during Release with Debug Info builds."
 222         FORCE)
 223     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 224         "Flags used by the compiler during release minsize builds."
 225         FORCE)
 226     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 227         "Flags used by the compiler during release builds"
 228         FORCE)
 229     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 230         "Flags used by the compiler during debug builds."
 231         FORCE)
 232
 233     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 234                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 235 ENDIF()
 236
 237 # Set visibility/export options if available
 238 IF(WIN32)
 239     SET(EXPORT_DECL "__declspec(dllexport)")
 240     IF(NOT MINGW)
 241         SET(ALIGN_DECL "__declspec(align(x))")
 242     ELSE()
 243         SET(ALIGN_DECL "__declspec(aligned(x))")
 244     ENDIF()
 245 ELSE()
 246     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 247     # Yes GCC, really don't accept visibility modes you don't support
 248     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 249
 250     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 251                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 252     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 253         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 254     ELSE()
 255         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 256                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 257         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 258             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 259         ENDIF()
 260     ENDIF()
 261
 262     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 263         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 264         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 265             ADD_DEFINITIONS(-fvisibility=internal)
 266         ELSE()
 267             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 268             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 269                 ADD_DEFINITIONS(-fvisibility=hidden)
 270             ENDIF()
 271         ENDIF()
 272     ENDIF()
 273
 274     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 275                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 276     IF(HAVE_ATTRIBUTE_ALIGNED)
 277         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 278     ENDIF()
 279
 280     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 281 ENDIF()
 282
 283 SET(SSE_SWITCH "")
 284 IF(MSVC)
 285     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 286     IF(HAVE_ARCHSSE_SWITCH)
 287         SET(SSE_SWITCH "/arch:SSE")
 288     ENDIF()
 289 ENDIF()
 290 IF(NOT SSE_SWITCH)
 291     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 292     IF(HAVE_MSSE_SWITCH)
 293         SET(SSE_SWITCH "-msse")
 294     ENDIF()
 295 ENDIF()
 296
 297 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 298                          int main() {return 0;}" HAVE_GCC_FORMAT)
 299
 300 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 301 IF(NOT HAVE_C99_VLA)
 302     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 303 ENDIF()
 304 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 305 CHECK_INCLUDE_FILE(ftw.h HAVE_FTW_H)
 306 CHECK_INCLUDE_FILE(io.h HAVE_IO_H)
 307 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 308 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 309 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 310 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 311 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 312 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 313 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 314 IF(NOT HAVE_GUIDDEF_H)
 315     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 316 ENDIF()
 317
 318 # Some systems need libm for some of the following math functions to work
 319 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 320 IF(HAVE_LIBM)
 321     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 322     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 323 ENDIF()
 324
 325
 326 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 327 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 328 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 329 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 330 IF(NOT HAVE_C99_VLA)
 331     IF(HAVE_ALLOCA_H)
 332         CHECK_SYMBOL_EXISTS(alloca alloca.h HAVE_ALLOCA)
 333     ELSEIF(HAVE_MALLOC_H)
 334         CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 335     ENDIF()
 336     IF(NOT HAVE_ALLOCA)
 337         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 338     ENDIF()
 339 ENDIF()
 340
 341 IF(HAVE_FLOAT_H)
 342     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 343     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 344 ENDIF()
 345 IF(HAVE_FTW_H)
 346     CHECK_SYMBOL_EXISTS(ftw ftw.h HAVE_FTW)
 347 ENDIF()
 348 IF(HAVE_IO_H)
 349     CHECK_SYMBOL_EXISTS(_wfindfirst io.h HAVE__WFINDFIRST)
 350 ENDIF()
 351
 352 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 353 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 354 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 355 IF(NOT HAVE_STRCASECMP)
 356     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 357     IF(NOT HAVE__STRICMP)
 358         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 359     ENDIF()
 360
 361     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 362 ENDIF()
 363
 364 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 365 IF(NOT HAVE_STRNCASECMP)
 366     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 367     IF(NOT HAVE__STRNICMP)
 368         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 369     ENDIF()
 370
 371     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 372 ENDIF()
 373
 374 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 375 IF(NOT HAVE_SNPRINTF)
 376     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 377     IF(NOT HAVE__SNPRINTF)
 378         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 379     ENDIF()
 380
 381     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 382 ENDIF()
 383
 384 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 385 IF(NOT HAVE_ISFINITE)
 386     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 387     IF(NOT HAVE_FINITE)
 388         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 389         IF(NOT HAVE__FINITE)
 390             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 391         ENDIF()
 392         ADD_DEFINITIONS(-Disfinite=_finite)
 393     ELSE()
 394         ADD_DEFINITIONS(-Disfinite=finite)
 395     ENDIF()
 396 ENDIF()
 397
 398 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 399 IF(NOT HAVE_ISNAN)
 400     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 401     IF(NOT HAVE__ISNAN)
 402         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 403     ENDIF()
 404
 405     ADD_DEFINITIONS(-Disnan=_isnan)
 406 ENDIF()
 407
 408
 409 # Check for the dlopen API (for dynamicly loading backend libs)
 410 IF(ALSOFT_DLOPEN)
 411     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 412     IF(HAVE_DLFCN_H)
 413         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 414         IF(HAVE_LIBDL)
 415             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 416         ENDIF()
 417     ENDIF()
 418 ENDIF()
 419
 420 # Check if we have Windows headers
 421 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 422 IF(NOT HAVE_WINDOWS_H)
 423     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 424     IF(NOT HAVE_GETTIMEOFDAY)
 425         MESSAGE(FATAL_ERROR "No timing function found!")
 426     ENDIF()
 427
 428     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 429     IF(NOT HAVE_NANOSLEEP)
 430         MESSAGE(FATAL_ERROR "No sleep function found!")
 431     ENDIF()
 432
 433     # We need pthreads outside of Windows
 434     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 435     IF(NOT HAVE_PTHREAD_H)
 436         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 437     ENDIF()
 438     # Some systems need pthread_np.h to get recursive mutexes
 439     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 440
 441     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 442     IF(HAVE_PTHREAD)
 443         ADD_DEFINITIONS(-pthread)
 444         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 445         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 446     ENDIF()
 447
 448     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 449     IF(HAVE_LIBPTHREAD)
 450         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 451     ENDIF()
 452
 453     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 454
 455     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 456     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 457         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 458     ENDIF()
 459     IF(HAVE_PTHREAD_NP_H)
 460         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 461     ENDIF()
 462
 463     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 464
 465     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 466     IF(HAVE_LIBRT)
 467         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 468     ENDIF()
 469 ENDIF()
 470
 471 # Check for a 64-bit type
 472 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 473 IF(NOT HAVE_STDINT_H)
 474     IF(HAVE_WINDOWS_H)
 475         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 476                                  #include <windows.h>
 477                                  __int64 foo;
 478                                  int main() {return 0;}" HAVE___INT64)
 479     ENDIF()
 480     IF(NOT HAVE___INT64)
 481         IF(NOT SIZEOF_LONG MATCHES "8")
 482             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 483                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 484             ENDIF()
 485         ENDIF()
 486     ENDIF()
 487 ENDIF()
 488
 489
 490 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 491                  OpenAL32/alBuffer.c
 492                  OpenAL32/alEffect.c
 493                  OpenAL32/alError.c
 494                  OpenAL32/alExtension.c
 495                  OpenAL32/alFilter.c
 496                  OpenAL32/alFontsound.c
 497                  OpenAL32/alListener.c
 498                  OpenAL32/alMidi.c
 499                  OpenAL32/alPreset.c
 500                  OpenAL32/alSoundfont.c
 501                  OpenAL32/alSource.c
 502                  OpenAL32/alState.c
 503                  OpenAL32/alThunk.c
 504                  OpenAL32/sample_cvt.c
 505 )
 506 SET(ALC_OBJS  Alc/ALc.c
 507               Alc/ALu.c
 508               Alc/alcConfig.c
 509               Alc/alcRing.c
 510               Alc/bs2b.c
 511               Alc/effects/autowah.c
 512               Alc/effects/chorus.c
 513               Alc/effects/compressor.c
 514               Alc/effects/dedicated.c
 515               Alc/effects/distortion.c
 516               Alc/effects/echo.c
 517               Alc/effects/equalizer.c
 518               Alc/effects/flanger.c
 519               Alc/effects/modulator.c
 520               Alc/effects/null.c
 521               Alc/effects/reverb.c
 522               Alc/helpers.c
 523               Alc/hrtf.c
 524               Alc/panning.c
 525               Alc/threads.c
 526               Alc/mixer.c
 527               Alc/mixer_c.c
 528 )
 529
 530
 531 SET(CPU_EXTS "Default")
 532 SET(HAVE_SSE  0)
 533 SET(HAVE_NEON 0)
 534
 535 # Check for SSE support
 536 OPTION(ALSOFT_REQUIRE_SSE "Require SSE/SSE2 support" OFF)
 537 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 538 IF(HAVE_XMMINTRIN_H)
 539     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE/SSE2 support" ON)
 540     IF(ALSOFT_CPUEXT_SSE AND ALIGN_DECL)
 541         SET(HAVE_SSE 1)
 542         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 543         IF(SSE_SWITCH)
 544             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 545                                         COMPILE_FLAGS "${SSE_SWITCH}")
 546         ENDIF()
 547         SET(CPU_EXTS "${CPU_EXTS}, SSE")
 548     ENDIF()
 549 ENDIF()
 550 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 551     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 552 ENDIF()
 553
 554 # Check for ARM Neon support
 555 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 556 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 557 IF(HAVE_ARM_NEON_H)
 558     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 559     IF(ALSOFT_CPUEXT_NEON)
 560         SET(HAVE_NEON 1)
 561         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 562         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 563     ENDIF()
 564 ENDIF()
 565 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 566     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 567 ENDIF()
 568
 569
 570 SET(ALC_OBJS  ${ALC_OBJS}
 571               Alc/midi/base.c
 572               Alc/midi/sf2load.c
 573               Alc/midi/dummy.c
 574               Alc/midi/fluidsynth.c
 575               Alc/midi/soft.c
 576 )
 577
 578 SET(HAVE_FLUIDSYNTH  0)
 579
 580 # Check for FluidSynth support
 581 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI" OFF)
 582 FIND_PACKAGE(FluidSynth)
 583 IF(FLUIDSYNTH_FOUND)
 584     OPTION(ALSOFT_MIDI_FLUIDSYNTH "Enable FluidSynth MIDI" ON)
 585     IF(ALSOFT_MIDI_FLUIDSYNTH)
 586         SET(HAVE_FLUIDSYNTH 1)
 587         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 588             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 589         ENDIF()
 590         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 591     ENDIF()
 592 ENDIF()
 593 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 594     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 595 ENDIF()
 596
 597
 598 SET(ALC_OBJS  ${ALC_OBJS}
 599               Alc/backends/base.c
 600               # Default backends, always available
 601               Alc/backends/loopback.c
 602               Alc/backends/null.c
 603 )
 604
 605 SET(BACKENDS "")
 606 SET(HAVE_ALSA       0)
 607 SET(HAVE_OSS        0)
 608 SET(HAVE_SOLARIS    0)
 609 SET(HAVE_SNDIO      0)
 610 SET(HAVE_QSA        0)
 611 SET(HAVE_DSOUND     0)
 612 SET(HAVE_MMDEVAPI   0)
 613 SET(HAVE_WINMM      0)
 614 SET(HAVE_PORTAUDIO  0)
 615 SET(HAVE_PULSEAUDIO 0)
 616 SET(HAVE_COREAUDIO  0)
 617 SET(HAVE_OPENSL     0)
 618 SET(HAVE_WAVE       0)
 619 IF(WIN32 OR HAVE_DLFCN_H)
 620     SET(IS_LINKED "")
 621     MACRO(ADD_BACKEND_LIBS _LIBS)
 622     ENDMACRO()
 623 ELSE()
 624     SET(IS_LINKED " (linked)")
 625     MACRO(ADD_BACKEND_LIBS _LIBS)
 626         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 627     ENDMACRO()
 628 ENDIF()
 629
 630 # Check ALSA backend
 631 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 632 FIND_PACKAGE(ALSA)
 633 IF(ALSA_FOUND)
 634     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 635     IF(ALSOFT_BACKEND_ALSA)
 636         SET(HAVE_ALSA 1)
 637         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 638         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 639         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 640         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 641             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 642         ENDIF()
 643     ENDIF()
 644 ENDIF()
 645 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 646     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 647 ENDIF()
 648
 649 # Check OSS backend
 650 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 651 FIND_PACKAGE(OSS)
 652 IF(OSS_FOUND)
 653     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 654     IF(ALSOFT_BACKEND_OSS)
 655         SET(HAVE_OSS 1)
 656         SET(BACKENDS  "${BACKENDS} OSS,")
 657         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 658         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 659             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 660         ENDIF()
 661     ENDIF()
 662 ENDIF()
 663 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 664     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 665 ENDIF()
 666
 667 # Check Solaris backend
 668 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 669 FIND_PACKAGE(AudioIO)
 670 IF(AUDIOIO_FOUND)
 671     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 672     IF(ALSOFT_BACKEND_SOLARIS)
 673         SET(HAVE_SOLARIS 1)
 674         SET(BACKENDS  "${BACKENDS} Solaris,")
 675         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 676         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 677             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 678         ENDIF()
 679     ENDIF()
 680 ENDIF()
 681 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 682     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 683 ENDIF()
 684
 685 # Check SndIO backend
 686 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 687 FIND_PACKAGE(SoundIO)
 688 IF(SOUNDIO_FOUND)
 689     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 690     IF(ALSOFT_BACKEND_SNDIO)
 691         SET(HAVE_SNDIO 1)
 692         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 693         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 694         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 695         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 696             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 697         ENDIF()
 698     ENDIF()
 699 ENDIF()
 700 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 701     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 702 ENDIF()
 703
 704 # Check QSA backend
 705 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 706 FIND_PACKAGE(QSA)
 707 IF(QSA_FOUND)
 708     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 709     IF(ALSOFT_BACKEND_QSA)
 710         SET(HAVE_QSA 1)
 711         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 712         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 713         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 714         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 715             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 716         ENDIF()
 717     ENDIF()
 718 ENDIF()
 719 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 720     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 721 ENDIF()
 722
 723 # Check DSound backend
 724 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 725 FIND_PACKAGE(DSound)
 726 IF(DSOUND_FOUND)
 727     OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 728     IF(ALSOFT_BACKEND_DSOUND)
 729         SET(HAVE_DSOUND 1)
 730         SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 731         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 732         ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 733         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 734             INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 735         ENDIF()
 736     ENDIF()
 737 ENDIF()
 738 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 739     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 740 ENDIF()
 741
 742 # Check for MMDevApi backend
 743 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 744 IF(HAVE_WINDOWS_H)
 745     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 746     IF(HAVE_MMDEVICEAPI_H)
 747         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 748         IF(ALSOFT_BACKEND_MMDEVAPI)
 749             SET(HAVE_MMDEVAPI 1)
 750             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 751             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 752         ENDIF()
 753     ENDIF()
 754 ENDIF()
 755 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 756     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 757 ENDIF()
 758
 759 # Check MMSystem backend
 760 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 761 IF(HAVE_WINDOWS_H)
 762     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 763     IF(HAVE_MMSYSTEM_H)
 764         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 765         IF(HAVE_LIBWINMM)
 766             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 767             IF(ALSOFT_BACKEND_WINMM)
 768                 SET(HAVE_WINMM 1)
 769                 SET(BACKENDS  "${BACKENDS} WinMM,")
 770                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 771                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 772             ENDIF()
 773         ENDIF()
 774     ENDIF()
 775 ENDIF()
 776 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 777     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 778 ENDIF()
 779
 780 # Check PortAudio backend
 781 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 782 FIND_PACKAGE(PortAudio)
 783 IF(PORTAUDIO_FOUND)
 784     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 785     IF(ALSOFT_BACKEND_PORTAUDIO)
 786         SET(HAVE_PORTAUDIO 1)
 787         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 788         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 789         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 790         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 791             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 792         ENDIF()
 793     ENDIF()
 794 ENDIF()
 795 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 796     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 797 ENDIF()
 798
 799 # Check PulseAudio backend
 800 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 801 FIND_PACKAGE(PulseAudio)
 802 IF(PULSEAUDIO_FOUND)
 803     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 804     IF(ALSOFT_BACKEND_PULSEAUDIO)
 805         SET(HAVE_PULSEAUDIO 1)
 806         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 807         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 808         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
 809         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 810             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
 811         ENDIF()
 812     ENDIF()
 813 ENDIF()
 814 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 815     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 816 ENDIF()
 817
 818 # Check CoreAudio backend
 819 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 820 FIND_LIBRARY(COREAUDIO_FRAMEWORK
 821              NAMES CoreAudio
 822              PATHS /System/Library/Frameworks
 823 )
 824 IF(COREAUDIO_FRAMEWORK)
 825     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 826     IF(ALSOFT_BACKEND_COREAUDIO)
 827         SET(HAVE_COREAUDIO 1)
 828         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 829         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 830         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
 831         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 832         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 833
 834         # Some versions of OSX may need the AudioToolbox framework. Add it if
 835         # it's found.
 836         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 837                      NAMES AudioToolbox
 838                      PATHS ~/Library/Frameworks
 839                            /Library/Frameworks
 840                            /System/Library/Frameworks
 841                     )
 842         IF(AUDIOTOOLBOX_LIBRARY)
 843             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 844         ENDIF()
 845     ENDIF()
 846 ENDIF()
 847 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 848     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 849 ENDIF()
 850
 851 # Check for OpenSL (Android) backend
 852 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
 853 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 854 IF(HAVE_SLES_OPENSLES_ANDROID_H)
 855     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 856     IF(HAVE_LIBOPENSLES)
 857         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
 858         IF(ALSOFT_BACKEND_OPENSL)
 859             SET(HAVE_OPENSL 1)
 860             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 861             SET(BACKENDS  "${BACKENDS} OpenSL,")
 862             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 863         ENDIF()
 864     ENDIF()
 865 ENDIF()
 866 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 867     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 868 ENDIF()
 869
 870 # Optionally enable the Wave Writer backend
 871 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
 872 IF(ALSOFT_BACKEND_WAVE)
 873     SET(HAVE_WAVE 1)
 874     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 875     SET(BACKENDS  "${BACKENDS} WaveFile,")
 876 ENDIF()
 877
 878 # This is always available
 879 SET(BACKENDS  "${BACKENDS} Null")
 880
 881 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 882     add_subdirectory(utils/alsoft-config)
 883 ENDIF()
 884 IF(ALSOFT_EXAMPLES)
 885     FIND_PACKAGE(SDL)
 886     IF(SDL_FOUND)
 887         FIND_PACKAGE(SDL_sound)
 888         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 889             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 890         ENDIF()
 891     ENDIF()
 892 ENDIF()
 893
 894 IF(LIBTYPE STREQUAL "STATIC")
 895     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 896     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 897 ENDIF()
 898
 899 # Needed for openal.pc.in
 900 SET(prefix ${CMAKE_INSTALL_PREFIX})
 901 SET(exec_prefix "\${prefix}")
 902 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 903 SET(bindir "\${exec_prefix}/bin")
 904 SET(includedir "\${prefix}/include")
 905 SET(PACKAGE_VERSION "${LIB_VERSION}")
 906
 907 # End configuration
 908 CONFIGURE_FILE(
 909     "${OpenAL_SOURCE_DIR}/config.h.in"
 910     "${OpenAL_BINARY_DIR}/config.h")
 911 CONFIGURE_FILE(
 912     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 913     "${OpenAL_BINARY_DIR}/openal.pc"
 914     @ONLY)
 915
 916 # Build a library
 917 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 918 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 919 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 920     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 921 ENDIF()
 922 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 923 IF(FLUIDSYNTH_FOUND)
 924     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 925 ENDIF()
 926 IF(HAVE_ALSA)
 927     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
 928 ENDIF()
 929 IF(HAVE_OSS)
 930     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
 931 ENDIF()
 932 IF(HAVE_SOLARIS)
 933     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
 934 ENDIF()
 935 IF(HAVE_SNDIO)
 936     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
 937 ENDIF()
 938 IF(HAVE_QSA)
 939     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
 940 ENDIF()
 941 IF(HAVE_DSOUND)
 942     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
 943 ENDIF()
 944 IF(HAVE_PORTAUDIO)
 945     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
 946 ENDIF()
 947 IF(HAVE_PULSEAUDIO)
 948     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
 949 ENDIF()
 950 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 951                                             SOVERSION ${LIB_MAJOR_VERSION})
 952 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 953     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 954 ENDIF()
 955
 956 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 957
 958 # Add an install target here
 959 INSTALL(TARGETS ${LIBNAME}
 960         RUNTIME DESTINATION bin
 961         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 962         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 963 )
 964 INSTALL(FILES include/AL/al.h
 965               include/AL/alc.h
 966               include/AL/alext.h
 967               include/AL/efx.h
 968               include/AL/efx-creative.h
 969               include/AL/efx-presets.h
 970         DESTINATION include/AL
 971 )
 972 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 973         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 974
 975
 976 MESSAGE(STATUS "")
 977 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 978 MESSAGE(STATUS "    ${BACKENDS}")
 979 MESSAGE(STATUS "")
 980 MESSAGE(STATUS "Building with support for CPU extensions:")
 981 MESSAGE(STATUS "    ${CPU_EXTS}")
 982 MESSAGE(STATUS "")
 983 IF(HAVE_FLUIDSYNTH)
 984     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
 985     MESSAGE(STATUS "")
 986 ENDIF()
 987
 988 IF(WIN32)
 989     IF(NOT HAVE_DSOUND)
 990         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
 991         MESSAGE(STATUS "         This is probably NOT what you want!")
 992         MESSAGE(STATUS "")
 993     ENDIF()
 994 ENDIF()
 995
 996 # Install alsoft.conf configuration file
 997 IF(ALSOFT_CONFIG)
 998     INSTALL(FILES alsoftrc.sample
 999             DESTINATION share/openal
1000     )
1001     MESSAGE(STATUS "Installing sample configuration")
1002     MESSAGE(STATUS "")
1003 ENDIF()
1004
1005 # Install HRTF definitions
1006 IF(ALSOFT_HRTF_DEFS)
1007     INSTALL(FILES hrtf/default-44100.mhr
1008             DESTINATION share/openal/hrtf
1009     )
1010     MESSAGE(STATUS "Installing HRTF definitions")
1011     MESSAGE(STATUS "")
1012 ENDIF()
1013
1014 IF(ALSOFT_UTILS)
1015     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1016     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1017
1018     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1019     IF(HAVE_LIBM)
1020         TARGET_LINK_LIBRARIES(makehrtf m)
1021     ENDIF()
1022
1023     INSTALL(TARGETS openal-info makehrtf
1024             RUNTIME DESTINATION bin
1025             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1026             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1027     )
1028
1029     MESSAGE(STATUS "Building utility programs")
1030     IF(TARGET alsoft-config)
1031         MESSAGE(STATUS "Building configuration program")
1032     ENDIF()
1033     MESSAGE(STATUS "")
1034 ENDIF()
1035
1036 IF(ALSOFT_EXAMPLES)
1037     IF(SDL_FOUND AND SDL_SOUND_FOUND)
1038         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1039                                      examples/common/sdl_sound.c)
1040         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1041
1042         ADD_EXECUTABLE(alstream examples/alstream.c)
1043         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1044         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1045
1046         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1047         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1048         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1049
1050         ADD_EXECUTABLE(allatency examples/allatency.c)
1051         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1052         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1053
1054         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1055         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
1056         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
1057                                                                            ${SDL_SOUND_INCLUDE_DIR})
1058
1059         INSTALL(TARGETS alstream alreverb allatency alloopback
1060                 RUNTIME DESTINATION bin
1061                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1062                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1063         )
1064
1065         MESSAGE(STATUS "Building example programs")
1066         MESSAGE(STATUS "")
1067     ENDIF()
1068 ENDIF()