CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 SET(CPP_DEFS ) # C pre-process, not C++
  66 SET(INC_PATHS )
  67 SET(C_FLAGS )
  68 SET(LINKER_FLAGS )
  69 SET(EXTRA_LIBS )
  70
  71 IF(WIN32)
  72     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  73
  74     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  75
  76     # This option is mainly for static linking OpenAL Soft into another project
  77     # that already defines the IDs. It is up to that project to ensure all
  78     # required IDs are defined.
  79     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  80
  81     IF(MINGW)
  82         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  83         IF(NOT DLLTOOL)
  84             IF(HOST)
  85                 SET(DLLTOOL "${HOST}-dlltool")
  86             ELSE()
  87                 SET(DLLTOOL "dlltool")
  88             ENDIF()
  89         ENDIF()
  90     ENDIF()
  91 ENDIF()
  92
  93
  94 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  95 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  96     SET(INC_PATHS ${INC_PATHS} /usr/include)
  97     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
  98 ENDIF()
  99
 100 IF(NOT LIBTYPE)
 101     SET(LIBTYPE SHARED)
 102 ENDIF()
 103
 104 SET(LIB_MAJOR_VERSION "1")
 105 SET(LIB_MINOR_VERSION "18")
 106 SET(LIB_REVISION "2")
 107 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 108
 109 SET(EXPORT_DECL "")
 110 SET(ALIGN_DECL "")
 111
 112
 113 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 114 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 115
 116
 117 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 118 IF(HAVE_STD_C11)
 119     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 120 ELSE()
 121     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 122     IF(HAVE_STD_C99)
 123         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 124     ENDIF()
 125 ENDIF()
 126
 127 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 128 IF(HAVE_STD_CXX11)
 129     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 130 ENDIF()
 131
 132 if(NOT WIN32)
 133     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 134     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 135     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 136         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 137         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 138         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 139         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 140             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 141         ELSE()
 142             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 143         ENDIF()
 144     ENDIF()
 145     UNSET(OLD_REQUIRED_FLAGS)
 146 ENDIF()
 147
 148 # Set defines for large file support
 149 CHECK_FILE_OFFSET_BITS()
 150 IF(_FILE_OFFSET_BITS)
 151     SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 152     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 153 ENDIF()
 154 SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 155 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 156
 157 # MSVC may need workarounds for C99 restrict and inline
 158 IF(MSVC)
 159     # TODO: Once we truly require C99, these restrict and inline checks should go
 160     # away.
 161     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 162                              int main() {return 0;}" HAVE_RESTRICT)
 163     IF(NOT HAVE_RESTRICT)
 164         SET(CPP_DEFS ${CPP_DEFS} "restrict=")
 165         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 166     ENDIF()
 167
 168     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 169                              int main() {return 0;}" HAVE_INLINE)
 170     IF(NOT HAVE_INLINE)
 171         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 172                                  int main() {return 0;}" HAVE___INLINE)
 173         IF(NOT HAVE___INLINE)
 174             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 175         ENDIF()
 176
 177         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 178         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 179     ENDIF()
 180 ENDIF()
 181
 182 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 183 IF(CMAKE_COMPILER_IS_GNUCC)
 184     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 185
 186     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 187     # Force no inlining for the next test.
 188     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 189
 190     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 191                              int main() {return foo();}" INLINE_IS_C99)
 192     IF(NOT INLINE_IS_C99)
 193         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 194                              Please update your compiler for better C99 compliance.")
 195     ENDIF()
 196
 197     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 198 ENDIF()
 199
 200 # Check if we have a proper timespec declaration
 201 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 202 IF(HAVE_STRUCT_TIMESPEC)
 203     # Define it here so we don't have to include config.h for it
 204     SET(CPP_DEFS ${CPP_DEFS} HAVE_STRUCT_TIMESPEC)
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Check if we have C99 variable length arrays
 232 CHECK_C_SOURCE_COMPILES(
 233 "int main(int argc, char *argv[])
 234  {
 235      volatile int tmp[argc];
 236      tmp[0] = argv[0][0];
 237      return tmp[0];
 238  }"
 239 HAVE_C99_VLA)
 240
 241 # Check if we have C99 bool
 242 CHECK_C_SOURCE_COMPILES(
 243 "int main(int argc, char *argv[])
 244  {
 245      volatile _Bool ret;
 246      ret = (argc > 1) ? 1 : 0;
 247      return ret ? -1 : 0;
 248  }"
 249 HAVE_C99_BOOL)
 250
 251 # Check if we have C11 static_assert
 252 CHECK_C_SOURCE_COMPILES(
 253 "int main()
 254  {
 255      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 256      return 0;
 257  }"
 258 HAVE_C11_STATIC_ASSERT)
 259
 260 # Check if we have C11 alignas
 261 CHECK_C_SOURCE_COMPILES(
 262 "_Alignas(16) int foo;
 263  int main()
 264  {
 265      return 0;
 266  }"
 267 HAVE_C11_ALIGNAS)
 268
 269 # Check if we have C11 _Atomic
 270 CHECK_C_SOURCE_COMPILES(
 271 "#include <stdatomic.h>
 272  int _Atomic foo = ATOMIC_VAR_INIT(0);
 273  int main()
 274  {
 275      atomic_fetch_add(&foo, 2);
 276      return 0;
 277  }"
 278 HAVE_C11_ATOMIC)
 279
 280 # Add definitions, compiler switches, etc.
 281 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 282
 283 IF(NOT CMAKE_BUILD_TYPE)
 284     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 285         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 286         FORCE)
 287 ENDIF()
 288 IF(NOT CMAKE_DEBUG_POSTFIX)
 289     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 290         "Library postfix for debug builds. Normally left blank."
 291         FORCE)
 292 ENDIF()
 293
 294 IF(MSVC)
 295     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 296     SET(C_FLAGS ${C_FLAGS} /wd4098)
 297
 298     IF(NOT DXSDK_DIR)
 299         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 300     ELSE()
 301         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 302     ENDIF()
 303     IF(DXSDK_DIR)
 304         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 305     ENDIF()
 306
 307     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 308     IF(FORCE_STATIC_VCRT)
 309         FOREACH(flag_var
 310                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 311                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 312             IF(${flag_var} MATCHES "/MD")
 313                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 314             ENDIF()
 315         ENDFOREACH(flag_var)
 316     ENDIF()
 317 ELSE()
 318     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 319     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 320     IF(HAVE_W_EXTRA)
 321         SET(C_FLAGS ${C_FLAGS} -Wextra)
 322     ENDIF()
 323
 324     IF(ALSOFT_WERROR)
 325         SET(C_FLAGS ${C_FLAGS} -Werror)
 326     ENDIF()
 327
 328     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 329     # instead of NDEBUG)
 330     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 331         IF(${flag_var} MATCHES "-DNDEBUG")
 332             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 333         ENDIF()
 334     ENDFOREACH()
 335
 336     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 337     IF(HAVE_FNO_MATH_ERRNO)
 338         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 339     ENDIF()
 340
 341     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 342                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 343
 344     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 345     if(ALSOFT_STATIC_LIBGCC)
 346         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 347         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 348         check_c_source_compiles(
 349 "#include <stdlib.h>
 350 int main()
 351 {
 352     return 0;
 353 }"
 354             HAVE_STATIC_LIBGCC_SWITCH
 355         )
 356         if(HAVE_STATIC_LIBGCC_SWITCH)
 357             SET(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 358         endif()
 359         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 360         unset(OLD_REQUIRED_LIBRARIES)
 361     endif()
 362 ENDIF()
 363
 364 # Set visibility/export options if available
 365 IF(WIN32)
 366     SET(EXPORT_DECL "__declspec(dllexport)")
 367     IF(NOT MINGW)
 368         SET(ALIGN_DECL "__declspec(align(x))")
 369     ELSE()
 370         SET(ALIGN_DECL "__declspec(aligned(x))")
 371     ENDIF()
 372 ELSE()
 373     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 374     # Yes GCC, really don't accept visibility modes you don't support
 375     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 376
 377     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 378                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 379     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 380         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 381     ELSE()
 382         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 383                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 384         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 385             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 386         ENDIF()
 387     ENDIF()
 388
 389     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 390         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 391         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 392             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 393         ENDIF()
 394     ENDIF()
 395
 396     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 397                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 398     IF(HAVE_ATTRIBUTE_ALIGNED)
 399         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 400     ENDIF()
 401
 402     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 403 ENDIF()
 404
 405 CHECK_C_SOURCE_COMPILES("
 406 int main()
 407 {
 408     float *ptr;
 409     ptr = __builtin_assume_aligned(ptr, 16);
 410     return 0;
 411 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 412 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 413     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 414 ELSE()
 415     SET(ASSUME_ALIGNED_DECL "x")
 416 ENDIF()
 417
 418 SET(SSE_SWITCH "")
 419 SET(SSE2_SWITCH "")
 420 SET(SSE3_SWITCH "")
 421 SET(SSE4_1_SWITCH "")
 422 SET(FPU_NEON_SWITCH "")
 423
 424 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 425 IF(HAVE_MSSE_SWITCH)
 426     SET(SSE_SWITCH "-msse")
 427 ENDIF()
 428 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 429 IF(HAVE_MSSE2_SWITCH)
 430     SET(SSE2_SWITCH "-msse2")
 431 ENDIF()
 432 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 433 IF(HAVE_MSSE3_SWITCH)
 434     SET(SSE3_SWITCH "-msse3")
 435 ENDIF()
 436 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 437 IF(HAVE_MSSE4_1_SWITCH)
 438     SET(SSE4_1_SWITCH "-msse4.1")
 439 ENDIF()
 440 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 441 IF(HAVE_MFPU_NEON_SWITCH)
 442     SET(FPU_NEON_SWITCH "-mfpu=neon")
 443 ENDIF()
 444
 445 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 446                          int main() {return 0;}" HAVE_GCC_FORMAT)
 447
 448 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 449 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 450 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 451 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 452 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 453 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 454 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 455 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 456 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 457 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 458 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 459 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 460 IF(NOT HAVE_GUIDDEF_H)
 461     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 462 ENDIF()
 463
 464 # Some systems need libm for some of the following math functions to work
 465 SET(MATH_LIB )
 466 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 467 IF(HAVE_LIBM)
 468     SET(MATH_LIB ${MATH_LIB} m)
 469     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 470 ENDIF()
 471
 472 # Check for the dlopen API (for dynamicly loading backend libs)
 473 IF(ALSOFT_DLOPEN)
 474     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 475     IF(HAVE_LIBDL)
 476         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 477         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 478     ENDIF()
 479
 480     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 481 ENDIF()
 482
 483 # Check for a cpuid intrinsic
 484 IF(HAVE_CPUID_H)
 485     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 486         int main()
 487         {
 488             unsigned int eax, ebx, ecx, edx;
 489             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 490         }" HAVE_GCC_GET_CPUID)
 491 ENDIF()
 492 IF(HAVE_INTRIN_H)
 493     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 494         int main()
 495         {
 496             int regs[4];
 497             __cpuid(regs, 0);
 498             return regs[0];
 499         }" HAVE_CPUID_INTRINSIC)
 500 ENDIF()
 501
 502 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 503 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 504 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 505 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 506 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 507 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 508 IF(NOT HAVE_C99_VLA)
 509     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 510     IF(NOT HAVE_ALLOCA)
 511         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 512     ENDIF()
 513 ENDIF()
 514
 515 IF(HAVE_FLOAT_H)
 516     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 517     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 518 ENDIF()
 519
 520 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 521 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 522 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 523 IF(NOT HAVE_STRCASECMP)
 524     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 525     IF(NOT HAVE__STRICMP)
 526         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 527     ENDIF()
 528
 529     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 530 ENDIF()
 531
 532 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 533 IF(NOT HAVE_STRNCASECMP)
 534     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 535     IF(NOT HAVE__STRNICMP)
 536         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 537     ENDIF()
 538
 539     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 540 ENDIF()
 541
 542 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 543 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 544 IF(NOT HAVE_SNPRINTF)
 545     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 546     IF(NOT HAVE__SNPRINTF)
 547         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 548     ENDIF()
 549
 550     SET(CPP_DEFS ${CPP_DEFS} snprintf=_snprintf)
 551 ENDIF()
 552
 553 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 554 IF(NOT HAVE_ISFINITE)
 555     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 556     IF(NOT HAVE_FINITE)
 557         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 558         IF(NOT HAVE__FINITE)
 559             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 560         ENDIF()
 561         SET(CPP_DEFS ${CPP_DEFS} isfinite=_finite)
 562     ELSE()
 563         SET(CPP_DEFS ${CPP_DEFS} isfinite=finite)
 564     ENDIF()
 565 ENDIF()
 566
 567 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 568 IF(NOT HAVE_ISNAN)
 569     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 570     IF(NOT HAVE__ISNAN)
 571         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 572     ENDIF()
 573
 574     SET(CPP_DEFS ${CPP_DEFS} isnan=_isnan)
 575 ENDIF()
 576
 577
 578 # Check if we have Windows headers
 579 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 580 IF(NOT HAVE_WINDOWS_H)
 581     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 582     IF(NOT HAVE_GETTIMEOFDAY)
 583         MESSAGE(FATAL_ERROR "No timing function found!")
 584     ENDIF()
 585
 586     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 587     IF(NOT HAVE_NANOSLEEP)
 588         MESSAGE(FATAL_ERROR "No sleep function found!")
 589     ENDIF()
 590
 591     # We need pthreads outside of Windows
 592     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 593     IF(NOT HAVE_PTHREAD_H)
 594         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 595     ENDIF()
 596     # Some systems need pthread_np.h to get recursive mutexes
 597     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 598
 599     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 600     IF(HAVE_PTHREAD)
 601         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 602         SET(C_FLAGS ${C_FLAGS} -pthread)
 603         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 604     ENDIF()
 605
 606     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 607     IF(HAVE_LIBPTHREAD)
 608         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 609     ENDIF()
 610
 611     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 612
 613     IF(HAVE_PTHREAD_NP_H)
 614         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 615         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 616             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 617         ELSE()
 618             CHECK_C_SOURCE_COMPILES("
 619 #include <pthread.h>
 620 #include <pthread_np.h>
 621 int main()
 622 {
 623     pthread_setname_np(\"testname\");
 624     return 0;
 625 }"
 626                 PTHREAD_SETNAME_NP_ONE_PARAM
 627             )
 628             CHECK_C_SOURCE_COMPILES("
 629 #include <pthread.h>
 630 #include <pthread_np.h>
 631 int main()
 632 {
 633     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 634     return 0;
 635 }"
 636                 PTHREAD_SETNAME_NP_THREE_PARAMS
 637             )
 638         ENDIF()
 639         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 640     ELSE()
 641         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 642         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 643             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 644         ELSE()
 645             CHECK_C_SOURCE_COMPILES("
 646 #include <pthread.h>
 647 int main()
 648 {
 649     pthread_setname_np(\"testname\");
 650     return 0;
 651 }"
 652                 PTHREAD_SETNAME_NP_ONE_PARAM
 653             )
 654             CHECK_C_SOURCE_COMPILES("
 655 #include <pthread.h>
 656 int main()
 657 {
 658     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 659     return 0;
 660 }"
 661                 PTHREAD_SETNAME_NP_THREE_PARAMS
 662             )
 663         ENDIF()
 664         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 665     ENDIF()
 666
 667     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 668
 669     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 670     IF(HAVE_LIBRT)
 671         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 672     ENDIF()
 673 ENDIF()
 674
 675 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 676
 677 # Check for a 64-bit type
 678 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 679 IF(NOT HAVE_STDINT_H)
 680     IF(HAVE_WINDOWS_H)
 681         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 682                                  #include <windows.h>
 683                                  __int64 foo;
 684                                  int main() {return 0;}" HAVE___INT64)
 685     ENDIF()
 686     IF(NOT HAVE___INT64)
 687         IF(NOT SIZEOF_LONG MATCHES "8")
 688             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 689                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 690             ENDIF()
 691         ENDIF()
 692     ENDIF()
 693 ENDIF()
 694
 695
 696 SET(COMMON_OBJS  common/almalloc.c
 697                  common/atomic.c
 698                  common/rwlock.c
 699                  common/threads.c
 700                  common/uintmap.c
 701 )
 702 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 703                  OpenAL32/alBuffer.c
 704                  OpenAL32/alEffect.c
 705                  OpenAL32/alError.c
 706                  OpenAL32/alExtension.c
 707                  OpenAL32/alFilter.c
 708                  OpenAL32/alListener.c
 709                  OpenAL32/alSource.c
 710                  OpenAL32/alState.c
 711                  OpenAL32/alThunk.c
 712                  OpenAL32/sample_cvt.c
 713 )
 714 SET(ALC_OBJS  Alc/ALc.c
 715               Alc/ALu.c
 716               Alc/alcConfig.c
 717               Alc/alcRing.c
 718               Alc/bs2b.c
 719               Alc/converter.c
 720               Alc/mastering.c
 721               Alc/effects/chorus.c
 722               Alc/effects/compressor.c
 723               Alc/effects/dedicated.c
 724               Alc/effects/distortion.c
 725               Alc/effects/echo.c
 726               Alc/effects/equalizer.c
 727               Alc/effects/flanger.c
 728               Alc/effects/modulator.c
 729               Alc/effects/null.c
 730               Alc/effects/reverb.c
 731               Alc/helpers.c
 732               Alc/hrtf.c
 733               Alc/uhjfilter.c
 734               Alc/ambdec.c
 735               Alc/bformatdec.c
 736               Alc/nfcfilter.c
 737               Alc/panning.c
 738               Alc/mixer.c
 739               Alc/mixer_c.c
 740 )
 741
 742
 743 SET(CPU_EXTS "Default")
 744 SET(HAVE_SSE        0)
 745 SET(HAVE_SSE2       0)
 746 SET(HAVE_SSE3       0)
 747 SET(HAVE_SSE4_1     0)
 748 SET(HAVE_NEON       0)
 749
 750 SET(HAVE_ALSA       0)
 751 SET(HAVE_OSS        0)
 752 SET(HAVE_SOLARIS    0)
 753 SET(HAVE_SNDIO      0)
 754 SET(HAVE_QSA        0)
 755 SET(HAVE_DSOUND     0)
 756 SET(HAVE_MMDEVAPI   0)
 757 SET(HAVE_WINMM      0)
 758 SET(HAVE_PORTAUDIO  0)
 759 SET(HAVE_PULSEAUDIO 0)
 760 SET(HAVE_COREAUDIO  0)
 761 SET(HAVE_OPENSL     0)
 762 SET(HAVE_WAVE       0)
 763
 764 # Check for SSE support
 765 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 766 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 767 IF(HAVE_XMMINTRIN_H)
 768     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 769     IF(ALSOFT_CPUEXT_SSE)
 770         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 771             SET(HAVE_SSE 1)
 772             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 773             IF(SSE_SWITCH)
 774                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 775                                             COMPILE_FLAGS "${SSE_SWITCH}")
 776             ENDIF()
 777             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 778         ENDIF()
 779     ENDIF()
 780 ENDIF()
 781 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 782     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 783 ENDIF()
 784
 785 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 786 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 787 IF(HAVE_EMMINTRIN_H)
 788     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 789     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 790         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 791             SET(HAVE_SSE2 1)
 792             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 793             IF(SSE2_SWITCH)
 794                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 795                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 796             ENDIF()
 797             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 798         ENDIF()
 799     ENDIF()
 800 ENDIF()
 801 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 802     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 803 ENDIF()
 804
 805 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 806 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 807 IF(HAVE_EMMINTRIN_H)
 808     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 809     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 810         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 811             SET(HAVE_SSE3 1)
 812             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 813             IF(SSE2_SWITCH)
 814                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 815                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 816             ENDIF()
 817             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 818         ENDIF()
 819     ENDIF()
 820 ENDIF()
 821 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 822     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 823 ENDIF()
 824
 825 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 826 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 827 IF(HAVE_SMMINTRIN_H)
 828     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 829     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 830         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 831             SET(HAVE_SSE4_1 1)
 832             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 833             IF(SSE4_1_SWITCH)
 834                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 835                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 836             ENDIF()
 837             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 838         ENDIF()
 839     ENDIF()
 840 ENDIF()
 841 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 842     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 843 ENDIF()
 844
 845 # Check for ARM Neon support
 846 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 847 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 848 IF(HAVE_ARM_NEON_H)
 849     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 850     IF(ALSOFT_CPUEXT_NEON)
 851         SET(HAVE_NEON 1)
 852         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 853         IF(FPU_NEON_SWITCH)
 854             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 855                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 856         ENDIF()
 857         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 858     ENDIF()
 859 ENDIF()
 860 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 861     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 862 ENDIF()
 863
 864
 865 IF(WIN32 OR HAVE_DLFCN_H)
 866     SET(IS_LINKED "")
 867     MACRO(ADD_BACKEND_LIBS _LIBS)
 868     ENDMACRO()
 869 ELSE()
 870     SET(IS_LINKED " (linked)")
 871     MACRO(ADD_BACKEND_LIBS _LIBS)
 872         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 873     ENDMACRO()
 874 ENDIF()
 875
 876 SET(BACKENDS "")
 877 SET(ALC_OBJS  ${ALC_OBJS}
 878               Alc/backends/base.c
 879               # Default backends, always available
 880               Alc/backends/loopback.c
 881               Alc/backends/null.c
 882 )
 883
 884 # Check ALSA backend
 885 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 886 FIND_PACKAGE(ALSA)
 887 IF(ALSA_FOUND)
 888     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 889     IF(ALSOFT_BACKEND_ALSA)
 890         SET(HAVE_ALSA 1)
 891         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 892         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 893         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 894         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 895     ENDIF()
 896 ENDIF()
 897 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 898     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 899 ENDIF()
 900
 901 # Check OSS backend
 902 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 903 FIND_PACKAGE(OSS)
 904 IF(OSS_FOUND)
 905     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 906     IF(ALSOFT_BACKEND_OSS)
 907         SET(HAVE_OSS 1)
 908         SET(BACKENDS  "${BACKENDS} OSS,")
 909         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 910         IF(OSS_LIBRARIES)
 911             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 912         ENDIF()
 913         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 914     ENDIF()
 915 ENDIF()
 916 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 917     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 918 ENDIF()
 919
 920 # Check Solaris backend
 921 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 922 FIND_PACKAGE(AudioIO)
 923 IF(AUDIOIO_FOUND)
 924     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 925     IF(ALSOFT_BACKEND_SOLARIS)
 926         SET(HAVE_SOLARIS 1)
 927         SET(BACKENDS  "${BACKENDS} Solaris,")
 928         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 929         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 930     ENDIF()
 931 ENDIF()
 932 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 933     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 934 ENDIF()
 935
 936 # Check SndIO backend
 937 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 938 FIND_PACKAGE(SoundIO)
 939 IF(SOUNDIO_FOUND)
 940     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 941     IF(ALSOFT_BACKEND_SNDIO)
 942         SET(HAVE_SNDIO 1)
 943         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 944         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 945         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 946         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 947     ENDIF()
 948 ENDIF()
 949 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 950     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 951 ENDIF()
 952
 953 # Check QSA backend
 954 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 955 FIND_PACKAGE(QSA)
 956 IF(QSA_FOUND)
 957     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 958     IF(ALSOFT_BACKEND_QSA)
 959         SET(HAVE_QSA 1)
 960         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 961         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 962         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 963         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
 964     ENDIF()
 965 ENDIF()
 966 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 967     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 968 ENDIF()
 969
 970 # Check Windows-only backends
 971 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 972 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 973 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 974 IF(HAVE_WINDOWS_H)
 975     # Check MMSystem backend
 976     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 977     IF(HAVE_MMSYSTEM_H)
 978         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 979         IF(HAVE_LIBWINMM)
 980             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 981             IF(ALSOFT_BACKEND_WINMM)
 982                 SET(HAVE_WINMM 1)
 983                 SET(BACKENDS  "${BACKENDS} WinMM,")
 984                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 985                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 986             ENDIF()
 987         ENDIF()
 988     ENDIF()
 989
 990     # Check DSound backend
 991     FIND_PACKAGE(DSound)
 992     IF(DSOUND_FOUND)
 993         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 994         IF(ALSOFT_BACKEND_DSOUND)
 995             SET(HAVE_DSOUND 1)
 996             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 997             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 998             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 999             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1000         ENDIF()
1001     ENDIF()
1002
1003     # Check for MMDevApi backend
1004     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1005     IF(HAVE_MMDEVICEAPI_H)
1006         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
1007         IF(ALSOFT_BACKEND_MMDEVAPI)
1008             SET(HAVE_MMDEVAPI 1)
1009             SET(BACKENDS  "${BACKENDS} MMDevApi,")
1010             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
1011         ENDIF()
1012     ENDIF()
1013 ENDIF()
1014 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1015     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1016 ENDIF()
1017 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1018     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1019 ENDIF()
1020 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
1021     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
1022 ENDIF()
1023
1024 # Check PortAudio backend
1025 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1026 FIND_PACKAGE(PortAudio)
1027 IF(PORTAUDIO_FOUND)
1028     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1029     IF(ALSOFT_BACKEND_PORTAUDIO)
1030         SET(HAVE_PORTAUDIO 1)
1031         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1032         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1033         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1034         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1035     ENDIF()
1036 ENDIF()
1037 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1038     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1039 ENDIF()
1040
1041 # Check PulseAudio backend
1042 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1043 FIND_PACKAGE(PulseAudio)
1044 IF(PULSEAUDIO_FOUND)
1045     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1046     IF(ALSOFT_BACKEND_PULSEAUDIO)
1047         SET(HAVE_PULSEAUDIO 1)
1048         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1049         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1050         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1051         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1052     ENDIF()
1053 ENDIF()
1054 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1055     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1056 ENDIF()
1057
1058 # Check JACK backend
1059 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1060 FIND_PACKAGE(JACK)
1061 IF(JACK_FOUND)
1062     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1063     IF(ALSOFT_BACKEND_JACK)
1064         SET(HAVE_JACK 1)
1065         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1066         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1067         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1068         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1069     ENDIF()
1070 ENDIF()
1071 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1072     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1073 ENDIF()
1074
1075 # Check CoreAudio backend
1076 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1077 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1078              NAMES CoreAudio
1079              PATHS /System/Library/Frameworks
1080 )
1081 IF(COREAUDIO_FRAMEWORK)
1082     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1083     IF(ALSOFT_BACKEND_COREAUDIO)
1084         SET(HAVE_COREAUDIO 1)
1085         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1086         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1087         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1088         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1089         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1090
1091         # Some versions of OSX may need the AudioToolbox framework. Add it if
1092         # it's found.
1093         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1094                      NAMES AudioToolbox
1095                      PATHS ~/Library/Frameworks
1096                            /Library/Frameworks
1097                            /System/Library/Frameworks
1098                     )
1099         IF(AUDIOTOOLBOX_LIBRARY)
1100             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1101         ENDIF()
1102     ENDIF()
1103 ENDIF()
1104 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1105     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1106 ENDIF()
1107
1108 # Check for OpenSL (Android) backend
1109 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1110 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1111 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1112     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1113     IF(HAVE_LIBOPENSLES)
1114         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1115         IF(ALSOFT_BACKEND_OPENSL)
1116             SET(HAVE_OPENSL 1)
1117             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1118             SET(BACKENDS  "${BACKENDS} OpenSL,")
1119             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1120         ENDIF()
1121     ENDIF()
1122 ENDIF()
1123 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1124     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1125 ENDIF()
1126
1127 # Optionally enable the Wave Writer backend
1128 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1129 IF(ALSOFT_BACKEND_WAVE)
1130     SET(HAVE_WAVE 1)
1131     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1132     SET(BACKENDS  "${BACKENDS} WaveFile,")
1133 ENDIF()
1134
1135 # This is always available
1136 SET(BACKENDS  "${BACKENDS} Null")
1137
1138
1139 FIND_PACKAGE(Git)
1140 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1141     # Get the current working branch and its latest abbreviated commit hash
1142     ADD_CUSTOM_TARGET(build_version
1143         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1144                          -D LIB_VERSION=${LIB_VERSION}
1145                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1146                          -D DST=${OpenAL_BINARY_DIR}/version.h
1147                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1148         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1149         VERBATIM
1150     )
1151 ELSE()
1152     SET(GIT_BRANCH "UNKNOWN")
1153     SET(GIT_COMMIT_HASH "unknown")
1154     CONFIGURE_FILE(
1155         "${OpenAL_SOURCE_DIR}/version.h.in"
1156         "${OpenAL_BINARY_DIR}/version.h")
1157 ENDIF()
1158
1159 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1160 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1161 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1162
1163 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1164 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1165 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1166     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1167     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1168     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1169     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1170     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1171     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1172                      C "${NATIVE_SRC_DIR}bsincgen.c"
1173     VERBATIM
1174 )
1175 ADD_CUSTOM_TARGET(native-tools
1176     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1177     VERBATIM
1178 )
1179
1180 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1181 if(ALSOFT_EMBED_HRTF_DATA)
1182     MACRO(make_hrtf_header FILENAME VARNAME)
1183         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1184         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1185
1186         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1187             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1188             DEPENDS native-tools "${infile}"
1189             VERBATIM
1190         )
1191         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1192     ENDMACRO()
1193
1194     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1195     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1196 endif()
1197
1198 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1199     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1200     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1201     VERBATIM
1202 )
1203 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1204
1205
1206 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1207     add_subdirectory(utils/alsoft-config)
1208 ENDIF()
1209 IF(ALSOFT_EXAMPLES)
1210     FIND_PACKAGE(SDL2)
1211     IF(SDL2_FOUND)
1212         FIND_PACKAGE(SDL_sound)
1213         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1214     ENDIF()
1215 ENDIF()
1216
1217 IF(NOT WIN32)
1218     SET(LIBNAME "openal")
1219 ELSE()
1220     SET(LIBNAME "OpenAL32")
1221 ENDIF()
1222
1223 # Needed for openal.pc.in
1224 SET(prefix ${CMAKE_INSTALL_PREFIX})
1225 SET(exec_prefix "\${prefix}")
1226 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1227 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1228 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1229 SET(PACKAGE_VERSION "${LIB_VERSION}")
1230 IF(LIBTYPE STREQUAL "STATIC")
1231     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1232 ENDIF()
1233
1234 # End configuration
1235 CONFIGURE_FILE(
1236     "${OpenAL_SOURCE_DIR}/config.h.in"
1237     "${OpenAL_BINARY_DIR}/config.h")
1238 CONFIGURE_FILE(
1239     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1240     "${OpenAL_BINARY_DIR}/openal.pc"
1241     @ONLY)
1242
1243 UNSET(HAS_ROUTER)
1244 SET(IMPL_TARGET OpenAL)
1245 SET(SUBSYS_FLAG )
1246
1247 # Build main library
1248 IF(LIBTYPE STREQUAL "STATIC")
1249     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1250     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1251         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1252     ENDIF()
1253     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1254 ELSE()
1255     IF(WIN32)
1256         IF(MSVC)
1257             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1258         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1259             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1260         ENDIF()
1261     ENDIF()
1262
1263     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1264         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c ${COMMON_OBJS})
1265         TARGET_COMPILE_DEFINITIONS(OpenAL
1266             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1267         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1268         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${LINKER_FLAGS})
1269         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1270         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1271         IF(TARGET build_version)
1272             ADD_DEPENDENCIES(OpenAL build_version)
1273         ENDIF()
1274         SET(HAS_ROUTER 1)
1275
1276         SET(LIBNAME "soft_oal")
1277         SET(IMPL_TARGET soft_oal)
1278     ENDIF()
1279
1280     ADD_LIBRARY(${IMPL_TARGET} SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1281     IF(WIN32)
1282         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1283     ENDIF()
1284 ENDIF()
1285 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1286     VERSION ${LIB_VERSION}
1287     SOVERSION ${LIB_MAJOR_VERSION}
1288 )
1289 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1290     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1291 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1292     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1293 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1294 TARGET_LINK_LIBRARIES(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1295 IF(TARGET build_version)
1296     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1297 ENDIF()
1298
1299 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1300     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1301     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1302     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1303         MESSAGE(STATUS "")
1304         IF(NOT SED_EXECUTABLE)
1305             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1306         ENDIF()
1307         IF(NOT DLLTOOL_EXECUTABLE)
1308             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1309         ENDIF()
1310     ELSE()
1311         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1312                         " -Wl,--output-def,OpenAL32.def")
1313         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1314             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1315             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1316             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1317             VERBATIM
1318         )
1319     ENDIF()
1320 ENDIF()
1321
1322 IF(ALSOFT_INSTALL)
1323     INSTALL(TARGETS OpenAL EXPORT OpenAL
1324             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1325             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1326             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1327             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1328     )
1329     EXPORT(TARGETS OpenAL
1330            NAMESPACE OpenAL::
1331            FILE OpenALConfig.cmake)
1332     INSTALL(EXPORT OpenAL
1333             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1334             NAMESPACE OpenAL::
1335             FILE OpenALConfig.cmake)
1336     INSTALL(FILES include/AL/al.h
1337                   include/AL/alc.h
1338                   include/AL/alext.h
1339                   include/AL/efx.h
1340                   include/AL/efx-creative.h
1341                   include/AL/efx-presets.h
1342             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1343     )
1344     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1345             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1346     IF(TARGET soft_oal)
1347         INSTALL(TARGETS soft_oal
1348                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1349         )
1350     ENDIF()
1351 ENDIF()
1352
1353
1354 if(HAS_ROUTER)
1355     message(STATUS "")
1356     message(STATUS "Building DLL router")
1357 endif()
1358
1359 MESSAGE(STATUS "")
1360 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1361 MESSAGE(STATUS "    ${BACKENDS}")
1362 MESSAGE(STATUS "")
1363 MESSAGE(STATUS "Building with support for CPU extensions:")
1364 MESSAGE(STATUS "    ${CPU_EXTS}")
1365 MESSAGE(STATUS "")
1366
1367 IF(WIN32)
1368     IF(NOT HAVE_DSOUND)
1369         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1370         MESSAGE(STATUS "         This is probably NOT what you want!")
1371         MESSAGE(STATUS "")
1372     ENDIF()
1373 ENDIF()
1374
1375 if(ALSOFT_EMBED_HRTF_DATA)
1376     message(STATUS "Embedding HRTF datasets")
1377     message(STATUS "")
1378 endif()
1379
1380 # Install alsoft.conf configuration file
1381 IF(ALSOFT_CONFIG)
1382     INSTALL(FILES alsoftrc.sample
1383             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1384     )
1385     MESSAGE(STATUS "Installing sample configuration")
1386     MESSAGE(STATUS "")
1387 ENDIF()
1388
1389 # Install HRTF definitions
1390 IF(ALSOFT_HRTF_DEFS)
1391     INSTALL(FILES hrtf/default-44100.mhr
1392                   hrtf/default-48000.mhr
1393             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1394     )
1395     MESSAGE(STATUS "Installing HRTF definitions")
1396     MESSAGE(STATUS "")
1397 ENDIF()
1398
1399 # Install AmbDec presets
1400 IF(ALSOFT_AMBDEC_PRESETS)
1401     INSTALL(FILES presets/3D7.1.ambdec
1402                   presets/hexagon.ambdec
1403                   presets/itu5.1.ambdec
1404                   presets/itu5.1-nocenter.ambdec
1405                   presets/rectangle.ambdec
1406                   presets/square.ambdec
1407                   presets/presets.txt
1408             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1409     )
1410     MESSAGE(STATUS "Installing AmbDec presets")
1411     MESSAGE(STATUS "")
1412 ENDIF()
1413
1414 IF(ALSOFT_UTILS)
1415     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1416     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1417     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1418
1419     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1420     IF(NOT HAVE_GETOPT)
1421         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c)
1422     ENDIF()
1423     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1424     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1425     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1426     IF(HAVE_LIBM)
1427         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1428     ENDIF()
1429
1430     IF(ALSOFT_INSTALL)
1431         INSTALL(TARGETS openal-info makehrtf
1432                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1433                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1434                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1435         )
1436     ENDIF()
1437
1438     MESSAGE(STATUS "Building utility programs")
1439     IF(TARGET alsoft-config)
1440         MESSAGE(STATUS "Building configuration program")
1441     ENDIF()
1442     MESSAGE(STATUS "")
1443 ENDIF()
1444
1445 IF(ALSOFT_TESTS)
1446     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1447
1448     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1449     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1450     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1451     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} OpenAL ${MATH_LIB})
1452
1453     IF(ALSOFT_INSTALL)
1454         INSTALL(TARGETS altonegen
1455                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1456                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1457                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1458         )
1459     ENDIF()
1460
1461     MESSAGE(STATUS "Building test programs")
1462     MESSAGE(STATUS "")
1463 ENDIF()
1464
1465 IF(ALSOFT_EXAMPLES)
1466     ADD_EXECUTABLE(alrecord examples/alrecord.c ${COMMON_OBJS})
1467     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1468     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1469     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} OpenAL)
1470
1471     IF(ALSOFT_INSTALL)
1472         INSTALL(TARGETS alrecord
1473                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1474                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1475                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1476         )
1477     ENDIF()
1478
1479     MESSAGE(STATUS "Building example programs")
1480
1481     IF(SDL2_FOUND)
1482         IF(SDL_SOUND_FOUND)
1483             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1484
1485             ADD_EXECUTABLE(alplay examples/alplay.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1486             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1487             TARGET_INCLUDE_DIRECTORIES(alplay
1488                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1489             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1490             TARGET_LINK_LIBRARIES(alplay
1491                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1492
1493             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1494             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1495             TARGET_INCLUDE_DIRECTORIES(alstream
1496                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1497             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1498             TARGET_LINK_LIBRARIES(alstream
1499                  PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1500
1501             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1502             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1503             TARGET_INCLUDE_DIRECTORIES(alreverb
1504                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1505             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1506             TARGET_LINK_LIBRARIES(alreverb
1507                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1508
1509             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1510             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1511             TARGET_INCLUDE_DIRECTORIES(allatency
1512                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1513             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1514             TARGET_LINK_LIBRARIES(allatency
1515                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1516
1517             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1518             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1519             TARGET_INCLUDE_DIRECTORIES(alloopback
1520                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1521             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1522             TARGET_LINK_LIBRARIES(alloopback
1523                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL ${MATH_LIB})
1524
1525             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1526             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1527             TARGET_INCLUDE_DIRECTORIES(alhrtf
1528                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1529             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1530             TARGET_LINK_LIBRARIES(alhrtf
1531                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL ${MATH_LIB})
1532
1533             IF(ALSOFT_INSTALL)
1534                 INSTALL(TARGETS alplay alstream alreverb allatency alloopback alhrtf
1535                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1536                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1537                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1538                 )
1539             ENDIF()
1540
1541             MESSAGE(STATUS "Building SDL_sound example programs")
1542         ENDIF()
1543
1544         SET(FFVER_OK FALSE)
1545         IF(FFMPEG_FOUND)
1546             SET(FFVER_OK TRUE)
1547             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1548                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1549                 SET(FFVER_OK FALSE)
1550             ENDIF()
1551             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1552                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1553                 SET(FFVER_OK FALSE)
1554             ENDIF()
1555             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1556                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1557                 SET(FFVER_OK FALSE)
1558             ENDIF()
1559             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1560                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1561                 SET(FFVER_OK FALSE)
1562             ENDIF()
1563             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1564                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1565                 SET(FFVER_OK FALSE)
1566             ENDIF()
1567         ENDIF()
1568         IF(FFVER_OK)
1569             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1570             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1571             TARGET_INCLUDE_DIRECTORIES(alffplay
1572                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1573             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1574             TARGET_LINK_LIBRARIES(alffplay
1575                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} OpenAL)
1576
1577             IF(ALSOFT_INSTALL)
1578                 INSTALL(TARGETS alffplay
1579                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1580                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1581                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1582                 )
1583             ENDIF()
1584             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1585         ENDIF()
1586         MESSAGE(STATUS "")
1587     ENDIF()
1588 ENDIF()