CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 IF(WIN32)
  66     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  67
  68     # This option is mainly for static linking OpenAL Soft into another project
  69     # that already defines the IDs. It is up to that project to ensure all
  70     # required IDs are defined.
  71     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  72
  73     IF(MINGW)
  74         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  75         IF(NOT DLLTOOL)
  76             IF(HOST)
  77                 SET(DLLTOOL "${HOST}-dlltool")
  78             ELSE()
  79                 SET(DLLTOOL "dlltool")
  80             ENDIF()
  81         ENDIF()
  82     ENDIF()
  83 ENDIF()
  84
  85
  86 SET(EXTRA_LIBS "")
  87 SET(EXTRA_LDFLAGS "")
  88
  89 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  90 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  91     ADD_DEFINITIONS("-I/usr/include")
  92     SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -L/usr/lib")
  93 ENDIF()
  94
  95 IF(NOT LIBTYPE)
  96     SET(LIBTYPE SHARED)
  97 ENDIF()
  98
  99 SET(LIB_MAJOR_VERSION "1")
 100 SET(LIB_MINOR_VERSION "18")
 101 SET(LIB_REVISION "0")
 102 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 103
 104 SET(EXPORT_DECL "")
 105 SET(ALIGN_DECL "")
 106
 107
 108 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 109 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 110
 111
 112 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 113 IF(HAVE_STD_C11)
 114     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 115 ELSE()
 116     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 117     IF(HAVE_STD_C99)
 118         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 119     ENDIF()
 120 ENDIF()
 121
 122 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 123 IF(HAVE_STD_CXX11)
 124     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 125 ENDIF()
 126
 127 if(NOT WIN32)
 128     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 129     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 130     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 131         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 132         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 133         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 134         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 135             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 136         ELSE()
 137             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600)
 138         ENDIF()
 139     ENDIF()
 140     UNSET(OLD_REQUIRED_FLAGS)
 141 ENDIF()
 142
 143 # Set defines for large file support
 144 CHECK_FILE_OFFSET_BITS()
 145 IF(_FILE_OFFSET_BITS)
 146     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 147     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 148 ENDIF()
 149 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 150 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 151
 152 # MSVC may need workarounds for C99 restrict and inline
 153 IF(MSVC)
 154     # TODO: Once we truly require C99, these restrict and inline checks should go
 155     # away.
 156     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 157                              int main() {return 0;}" HAVE_RESTRICT)
 158     IF(NOT HAVE_RESTRICT)
 159         ADD_DEFINITIONS("-Drestrict=")
 160         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 161     ENDIF()
 162
 163     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 164                              int main() {return 0;}" HAVE_INLINE)
 165     IF(NOT HAVE_INLINE)
 166         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 167                                  int main() {return 0;}" HAVE___INLINE)
 168         IF(NOT HAVE___INLINE)
 169             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 170         ENDIF()
 171
 172         ADD_DEFINITIONS(-Dinline=__inline)
 173         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 174     ENDIF()
 175 ENDIF()
 176
 177 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 178 IF(CMAKE_COMPILER_IS_GNUCC)
 179     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 180
 181     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 182     # Force no inlining for the next test.
 183     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 184
 185     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 186                              int main() {return foo();}" INLINE_IS_C99)
 187     IF(NOT INLINE_IS_C99)
 188         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 189                              Please update your compiler for better C99 compliance.")
 190     ENDIF()
 191
 192     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 193 ENDIF()
 194
 195 # Check if we have a proper timespec declaration
 196 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 197 IF(HAVE_STRUCT_TIMESPEC)
 198     # Define it here so we don't have to include config.h for it
 199     ADD_DEFINITIONS("-DHAVE_STRUCT_TIMESPEC")
 200 ENDIF()
 201
 202 # Some systems may need libatomic for C11 atomic functions to work
 203 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 204 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 205 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 206 int _Atomic foo = ATOMIC_VAR_INIT(0);
 207 int main()
 208 {
 209     return atomic_fetch_add(&foo, 2);
 210 }"
 211 HAVE_LIBATOMIC)
 212 IF(NOT HAVE_LIBATOMIC)
 213     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 214 ELSE()
 215     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 216 ENDIF()
 217 UNSET(OLD_REQUIRED_LIBRARIES)
 218
 219 # Include liblog for Android logging
 220 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 221 IF(HAVE_LIBLOG)
 222     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 223     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 224 ENDIF()
 225
 226 # Check if we have C99 variable length arrays
 227 CHECK_C_SOURCE_COMPILES(
 228 "int main(int argc, char *argv[])
 229  {
 230      volatile int tmp[argc];
 231      tmp[0] = argv[0][0];
 232      return tmp[0];
 233  }"
 234 HAVE_C99_VLA)
 235
 236 # Check if we have C99 bool
 237 CHECK_C_SOURCE_COMPILES(
 238 "int main(int argc, char *argv[])
 239  {
 240      volatile _Bool ret;
 241      ret = (argc > 1) ? 1 : 0;
 242      return ret ? -1 : 0;
 243  }"
 244 HAVE_C99_BOOL)
 245
 246 # Check if we have C11 static_assert
 247 CHECK_C_SOURCE_COMPILES(
 248 "int main()
 249  {
 250      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 251      return 0;
 252  }"
 253 HAVE_C11_STATIC_ASSERT)
 254
 255 # Check if we have C11 alignas
 256 CHECK_C_SOURCE_COMPILES(
 257 "_Alignas(16) int foo;
 258  int main()
 259  {
 260      return 0;
 261  }"
 262 HAVE_C11_ALIGNAS)
 263
 264 # Check if we have C11 _Atomic
 265 CHECK_C_SOURCE_COMPILES(
 266 "#include <stdatomic.h>
 267  int _Atomic foo = ATOMIC_VAR_INIT(0);
 268  int main()
 269  {
 270      atomic_fetch_add(&foo, 2);
 271      return 0;
 272  }"
 273 HAVE_C11_ATOMIC)
 274
 275 # Add definitions, compiler switches, etc.
 276 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 277
 278 IF(NOT CMAKE_BUILD_TYPE)
 279     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 280         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 281         FORCE)
 282 ENDIF()
 283 IF(NOT CMAKE_DEBUG_POSTFIX)
 284     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 285         "Library postfix for debug builds. Normally left blank."
 286         FORCE)
 287 ENDIF()
 288
 289 SET(EXTRA_CFLAGS "")
 290 IF(MSVC)
 291     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 292     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 293     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 294
 295     IF(NOT DXSDK_DIR)
 296         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 297     ELSE()
 298         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 299     ENDIF()
 300     IF(DXSDK_DIR)
 301         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 302     ENDIF()
 303
 304     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 305     IF(FORCE_STATIC_VCRT)
 306         FOREACH(flag_var
 307                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 308                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 309             IF(${flag_var} MATCHES "/MD")
 310                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 311             ENDIF()
 312         ENDFOREACH(flag_var)
 313     ENDIF()
 314 ELSE()
 315     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 316     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 317     IF(HAVE_W_EXTRA)
 318         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 319     ENDIF()
 320
 321     IF(ALSOFT_WERROR)
 322         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 323     ENDIF()
 324
 325     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 326     # instead of NDEBUG)
 327     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 328         IF(${flag_var} MATCHES "-DNDEBUG")
 329             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 330         ENDIF()
 331     ENDFOREACH()
 332
 333     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 334     IF(HAVE_FNO_MATH_ERRNO)
 335         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fno-math-errno")
 336     ENDIF()
 337
 338     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 339                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 340
 341     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 342     if(ALSOFT_STATIC_LIBGCC)
 343         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 344         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 345         check_c_source_compiles(
 346 "#include <stdlib.h>
 347 int main()
 348 {
 349     return 0;
 350 }"
 351             HAVE_STATIC_LIBGCC_SWITCH
 352         )
 353         if(HAVE_STATIC_LIBGCC_SWITCH)
 354             set(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -static-libgcc")
 355         endif()
 356         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 357         unset(OLD_REQUIRED_LIBRARIES)
 358     endif()
 359 ENDIF()
 360
 361 # Set visibility/export options if available
 362 IF(WIN32)
 363     SET(EXPORT_DECL "__declspec(dllexport)")
 364     IF(NOT MINGW)
 365         SET(ALIGN_DECL "__declspec(align(x))")
 366     ELSE()
 367         SET(ALIGN_DECL "__declspec(aligned(x))")
 368     ENDIF()
 369 ELSE()
 370     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 371     # Yes GCC, really don't accept visibility modes you don't support
 372     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 373
 374     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 375                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 376     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 377         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 378     ELSE()
 379         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 380                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 381         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 382             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 383         ENDIF()
 384     ENDIF()
 385
 386     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 387         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 388         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 389             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 390         ENDIF()
 391     ENDIF()
 392
 393     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 394                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 395     IF(HAVE_ATTRIBUTE_ALIGNED)
 396         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 397     ENDIF()
 398
 399     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 400 ENDIF()
 401
 402 CHECK_C_SOURCE_COMPILES("
 403 int main()
 404 {
 405     float *ptr;
 406     ptr = __builtin_assume_aligned(ptr, 16);
 407     return 0;
 408 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 409 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 410     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 411 ELSE()
 412     SET(ASSUME_ALIGNED_DECL "x")
 413 ENDIF()
 414
 415 SET(SSE_SWITCH "")
 416 SET(SSE2_SWITCH "")
 417 SET(SSE3_SWITCH "")
 418 SET(SSE4_1_SWITCH "")
 419 SET(FPU_NEON_SWITCH "")
 420 IF(NOT MSVC)
 421     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 422     IF(HAVE_MSSE_SWITCH)
 423         SET(SSE_SWITCH "-msse")
 424     ENDIF()
 425     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 426     IF(HAVE_MSSE2_SWITCH)
 427         SET(SSE2_SWITCH "-msse2")
 428     ENDIF()
 429     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 430     IF(HAVE_MSSE3_SWITCH)
 431         SET(SSE3_SWITCH "-msse3")
 432     ENDIF()
 433     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 434     IF(HAVE_MSSE4_1_SWITCH)
 435         SET(SSE4_1_SWITCH "-msse4.1")
 436     ENDIF()
 437     CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 438     IF(HAVE_MFPU_NEON_SWITCH)
 439         SET(FPU_NEON_SWITCH "-mfpu=neon")
 440     ENDIF()
 441 ENDIF()
 442
 443 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 444                          int main() {return 0;}" HAVE_GCC_FORMAT)
 445
 446 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 447 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 448 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 449 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 450 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 451 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 452 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 453 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 454 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 455 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 456 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 457 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 458 IF(NOT HAVE_GUIDDEF_H)
 459     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 460 ENDIF()
 461
 462 # Some systems need libm for some of the following math functions to work
 463 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 464 IF(HAVE_LIBM)
 465     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 466     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 467 ENDIF()
 468
 469 # Check for the dlopen API (for dynamicly loading backend libs)
 470 IF(ALSOFT_DLOPEN)
 471     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 472     IF(HAVE_LIBDL)
 473         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 474         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 475     ENDIF()
 476
 477     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 478 ENDIF()
 479
 480 # Check for a cpuid intrinsic
 481 IF(HAVE_CPUID_H)
 482     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 483         int main()
 484         {
 485             unsigned int eax, ebx, ecx, edx;
 486             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 487         }" HAVE_GCC_GET_CPUID)
 488 ENDIF()
 489 IF(HAVE_INTRIN_H)
 490     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 491         int main()
 492         {
 493             int regs[4];
 494             __cpuid(regs, 0);
 495             return regs[0];
 496         }" HAVE_CPUID_INTRINSIC)
 497 ENDIF()
 498
 499 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 500 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 501 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 502 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 503 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 504 IF(NOT HAVE_C99_VLA)
 505     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 506     IF(NOT HAVE_ALLOCA)
 507         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 508     ENDIF()
 509 ENDIF()
 510
 511 IF(HAVE_FLOAT_H)
 512     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 513     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 514 ENDIF()
 515
 516 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 517 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 518 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 519 IF(NOT HAVE_STRCASECMP)
 520     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 521     IF(NOT HAVE__STRICMP)
 522         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 523     ENDIF()
 524
 525     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 526 ENDIF()
 527
 528 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 529 IF(NOT HAVE_STRNCASECMP)
 530     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 531     IF(NOT HAVE__STRNICMP)
 532         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 533     ENDIF()
 534
 535     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 536 ENDIF()
 537
 538 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 539 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 540 IF(NOT HAVE_SNPRINTF)
 541     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 542     IF(NOT HAVE__SNPRINTF)
 543         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 544     ENDIF()
 545
 546     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 547 ENDIF()
 548
 549 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 550 IF(NOT HAVE_ISFINITE)
 551     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 552     IF(NOT HAVE_FINITE)
 553         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 554         IF(NOT HAVE__FINITE)
 555             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 556         ENDIF()
 557         ADD_DEFINITIONS(-Disfinite=_finite)
 558     ELSE()
 559         ADD_DEFINITIONS(-Disfinite=finite)
 560     ENDIF()
 561 ENDIF()
 562
 563 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 564 IF(NOT HAVE_ISNAN)
 565     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 566     IF(NOT HAVE__ISNAN)
 567         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 568     ENDIF()
 569
 570     ADD_DEFINITIONS(-Disnan=_isnan)
 571 ENDIF()
 572
 573
 574 # Check if we have Windows headers
 575 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 576 IF(NOT HAVE_WINDOWS_H)
 577     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 578     IF(NOT HAVE_GETTIMEOFDAY)
 579         MESSAGE(FATAL_ERROR "No timing function found!")
 580     ENDIF()
 581
 582     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 583     IF(NOT HAVE_NANOSLEEP)
 584         MESSAGE(FATAL_ERROR "No sleep function found!")
 585     ENDIF()
 586
 587     # We need pthreads outside of Windows
 588     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 589     IF(NOT HAVE_PTHREAD_H)
 590         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 591     ENDIF()
 592     # Some systems need pthread_np.h to get recursive mutexes
 593     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 594
 595     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 596     IF(HAVE_PTHREAD)
 597         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 598         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 599         SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -pthread")
 600     ENDIF()
 601
 602     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 603     IF(HAVE_LIBPTHREAD)
 604         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 605     ENDIF()
 606
 607     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 608
 609     IF(HAVE_PTHREAD_NP_H)
 610         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 611         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 612             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 613         ELSE()
 614             CHECK_C_SOURCE_COMPILES("
 615 #include <pthread.h>
 616 #include <pthread_np.h>
 617 int main()
 618 {
 619     pthread_setname_np(\"testname\");
 620     return 0;
 621 }"
 622                 PTHREAD_SETNAME_NP_ONE_PARAM
 623             )
 624         ENDIF()
 625         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 626     ELSE()
 627         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 628         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 629             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 630         ELSE()
 631             CHECK_C_SOURCE_COMPILES("
 632 #include <pthread.h>
 633 int main()
 634 {
 635     pthread_setname_np(\"testname\");
 636     return 0;
 637 }"
 638                 PTHREAD_SETNAME_NP_ONE_PARAM
 639             )
 640         ENDIF()
 641         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 642     ENDIF()
 643
 644     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 645
 646     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 647     IF(HAVE_LIBRT)
 648         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 649     ENDIF()
 650 ENDIF()
 651
 652 # Check for a 64-bit type
 653 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 654 IF(NOT HAVE_STDINT_H)
 655     IF(HAVE_WINDOWS_H)
 656         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 657                                  #include <windows.h>
 658                                  __int64 foo;
 659                                  int main() {return 0;}" HAVE___INT64)
 660     ENDIF()
 661     IF(NOT HAVE___INT64)
 662         IF(NOT SIZEOF_LONG MATCHES "8")
 663             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 664                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 665             ENDIF()
 666         ENDIF()
 667     ENDIF()
 668 ENDIF()
 669
 670
 671 SET(COMMON_OBJS  common/almalloc.c
 672                  common/atomic.c
 673                  common/rwlock.c
 674                  common/threads.c
 675                  common/uintmap.c
 676 )
 677 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 678                  OpenAL32/alBuffer.c
 679                  OpenAL32/alEffect.c
 680                  OpenAL32/alError.c
 681                  OpenAL32/alExtension.c
 682                  OpenAL32/alFilter.c
 683                  OpenAL32/alListener.c
 684                  OpenAL32/alSource.c
 685                  OpenAL32/alState.c
 686                  OpenAL32/alThunk.c
 687                  OpenAL32/sample_cvt.c
 688 )
 689 SET(ALC_OBJS  Alc/ALc.c
 690               Alc/ALu.c
 691               Alc/alcConfig.c
 692               Alc/alcRing.c
 693               Alc/bs2b.c
 694               Alc/converter.c
 695               Alc/mastering.c
 696               Alc/effects/chorus.c
 697               Alc/effects/compressor.c
 698               Alc/effects/dedicated.c
 699               Alc/effects/distortion.c
 700               Alc/effects/echo.c
 701               Alc/effects/equalizer.c
 702               Alc/effects/flanger.c
 703               Alc/effects/modulator.c
 704               Alc/effects/null.c
 705               Alc/effects/reverb.c
 706               Alc/helpers.c
 707               Alc/bsinc.c
 708               Alc/hrtf.c
 709               Alc/uhjfilter.c
 710               Alc/ambdec.c
 711               Alc/bformatdec.c
 712               Alc/nfcfilter.c
 713               Alc/panning.c
 714               Alc/mixer.c
 715               Alc/mixer_c.c
 716 )
 717
 718
 719 SET(CPU_EXTS "Default")
 720 SET(HAVE_SSE        0)
 721 SET(HAVE_SSE2       0)
 722 SET(HAVE_SSE3       0)
 723 SET(HAVE_SSE4_1     0)
 724 SET(HAVE_NEON       0)
 725
 726 SET(HAVE_ALSA       0)
 727 SET(HAVE_OSS        0)
 728 SET(HAVE_SOLARIS    0)
 729 SET(HAVE_SNDIO      0)
 730 SET(HAVE_QSA        0)
 731 SET(HAVE_DSOUND     0)
 732 SET(HAVE_MMDEVAPI   0)
 733 SET(HAVE_WINMM      0)
 734 SET(HAVE_PORTAUDIO  0)
 735 SET(HAVE_PULSEAUDIO 0)
 736 SET(HAVE_COREAUDIO  0)
 737 SET(HAVE_OPENSL     0)
 738 SET(HAVE_WAVE       0)
 739
 740 # Check for SSE support
 741 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 742 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 743 IF(HAVE_XMMINTRIN_H)
 744     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 745     IF(ALSOFT_CPUEXT_SSE)
 746         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 747             SET(HAVE_SSE 1)
 748             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 749             IF(SSE_SWITCH)
 750                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 751                                             COMPILE_FLAGS "${SSE_SWITCH}")
 752             ENDIF()
 753             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 754         ENDIF()
 755     ENDIF()
 756 ENDIF()
 757 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 758     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 759 ENDIF()
 760
 761 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 762 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 763 IF(HAVE_EMMINTRIN_H)
 764     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 765     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 766         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 767             SET(HAVE_SSE2 1)
 768             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 769             IF(SSE2_SWITCH)
 770                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 771                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 772             ENDIF()
 773             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 774         ENDIF()
 775     ENDIF()
 776 ENDIF()
 777 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 778     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 779 ENDIF()
 780
 781 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 782 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 783 IF(HAVE_EMMINTRIN_H)
 784     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 785     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 786         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 787             SET(HAVE_SSE3 1)
 788             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 789             IF(SSE2_SWITCH)
 790                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 791                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 792             ENDIF()
 793             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 794         ENDIF()
 795     ENDIF()
 796 ENDIF()
 797 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 798     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 799 ENDIF()
 800
 801 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 802 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 803 IF(HAVE_SMMINTRIN_H)
 804     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 805     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 806         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 807             SET(HAVE_SSE4_1 1)
 808             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 809             IF(SSE4_1_SWITCH)
 810                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 811                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 812             ENDIF()
 813             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 814         ENDIF()
 815     ENDIF()
 816 ENDIF()
 817 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 818     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 819 ENDIF()
 820
 821 # Check for ARM Neon support
 822 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 823 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 824 IF(HAVE_ARM_NEON_H)
 825     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 826     IF(ALSOFT_CPUEXT_NEON)
 827         SET(HAVE_NEON 1)
 828         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 829         IF(FPU_NEON_SWITCH)
 830             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 831                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 832         ENDIF()
 833         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 834     ENDIF()
 835 ENDIF()
 836 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 837     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 838 ENDIF()
 839
 840
 841 IF(WIN32 OR HAVE_DLFCN_H)
 842     SET(IS_LINKED "")
 843     MACRO(ADD_BACKEND_LIBS _LIBS)
 844     ENDMACRO()
 845 ELSE()
 846     SET(IS_LINKED " (linked)")
 847     MACRO(ADD_BACKEND_LIBS _LIBS)
 848         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 849     ENDMACRO()
 850 ENDIF()
 851
 852 SET(BACKENDS "")
 853 SET(ALC_OBJS  ${ALC_OBJS}
 854               Alc/backends/base.c
 855               # Default backends, always available
 856               Alc/backends/loopback.c
 857               Alc/backends/null.c
 858 )
 859
 860 # Check ALSA backend
 861 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 862 FIND_PACKAGE(ALSA)
 863 IF(ALSA_FOUND)
 864     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 865     IF(ALSOFT_BACKEND_ALSA)
 866         SET(HAVE_ALSA 1)
 867         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 868         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 869         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 870     ENDIF()
 871 ENDIF()
 872 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 873     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 874 ENDIF()
 875
 876 # Check OSS backend
 877 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 878 FIND_PACKAGE(OSS)
 879 IF(OSS_FOUND)
 880     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 881     IF(ALSOFT_BACKEND_OSS)
 882         SET(HAVE_OSS 1)
 883         SET(BACKENDS  "${BACKENDS} OSS,")
 884         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 885     ENDIF()
 886 ENDIF()
 887 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 888     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 889 ENDIF()
 890
 891 # Check Solaris backend
 892 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 893 FIND_PACKAGE(AudioIO)
 894 IF(AUDIOIO_FOUND)
 895     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 896     IF(ALSOFT_BACKEND_SOLARIS)
 897         SET(HAVE_SOLARIS 1)
 898         SET(BACKENDS  "${BACKENDS} Solaris,")
 899         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 900     ENDIF()
 901 ENDIF()
 902 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 903     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 904 ENDIF()
 905
 906 # Check SndIO backend
 907 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 908 FIND_PACKAGE(SoundIO)
 909 IF(SOUNDIO_FOUND)
 910     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 911     IF(ALSOFT_BACKEND_SNDIO)
 912         SET(HAVE_SNDIO 1)
 913         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 914         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 915         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 916     ENDIF()
 917 ENDIF()
 918 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 919     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 920 ENDIF()
 921
 922 # Check QSA backend
 923 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 924 FIND_PACKAGE(QSA)
 925 IF(QSA_FOUND)
 926     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 927     IF(ALSOFT_BACKEND_QSA)
 928         SET(HAVE_QSA 1)
 929         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 930         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 931         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 932     ENDIF()
 933 ENDIF()
 934 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 935     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 936 ENDIF()
 937
 938 # Check Windows-only backends
 939 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 940 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 941 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 942 IF(HAVE_WINDOWS_H)
 943     # Check MMSystem backend
 944     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 945     IF(HAVE_MMSYSTEM_H)
 946         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 947         IF(HAVE_LIBWINMM)
 948             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 949             IF(ALSOFT_BACKEND_WINMM)
 950                 SET(HAVE_WINMM 1)
 951                 SET(BACKENDS  "${BACKENDS} WinMM,")
 952                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 953                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 954             ENDIF()
 955         ENDIF()
 956     ENDIF()
 957
 958     # Check DSound backend
 959     FIND_PACKAGE(DSound)
 960     IF(DSOUND_FOUND)
 961         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 962         IF(ALSOFT_BACKEND_DSOUND)
 963             SET(HAVE_DSOUND 1)
 964             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 965             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 966             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 967         ENDIF()
 968     ENDIF()
 969
 970     # Check for MMDevApi backend
 971     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 972     IF(HAVE_MMDEVICEAPI_H)
 973         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 974         IF(ALSOFT_BACKEND_MMDEVAPI)
 975             SET(HAVE_MMDEVAPI 1)
 976             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 977             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 978         ENDIF()
 979     ENDIF()
 980 ENDIF()
 981 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 982     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 983 ENDIF()
 984 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 985     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 986 ENDIF()
 987 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 988     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 989 ENDIF()
 990
 991 # Check PortAudio backend
 992 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 993 FIND_PACKAGE(PortAudio)
 994 IF(PORTAUDIO_FOUND)
 995     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 996     IF(ALSOFT_BACKEND_PORTAUDIO)
 997         SET(HAVE_PORTAUDIO 1)
 998         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 999         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1000         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1001     ENDIF()
1002 ENDIF()
1003 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1004     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1005 ENDIF()
1006
1007 # Check PulseAudio backend
1008 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1009 FIND_PACKAGE(PulseAudio)
1010 IF(PULSEAUDIO_FOUND)
1011     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1012     IF(ALSOFT_BACKEND_PULSEAUDIO)
1013         SET(HAVE_PULSEAUDIO 1)
1014         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1015         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1016         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1017     ENDIF()
1018 ENDIF()
1019 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1020     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1021 ENDIF()
1022
1023 # Check JACK backend
1024 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1025 FIND_PACKAGE(JACK)
1026 IF(JACK_FOUND)
1027     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1028     IF(ALSOFT_BACKEND_JACK)
1029         SET(HAVE_JACK 1)
1030         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1031         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1032         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1033     ENDIF()
1034 ENDIF()
1035 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1036     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1037 ENDIF()
1038
1039 # Check CoreAudio backend
1040 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1041 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1042              NAMES CoreAudio
1043              PATHS /System/Library/Frameworks
1044 )
1045 IF(COREAUDIO_FRAMEWORK)
1046     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1047     IF(ALSOFT_BACKEND_COREAUDIO)
1048         SET(HAVE_COREAUDIO 1)
1049         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1050         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1051         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1052         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1053         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1054
1055         # Some versions of OSX may need the AudioToolbox framework. Add it if
1056         # it's found.
1057         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1058                      NAMES AudioToolbox
1059                      PATHS ~/Library/Frameworks
1060                            /Library/Frameworks
1061                            /System/Library/Frameworks
1062                     )
1063         IF(AUDIOTOOLBOX_LIBRARY)
1064             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1065         ENDIF()
1066     ENDIF()
1067 ENDIF()
1068 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1069     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1070 ENDIF()
1071
1072 # Check for OpenSL (Android) backend
1073 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1074 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1075 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1076     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1077     IF(HAVE_LIBOPENSLES)
1078         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1079         IF(ALSOFT_BACKEND_OPENSL)
1080             SET(HAVE_OPENSL 1)
1081             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1082             SET(BACKENDS  "${BACKENDS} OpenSL,")
1083             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1084         ENDIF()
1085     ENDIF()
1086 ENDIF()
1087 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1088     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1089 ENDIF()
1090
1091 # Optionally enable the Wave Writer backend
1092 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1093 IF(ALSOFT_BACKEND_WAVE)
1094     SET(HAVE_WAVE 1)
1095     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1096     SET(BACKENDS  "${BACKENDS} WaveFile,")
1097 ENDIF()
1098
1099 # This is always available
1100 SET(BACKENDS  "${BACKENDS} Null")
1101
1102 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1103 if(ALSOFT_EMBED_HRTF_DATA)
1104     SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1105     SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1106     FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1107
1108     SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1109     ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}"
1110         COMMAND ${CMAKE_COMMAND} "${NATIVE_SRC_DIR}"
1111         COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1112         WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1113         DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt" "${NATIVE_SRC_DIR}bin2h.c"
1114         VERBATIM
1115     )
1116
1117     MACRO(make_hrtf_header FILENAME VARNAME)
1118         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1119         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1120
1121         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1122             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1123             DEPENDS "${BIN2H_COMMAND}" "${infile}"
1124             COMMENT "Generating ${FILENAME}.h"
1125             VERBATIM
1126         )
1127
1128         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1129     ENDMACRO()
1130
1131     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1132     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1133 endif()
1134
1135
1136 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1137     add_subdirectory(utils/alsoft-config)
1138 ENDIF()
1139 IF(ALSOFT_EXAMPLES)
1140     FIND_PACKAGE(SDL2)
1141     IF(SDL2_FOUND)
1142         FIND_PACKAGE(SDL_sound)
1143         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1144     ENDIF()
1145 ENDIF()
1146
1147 IF(LIBTYPE STREQUAL "STATIC")
1148     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1149     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1150 ENDIF()
1151
1152 IF(NOT WIN32)
1153     SET(LIBNAME "openal")
1154 ELSE()
1155     SET(LIBNAME "OpenAL32")
1156 ENDIF()
1157
1158 FIND_PACKAGE(Git)
1159 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1160     # Get the current working branch and its latest abbreviated commit hash
1161     ADD_CUSTOM_TARGET(build_version
1162         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1163                          -D LIB_VERSION=${LIB_VERSION}
1164                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1165                          -D DST=${OpenAL_BINARY_DIR}/version.h
1166                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1167         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1168         VERBATIM
1169     )
1170 ELSE()
1171     SET(GIT_BRANCH "UNKNOWN")
1172     SET(GIT_COMMIT_HASH "unknown")
1173     CONFIGURE_FILE(
1174         "${OpenAL_SOURCE_DIR}/version.h.in"
1175         "${OpenAL_BINARY_DIR}/version.h")
1176 ENDIF()
1177
1178 # Needed for openal.pc.in
1179 SET(prefix ${CMAKE_INSTALL_PREFIX})
1180 SET(exec_prefix "\${prefix}")
1181 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1182 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1183 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1184 SET(PACKAGE_VERSION "${LIB_VERSION}")
1185
1186 # End configuration
1187 CONFIGURE_FILE(
1188     "${OpenAL_SOURCE_DIR}/config.h.in"
1189     "${OpenAL_BINARY_DIR}/config.h")
1190 CONFIGURE_FILE(
1191     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1192     "${OpenAL_BINARY_DIR}/openal.pc"
1193     @ONLY)
1194
1195 # Build main library
1196 IF(LIBTYPE STREQUAL "STATIC")
1197     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1198 ELSE()
1199     ADD_LIBRARY(OpenAL SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1200 ENDIF()
1201 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1202 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
1203 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1204     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1205 ENDIF()
1206 SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1207 IF(HAVE_ALSA)
1208     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1209 ENDIF()
1210 IF(HAVE_OSS)
1211     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1212 ENDIF()
1213 IF(HAVE_SOLARIS)
1214     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1215 ENDIF()
1216 IF(HAVE_SNDIO)
1217     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1218 ENDIF()
1219 IF(HAVE_QSA)
1220     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1221 ENDIF()
1222 IF(HAVE_DSOUND)
1223     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1224 ENDIF()
1225 IF(HAVE_PORTAUDIO)
1226     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1227 ENDIF()
1228 IF(HAVE_PULSEAUDIO)
1229     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1230 ENDIF()
1231 IF(HAVE_JACK)
1232     SET_PROPERTY(TARGET OpenAL APPEND PROPERTY INCLUDE_DIRECTORIES ${JACK_INCLUDE_DIRS})
1233 ENDIF()
1234 IF(WIN32)
1235     IF(MSVC)
1236         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1237     ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1238         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1239     ENDIF()
1240 ENDIF()
1241
1242 SET_TARGET_PROPERTIES(OpenAL PROPERTIES VERSION ${LIB_VERSION}
1243                                         SOVERSION ${LIB_MAJOR_VERSION})
1244 SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1245
1246 if(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1247     SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1248
1249     IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1250         FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1251         FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1252         IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1253             MESSAGE(STATUS "")
1254             IF(NOT SED_EXECUTABLE)
1255                 MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1256             ENDIF()
1257             IF(NOT DLLTOOL_EXECUTABLE)
1258                 MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1259             ENDIF()
1260         ELSE()
1261             SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -Wl,--output-def,OpenAL32.def")
1262             ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1263                 COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1264                 COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1265                 COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1266                 VERBATIM
1267             )
1268         ENDIF()
1269     ENDIF()
1270 ENDIF()
1271
1272 SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1273 TARGET_LINK_LIBRARIES(OpenAL ${EXTRA_LIBS})
1274 IF(TARGET build_version)
1275     ADD_DEPENDENCIES(OpenAL build_version)
1276 ENDIF()
1277
1278 IF(ALSOFT_INSTALL)
1279     # Add an install target here
1280     INSTALL(TARGETS OpenAL EXPORT OpenAL
1281             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1282             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1283             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1284             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1285     )
1286     EXPORT(TARGETS OpenAL
1287            NAMESPACE OpenAL::
1288            FILE OpenALConfig.cmake)
1289     INSTALL(EXPORT OpenAL
1290             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1291             NAMESPACE OpenAL::
1292             FILE OpenALConfig.cmake)
1293     INSTALL(FILES include/AL/al.h
1294                   include/AL/alc.h
1295                   include/AL/alext.h
1296                   include/AL/efx.h
1297                   include/AL/efx-creative.h
1298                   include/AL/efx-presets.h
1299             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1300     )
1301     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1302             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1303 ENDIF()
1304
1305
1306 MESSAGE(STATUS "")
1307 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1308 MESSAGE(STATUS "    ${BACKENDS}")
1309 MESSAGE(STATUS "")
1310 MESSAGE(STATUS "Building with support for CPU extensions:")
1311 MESSAGE(STATUS "    ${CPU_EXTS}")
1312 MESSAGE(STATUS "")
1313
1314 IF(WIN32)
1315     IF(NOT HAVE_DSOUND)
1316         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1317         MESSAGE(STATUS "         This is probably NOT what you want!")
1318         MESSAGE(STATUS "")
1319     ENDIF()
1320 ENDIF()
1321
1322 if(ALSOFT_EMBED_HRTF_DATA)
1323     message(STATUS "Embedding HRTF datasets")
1324     message(STATUS "")
1325 endif()
1326
1327 # Install alsoft.conf configuration file
1328 IF(ALSOFT_CONFIG)
1329     INSTALL(FILES alsoftrc.sample
1330             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1331     )
1332     MESSAGE(STATUS "Installing sample configuration")
1333     MESSAGE(STATUS "")
1334 ENDIF()
1335
1336 # Install HRTF definitions
1337 IF(ALSOFT_HRTF_DEFS)
1338     INSTALL(FILES hrtf/default-44100.mhr
1339                   hrtf/default-48000.mhr
1340             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1341     )
1342     MESSAGE(STATUS "Installing HRTF definitions")
1343     MESSAGE(STATUS "")
1344 ENDIF()
1345
1346 # Install AmbDec presets
1347 IF(ALSOFT_AMBDEC_PRESETS)
1348     INSTALL(FILES presets/3D7.1.ambdec
1349                   presets/hexagon.ambdec
1350                   presets/itu5.1.ambdec
1351                   presets/rectangle.ambdec
1352                   presets/square.ambdec
1353                   presets/presets.txt
1354             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1355     )
1356     MESSAGE(STATUS "Installing AmbDec presets")
1357     MESSAGE(STATUS "")
1358 ENDIF()
1359
1360 IF(ALSOFT_UTILS)
1361     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1362     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1363     TARGET_LINK_LIBRARIES(openal-info OpenAL)
1364
1365     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1366     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1367     IF(HAVE_LIBM)
1368         TARGET_LINK_LIBRARIES(makehrtf m)
1369     ENDIF()
1370
1371     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1372     SET_PROPERTY(TARGET bsincgen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1373     IF(HAVE_LIBM)
1374         TARGET_LINK_LIBRARIES(bsincgen m)
1375     ENDIF()
1376
1377     IF(ALSOFT_INSTALL)
1378         INSTALL(TARGETS openal-info makehrtf bsincgen
1379                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1380                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1381                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1382         )
1383     ENDIF()
1384
1385     MESSAGE(STATUS "Building utility programs")
1386     IF(TARGET alsoft-config)
1387         MESSAGE(STATUS "Building configuration program")
1388     ENDIF()
1389     MESSAGE(STATUS "")
1390 ENDIF()
1391
1392 IF(ALSOFT_TESTS)
1393     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1394
1395     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1396     TARGET_LINK_LIBRARIES(altonegen OpenAL)
1397     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1398
1399     IF(ALSOFT_INSTALL)
1400         INSTALL(TARGETS altonegen
1401                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1402                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1403                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1404         )
1405     ENDIF()
1406
1407     MESSAGE(STATUS "Building test programs")
1408     MESSAGE(STATUS "")
1409 ENDIF()
1410
1411 IF(ALSOFT_EXAMPLES)
1412     ADD_EXECUTABLE(alrecord examples/alrecord.c ${COMMON_OBJS})
1413     TARGET_LINK_LIBRARIES(alrecord OpenAL)
1414     SET_PROPERTY(TARGET alrecord APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1415
1416     IF(ALSOFT_INSTALL)
1417         INSTALL(TARGETS alrecord
1418                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1419                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1420                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1421         )
1422     ENDIF()
1423
1424     MESSAGE(STATUS "Building example programs")
1425
1426     IF(SDL2_FOUND)
1427         IF(SDL_SOUND_FOUND)
1428             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1429
1430             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1431             TARGET_LINK_LIBRARIES(alstream ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1432             SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1433             SET_PROPERTY(TARGET alstream APPEND PROPERTY
1434                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1435             )
1436
1437             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1438             TARGET_LINK_LIBRARIES(alreverb ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1439             SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1440             SET_PROPERTY(TARGET alreverb APPEND PROPERTY
1441                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1442             )
1443
1444             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1445             TARGET_LINK_LIBRARIES(allatency ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1446             SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1447             SET_PROPERTY(TARGET allatency APPEND PROPERTY
1448                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1449             )
1450
1451             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1452             TARGET_LINK_LIBRARIES(alloopback ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1453             SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1454             SET_PROPERTY(TARGET alloopback APPEND PROPERTY
1455                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1456             )
1457
1458             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1459             TARGET_LINK_LIBRARIES(alhrtf ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1460             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1461             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY
1462                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1463             )
1464
1465             IF(ALSOFT_INSTALL)
1466                 INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1467                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1468                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1469                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1470                 )
1471             ENDIF()
1472
1473             MESSAGE(STATUS "Building SDL_sound example programs")
1474         ENDIF()
1475
1476         SET(FFVER_OK FALSE)
1477         IF(FFMPEG_FOUND)
1478             SET(FFVER_OK TRUE)
1479             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1480                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1481                 SET(FFVER_OK FALSE)
1482             ENDIF()
1483             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1484                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1485                 SET(FFVER_OK FALSE)
1486             ENDIF()
1487             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1488                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1489                 SET(FFVER_OK FALSE)
1490             ENDIF()
1491             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1492                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1493                 SET(FFVER_OK FALSE)
1494             ENDIF()
1495             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1496                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1497                 SET(FFVER_OK FALSE)
1498             ENDIF()
1499         ENDIF()
1500         IF(FFVER_OK)
1501             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1502             TARGET_LINK_LIBRARIES(alffplay ${SDL2_LIBRARY} OpenAL ${FFMPEG_LIBRARIES})
1503             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1504             SET_PROPERTY(TARGET alffplay APPEND PROPERTY
1505                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS}
1506             )
1507
1508             IF(ALSOFT_INSTALL)
1509                 INSTALL(TARGETS alffplay
1510                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1511                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1512                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1513                 )
1514             ENDIF()
1515             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1516         ENDIF()
1517         MESSAGE(STATUS "")
1518     ENDIF()
1519 ENDIF()