CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 INCLUDE(CheckFunctionExists)
   4 INCLUDE(CheckLibraryExists)
   5 INCLUDE(CheckIncludeFile)
   6 INCLUDE(CheckIncludeFiles)
   7 INCLUDE(CheckCCompilerFlag)
   8 INCLUDE(CheckCSourceCompiles)
   9 INCLUDE(CheckTypeSize)
  10
  11
  12 PROJECT(OpenAL)
  13
  14
  15 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  16
  17
  18 OPTION(ALSA    "Check for ALSA backend"                ON)
  19 OPTION(OSS     "Check for OSS backend"                 ON)
  20 OPTION(DSOUND  "Check for DirectSound backend"         ON)
  21 OPTION(WINMM   "Check for Windows Multimedia backend"  ON)
  22
  23 OPTION(DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  24
  25 OPTION(WERROR   "Treat compile warnings as errors"          OFF)
  26
  27
  28 SET(LIB_MAJOR_VERSION "1")
  29 SET(LIB_MINOR_VERSION "1")
  30 SET(LIB_BUILD_VERSION "93")
  31 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_BUILD_VERSION}")
  32
  33
  34 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  35 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  36 CHECK_TYPE_SIZE("unsigned int" SIZEOF_UINT)
  37 CHECK_TYPE_SIZE("void*" SIZEOF_VOIDP)
  38
  39
  40 # Add definitions, compiler switches, etc.
  41 INCLUDE_DIRECTORIES(OpenAL32/Include include "${OpenAL_BINARY_DIR}")
  42
  43 IF(NOT CMAKE_BUILD_TYPE)
  44     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  45         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  46         FORCE)
  47 ENDIF()
  48
  49 IF(MSVC)
  50     # ???
  51     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
  52     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
  53     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
  54     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
  55 ELSE()
  56     ADD_DEFINITIONS(-Wall)
  57     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
  58     IF("${HAVE_W_EXTRA}")
  59         ADD_DEFINITIONS(-Wextra)
  60     ENDIF()
  61
  62     IF(WERROR)
  63         ADD_DEFINITIONS(-Werror)
  64     ENDIF()
  65
  66     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -funroll-loops -D_DEBUG" CACHE STRING
  67         "Flags used by the compiler during Release with Debug Info builds."
  68         FORCE)
  69     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
  70         "Flags used by the compiler during release minsize builds."
  71         FORCE)
  72     SET(CMAKE_C_FLAGS_RELEASE "-O2 -funroll-loops -fomit-frame-pointer -DNDEBUG" CACHE STRING
  73         "Flags used by the compiler during release builds"
  74         FORCE)
  75     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
  76         "Flags used by the compiler during debug builds."
  77         FORCE)
  78
  79     # The mixer doesn't like GCC's strict aliasing optimizations. Make sure
  80     # it's turned off
  81     CHECK_C_COMPILER_FLAG(-fstrict-aliasing HAVE_STRICT_ALIASING)
  82     IF("${HAVE_STRICT_ALIASING}")
  83         ADD_DEFINITIONS(-fno-strict-aliasing)
  84     ENDIF()
  85
  86     # Set visibility options if available
  87     IF(NOT WIN32)
  88         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
  89                                  int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
  90
  91         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_SWITCH)
  92         IF("${HAVE_VISIBILITY_SWITCH}")
  93             CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
  94                                      int main() {return 0;}" HAVE_GCC_VISIBILITY)
  95             IF("${HAVE_GCC_VISIBILITY}")
  96                 ADD_DEFINITIONS(-fvisibility=hidden -DHAVE_GCC_VISIBILITY)
  97             ENDIF()
  98         ENDIF()
  99     ENDIF()
 100 ENDIF()
 101
 102
 103 CHECK_LIBRARY_EXISTS(m  sqrtf  "" HAVE_SQRTF)
 104 IF(HAVE_SQRTF)
 105     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 106 ENDIF()
 107 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 108
 109 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 110 IF(NOT HAVE_STRCASECMP)
 111     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 112     IF(NOT HAVE__STRICMP)
 113         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 114     ENDIF()
 115
 116     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 117 ENDIF()
 118
 119 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 120 IF(NOT HAVE_STRNCASECMP)
 121     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 122     IF(NOT HAVE__STRNICMP)
 123         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 124     ENDIF()
 125
 126     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 127 ENDIF()
 128
 129 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 130 IF(NOT HAVE_SNPRINTF)
 131     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 132     IF(NOT HAVE__SNPRINTF)
 133         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 134     ENDIF()
 135
 136     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 137 ENDIF()
 138
 139 # Check for the dlopen API (for dynamicly loading backend libs)
 140 IF(DLOPEN)
 141     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 142     IF(HAVE_DLFCN_H)
 143         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 144         IF(HAVE_LIBDL)
 145             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 146         ENDIF()
 147     ENDIF()
 148 ENDIF()
 149
 150 # Check if we have Windows headers
 151 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
 152 IF(NOT HAVE_WINDOWS_H)
 153     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 154     IF(NOT HAVE_GETTIMEOFDAY)
 155         MESSAGE(FATAL_ERROR "No timing function found!")
 156     ENDIF()
 157
 158     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 159     IF(NOT HAVE_NANOSLEEP)
 160         MESSAGE(FATAL_ERROR "No sleep function found!")
 161     ENDIF()
 162
 163     # We need pthreads outside of Windows
 164     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 165     IF(NOT HAVE_PTHREAD_H)
 166         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 167     ENDIF()
 168
 169     # _GNU_SOURCE is needed on some systems for extra attributes, and
 170     # _REENTRANT is needed for libc thread-safety
 171     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_REENTRANT)
 172     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 173     IF(HAVE_LIBPTHREAD)
 174         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 175     ENDIF()
 176 ENDIF()
 177
 178 # Check for a 64-bit type
 179 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 180 IF(NOT HAVE_STDINT_H)
 181     IF(HAVE_WINDOWS_H)
 182         CHECK_C_SOURCE_COMPILES("\#include <windows.h>
 183                                  __int64 foo;
 184                                  int main() {return 0;}" HAVE___INT64)
 185     ENDIF()
 186     IF(NOT HAVE___INT64)
 187         IF(NOT SIZEOF_LONG MATCHES "8")
 188             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 189                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 190             ENDIF()
 191         ENDIF()
 192     ENDIF()
 193 ENDIF()
 194
 195
 196 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 197                  OpenAL32/alBuffer.c
 198                  OpenAL32/alEffect.c
 199                  OpenAL32/alError.c
 200                  OpenAL32/alExtension.c
 201                  OpenAL32/alFilter.c
 202                  OpenAL32/alListener.c
 203                  OpenAL32/alSource.c
 204                  OpenAL32/alState.c
 205                  OpenAL32/alThunk.c
 206                  OpenAL32/OpenAL32.c
 207 )
 208 SET(ALC_OBJS  Alc/ALc.c
 209               Alc/ALu.c
 210               Alc/alcConfig.c
 211               Alc/alcRing.c
 212               Alc/alcThread.c
 213               Alc/bs2b.c
 214               Alc/wave.c
 215 )
 216
 217 SET(BACKENDS "")
 218
 219 # Check ALSA backend
 220 IF(ALSA)
 221     CHECK_INCLUDE_FILE(alsa/asoundlib.h HAVE_ALSA_ASOUNDLIB_H)
 222     IF(HAVE_ALSA_ASOUNDLIB_H)
 223         CHECK_LIBRARY_EXISTS(asound snd_pcm_open "" HAVE_LIBASOUND)
 224         IF(HAVE_DLFCN_H OR HAVE_LIBASOUND)
 225             SET(HAVE_ALSA 1)
 226             SET(ALC_OBJS  ${ALC_OBJS} Alc/alsa.c)
 227             IF(HAVE_DLFCN_H)
 228                 SET(BACKENDS  "${BACKENDS} ALSA,")
 229             ELSE()
 230                 SET(BACKENDS  "${BACKENDS} ALSA \(linked\),")
 231                 SET(EXTRA_LIBS asound ${EXTRA_LIBS})
 232             ENDIF()
 233         ENDIF()
 234     ENDIF()
 235 ENDIF()
 236
 237 # Check OSS backend
 238 IF(OSS)
 239     CHECK_INCLUDE_FILE(sys/soundcard.h HAVE_SYS_SOUNDCARD_H)
 240     IF(HAVE_SYS_SOUNDCARD_H)
 241         SET(HAVE_OSS 1)
 242         SET(ALC_OBJS  ${ALC_OBJS} Alc/oss.c)
 243         SET(BACKENDS  "${BACKENDS} OSS,")
 244     ENDIF()
 245 ENDIF()
 246
 247 # Check DSound/MMSystem backend
 248 IF(HAVE_WINDOWS_H)
 249     SET(CMAKE_REQUIRED_LIBRARIES ole32)
 250     CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBOLE32)
 251     SET(CMAKE_REQUIRED_LIBRARIES "")
 252 #    CHECK_LIBRARY_EXISTS(ole32 CoInitialize "" HAVE_LIBOLE32)
 253     IF(HAVE_LIBOLE32)
 254         SET(EXTRA_LIBS ole32 ${EXTRA_LIBS})
 255     ENDIF()
 256
 257     IF(DSOUND)
 258         CHECK_INCLUDE_FILE(dsound.h HAVE_DSOUND_H)
 259         IF(HAVE_DSOUND_H)
 260             SET(HAVE_DSOUND 1)
 261             SET(ALC_OBJS  ${ALC_OBJS} Alc/dsound.c)
 262             SET(BACKENDS  "${BACKENDS} DirectSound,")
 263
 264             CHECK_LIBRARY_EXISTS(dxguid IID_IDirectSound "" HAVE_LIBDXGUID)
 265             IF(HAVE_LIBDXGUID)
 266                 SET(EXTRA_LIBS dxguid ${EXTRA_LIBS})
 267             ENDIF()
 268         ENDIF()
 269     ENDIF()
 270     IF(WINMM)
 271         CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H)
 272         IF(HAVE_MMSYSTEM_H)
 273             SET(HAVE_WINMM 1)
 274             SET(ALC_OBJS  ${ALC_OBJS} Alc/winmm.c)
 275             SET(BACKENDS  "${BACKENDS} WinMM,")
 276
 277             SET(CMAKE_REQUIRED_LIBRARIES winmm)
 278             CHECK_C_SOURCE_COMPILES("int main() {return 0;}" HAVE_LIBWINMM)
 279             SET(CMAKE_REQUIRED_LIBRARIES "")
 280 #            CHECK_LIBRARY_EXISTS(winmm waveInOpen "" HAVE_LIBWINMM)
 281             IF(HAVE_LIBWINMM)
 282                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 283             ENDIF()
 284         ENDIF()
 285     ENDIF()
 286 ENDIF()
 287
 288 # This is always available
 289 SET(BACKENDS  "${BACKENDS} WaveFile")
 290
 291 # End configuration
 292 CONFIGURE_FILE(
 293     "${OpenAL_SOURCE_DIR}/config.h.in"
 294     "${OpenAL_BINARY_DIR}/config.h")
 295
 296 ADD_DEFINITIONS(-DAL_BUILD_LIBRARY)
 297
 298 # Build a shared library
 299 IF(WIN32)
 300     SET(LIBNAME openal32)
 301 ELSE()
 302     SET(LIBNAME openal)
 303 ENDIF()
 304
 305 ADD_LIBRARY(${LIBNAME} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
 306 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 307                                             SOVERSION ${LIB_MAJOR_VERSION})
 308 IF(WIN32)
 309     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 310 ENDIF()
 311
 312 TARGET_LINK_LIBRARIES(${LIBNAME} ${EXTRA_LIBS})
 313
 314 # Add an install target here
 315 INSTALL(TARGETS ${LIBNAME}
 316         RUNTIME DESTINATION bin
 317         LIBRARY DESTINATION lib
 318         ARCHIVE DESTINATION lib
 319 )
 320 INSTALL(FILES include/AL/al.h
 321               include/AL/alc.h
 322         DESTINATION include/AL
 323 )
 324
 325 MESSAGE(STATUS "")
 326 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
 327 MESSAGE(STATUS "    ${BACKENDS}")
 328 MESSAGE(STATUS "")