cmake/FindFFmpeg.cmake

   1 # vim: ts=2 sw=2
   2 # - Try to find the required ffmpeg components(default: AVFORMAT, AVUTIL, AVCODEC)
   3 #
   4 # Once done this will define
   5 #  FFMPEG_FOUND         - System has the all required components.
   6 #  FFMPEG_INCLUDE_DIRS  - Include directory necessary for using the required components headers.
   7 #  FFMPEG_LIBRARIES     - Link these to use the required ffmpeg components.
   8 #  FFMPEG_DEFINITIONS   - Compiler switches required for using the required ffmpeg components.
   9 #
  10 # For each of the components it will additionaly set.
  11 #   - AVCODEC
  12 #   - AVDEVICE
  13 #   - AVFORMAT
  14 #   - AVUTIL
  15 #   - POSTPROC
  16 #   - SWSCALE
  17 #   - SWRESAMPLE
  18 # the following variables will be defined
  19 #  <component>_FOUND        - System has <component>
  20 #  <component>_INCLUDE_DIRS - Include directory necessary for using the <component> headers
  21 #  <component>_LIBRARIES    - Link these to use <component>
  22 #  <component>_DEFINITIONS  - Compiler switches required for using <component>
  23 #  <component>_VERSION      - The components version
  24 #
  25 # Copyright (c) 2006, Matthias Kretz, <kretz@kde.org>
  26 # Copyright (c) 2008, Alexander Neundorf, <neundorf@kde.org>
  27 # Copyright (c) 2011, Michael Jansen, <kde@michael-jansen.biz>
  28 #
  29 # Redistribution and use is allowed according to the terms of the BSD license.
  30
  31 include(FindPackageHandleStandardArgs)
  32
  33 if(NOT FFmpeg_FIND_COMPONENTS)
  34     set(FFmpeg_FIND_COMPONENTS AVFORMAT AVCODEC AVUTIL)
  35 endif()
  36
  37 #
  38 ### Macro: set_component_found
  39 #
  40 # Marks the given component as found if both *_LIBRARIES AND *_INCLUDE_DIRS is present.
  41 #
  42 macro(set_component_found _component)
  43     if(${_component}_LIBRARIES AND ${_component}_INCLUDE_DIRS)
  44         # message(STATUS "  - ${_component} found.")
  45         set(${_component}_FOUND TRUE)
  46     else()
  47         # message(STATUS "  - ${_component} not found.")
  48     endif()
  49 endmacro()
  50
  51 #
  52 ### Macro: find_component
  53 #
  54 # Checks for the given component by invoking pkgconfig and then looking up the libraries and
  55 # include directories.
  56 #
  57 macro(find_component _component _pkgconfig _library _header)
  58     if(NOT WIN32)
  59         # use pkg-config to get the directories and then use these values
  60         # in the FIND_PATH() and FIND_LIBRARY() calls
  61         find_package(PkgConfig)
  62         if(PKG_CONFIG_FOUND)
  63             pkg_check_modules(PC_${_component} ${_pkgconfig})
  64         endif()
  65     endif()
  66
  67     find_path(${_component}_INCLUDE_DIRS ${_header}
  68         HINTS
  69             ${FFMPEGSDK_INC}
  70             ${PC_LIB${_component}_INCLUDEDIR}
  71             ${PC_LIB${_component}_INCLUDE_DIRS}
  72         PATH_SUFFIXES
  73             ffmpeg
  74     )
  75
  76     find_library(${_component}_LIBRARIES NAMES ${_library}
  77         HINTS
  78             ${FFMPEGSDK_LIB}
  79             ${PC_LIB${_component}_LIBDIR}
  80             ${PC_LIB${_component}_LIBRARY_DIRS}
  81     )
  82
  83     set(${_component}_VERSION     ${PC_${_component}_VERSION}      CACHE STRING "The ${_component} version number." FORCE)
  84     set(${_component}_DEFINITIONS ${PC_${_component}_CFLAGS_OTHER} CACHE STRING "The ${_component} CFLAGS." FORCE)
  85
  86     set_component_found(${_component})
  87
  88     mark_as_advanced(
  89         ${_component}_INCLUDE_DIRS
  90         ${_component}_LIBRARIES
  91         ${_component}_DEFINITIONS
  92         ${_component}_VERSION)
  93 endmacro()
  94
  95
  96 set(FFMPEGSDK $ENV{FFMPEG_HOME})
  97 if(FFMPEGSDK)
  98     set(FFMPEGSDK_INC "${FFMPEGSDK}/include")
  99     set(FFMPEGSDK_LIB "${FFMPEGSDK}/lib")
 100 endif()
 101
 102 # Check for all possible components.
 103 find_component(AVCODEC    libavcodec    avcodec    libavcodec/avcodec.h)
 104 find_component(AVFORMAT   libavformat   avformat   libavformat/avformat.h)
 105 find_component(AVDEVICE   libavdevice   avdevice   libavdevice/avdevice.h)
 106 find_component(AVUTIL     libavutil     avutil     libavutil/avutil.h)
 107 find_component(SWSCALE    libswscale    swscale    libswscale/swscale.h)
 108 find_component(SWRESAMPLE libswresample swresample libswresample/swresample.h)
 109 find_component(POSTPROC   libpostproc   postproc   libpostproc/postprocess.h)
 110
 111 # Check if the required components were found and add their stuff to the FFMPEG_* vars.
 112 foreach(_component ${FFmpeg_FIND_COMPONENTS})
 113     if(${_component}_FOUND)
 114         # message(STATUS "Required component ${_component} present.")
 115         set(FFMPEG_LIBRARIES   ${FFMPEG_LIBRARIES}   ${${_component}_LIBRARIES})
 116         set(FFMPEG_DEFINITIONS ${FFMPEG_DEFINITIONS} ${${_component}_DEFINITIONS})
 117         list(APPEND FFMPEG_INCLUDE_DIRS ${${_component}_INCLUDE_DIRS})
 118     else()
 119         # message(STATUS "Required component ${_component} missing.")
 120     endif()
 121 endforeach()
 122
 123 # Add libz if it exists (needed for static ffmpeg builds)
 124 find_library(_FFmpeg_HAVE_LIBZ NAMES z)
 125 if(_FFmpeg_HAVE_LIBZ)
 126     set(FFMPEG_LIBRARIES ${FFMPEG_LIBRARIES} ${_FFmpeg_HAVE_LIBZ})
 127 endif()
 128
 129 # Build the include path and library list with duplicates removed.
 130 if(FFMPEG_INCLUDE_DIRS)
 131     list(REMOVE_DUPLICATES FFMPEG_INCLUDE_DIRS)
 132 endif()
 133
 134 if(FFMPEG_LIBRARIES)
 135     list(REMOVE_DUPLICATES FFMPEG_LIBRARIES)
 136 endif()
 137
 138 # cache the vars.
 139 set(FFMPEG_INCLUDE_DIRS ${FFMPEG_INCLUDE_DIRS} CACHE STRING "The FFmpeg include directories." FORCE)
 140 set(FFMPEG_LIBRARIES    ${FFMPEG_LIBRARIES}    CACHE STRING "The FFmpeg libraries." FORCE)
 141 set(FFMPEG_DEFINITIONS  ${FFMPEG_DEFINITIONS}  CACHE STRING "The FFmpeg cflags." FORCE)
 142
 143 mark_as_advanced(FFMPEG_INCLUDE_DIRS FFMPEG_LIBRARIES FFMPEG_DEFINITIONS)
 144
 145 # Now set the noncached _FOUND vars for the components.
 146 foreach(_component AVCODEC AVDEVICE AVFORMAT AVUTIL POSTPROCESS SWRESAMPLE SWSCALE)
 147     set_component_found(${_component})
 148 endforeach ()
 149
 150 # Compile the list of required vars
 151 set(_FFmpeg_REQUIRED_VARS FFMPEG_LIBRARIES FFMPEG_INCLUDE_DIRS)
 152 foreach(_component ${FFmpeg_FIND_COMPONENTS})
 153     list(APPEND _FFmpeg_REQUIRED_VARS ${_component}_LIBRARIES ${_component}_INCLUDE_DIRS)
 154 endforeach()
 155
 156 # Give a nice error message if some of the required vars are missing.
 157 find_package_handle_standard_args(FFmpeg DEFAULT_MSG ${_FFmpeg_REQUIRED_VARS})