CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 SET(CPP_DEFS ) # C pre-process, not C++
  66 SET(INC_PATHS )
  67 SET(C_FLAGS )
  68 SET(LINKER_FLAGS )
  69 SET(EXTRA_LIBS )
  70
  71 IF(WIN32)
  72     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  73
  74     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  75
  76     # This option is mainly for static linking OpenAL Soft into another project
  77     # that already defines the IDs. It is up to that project to ensure all
  78     # required IDs are defined.
  79     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  80
  81     IF(MINGW)
  82         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  83         IF(NOT DLLTOOL)
  84             IF(HOST)
  85                 SET(DLLTOOL "${HOST}-dlltool")
  86             ELSE()
  87                 SET(DLLTOOL "dlltool")
  88             ENDIF()
  89         ENDIF()
  90     ENDIF()
  91 ENDIF()
  92
  93
  94 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  95 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  96     SET(INC_PATHS ${INC_PATHS} /usr/include)
  97     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
  98 ENDIF()
  99
 100 IF(NOT LIBTYPE)
 101     SET(LIBTYPE SHARED)
 102 ENDIF()
 103
 104 SET(LIB_MAJOR_VERSION "1")
 105 SET(LIB_MINOR_VERSION "18")
 106 SET(LIB_REVISION "2")
 107 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 108
 109 SET(EXPORT_DECL "")
 110 SET(ALIGN_DECL "")
 111
 112
 113 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 114 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 115
 116
 117 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 118 IF(HAVE_STD_C11)
 119     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 120 ELSE()
 121     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 122     IF(HAVE_STD_C99)
 123         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 124     ENDIF()
 125 ENDIF()
 126
 127 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 128 IF(HAVE_STD_CXX11)
 129     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 130 ENDIF()
 131
 132 if(NOT WIN32)
 133     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 134     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 135     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 136         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 137         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 138         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 139         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 140             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 141         ELSE()
 142             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 143         ENDIF()
 144     ENDIF()
 145     UNSET(OLD_REQUIRED_FLAGS)
 146 ENDIF()
 147
 148 # Set defines for large file support
 149 CHECK_FILE_OFFSET_BITS()
 150 IF(_FILE_OFFSET_BITS)
 151     SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 152     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 153 ENDIF()
 154 SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 155 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 156
 157 # MSVC may need workarounds for C99 restrict and inline
 158 IF(MSVC)
 159     # TODO: Once we truly require C99, these restrict and inline checks should go
 160     # away.
 161     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 162                              int main() {return 0;}" HAVE_RESTRICT)
 163     IF(NOT HAVE_RESTRICT)
 164         SET(CPP_DEFS ${CPP_DEFS} "restrict=")
 165         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 166     ENDIF()
 167
 168     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 169                              int main() {return 0;}" HAVE_INLINE)
 170     IF(NOT HAVE_INLINE)
 171         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 172                                  int main() {return 0;}" HAVE___INLINE)
 173         IF(NOT HAVE___INLINE)
 174             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 175         ENDIF()
 176
 177         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 178         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 179     ENDIF()
 180 ENDIF()
 181
 182 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 183 IF(CMAKE_COMPILER_IS_GNUCC)
 184     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 185
 186     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 187     # Force no inlining for the next test.
 188     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 189
 190     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 191                              int main() {return foo();}" INLINE_IS_C99)
 192     IF(NOT INLINE_IS_C99)
 193         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 194                              Please update your compiler for better C99 compliance.")
 195     ENDIF()
 196
 197     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 198 ENDIF()
 199
 200 # Check if we have a proper timespec declaration
 201 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 202 IF(HAVE_STRUCT_TIMESPEC)
 203     # Define it here so we don't have to include config.h for it
 204     SET(CPP_DEFS ${CPP_DEFS} HAVE_STRUCT_TIMESPEC)
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Check if we have C99 variable length arrays
 232 CHECK_C_SOURCE_COMPILES(
 233 "int main(int argc, char *argv[])
 234  {
 235      volatile int tmp[argc];
 236      tmp[0] = argv[0][0];
 237      return tmp[0];
 238  }"
 239 HAVE_C99_VLA)
 240
 241 # Check if we have C99 bool
 242 CHECK_C_SOURCE_COMPILES(
 243 "int main(int argc, char *argv[])
 244  {
 245      volatile _Bool ret;
 246      ret = (argc > 1) ? 1 : 0;
 247      return ret ? -1 : 0;
 248  }"
 249 HAVE_C99_BOOL)
 250
 251 # Check if we have C11 static_assert
 252 CHECK_C_SOURCE_COMPILES(
 253 "int main()
 254  {
 255      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 256      return 0;
 257  }"
 258 HAVE_C11_STATIC_ASSERT)
 259
 260 # Check if we have C11 alignas
 261 CHECK_C_SOURCE_COMPILES(
 262 "_Alignas(16) int foo;
 263  int main()
 264  {
 265      return 0;
 266  }"
 267 HAVE_C11_ALIGNAS)
 268
 269 # Check if we have C11 _Atomic
 270 CHECK_C_SOURCE_COMPILES(
 271 "#include <stdatomic.h>
 272  int _Atomic foo = ATOMIC_VAR_INIT(0);
 273  int main()
 274  {
 275      atomic_fetch_add(&foo, 2);
 276      return 0;
 277  }"
 278 HAVE_C11_ATOMIC)
 279
 280 # Add definitions, compiler switches, etc.
 281 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 282
 283 IF(NOT CMAKE_BUILD_TYPE)
 284     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 285         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 286         FORCE)
 287 ENDIF()
 288 IF(NOT CMAKE_DEBUG_POSTFIX)
 289     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 290         "Library postfix for debug builds. Normally left blank."
 291         FORCE)
 292 ENDIF()
 293
 294 IF(MSVC)
 295     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 296     SET(C_FLAGS ${C_FLAGS} /wd4098)
 297
 298     IF(NOT DXSDK_DIR)
 299         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 300     ELSE()
 301         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 302     ENDIF()
 303     IF(DXSDK_DIR)
 304         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 305     ENDIF()
 306
 307     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 308     IF(FORCE_STATIC_VCRT)
 309         FOREACH(flag_var
 310                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 311                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 312             IF(${flag_var} MATCHES "/MD")
 313                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 314             ENDIF()
 315         ENDFOREACH(flag_var)
 316     ENDIF()
 317 ELSE()
 318     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 319     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 320     IF(HAVE_W_EXTRA)
 321         SET(C_FLAGS ${C_FLAGS} -Wextra)
 322     ENDIF()
 323
 324     IF(ALSOFT_WERROR)
 325         SET(C_FLAGS ${C_FLAGS} -Werror)
 326     ENDIF()
 327
 328     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 329     # instead of NDEBUG)
 330     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 331         IF(${flag_var} MATCHES "-DNDEBUG")
 332             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 333         ENDIF()
 334     ENDFOREACH()
 335
 336     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 337     IF(HAVE_FNO_MATH_ERRNO)
 338         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 339     ENDIF()
 340
 341     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 342                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 343
 344     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 345     if(ALSOFT_STATIC_LIBGCC)
 346         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 347         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 348         check_c_source_compiles(
 349 "#include <stdlib.h>
 350 int main()
 351 {
 352     return 0;
 353 }"
 354             HAVE_STATIC_LIBGCC_SWITCH
 355         )
 356         if(HAVE_STATIC_LIBGCC_SWITCH)
 357             SET(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 358         endif()
 359         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 360         unset(OLD_REQUIRED_LIBRARIES)
 361     endif()
 362 ENDIF()
 363
 364 # Set visibility/export options if available
 365 IF(WIN32)
 366     SET(EXPORT_DECL "__declspec(dllexport)")
 367     IF(NOT MINGW)
 368         SET(ALIGN_DECL "__declspec(align(x))")
 369     ELSE()
 370         SET(ALIGN_DECL "__declspec(aligned(x))")
 371     ENDIF()
 372 ELSE()
 373     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 374     # Yes GCC, really don't accept visibility modes you don't support
 375     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 376
 377     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 378                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 379     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 380         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 381     ELSE()
 382         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 383                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 384         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 385             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 386         ENDIF()
 387     ENDIF()
 388
 389     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 390         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 391         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 392             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 393         ENDIF()
 394     ENDIF()
 395
 396     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 397                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 398     IF(HAVE_ATTRIBUTE_ALIGNED)
 399         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 400     ENDIF()
 401
 402     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 403 ENDIF()
 404
 405 CHECK_C_SOURCE_COMPILES("
 406 int main()
 407 {
 408     float *ptr;
 409     ptr = __builtin_assume_aligned(ptr, 16);
 410     return 0;
 411 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 412 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 413     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 414 ELSE()
 415     SET(ASSUME_ALIGNED_DECL "x")
 416 ENDIF()
 417
 418 SET(SSE_SWITCH "")
 419 SET(SSE2_SWITCH "")
 420 SET(SSE3_SWITCH "")
 421 SET(SSE4_1_SWITCH "")
 422 SET(FPU_NEON_SWITCH "")
 423
 424 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 425 IF(HAVE_MSSE_SWITCH)
 426     SET(SSE_SWITCH "-msse")
 427 ENDIF()
 428 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 429 IF(HAVE_MSSE2_SWITCH)
 430     SET(SSE2_SWITCH "-msse2")
 431 ENDIF()
 432 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 433 IF(HAVE_MSSE3_SWITCH)
 434     SET(SSE3_SWITCH "-msse3")
 435 ENDIF()
 436 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 437 IF(HAVE_MSSE4_1_SWITCH)
 438     SET(SSE4_1_SWITCH "-msse4.1")
 439 ENDIF()
 440 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 441 IF(HAVE_MFPU_NEON_SWITCH)
 442     SET(FPU_NEON_SWITCH "-mfpu=neon")
 443 ENDIF()
 444
 445 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 446                          int main() {return 0;}" HAVE_GCC_FORMAT)
 447
 448 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 449 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 450 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 451 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 452 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 453 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 454 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 455 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 456 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 457 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 458 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 459 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 460 IF(NOT HAVE_GUIDDEF_H)
 461     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 462 ENDIF()
 463
 464 # Some systems need libm for some of the following math functions to work
 465 SET(MATH_LIB )
 466 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 467 IF(HAVE_LIBM)
 468     SET(MATH_LIB ${MATH_LIB} m)
 469     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 470 ENDIF()
 471
 472 # Check for the dlopen API (for dynamicly loading backend libs)
 473 IF(ALSOFT_DLOPEN)
 474     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 475     IF(HAVE_LIBDL)
 476         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 477         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 478     ENDIF()
 479
 480     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 481 ENDIF()
 482
 483 # Check for a cpuid intrinsic
 484 IF(HAVE_CPUID_H)
 485     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 486         int main()
 487         {
 488             unsigned int eax, ebx, ecx, edx;
 489             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 490         }" HAVE_GCC_GET_CPUID)
 491 ENDIF()
 492 IF(HAVE_INTRIN_H)
 493     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 494         int main()
 495         {
 496             int regs[4];
 497             __cpuid(regs, 0);
 498             return regs[0];
 499         }" HAVE_CPUID_INTRINSIC)
 500 ENDIF()
 501
 502 CHECK_SYMBOL_EXISTS(sysconf          unistd.h HAVE_SYSCONF)
 503 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 504 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 505 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 506 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 507 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 508 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 509 IF(NOT HAVE_C99_VLA)
 510     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 511     IF(NOT HAVE_ALLOCA)
 512         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 513     ENDIF()
 514 ENDIF()
 515
 516 IF(HAVE_FLOAT_H)
 517     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 518     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 519 ENDIF()
 520
 521 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 522 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 523 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 524 IF(NOT HAVE_STRCASECMP)
 525     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 526     IF(NOT HAVE__STRICMP)
 527         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 528     ENDIF()
 529
 530     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 531 ENDIF()
 532
 533 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 534 IF(NOT HAVE_STRNCASECMP)
 535     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 536     IF(NOT HAVE__STRNICMP)
 537         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 538     ENDIF()
 539
 540     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 541 ENDIF()
 542
 543 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 544 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 545 IF(NOT HAVE_SNPRINTF)
 546     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 547     IF(NOT HAVE__SNPRINTF)
 548         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 549     ENDIF()
 550
 551     SET(CPP_DEFS ${CPP_DEFS} snprintf=_snprintf)
 552 ENDIF()
 553
 554 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 555 IF(NOT HAVE_ISFINITE)
 556     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 557     IF(NOT HAVE_FINITE)
 558         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 559         IF(NOT HAVE__FINITE)
 560             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 561         ENDIF()
 562         SET(CPP_DEFS ${CPP_DEFS} isfinite=_finite)
 563     ELSE()
 564         SET(CPP_DEFS ${CPP_DEFS} isfinite=finite)
 565     ENDIF()
 566 ENDIF()
 567
 568 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 569 IF(NOT HAVE_ISNAN)
 570     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 571     IF(NOT HAVE__ISNAN)
 572         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 573     ENDIF()
 574
 575     SET(CPP_DEFS ${CPP_DEFS} isnan=_isnan)
 576 ENDIF()
 577
 578
 579 # Check if we have Windows headers
 580 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 581 IF(NOT HAVE_WINDOWS_H)
 582     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 583     IF(NOT HAVE_GETTIMEOFDAY)
 584         MESSAGE(FATAL_ERROR "No timing function found!")
 585     ENDIF()
 586
 587     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 588     IF(NOT HAVE_NANOSLEEP)
 589         MESSAGE(FATAL_ERROR "No sleep function found!")
 590     ENDIF()
 591
 592     # We need pthreads outside of Windows
 593     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 594     IF(NOT HAVE_PTHREAD_H)
 595         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 596     ENDIF()
 597     # Some systems need pthread_np.h to get recursive mutexes
 598     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 599
 600     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 601     IF(HAVE_PTHREAD)
 602         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 603         SET(C_FLAGS ${C_FLAGS} -pthread)
 604         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 605     ENDIF()
 606
 607     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 608     IF(HAVE_LIBPTHREAD)
 609         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 610     ENDIF()
 611
 612     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 613
 614     IF(HAVE_PTHREAD_NP_H)
 615         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 616         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 617             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 618         ELSE()
 619             CHECK_C_SOURCE_COMPILES("
 620 #include <pthread.h>
 621 #include <pthread_np.h>
 622 int main()
 623 {
 624     pthread_setname_np(\"testname\");
 625     return 0;
 626 }"
 627                 PTHREAD_SETNAME_NP_ONE_PARAM
 628             )
 629             CHECK_C_SOURCE_COMPILES("
 630 #include <pthread.h>
 631 #include <pthread_np.h>
 632 int main()
 633 {
 634     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 635     return 0;
 636 }"
 637                 PTHREAD_SETNAME_NP_THREE_PARAMS
 638             )
 639         ENDIF()
 640         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 641     ELSE()
 642         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 643         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 644             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 645         ELSE()
 646             CHECK_C_SOURCE_COMPILES("
 647 #include <pthread.h>
 648 int main()
 649 {
 650     pthread_setname_np(\"testname\");
 651     return 0;
 652 }"
 653                 PTHREAD_SETNAME_NP_ONE_PARAM
 654             )
 655             CHECK_C_SOURCE_COMPILES("
 656 #include <pthread.h>
 657 int main()
 658 {
 659     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 660     return 0;
 661 }"
 662                 PTHREAD_SETNAME_NP_THREE_PARAMS
 663             )
 664         ENDIF()
 665         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 666     ENDIF()
 667
 668     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 669
 670     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 671     IF(HAVE_LIBRT)
 672         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 673     ENDIF()
 674 ENDIF()
 675
 676 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 677
 678 # Check for a 64-bit type
 679 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 680 IF(NOT HAVE_STDINT_H)
 681     IF(HAVE_WINDOWS_H)
 682         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 683                                  #include <windows.h>
 684                                  __int64 foo;
 685                                  int main() {return 0;}" HAVE___INT64)
 686     ENDIF()
 687     IF(NOT HAVE___INT64)
 688         IF(NOT SIZEOF_LONG MATCHES "8")
 689             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 690                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 691             ENDIF()
 692         ENDIF()
 693     ENDIF()
 694 ENDIF()
 695
 696
 697 SET(COMMON_OBJS  common/almalloc.c
 698                  common/atomic.c
 699                  common/rwlock.c
 700                  common/threads.c
 701                  common/uintmap.c
 702 )
 703 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 704                  OpenAL32/alBuffer.c
 705                  OpenAL32/alEffect.c
 706                  OpenAL32/alError.c
 707                  OpenAL32/alExtension.c
 708                  OpenAL32/alFilter.c
 709                  OpenAL32/alListener.c
 710                  OpenAL32/alSource.c
 711                  OpenAL32/alState.c
 712                  OpenAL32/alThunk.c
 713                  OpenAL32/sample_cvt.c
 714 )
 715 SET(ALC_OBJS  Alc/ALc.c
 716               Alc/ALu.c
 717               Alc/alconfig.c
 718               Alc/bs2b.c
 719               Alc/converter.c
 720               Alc/mastering.c
 721               Alc/ringbuffer.c
 722               Alc/effects/chorus.c
 723               Alc/effects/compressor.c
 724               Alc/effects/dedicated.c
 725               Alc/effects/distortion.c
 726               Alc/effects/echo.c
 727               Alc/effects/equalizer.c
 728               Alc/effects/modulator.c
 729               Alc/effects/null.c
 730               Alc/effects/reverb.c
 731               Alc/helpers.c
 732               Alc/hrtf.c
 733               Alc/uhjfilter.c
 734               Alc/ambdec.c
 735               Alc/bformatdec.c
 736               Alc/nfcfilter.c
 737               Alc/panning.c
 738               Alc/mixer.c
 739               Alc/mixer_c.c
 740 )
 741
 742
 743 SET(CPU_EXTS "Default")
 744 SET(HAVE_SSE        0)
 745 SET(HAVE_SSE2       0)
 746 SET(HAVE_SSE3       0)
 747 SET(HAVE_SSE4_1     0)
 748 SET(HAVE_NEON       0)
 749
 750 SET(HAVE_ALSA       0)
 751 SET(HAVE_OSS        0)
 752 SET(HAVE_SOLARIS    0)
 753 SET(HAVE_SNDIO      0)
 754 SET(HAVE_QSA        0)
 755 SET(HAVE_DSOUND     0)
 756 SET(HAVE_MMDEVAPI   0)
 757 SET(HAVE_WINMM      0)
 758 SET(HAVE_PORTAUDIO  0)
 759 SET(HAVE_PULSEAUDIO 0)
 760 SET(HAVE_COREAUDIO  0)
 761 SET(HAVE_OPENSL     0)
 762 SET(HAVE_WAVE       0)
 763
 764 # Check for SSE support
 765 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 766 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 767 IF(HAVE_XMMINTRIN_H)
 768     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 769     IF(ALSOFT_CPUEXT_SSE)
 770         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 771             SET(HAVE_SSE 1)
 772             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 773             IF(SSE_SWITCH)
 774                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 775                                             COMPILE_FLAGS "${SSE_SWITCH}")
 776             ENDIF()
 777             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 778         ENDIF()
 779     ENDIF()
 780 ENDIF()
 781 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 782     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 783 ENDIF()
 784
 785 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 786 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 787 IF(HAVE_EMMINTRIN_H)
 788     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 789     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 790         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 791             SET(HAVE_SSE2 1)
 792             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 793             IF(SSE2_SWITCH)
 794                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 795                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 796             ENDIF()
 797             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 798         ENDIF()
 799     ENDIF()
 800 ENDIF()
 801 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 802     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 803 ENDIF()
 804
 805 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 806 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 807 IF(HAVE_EMMINTRIN_H)
 808     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 809     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 810         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 811             SET(HAVE_SSE3 1)
 812             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 813             IF(SSE2_SWITCH)
 814                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 815                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 816             ENDIF()
 817             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 818         ENDIF()
 819     ENDIF()
 820 ENDIF()
 821 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 822     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 823 ENDIF()
 824
 825 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 826 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 827 IF(HAVE_SMMINTRIN_H)
 828     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 829     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 830         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 831             SET(HAVE_SSE4_1 1)
 832             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 833             IF(SSE4_1_SWITCH)
 834                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 835                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 836             ENDIF()
 837             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 838         ENDIF()
 839     ENDIF()
 840 ENDIF()
 841 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 842     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 843 ENDIF()
 844
 845 # Check for ARM Neon support
 846 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 847 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 848 IF(HAVE_ARM_NEON_H)
 849     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 850     IF(ALSOFT_CPUEXT_NEON)
 851         SET(HAVE_NEON 1)
 852         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 853         IF(FPU_NEON_SWITCH)
 854             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 855                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 856         ENDIF()
 857         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 858     ENDIF()
 859 ENDIF()
 860 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 861     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 862 ENDIF()
 863
 864
 865 IF(WIN32 OR HAVE_DLFCN_H)
 866     SET(IS_LINKED "")
 867     MACRO(ADD_BACKEND_LIBS _LIBS)
 868     ENDMACRO()
 869 ELSE()
 870     SET(IS_LINKED " (linked)")
 871     MACRO(ADD_BACKEND_LIBS _LIBS)
 872         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 873     ENDMACRO()
 874 ENDIF()
 875
 876 SET(BACKENDS "")
 877 SET(ALC_OBJS  ${ALC_OBJS}
 878               Alc/backends/base.c
 879               # Default backends, always available
 880               Alc/backends/loopback.c
 881               Alc/backends/null.c
 882 )
 883
 884 # Check ALSA backend
 885 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 886 FIND_PACKAGE(ALSA)
 887 IF(ALSA_FOUND)
 888     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 889     IF(ALSOFT_BACKEND_ALSA)
 890         SET(HAVE_ALSA 1)
 891         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 892         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 893         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 894         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 895     ENDIF()
 896 ENDIF()
 897 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 898     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 899 ENDIF()
 900
 901 # Check OSS backend
 902 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 903 FIND_PACKAGE(OSS)
 904 IF(OSS_FOUND)
 905     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 906     IF(ALSOFT_BACKEND_OSS)
 907         SET(HAVE_OSS 1)
 908         SET(BACKENDS  "${BACKENDS} OSS,")
 909         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 910         IF(OSS_LIBRARIES)
 911             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 912         ENDIF()
 913         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 914     ENDIF()
 915 ENDIF()
 916 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 917     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 918 ENDIF()
 919
 920 # Check Solaris backend
 921 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 922 FIND_PACKAGE(AudioIO)
 923 IF(AUDIOIO_FOUND)
 924     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 925     IF(ALSOFT_BACKEND_SOLARIS)
 926         SET(HAVE_SOLARIS 1)
 927         SET(BACKENDS  "${BACKENDS} Solaris,")
 928         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 929         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 930     ENDIF()
 931 ENDIF()
 932 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 933     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 934 ENDIF()
 935
 936 # Check SndIO backend
 937 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 938 FIND_PACKAGE(SoundIO)
 939 IF(SOUNDIO_FOUND)
 940     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 941     IF(ALSOFT_BACKEND_SNDIO)
 942         SET(HAVE_SNDIO 1)
 943         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 944         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 945         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 946         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 947     ENDIF()
 948 ENDIF()
 949 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 950     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 951 ENDIF()
 952
 953 # Check QSA backend
 954 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 955 FIND_PACKAGE(QSA)
 956 IF(QSA_FOUND)
 957     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 958     IF(ALSOFT_BACKEND_QSA)
 959         SET(HAVE_QSA 1)
 960         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 961         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 962         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 963         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
 964     ENDIF()
 965 ENDIF()
 966 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 967     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 968 ENDIF()
 969
 970 # Check Windows-only backends
 971 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 972 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 973 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 974 IF(HAVE_WINDOWS_H)
 975     # Check MMSystem backend
 976     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 977     IF(HAVE_MMSYSTEM_H)
 978         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 979         IF(HAVE_LIBWINMM)
 980             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 981             IF(ALSOFT_BACKEND_WINMM)
 982                 SET(HAVE_WINMM 1)
 983                 SET(BACKENDS  "${BACKENDS} WinMM,")
 984                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 985                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 986             ENDIF()
 987         ENDIF()
 988     ENDIF()
 989
 990     # Check DSound backend
 991     FIND_PACKAGE(DSound)
 992     IF(DSOUND_FOUND)
 993         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 994         IF(ALSOFT_BACKEND_DSOUND)
 995             SET(HAVE_DSOUND 1)
 996             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 997             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 998             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 999             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1000         ENDIF()
1001     ENDIF()
1002
1003     # Check for MMDevApi backend
1004     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1005     IF(HAVE_MMDEVICEAPI_H)
1006         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
1007         IF(ALSOFT_BACKEND_MMDEVAPI)
1008             SET(HAVE_MMDEVAPI 1)
1009             SET(BACKENDS  "${BACKENDS} MMDevApi,")
1010             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
1011         ENDIF()
1012     ENDIF()
1013 ENDIF()
1014 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1015     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1016 ENDIF()
1017 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1018     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1019 ENDIF()
1020 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
1021     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
1022 ENDIF()
1023
1024 # Check PortAudio backend
1025 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1026 FIND_PACKAGE(PortAudio)
1027 IF(PORTAUDIO_FOUND)
1028     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1029     IF(ALSOFT_BACKEND_PORTAUDIO)
1030         SET(HAVE_PORTAUDIO 1)
1031         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1032         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1033         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1034         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1035     ENDIF()
1036 ENDIF()
1037 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1038     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1039 ENDIF()
1040
1041 # Check PulseAudio backend
1042 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1043 FIND_PACKAGE(PulseAudio)
1044 IF(PULSEAUDIO_FOUND)
1045     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1046     IF(ALSOFT_BACKEND_PULSEAUDIO)
1047         SET(HAVE_PULSEAUDIO 1)
1048         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1049         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1050         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1051         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1052     ENDIF()
1053 ENDIF()
1054 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1055     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1056 ENDIF()
1057
1058 # Check JACK backend
1059 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1060 FIND_PACKAGE(JACK)
1061 IF(JACK_FOUND)
1062     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1063     IF(ALSOFT_BACKEND_JACK)
1064         SET(HAVE_JACK 1)
1065         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1066         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1067         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1068         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1069     ENDIF()
1070 ENDIF()
1071 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1072     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1073 ENDIF()
1074
1075 # Check CoreAudio backend
1076 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1077 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1078              NAMES CoreAudio
1079              PATHS /System/Library/Frameworks
1080 )
1081 IF(COREAUDIO_FRAMEWORK)
1082     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1083     IF(ALSOFT_BACKEND_COREAUDIO)
1084         SET(HAVE_COREAUDIO 1)
1085         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1086         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1087         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1088         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1089         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1090
1091         # Some versions of OSX may need the AudioToolbox framework. Add it if
1092         # it's found.
1093         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1094                      NAMES AudioToolbox
1095                      PATHS ~/Library/Frameworks
1096                            /Library/Frameworks
1097                            /System/Library/Frameworks
1098                     )
1099         IF(AUDIOTOOLBOX_LIBRARY)
1100             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1101         ENDIF()
1102     ENDIF()
1103 ENDIF()
1104 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1105     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1106 ENDIF()
1107
1108 # Check for OpenSL (Android) backend
1109 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1110 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1111 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1112     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1113     IF(HAVE_LIBOPENSLES)
1114         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1115         IF(ALSOFT_BACKEND_OPENSL)
1116             SET(HAVE_OPENSL 1)
1117             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1118             SET(BACKENDS  "${BACKENDS} OpenSL,")
1119             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1120         ENDIF()
1121     ENDIF()
1122 ENDIF()
1123 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1124     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1125 ENDIF()
1126
1127 # Optionally enable the Wave Writer backend
1128 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1129 IF(ALSOFT_BACKEND_WAVE)
1130     SET(HAVE_WAVE 1)
1131     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1132     SET(BACKENDS  "${BACKENDS} WaveFile,")
1133 ENDIF()
1134
1135 # This is always available
1136 SET(BACKENDS  "${BACKENDS} Null")
1137
1138
1139 FIND_PACKAGE(Git)
1140 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1141     # Get the current working branch and its latest abbreviated commit hash
1142     ADD_CUSTOM_TARGET(build_version
1143         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1144                          -D LIB_VERSION=${LIB_VERSION}
1145                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1146                          -D DST=${OpenAL_BINARY_DIR}/version.h
1147                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1148         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1149         VERBATIM
1150     )
1151 ELSE()
1152     SET(GIT_BRANCH "UNKNOWN")
1153     SET(GIT_COMMIT_HASH "unknown")
1154     CONFIGURE_FILE(
1155         "${OpenAL_SOURCE_DIR}/version.h.in"
1156         "${OpenAL_BINARY_DIR}/version.h")
1157 ENDIF()
1158
1159 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1160 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1161 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1162
1163 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1164 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1165 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1166     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1167     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1168     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1169     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1170     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1171     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1172                      C "${NATIVE_SRC_DIR}bsincgen.c"
1173     VERBATIM
1174 )
1175 ADD_CUSTOM_TARGET(native-tools
1176     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1177     VERBATIM
1178 )
1179
1180 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1181 if(ALSOFT_EMBED_HRTF_DATA)
1182     MACRO(make_hrtf_header FILENAME VARNAME)
1183         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1184         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1185
1186         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1187             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1188             DEPENDS native-tools "${infile}"
1189             VERBATIM
1190         )
1191         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1192     ENDMACRO()
1193
1194     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1195     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1196 endif()
1197
1198 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1199     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1200     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1201     VERBATIM
1202 )
1203 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1204
1205
1206 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1207     add_subdirectory(utils/alsoft-config)
1208 ENDIF()
1209 IF(ALSOFT_EXAMPLES)
1210     FIND_PACKAGE(SDL2)
1211     IF(SDL2_FOUND)
1212         FIND_PACKAGE(SDL_sound)
1213         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1214     ENDIF()
1215 ENDIF()
1216
1217 IF(NOT WIN32)
1218     SET(LIBNAME "openal")
1219 ELSE()
1220     SET(LIBNAME "OpenAL32")
1221 ENDIF()
1222
1223 # Needed for openal.pc.in
1224 SET(prefix ${CMAKE_INSTALL_PREFIX})
1225 SET(exec_prefix "\${prefix}")
1226 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1227 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1228 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1229 SET(PACKAGE_VERSION "${LIB_VERSION}")
1230 IF(LIBTYPE STREQUAL "STATIC")
1231     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1232 ENDIF()
1233
1234 # End configuration
1235 CONFIGURE_FILE(
1236     "${OpenAL_SOURCE_DIR}/config.h.in"
1237     "${OpenAL_BINARY_DIR}/config.h")
1238 CONFIGURE_FILE(
1239     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1240     "${OpenAL_BINARY_DIR}/openal.pc"
1241     @ONLY)
1242
1243
1244 # Add a static library with common functions used by multiple targets
1245 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1246 TARGET_COMPILE_DEFINITIONS(common PRIVATE ${CPP_DEFS})
1247 TARGET_COMPILE_OPTIONS(common PRIVATE ${C_FLAGS})
1248
1249
1250 UNSET(HAS_ROUTER)
1251 SET(IMPL_TARGET OpenAL)
1252 SET(COMMON_LIB )
1253 SET(SUBSYS_FLAG )
1254
1255 # Build main library
1256 IF(LIBTYPE STREQUAL "STATIC")
1257     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1258     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1259         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1260     ENDIF()
1261     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1262 ELSE()
1263     # Make sure to compile the common code with PIC, since it'll be linked into
1264     # shared libs that needs it.
1265     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1266     SET(COMMON_LIB common)
1267
1268     IF(WIN32)
1269         IF(MSVC)
1270             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1271         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1272             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1273         ENDIF()
1274     ENDIF()
1275
1276     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1277         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c)
1278         TARGET_COMPILE_DEFINITIONS(OpenAL
1279             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1280         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1281         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${LINKER_FLAGS} ${COMMON_LIB})
1282         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1283         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1284         IF(TARGET build_version)
1285             ADD_DEPENDENCIES(OpenAL build_version)
1286         ENDIF()
1287         SET(HAS_ROUTER 1)
1288
1289         SET(LIBNAME "soft_oal")
1290         SET(IMPL_TARGET soft_oal)
1291     ENDIF()
1292
1293     ADD_LIBRARY(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1294     IF(WIN32)
1295         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1296     ENDIF()
1297 ENDIF()
1298 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1299     VERSION ${LIB_VERSION}
1300     SOVERSION ${LIB_MAJOR_VERSION}
1301 )
1302 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1303     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1304 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1305     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1306 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1307 TARGET_LINK_LIBRARIES(${IMPL_TARGET}
1308     PRIVATE ${LINKER_FLAGS} ${COMMON_LIB} ${EXTRA_LIBS} ${MATH_LIB})
1309 IF(TARGET build_version)
1310     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1311 ENDIF()
1312
1313 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1314     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1315     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1316     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1317         MESSAGE(STATUS "")
1318         IF(NOT SED_EXECUTABLE)
1319             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1320         ENDIF()
1321         IF(NOT DLLTOOL_EXECUTABLE)
1322             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1323         ENDIF()
1324     ELSE()
1325         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1326                         " -Wl,--output-def,OpenAL32.def")
1327         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1328             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1329             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1330             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1331             VERBATIM
1332         )
1333     ENDIF()
1334 ENDIF()
1335
1336 IF(ALSOFT_INSTALL)
1337     INSTALL(TARGETS OpenAL EXPORT OpenAL
1338             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1339             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1340             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1341             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1342     )
1343     EXPORT(TARGETS OpenAL
1344            NAMESPACE OpenAL::
1345            FILE OpenALConfig.cmake)
1346     INSTALL(EXPORT OpenAL
1347             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1348             NAMESPACE OpenAL::
1349             FILE OpenALConfig.cmake)
1350     INSTALL(FILES include/AL/al.h
1351                   include/AL/alc.h
1352                   include/AL/alext.h
1353                   include/AL/efx.h
1354                   include/AL/efx-creative.h
1355                   include/AL/efx-presets.h
1356             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1357     )
1358     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1359             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1360     IF(TARGET soft_oal)
1361         INSTALL(TARGETS soft_oal
1362                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1363         )
1364     ENDIF()
1365 ENDIF()
1366
1367
1368 if(HAS_ROUTER)
1369     message(STATUS "")
1370     message(STATUS "Building DLL router")
1371 endif()
1372
1373 MESSAGE(STATUS "")
1374 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1375 MESSAGE(STATUS "    ${BACKENDS}")
1376 MESSAGE(STATUS "")
1377 MESSAGE(STATUS "Building with support for CPU extensions:")
1378 MESSAGE(STATUS "    ${CPU_EXTS}")
1379 MESSAGE(STATUS "")
1380
1381 IF(WIN32)
1382     IF(NOT HAVE_DSOUND)
1383         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1384         MESSAGE(STATUS "         This is probably NOT what you want!")
1385         MESSAGE(STATUS "")
1386     ENDIF()
1387 ENDIF()
1388
1389 if(ALSOFT_EMBED_HRTF_DATA)
1390     message(STATUS "Embedding HRTF datasets")
1391     message(STATUS "")
1392 endif()
1393
1394 # Install alsoft.conf configuration file
1395 IF(ALSOFT_CONFIG)
1396     INSTALL(FILES alsoftrc.sample
1397             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1398     )
1399     MESSAGE(STATUS "Installing sample configuration")
1400     MESSAGE(STATUS "")
1401 ENDIF()
1402
1403 # Install HRTF definitions
1404 IF(ALSOFT_HRTF_DEFS)
1405     INSTALL(FILES hrtf/default-44100.mhr
1406                   hrtf/default-48000.mhr
1407             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1408     )
1409     MESSAGE(STATUS "Installing HRTF definitions")
1410     MESSAGE(STATUS "")
1411 ENDIF()
1412
1413 # Install AmbDec presets
1414 IF(ALSOFT_AMBDEC_PRESETS)
1415     INSTALL(FILES presets/3D7.1.ambdec
1416                   presets/hexagon.ambdec
1417                   presets/itu5.1.ambdec
1418                   presets/itu5.1-nocenter.ambdec
1419                   presets/rectangle.ambdec
1420                   presets/square.ambdec
1421                   presets/presets.txt
1422             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1423     )
1424     MESSAGE(STATUS "Installing AmbDec presets")
1425     MESSAGE(STATUS "")
1426 ENDIF()
1427
1428 IF(ALSOFT_UTILS)
1429     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1430     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1431     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1432
1433     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1434     IF(NOT HAVE_GETOPT)
1435         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c)
1436     ENDIF()
1437     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1438     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1439     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1440     IF(HAVE_LIBM)
1441         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1442     ENDIF()
1443
1444     IF(ALSOFT_INSTALL)
1445         INSTALL(TARGETS openal-info makehrtf
1446                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1447                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1448                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1449         )
1450     ENDIF()
1451
1452     MESSAGE(STATUS "Building utility programs")
1453     IF(TARGET alsoft-config)
1454         MESSAGE(STATUS "Building configuration program")
1455     ENDIF()
1456     MESSAGE(STATUS "")
1457 ENDIF()
1458
1459 IF(ALSOFT_TESTS)
1460     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1461
1462     ADD_EXECUTABLE(altonegen examples/altonegen.c ${TEST_COMMON_OBJS})
1463     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1464     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1465     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} common OpenAL ${MATH_LIB})
1466
1467     IF(ALSOFT_INSTALL)
1468         INSTALL(TARGETS altonegen
1469                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1470                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1471                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1472         )
1473     ENDIF()
1474
1475     MESSAGE(STATUS "Building test programs")
1476     MESSAGE(STATUS "")
1477 ENDIF()
1478
1479 IF(ALSOFT_EXAMPLES)
1480     ADD_EXECUTABLE(alrecord examples/alrecord.c)
1481     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1482     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1483     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} common OpenAL)
1484
1485     IF(ALSOFT_INSTALL)
1486         INSTALL(TARGETS alrecord
1487                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1488                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1489                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1490         )
1491     ENDIF()
1492
1493     MESSAGE(STATUS "Building example programs")
1494
1495     IF(SDL2_FOUND)
1496         IF(SDL_SOUND_FOUND)
1497             # Add a static library with common functions used by multiple targets
1498             ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c)
1499             TARGET_COMPILE_DEFINITIONS(ex-common PRIVATE ${CPP_DEFS})
1500             TARGET_COMPILE_OPTIONS(ex-common PRIVATE ${C_FLAGS})
1501
1502             ADD_EXECUTABLE(alplay examples/alplay.c)
1503             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1504             TARGET_INCLUDE_DIRECTORIES(alplay
1505                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1506             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1507             TARGET_LINK_LIBRARIES(alplay
1508                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1509                         OpenAL)
1510
1511             ADD_EXECUTABLE(alstream examples/alstream.c)
1512             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1513             TARGET_INCLUDE_DIRECTORIES(alstream
1514                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1515             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1516             TARGET_LINK_LIBRARIES(alstream
1517                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1518                         OpenAL)
1519
1520             ADD_EXECUTABLE(alreverb examples/alreverb.c)
1521             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1522             TARGET_INCLUDE_DIRECTORIES(alreverb
1523                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1524             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1525             TARGET_LINK_LIBRARIES(alreverb
1526                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1527                         OpenAL)
1528
1529             ADD_EXECUTABLE(allatency examples/allatency.c)
1530             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1531             TARGET_INCLUDE_DIRECTORIES(allatency
1532                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1533             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1534             TARGET_LINK_LIBRARIES(allatency
1535                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1536                         OpenAL)
1537
1538             ADD_EXECUTABLE(alloopback examples/alloopback.c)
1539             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1540             TARGET_INCLUDE_DIRECTORIES(alloopback
1541                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1542             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1543             TARGET_LINK_LIBRARIES(alloopback
1544                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1545                         OpenAL ${MATH_LIB})
1546
1547             ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1548             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1549             TARGET_INCLUDE_DIRECTORIES(alhrtf
1550                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1551             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1552             TARGET_LINK_LIBRARIES(alhrtf
1553                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1554                         OpenAL ${MATH_LIB})
1555
1556             IF(ALSOFT_INSTALL)
1557                 INSTALL(TARGETS alplay alstream alreverb allatency alloopback alhrtf
1558                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1559                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1560                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1561                 )
1562             ENDIF()
1563
1564             MESSAGE(STATUS "Building SDL_sound example programs")
1565         ENDIF()
1566
1567         SET(FFVER_OK FALSE)
1568         IF(FFMPEG_FOUND)
1569             SET(FFVER_OK TRUE)
1570             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1571                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1572                 SET(FFVER_OK FALSE)
1573             ENDIF()
1574             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1575                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1576                 SET(FFVER_OK FALSE)
1577             ENDIF()
1578             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1579                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1580                 SET(FFVER_OK FALSE)
1581             ENDIF()
1582             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1583                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1584                 SET(FFVER_OK FALSE)
1585             ENDIF()
1586             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1587                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1588                 SET(FFVER_OK FALSE)
1589             ENDIF()
1590         ENDIF()
1591         IF(FFVER_OK)
1592             ADD_EXECUTABLE(alffplay examples/alffplay.cpp)
1593             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1594             TARGET_INCLUDE_DIRECTORIES(alffplay
1595                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1596             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1597             TARGET_LINK_LIBRARIES(alffplay
1598                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} common OpenAL)
1599
1600             IF(ALSOFT_INSTALL)
1601                 INSTALL(TARGETS alffplay
1602                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1603                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1604                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1605                 )
1606             ENDIF()
1607             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1608         ENDIF()
1609         MESSAGE(STATUS "")
1610     ENDIF()
1611 ENDIF()