CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 INCLUDE(CheckFunctionExists)
   4 INCLUDE(CheckLibraryExists)
   5 INCLUDE(CheckIncludeFile)
   6 INCLUDE(CheckIncludeFiles)
   7 INCLUDE(CheckCCompilerFlag)
   8 INCLUDE(CheckCSourceCompiles)
   9 INCLUDE(CheckTypeSize)
  10
  11
  12 PROJECT(OpenAL)
  13
  14
  15 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  16
  17
  18 OPTION(ALSA    "Check for ALSA backend"                ON)
  19 OPTION(OSS     "Check for OSS backend"                 ON)
  20 OPTION(DSOUND  "Check for DirectSound backend"         ON)
  21 OPTION(WINMM   "Check for Windows Multimedia backend"  ON)
  22
  23 OPTION(DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  24
  25 OPTION(WERROR   "Treat compile warnings as errors"          OFF)
  26
  27
  28 SET(LIB_MAJOR_VERSION "1")
  29 SET(LIB_MINOR_VERSION "3")
  30 SET(LIB_BUILD_VERSION "253")
  31 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_BUILD_VERSION}")
  32
  33
  34 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  35 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  36 CHECK_TYPE_SIZE("unsigned int" SIZEOF_UINT)
  37 CHECK_TYPE_SIZE("void*" SIZEOF_VOIDP)
  38
  39
  40 # Add definitions, compiler switches, etc.
  41 INCLUDE_DIRECTORIES(OpenAL32/Include include "${OpenAL_BINARY_DIR}")
  42
  43 IF(NOT CMAKE_BUILD_TYPE)
  44     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  45         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  46         FORCE)
  47 ENDIF()
  48
  49 IF(MSVC)
  50     # ???
  51     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
  52     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
  53     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
  54     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
  55 ELSE()
  56     ADD_DEFINITIONS(-Wall)
  57     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
  58     IF("${HAVE_W_EXTRA}")
  59         ADD_DEFINITIONS(-Wextra)
  60     ENDIF()
  61
  62     IF(WERROR)
  63         ADD_DEFINITIONS(-Werror)
  64     ENDIF()
  65
  66     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -funroll-loops -D_DEBUG" CACHE STRING
  67         "Flags used by the compiler during Release with Debug Info builds."
  68         FORCE)
  69     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
  70         "Flags used by the compiler during release minsize builds."
  71         FORCE)
  72     SET(CMAKE_C_FLAGS_RELEASE "-O2 -funroll-loops -fomit-frame-pointer -DNDEBUG" CACHE STRING
  73         "Flags used by the compiler during release builds"
  74         FORCE)
  75     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
  76         "Flags used by the compiler during debug builds."
  77         FORCE)
  78
  79     # The mixer doesn't like GCC's strict aliasing optimizations. Make sure
  80     # it's turned off
  81     CHECK_C_COMPILER_FLAG(-fstrict-aliasing HAVE_STRICT_ALIASING)
  82     IF("${HAVE_STRICT_ALIASING}")
  83         ADD_DEFINITIONS(-fno-strict-aliasing)
  84     ENDIF()
  85
  86     # Set visibility options if available
  87     IF(NOT WIN32)
  88         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
  89                                  int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
  90
  91         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_SWITCH)
  92         IF("${HAVE_VISIBILITY_SWITCH}")
  93             CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
  94                                      int main() {return 0;}" HAVE_GCC_VISIBILITY)
  95             IF("${HAVE_GCC_VISIBILITY}")
  96                 ADD_DEFINITIONS(-fvisibility=hidden -DHAVE_GCC_VISIBILITY)
  97             ENDIF()
  98         ENDIF()
  99     ENDIF()
 100 ENDIF()
 101
 102
 103 CHECK_LIBRARY_EXISTS(m  sqrtf  "" HAVE_SQRTF)
 104 CHECK_LIBRARY_EXISTS(m  acosf  "" HAVE_ACOSF)
 105 IF(HAVE_SQRTF OR HAVE_ACOSF)
 106     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 107 ENDIF()
 108 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 109
 110 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 111 IF(NOT HAVE_STRCASECMP)
 112     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 113     IF(NOT HAVE__STRICMP)
 114         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 115     ENDIF()
 116
 117     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 118 ENDIF()
 119
 120 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 121 IF(NOT HAVE_STRNCASECMP)
 122     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 123     IF(NOT HAVE__STRNICMP)
 124         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 125     ENDIF()
 126
 127     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 128 ENDIF()
 129
 130 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 131 IF(NOT HAVE_SNPRINTF)
 132     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 133     IF(NOT HAVE__SNPRINTF)
 134         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 135     ENDIF()
 136
 137     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 138 ENDIF()
 139
 140 # Check for the dlopen API (for dynamicly loading backend libs)
 141 IF(DLOPEN)
 142     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 143     IF(HAVE_DLFCN_H)
 144         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 145         IF(HAVE_LIBDL)
 146             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 147         ENDIF()
 148     ENDIF()
 149 ENDIF()
 150
 151 # Check if we have Windows headers
 152 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0500)
 153 IF(NOT HAVE_WINDOWS_H)
 154     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 155     IF(NOT HAVE_GETTIMEOFDAY)
 156         MESSAGE(FATAL_ERROR "No timing function found!")
 157     ENDIF()
 158
 159     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 160     IF(NOT HAVE_NANOSLEEP)
 161         MESSAGE(FATAL_ERROR "No sleep function found!")
 162     ENDIF()
 163
 164     # We need pthreads outside of Windows
 165     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 166     IF(NOT HAVE_PTHREAD_H)
 167         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 168     ENDIF()
 169
 170     # Some systems need pthread_np.h to get recursive mutexes
 171     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 172
 173     # _GNU_SOURCE is needed on some systems for extra attributes, and
 174     # _REENTRANT is needed for libc thread-safety
 175     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_REENTRANT)
 176     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 177     IF(HAVE_LIBPTHREAD)
 178         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 179     ENDIF()
 180 ENDIF()
 181
 182 # Check for a 64-bit type
 183 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 184 IF(NOT HAVE_STDINT_H)
 185     IF(HAVE_WINDOWS_H)
 186         CHECK_C_SOURCE_COMPILES("\#define _WIN32_WINNT 0x0500
 187                                  \#include <windows.h>
 188                                  __int64 foo;
 189                                  int main() {return 0;}" HAVE___INT64)
 190     ENDIF()
 191     IF(NOT HAVE___INT64)
 192         IF(NOT SIZEOF_LONG MATCHES "8")
 193             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 194                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 195             ENDIF()
 196         ENDIF()
 197     ENDIF()
 198 ENDIF()
 199
 200
 201 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 202                  OpenAL32/alBuffer.c
 203                  OpenAL32/alEffect.c
 204                  OpenAL32/alError.c
 205                  OpenAL32/alExtension.c
 206                  OpenAL32/alFilter.c
 207                  OpenAL32/alListener.c
 208                  OpenAL32/alSource.c
 209                  OpenAL32/alState.c
 210                  OpenAL32/alThunk.c
 211                  OpenAL32/OpenAL32.c
 212 )
 213 SET(ALC_OBJS  Alc/ALc.c
 214               Alc/ALu.c
 215               Alc/alcConfig.c
 216               Alc/alcRing.c
 217               Alc/alcThread.c
 218               Alc/bs2b.c
 219               Alc/wave.c
 220 )
 221
 222 SET(BACKENDS "")
 223
 224 # Check ALSA backend
 225 IF(ALSA)
 226     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 227     IF(HAVE_ALSA_ASOUNDLIB_H)
 228         CHECK_LIBRARY_EXISTS(asound snd_pcm_open "" HAVE_LIBASOUND)
 229         IF(HAVE_DLFCN_H OR HAVE_LIBASOUND)
 230             SET(HAVE_ALSA 1)
 231             SET(ALC_OBJS  ${ALC_OBJS} Alc/alsa.c)
 232             IF(HAVE_DLFCN_H)
 233                 SET(BACKENDS  "${BACKENDS} ALSA,")
 234             ELSE()
 235                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 236                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 237             ENDIF()
 238         ENDIF()
 239     ENDIF()
 240 ENDIF()
 241
 242 # Check OSS backend
 243 IF(OSS)
 244     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 245     IF(HAVE_SYS_SOUNDCARD_H)
 246         SET(HAVE_OSS 1)
 247         SET(ALC_OBJS  ${ALC_OBJS} Alc/oss.c)
 248         SET(BACKENDS  "${BACKENDS} OSS,")
 249     ENDIF()
 250 ENDIF()
 251
 252 # Check DSound/MMSystem backend
 253 IF(HAVE_WINDOWS_H)
 254     IF(DSOUND)
 255         CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 256         IF(HAVE_DSOUND_H)
 257             SET(HAVE_DSOUND 1)
 258             SET(ALC_OBJS  ${ALC_OBJS} Alc/dsound.c)
 259             SET(BACKENDS  "${BACKENDS} DirectSound,")
 260
 261             SET(CMAKE_REQUIRED_LIBRARIES dsound)
 262             CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBDSOUND)
 263             SET(CMAKE_REQUIRED_LIBRARIES "")
 264 #            CHECK_LIBRARY_EXISTS(dsound DirectSoundCreate "" HAVE_LIBDSOUND)
 265             IF(HAVE_LIBDSOUND)
 266                 SET(EXTRA_LIBS dsound ${EXTRA_LIBS})
 267             ENDIF()
 268         ENDIF()
 269     ENDIF()
 270     IF(WINMM)
 271         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0500)
 272         IF(HAVE_MMSYSTEM_H)
 273             SET(HAVE_WINMM 1)
 274             SET(ALC_OBJS  ${ALC_OBJS} Alc/winmm.c)
 275             SET(BACKENDS  "${BACKENDS} WinMM,")
 276
 277             SET(CMAKE_REQUIRED_LIBRARIES winmm)
 278             CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBWINMM)
 279             SET(CMAKE_REQUIRED_LIBRARIES "")
 280 #            CHECK_LIBRARY_EXISTS(winmm waveInOpen "" HAVE_LIBWINMM)
 281             IF(HAVE_LIBWINMM)
 282                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 283             ENDIF()
 284         ENDIF()
 285     ENDIF()
 286 ENDIF()
 287
 288 # This is always available
 289 SET(BACKENDS  "${BACKENDS} WaveFile")
 290
 291 # End configuration
 292 CONFIGURE_FILE(
 293     "${OpenAL_SOURCE_DIR}/config.h.in"
 294     "${OpenAL_BINARY_DIR}/config.h")
 295
 296 ADD_DEFINITIONS(-DAL_BUILD_LIBRARY)
 297
 298 # Build a shared library
 299 IF(WIN32)
 300     SET(LIBNAME openal32)
 301 ELSE()
 302     SET(LIBNAME openal)
 303 ENDIF()
 304
 305 ADD_LIBRARY(${LIBNAME} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
 306 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 307                                             SOVERSION ${LIB_MAJOR_VERSION})
 308 IF(WIN32)
 309     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 310 ENDIF()
 311
 312 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 313
 314 # Add an install target here
 315 INSTALL(TARGETS ${LIBNAME}
 316         RUNTIME DESTINATION bin
 317         LIBRARY DESTINATION lib
 318         ARCHIVE DESTINATION lib
 319 )
 320 INSTALL(FILES include/AL/al.h
 321               include/AL/alc.h
 322               include/AL/alext.h
 323         DESTINATION include/AL
 324 )
 325
 326 MESSAGE(STATUS "")
 327 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 328 MESSAGE(STATUS "    ${BACKENDS}")
 329 MESSAGE(STATUS "")