CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 IF(WIN32)
  29     # This option is mainly for static linking OpenAL Soft into another project
  30     # that already defines the IDs. It is up to that project to ensure all
  31     # required IDs are defined.
  32     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  33 ELSE()
  34     # These are needed on non-Windows systems for extra features
  35     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
  36     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
  37 ENDIF()
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48
  49 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  50 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  51
  52
  53 IF(WIN32)
  54     SET(LIBNAME OpenAL32)
  55     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  56 ELSE()
  57     SET(LIBNAME openal)
  58 ENDIF()
  59
  60 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  61 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  62     ADD_DEFINITIONS("-I/usr/include")
  63     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  64 ENDIF()
  65
  66 IF(NOT LIBTYPE)
  67     SET(LIBTYPE SHARED)
  68 ENDIF()
  69
  70 SET(LIB_MAJOR_VERSION "1")
  71 SET(LIB_MINOR_VERSION "15")
  72 SET(LIB_REVISION "1")
  73 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  74
  75 SET(EXPORT_DECL "")
  76 SET(ALIGN_DECL "")
  77
  78
  79 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  80 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  81
  82
  83 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
  84 IF(HAVE_STD_C99)
  85     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
  86 ENDIF()
  87
  88 # MSVC may need workarounds for C99 restrict and inline
  89 IF(MSVC)
  90     # TODO: Once we truly require C99, these restrict and inline checks should go
  91     # away.
  92     CHECK_C_SOURCE_COMPILES("int *restrict foo;
  93                              int main() {return 0;}" HAVE_RESTRICT)
  94     IF(NOT HAVE_RESTRICT)
  95         ADD_DEFINITIONS("-Drestrict=")
  96         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
  97     ENDIF()
  98
  99     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 100                              int main() {return 0;}" HAVE_INLINE)
 101     IF(NOT HAVE_INLINE)
 102         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 103                                  int main() {return 0;}" HAVE___INLINE)
 104         IF(NOT HAVE___INLINE)
 105             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 106         ENDIF()
 107
 108         ADD_DEFINITIONS(-Dinline=__inline)
 109         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 110     ENDIF()
 111 ENDIF()
 112
 113 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 114 IF(CMAKE_COMPILER_IS_GNUCC)
 115     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 116     # Force no inlining for the next test.
 117     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 118
 119     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 120                              int main() {return foo();}" INLINE_IS_C99)
 121     IF(NOT INLINE_IS_C99)
 122         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 123                              Please update your compiler for better C99 compliance.")
 124     ENDIF()
 125
 126     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 127 ENDIF()
 128
 129 # Check if we have C99 variable length arrays
 130 CHECK_C_SOURCE_COMPILES(
 131 "int main(int argc, char *argv[])
 132  {
 133      volatile int tmp[argc];
 134      tmp[0] = argv[0][0];
 135      return tmp[0];
 136  }"
 137 HAVE_C99_VLA)
 138
 139 # Check if we have C99 bool
 140 CHECK_C_SOURCE_COMPILES(
 141 "int main(int argc, char *argv[])
 142  {
 143      volatile _Bool ret;
 144      ret = (argc > 1) ? 1 : 0;
 145      return ret ? -1 : 0;
 146  }"
 147 HAVE_C99_BOOL)
 148
 149 # Check if we have C11 static_assert
 150 CHECK_C_SOURCE_COMPILES(
 151 "int main()
 152  {
 153      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 154      return 0;
 155  }"
 156 HAVE_C11_STATIC_ASSERT)
 157
 158 # Check if we have C11 alignas
 159 CHECK_C_SOURCE_COMPILES(
 160 "_Alignas(16) int foo;
 161  int main()
 162  {
 163      return 0;
 164  }"
 165 HAVE_C11_ALIGNAS)
 166
 167 # Add definitions, compiler switches, etc.
 168 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 169 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 170     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 171     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 172         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 173     ENDIF()
 174 ENDIF()
 175
 176 IF(NOT CMAKE_BUILD_TYPE)
 177     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 178         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 179         FORCE)
 180 ENDIF()
 181 IF(NOT CMAKE_DEBUG_POSTFIX)
 182     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 183         "Library postfix for debug builds. Normally left blank."
 184         FORCE)
 185 ENDIF()
 186
 187 IF(MSVC)
 188     # ???
 189     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 190     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 191     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 192     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 193     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 194     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 195     ADD_DEFINITIONS("/wd4098")
 196
 197     IF(NOT DXSDK_DIR)
 198         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 199     ELSE()
 200         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 201     ENDIF()
 202     IF(DXSDK_DIR)
 203         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 204         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 205         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 206         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 207     ENDIF()
 208
 209     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 210     IF(FORCE_STATIC_VCRT)
 211         FOREACH(flag_var
 212                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 213                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 214             IF(${flag_var} MATCHES "/MD")
 215                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 216             ENDIF()
 217         ENDFOREACH(flag_var)
 218     ENDIF()
 219 ELSE()
 220     ADD_DEFINITIONS(-Winline -Wall)
 221     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 222     IF(HAVE_W_EXTRA)
 223         ADD_DEFINITIONS(-Wextra)
 224     ENDIF()
 225
 226     IF(ALSOFT_WERROR)
 227         ADD_DEFINITIONS(-Werror)
 228     ENDIF()
 229
 230     # Force enable PIC if available. The static common library will be linked
 231     # into the dynamic openal library, which requires all its code to be
 232     # position-independent, and CMake doesn't automatically enable PIC for
 233     # static library targets (Windows code is always position-independent).
 234     CHECK_C_COMPILER_FLAG(-fPIC HAVE_FPIC_SWITCH)
 235     IF(HAVE_FPIC_SWITCH AND NOT WIN32)
 236         ADD_DEFINITIONS(-fPIC)
 237     ENDIF()
 238
 239     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 240         "Flags used by the compiler during Release with Debug Info builds."
 241         FORCE)
 242     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 243         "Flags used by the compiler during release minsize builds."
 244         FORCE)
 245     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 246         "Flags used by the compiler during release builds"
 247         FORCE)
 248     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 249         "Flags used by the compiler during debug builds."
 250         FORCE)
 251
 252     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 253                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 254 ENDIF()
 255
 256 # Set visibility/export options if available
 257 IF(WIN32)
 258     SET(EXPORT_DECL "__declspec(dllexport)")
 259     IF(NOT MINGW)
 260         SET(ALIGN_DECL "__declspec(align(x))")
 261     ELSE()
 262         SET(ALIGN_DECL "__declspec(aligned(x))")
 263     ENDIF()
 264 ELSE()
 265     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 266     # Yes GCC, really don't accept visibility modes you don't support
 267     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 268
 269     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 270                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 271     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 272         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 273     ELSE()
 274         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 275                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 276         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 277             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 278         ENDIF()
 279     ENDIF()
 280
 281     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 282         CHECK_C_COMPILER_FLAG(-fvisibility=internal HAVE_VISIBILITY_INTERNAL_SWITCH)
 283         IF(HAVE_VISIBILITY_INTERNAL_SWITCH)
 284             ADD_DEFINITIONS(-fvisibility=internal)
 285         ELSE()
 286             CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 287             IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 288                 ADD_DEFINITIONS(-fvisibility=hidden)
 289             ENDIF()
 290         ENDIF()
 291     ENDIF()
 292
 293     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 294                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 295     IF(HAVE_ATTRIBUTE_ALIGNED)
 296         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 297     ENDIF()
 298
 299     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 300 ENDIF()
 301
 302 SET(SSE_SWITCH "")
 303 IF(MSVC)
 304     CHECK_C_COMPILER_FLAG(/arch:SSE HAVE_ARCHSSE_SWITCH)
 305     IF(HAVE_ARCHSSE_SWITCH)
 306         SET(SSE_SWITCH "/arch:SSE")
 307     ENDIF()
 308 ENDIF()
 309 IF(NOT SSE_SWITCH)
 310     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 311     IF(HAVE_MSSE_SWITCH)
 312         SET(SSE_SWITCH "-msse")
 313     ENDIF()
 314 ENDIF()
 315
 316 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 317                          int main() {return 0;}" HAVE_GCC_FORMAT)
 318
 319 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 320 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 321 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 322 CHECK_INCLUDE_FILE(ftw.h HAVE_FTW_H)
 323 CHECK_INCLUDE_FILE(io.h HAVE_IO_H)
 324 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 325 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 326 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 327 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 328 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 329 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 330 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 331 IF(NOT HAVE_GUIDDEF_H)
 332     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 333 ENDIF()
 334
 335 # Some systems need libm for some of the following math functions to work
 336 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 337 IF(HAVE_LIBM)
 338     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 339     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 340 ENDIF()
 341
 342
 343 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 344 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 345 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 346 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 347 IF(NOT HAVE_C99_VLA)
 348     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 349     IF(NOT HAVE_ALLOCA)
 350         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 351     ENDIF()
 352 ENDIF()
 353
 354 IF(HAVE_FLOAT_H)
 355     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 356     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 357 ENDIF()
 358 IF(HAVE_FTW_H)
 359     CHECK_SYMBOL_EXISTS(ftw ftw.h HAVE_FTW)
 360 ENDIF()
 361 IF(HAVE_IO_H)
 362     CHECK_SYMBOL_EXISTS(_wfindfirst io.h HAVE__WFINDFIRST)
 363 ENDIF()
 364
 365 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 366 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 367 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 368 IF(NOT HAVE_STRCASECMP)
 369     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 370     IF(NOT HAVE__STRICMP)
 371         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 372     ENDIF()
 373
 374     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 375 ENDIF()
 376
 377 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 378 IF(NOT HAVE_STRNCASECMP)
 379     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 380     IF(NOT HAVE__STRNICMP)
 381         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 382     ENDIF()
 383
 384     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 385 ENDIF()
 386
 387 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 388 IF(NOT HAVE_SNPRINTF)
 389     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 390     IF(NOT HAVE__SNPRINTF)
 391         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 392     ENDIF()
 393
 394     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 395 ENDIF()
 396
 397 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 398 IF(NOT HAVE_ISFINITE)
 399     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 400     IF(NOT HAVE_FINITE)
 401         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 402         IF(NOT HAVE__FINITE)
 403             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 404         ENDIF()
 405         ADD_DEFINITIONS(-Disfinite=_finite)
 406     ELSE()
 407         ADD_DEFINITIONS(-Disfinite=finite)
 408     ENDIF()
 409 ENDIF()
 410
 411 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 412 IF(NOT HAVE_ISNAN)
 413     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 414     IF(NOT HAVE__ISNAN)
 415         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 416     ENDIF()
 417
 418     ADD_DEFINITIONS(-Disnan=_isnan)
 419 ENDIF()
 420
 421
 422 # Check for the dlopen API (for dynamicly loading backend libs)
 423 IF(ALSOFT_DLOPEN)
 424     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 425     IF(HAVE_DLFCN_H)
 426         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 427         IF(HAVE_LIBDL)
 428             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 429         ENDIF()
 430     ENDIF()
 431 ENDIF()
 432
 433 # Check if we have Windows headers
 434 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 435 IF(NOT HAVE_WINDOWS_H)
 436     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 437     IF(NOT HAVE_GETTIMEOFDAY)
 438         MESSAGE(FATAL_ERROR "No timing function found!")
 439     ENDIF()
 440
 441     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 442     IF(NOT HAVE_NANOSLEEP)
 443         MESSAGE(FATAL_ERROR "No sleep function found!")
 444     ENDIF()
 445
 446     # We need pthreads outside of Windows
 447     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 448     IF(NOT HAVE_PTHREAD_H)
 449         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 450     ENDIF()
 451     # Some systems need pthread_np.h to get recursive mutexes
 452     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 453
 454     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 455     IF(HAVE_PTHREAD)
 456         ADD_DEFINITIONS(-pthread)
 457         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 458         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 459     ENDIF()
 460
 461     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 462     IF(HAVE_LIBPTHREAD)
 463         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 464     ENDIF()
 465
 466     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 467
 468     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 469     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 470         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 471     ENDIF()
 472     IF(HAVE_PTHREAD_NP_H)
 473         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 474     ENDIF()
 475
 476     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 477
 478     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 479     IF(HAVE_LIBRT)
 480         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 481     ENDIF()
 482 ENDIF()
 483
 484 # Check for a 64-bit type
 485 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 486 IF(NOT HAVE_STDINT_H)
 487     IF(HAVE_WINDOWS_H)
 488         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 489                                  #include <windows.h>
 490                                  __int64 foo;
 491                                  int main() {return 0;}" HAVE___INT64)
 492     ENDIF()
 493     IF(NOT HAVE___INT64)
 494         IF(NOT SIZEOF_LONG MATCHES "8")
 495             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 496                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 497             ENDIF()
 498         ENDIF()
 499     ENDIF()
 500 ENDIF()
 501
 502
 503 SET(COMMON_OBJS  common/atomic.c
 504                  common/rwlock.c
 505                  common/threads.c
 506                  common/uintmap.c
 507 )
 508 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 509                  OpenAL32/alBuffer.c
 510                  OpenAL32/alEffect.c
 511                  OpenAL32/alError.c
 512                  OpenAL32/alExtension.c
 513                  OpenAL32/alFilter.c
 514                  OpenAL32/alFontsound.c
 515                  OpenAL32/alListener.c
 516                  OpenAL32/alMidi.c
 517                  OpenAL32/alPreset.c
 518                  OpenAL32/alSoundfont.c
 519                  OpenAL32/alSource.c
 520                  OpenAL32/alState.c
 521                  OpenAL32/alThunk.c
 522                  OpenAL32/sample_cvt.c
 523 )
 524 SET(ALC_OBJS  Alc/ALc.c
 525               Alc/ALu.c
 526               Alc/alcConfig.c
 527               Alc/alcRing.c
 528               Alc/bs2b.c
 529               Alc/effects/autowah.c
 530               Alc/effects/chorus.c
 531               Alc/effects/compressor.c
 532               Alc/effects/dedicated.c
 533               Alc/effects/distortion.c
 534               Alc/effects/echo.c
 535               Alc/effects/equalizer.c
 536               Alc/effects/flanger.c
 537               Alc/effects/modulator.c
 538               Alc/effects/null.c
 539               Alc/effects/reverb.c
 540               Alc/helpers.c
 541               Alc/hrtf.c
 542               Alc/panning.c
 543               Alc/mixer.c
 544               Alc/mixer_c.c
 545 )
 546
 547
 548 SET(CPU_EXTS "Default")
 549 SET(HAVE_SSE  0)
 550 SET(HAVE_NEON 0)
 551
 552 # Check for SSE support
 553 OPTION(ALSOFT_REQUIRE_SSE "Require SSE/SSE2 support" OFF)
 554 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 555 IF(HAVE_XMMINTRIN_H)
 556     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE/SSE2 support" ON)
 557     IF(ALSOFT_CPUEXT_SSE)
 558         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 559             SET(HAVE_SSE 1)
 560             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 561             IF(SSE_SWITCH)
 562                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 563                                             COMPILE_FLAGS "${SSE_SWITCH}")
 564             ENDIF()
 565             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 566         ENDIF()
 567     ENDIF()
 568 ENDIF()
 569 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 570     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 571 ENDIF()
 572
 573 # Check for ARM Neon support
 574 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 575 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 576 IF(HAVE_ARM_NEON_H)
 577     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 578     IF(ALSOFT_CPUEXT_NEON)
 579         SET(HAVE_NEON 1)
 580         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 581         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 582     ENDIF()
 583 ENDIF()
 584 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 585     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 586 ENDIF()
 587
 588
 589 SET(ALC_OBJS  ${ALC_OBJS}
 590               Alc/midi/base.c
 591               Alc/midi/sf2load.c
 592               Alc/midi/dummy.c
 593               Alc/midi/fluidsynth.c
 594               Alc/midi/soft.c
 595 )
 596
 597 SET(HAVE_FLUIDSYNTH  0)
 598
 599 # Check for FluidSynth support
 600 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI" OFF)
 601 FIND_PACKAGE(FluidSynth)
 602 IF(FLUIDSYNTH_FOUND)
 603     OPTION(ALSOFT_MIDI_FLUIDSYNTH "Enable FluidSynth MIDI" ON)
 604     IF(ALSOFT_MIDI_FLUIDSYNTH)
 605         SET(HAVE_FLUIDSYNTH 1)
 606         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 607             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 608         ENDIF()
 609         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 610     ENDIF()
 611 ENDIF()
 612 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 613     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 614 ENDIF()
 615
 616
 617 SET(ALC_OBJS  ${ALC_OBJS}
 618               Alc/backends/base.c
 619               # Default backends, always available
 620               Alc/backends/loopback.c
 621               Alc/backends/null.c
 622 )
 623
 624 SET(BACKENDS "")
 625 SET(HAVE_ALSA       0)
 626 SET(HAVE_OSS        0)
 627 SET(HAVE_SOLARIS    0)
 628 SET(HAVE_SNDIO      0)
 629 SET(HAVE_QSA        0)
 630 SET(HAVE_DSOUND     0)
 631 SET(HAVE_MMDEVAPI   0)
 632 SET(HAVE_WINMM      0)
 633 SET(HAVE_PORTAUDIO  0)
 634 SET(HAVE_PULSEAUDIO 0)
 635 SET(HAVE_COREAUDIO  0)
 636 SET(HAVE_OPENSL     0)
 637 SET(HAVE_WAVE       0)
 638 IF(WIN32 OR HAVE_DLFCN_H)
 639     SET(IS_LINKED "")
 640     MACRO(ADD_BACKEND_LIBS _LIBS)
 641     ENDMACRO()
 642 ELSE()
 643     SET(IS_LINKED " (linked)")
 644     MACRO(ADD_BACKEND_LIBS _LIBS)
 645         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 646     ENDMACRO()
 647 ENDIF()
 648
 649 # Check ALSA backend
 650 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 651 FIND_PACKAGE(ALSA)
 652 IF(ALSA_FOUND)
 653     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 654     IF(ALSOFT_BACKEND_ALSA)
 655         SET(HAVE_ALSA 1)
 656         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 657         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 658         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 659         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 660             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 661         ENDIF()
 662     ENDIF()
 663 ENDIF()
 664 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 665     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 666 ENDIF()
 667
 668 # Check OSS backend
 669 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 670 FIND_PACKAGE(OSS)
 671 IF(OSS_FOUND)
 672     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 673     IF(ALSOFT_BACKEND_OSS)
 674         SET(HAVE_OSS 1)
 675         SET(BACKENDS  "${BACKENDS} OSS,")
 676         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 677         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 678             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 679         ENDIF()
 680     ENDIF()
 681 ENDIF()
 682 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 683     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 684 ENDIF()
 685
 686 # Check Solaris backend
 687 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 688 FIND_PACKAGE(AudioIO)
 689 IF(AUDIOIO_FOUND)
 690     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 691     IF(ALSOFT_BACKEND_SOLARIS)
 692         SET(HAVE_SOLARIS 1)
 693         SET(BACKENDS  "${BACKENDS} Solaris,")
 694         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 695         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 696             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 697         ENDIF()
 698     ENDIF()
 699 ENDIF()
 700 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 701     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 702 ENDIF()
 703
 704 # Check SndIO backend
 705 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 706 FIND_PACKAGE(SoundIO)
 707 IF(SOUNDIO_FOUND)
 708     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 709     IF(ALSOFT_BACKEND_SNDIO)
 710         SET(HAVE_SNDIO 1)
 711         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 712         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 713         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 714         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 715             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 716         ENDIF()
 717     ENDIF()
 718 ENDIF()
 719 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 720     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 721 ENDIF()
 722
 723 # Check QSA backend
 724 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 725 FIND_PACKAGE(QSA)
 726 IF(QSA_FOUND)
 727     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 728     IF(ALSOFT_BACKEND_QSA)
 729         SET(HAVE_QSA 1)
 730         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 731         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 732         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 733         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 734             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 735         ENDIF()
 736     ENDIF()
 737 ENDIF()
 738 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 739     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 740 ENDIF()
 741
 742 # Check DSound backend
 743 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 744 FIND_PACKAGE(DSound)
 745 IF(DSOUND_FOUND)
 746     OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 747     IF(ALSOFT_BACKEND_DSOUND)
 748         SET(HAVE_DSOUND 1)
 749         SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 750         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 751         ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 752         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 753             INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 754         ENDIF()
 755     ENDIF()
 756 ENDIF()
 757 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 758     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 759 ENDIF()
 760
 761 # Check for MMDevApi backend
 762 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 763 IF(HAVE_WINDOWS_H)
 764     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 765     IF(HAVE_MMDEVICEAPI_H)
 766         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 767         IF(ALSOFT_BACKEND_MMDEVAPI)
 768             SET(HAVE_MMDEVAPI 1)
 769             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 770             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 771         ENDIF()
 772     ENDIF()
 773 ENDIF()
 774 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 775     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 776 ENDIF()
 777
 778 # Check MMSystem backend
 779 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 780 IF(HAVE_WINDOWS_H)
 781     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 782     IF(HAVE_MMSYSTEM_H)
 783         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 784         IF(HAVE_LIBWINMM)
 785             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 786             IF(ALSOFT_BACKEND_WINMM)
 787                 SET(HAVE_WINMM 1)
 788                 SET(BACKENDS  "${BACKENDS} WinMM,")
 789                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 790                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 791             ENDIF()
 792         ENDIF()
 793     ENDIF()
 794 ENDIF()
 795 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 796     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 797 ENDIF()
 798
 799 # Check PortAudio backend
 800 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 801 FIND_PACKAGE(PortAudio)
 802 IF(PORTAUDIO_FOUND)
 803     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 804     IF(ALSOFT_BACKEND_PORTAUDIO)
 805         SET(HAVE_PORTAUDIO 1)
 806         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 807         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 808         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 809         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 810             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 811         ENDIF()
 812     ENDIF()
 813 ENDIF()
 814 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 815     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 816 ENDIF()
 817
 818 # Check PulseAudio backend
 819 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 820 FIND_PACKAGE(PulseAudio)
 821 IF(PULSEAUDIO_FOUND)
 822     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 823     IF(ALSOFT_BACKEND_PULSEAUDIO)
 824         SET(HAVE_PULSEAUDIO 1)
 825         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 826         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 827         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
 828         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 829             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
 830         ENDIF()
 831     ENDIF()
 832 ENDIF()
 833 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 834     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 835 ENDIF()
 836
 837 # Check CoreAudio backend
 838 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 839 FIND_LIBRARY(COREAUDIO_FRAMEWORK
 840              NAMES CoreAudio
 841              PATHS /System/Library/Frameworks
 842 )
 843 IF(COREAUDIO_FRAMEWORK)
 844     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 845     IF(ALSOFT_BACKEND_COREAUDIO)
 846         SET(HAVE_COREAUDIO 1)
 847         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 848         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 849         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
 850         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 851         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 852
 853         # Some versions of OSX may need the AudioToolbox framework. Add it if
 854         # it's found.
 855         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 856                      NAMES AudioToolbox
 857                      PATHS ~/Library/Frameworks
 858                            /Library/Frameworks
 859                            /System/Library/Frameworks
 860                     )
 861         IF(AUDIOTOOLBOX_LIBRARY)
 862             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 863         ENDIF()
 864     ENDIF()
 865 ENDIF()
 866 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 867     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 868 ENDIF()
 869
 870 # Check for OpenSL (Android) backend
 871 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
 872 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 873 IF(HAVE_SLES_OPENSLES_ANDROID_H)
 874     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 875     IF(HAVE_LIBOPENSLES)
 876         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
 877         IF(ALSOFT_BACKEND_OPENSL)
 878             SET(HAVE_OPENSL 1)
 879             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 880             SET(BACKENDS  "${BACKENDS} OpenSL,")
 881             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 882         ENDIF()
 883     ENDIF()
 884 ENDIF()
 885 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 886     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 887 ENDIF()
 888
 889 # Optionally enable the Wave Writer backend
 890 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
 891 IF(ALSOFT_BACKEND_WAVE)
 892     SET(HAVE_WAVE 1)
 893     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 894     SET(BACKENDS  "${BACKENDS} WaveFile,")
 895 ENDIF()
 896
 897 # This is always available
 898 SET(BACKENDS  "${BACKENDS} Null")
 899
 900 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 901     add_subdirectory(utils/alsoft-config)
 902 ENDIF()
 903 IF(ALSOFT_EXAMPLES)
 904     FIND_PACKAGE(SDL)
 905     IF(SDL_FOUND)
 906         FIND_PACKAGE(SDL_sound)
 907         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 908             INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 909         ENDIF()
 910     ENDIF()
 911 ENDIF()
 912
 913 IF(LIBTYPE STREQUAL "STATIC")
 914     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 915     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 916 ENDIF()
 917
 918 # Needed for openal.pc.in
 919 SET(prefix ${CMAKE_INSTALL_PREFIX})
 920 SET(exec_prefix "\${prefix}")
 921 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 922 SET(bindir "\${exec_prefix}/bin")
 923 SET(includedir "\${prefix}/include")
 924 SET(PACKAGE_VERSION "${LIB_VERSION}")
 925
 926 # End configuration
 927 CONFIGURE_FILE(
 928     "${OpenAL_SOURCE_DIR}/config.h.in"
 929     "${OpenAL_BINARY_DIR}/config.h")
 930 CONFIGURE_FILE(
 931     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 932     "${OpenAL_BINARY_DIR}/openal.pc"
 933     @ONLY)
 934
 935 # Build a common library with reusable helpers
 936 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
 937
 938 # Build main library
 939 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 940 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 941 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 942     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 943 ENDIF()
 944 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 945 IF(FLUIDSYNTH_FOUND)
 946     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
 947 ENDIF()
 948 IF(HAVE_ALSA)
 949     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
 950 ENDIF()
 951 IF(HAVE_OSS)
 952     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
 953 ENDIF()
 954 IF(HAVE_SOLARIS)
 955     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
 956 ENDIF()
 957 IF(HAVE_SNDIO)
 958     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
 959 ENDIF()
 960 IF(HAVE_QSA)
 961     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
 962 ENDIF()
 963 IF(HAVE_DSOUND)
 964     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
 965 ENDIF()
 966 IF(HAVE_PORTAUDIO)
 967     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
 968 ENDIF()
 969 IF(HAVE_PULSEAUDIO)
 970     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
 971 ENDIF()
 972 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
 973                                             SOVERSION ${LIB_MAJOR_VERSION})
 974 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
 975     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
 976 ENDIF()
 977
 978 TARGET_LINK_LIBRARIES(${LIBNAME} common ${EXTRA_LIBS})
 979
 980 # Add an install target here
 981 INSTALL(TARGETS ${LIBNAME}
 982         RUNTIME DESTINATION bin
 983         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 984         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 985 )
 986 INSTALL(FILES include/AL/al.h
 987               include/AL/alc.h
 988               include/AL/alext.h
 989               include/AL/efx.h
 990               include/AL/efx-creative.h
 991               include/AL/efx-presets.h
 992         DESTINATION include/AL
 993 )
 994 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
 995         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
 996
 997
 998 MESSAGE(STATUS "")
 999 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1000 MESSAGE(STATUS "    ${BACKENDS}")
1001 MESSAGE(STATUS "")
1002 MESSAGE(STATUS "Building with support for CPU extensions:")
1003 MESSAGE(STATUS "    ${CPU_EXTS}")
1004 MESSAGE(STATUS "")
1005 IF(HAVE_FLUIDSYNTH)
1006     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
1007     MESSAGE(STATUS "")
1008 ENDIF()
1009
1010 IF(WIN32)
1011     IF(NOT HAVE_DSOUND)
1012         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1013         MESSAGE(STATUS "         This is probably NOT what you want!")
1014         MESSAGE(STATUS "")
1015     ENDIF()
1016 ENDIF()
1017
1018 # Install alsoft.conf configuration file
1019 IF(ALSOFT_CONFIG)
1020     INSTALL(FILES alsoftrc.sample
1021             DESTINATION share/openal
1022     )
1023     MESSAGE(STATUS "Installing sample configuration")
1024     MESSAGE(STATUS "")
1025 ENDIF()
1026
1027 # Install HRTF definitions
1028 IF(ALSOFT_HRTF_DEFS)
1029     INSTALL(FILES hrtf/default-44100.mhr
1030             DESTINATION share/openal/hrtf
1031     )
1032     MESSAGE(STATUS "Installing HRTF definitions")
1033     MESSAGE(STATUS "")
1034 ENDIF()
1035
1036 IF(ALSOFT_UTILS)
1037     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1038     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1039
1040     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1041     IF(HAVE_LIBM)
1042         TARGET_LINK_LIBRARIES(makehrtf m)
1043     ENDIF()
1044
1045     INSTALL(TARGETS openal-info makehrtf
1046             RUNTIME DESTINATION bin
1047             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1048             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1049     )
1050
1051     MESSAGE(STATUS "Building utility programs")
1052     IF(TARGET alsoft-config)
1053         MESSAGE(STATUS "Building configuration program")
1054     ENDIF()
1055     MESSAGE(STATUS "")
1056 ENDIF()
1057
1058 IF(ALSOFT_EXAMPLES)
1059     IF(SDL_FOUND AND SDL_SOUND_FOUND)
1060         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1061                                      examples/common/sdl_sound.c)
1062         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1063
1064         ADD_EXECUTABLE(alstream examples/alstream.c)
1065         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1066         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1067
1068         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1069         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1070         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1071
1072         ADD_EXECUTABLE(allatency examples/allatency.c)
1073         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${LIBNAME})
1074         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_SOUND_INCLUDE_DIR})
1075
1076         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1077         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL_LIBRARY} ${LIBNAME})
1078         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL_INCLUDE_DIR}
1079                                                                            ${SDL_SOUND_INCLUDE_DIR})
1080
1081         INSTALL(TARGETS alstream alreverb allatency alloopback
1082                 RUNTIME DESTINATION bin
1083                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1084                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1085         )
1086
1087         MESSAGE(STATUS "Building example programs")
1088         MESSAGE(STATUS "")
1089     ENDIF()
1090 ENDIF()