CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 SET(CPP_DEFS ) # C pre-process, not C++
  66 SET(INC_PATHS )
  67 SET(C_FLAGS )
  68 SET(LINKER_FLAGS )
  69 SET(EXTRA_LIBS )
  70
  71 IF(WIN32)
  72     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  73
  74     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  75
  76     # This option is mainly for static linking OpenAL Soft into another project
  77     # that already defines the IDs. It is up to that project to ensure all
  78     # required IDs are defined.
  79     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  80
  81     IF(MINGW)
  82         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  83         IF(NOT DLLTOOL)
  84             IF(HOST)
  85                 SET(DLLTOOL "${HOST}-dlltool")
  86             ELSE()
  87                 SET(DLLTOOL "dlltool")
  88             ENDIF()
  89         ENDIF()
  90     ENDIF()
  91 ENDIF()
  92
  93
  94 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  95 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  96     SET(INC_PATHS ${INC_PATHS} /usr/include)
  97     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
  98 ENDIF()
  99
 100 IF(NOT LIBTYPE)
 101     SET(LIBTYPE SHARED)
 102 ENDIF()
 103
 104 SET(LIB_MAJOR_VERSION "1")
 105 SET(LIB_MINOR_VERSION "18")
 106 SET(LIB_REVISION "2")
 107 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 108
 109 SET(EXPORT_DECL "")
 110 SET(ALIGN_DECL "")
 111
 112
 113 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 114 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 115
 116
 117 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 118 IF(HAVE_STD_C11)
 119     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 120 ELSE()
 121     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 122     IF(HAVE_STD_C99)
 123         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 124     ENDIF()
 125 ENDIF()
 126
 127 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 128 IF(HAVE_STD_CXX11)
 129     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 130 ENDIF()
 131
 132 if(NOT WIN32)
 133     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 134     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 135     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 136         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 137         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 138         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 139         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 140             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 141         ELSE()
 142             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 143         ENDIF()
 144     ENDIF()
 145     UNSET(OLD_REQUIRED_FLAGS)
 146 ENDIF()
 147
 148 # Set defines for large file support
 149 CHECK_FILE_OFFSET_BITS()
 150 IF(_FILE_OFFSET_BITS)
 151     SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 152     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 153 ENDIF()
 154 SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 155 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 156
 157 # MSVC may need workarounds for C99 restrict and inline
 158 IF(MSVC)
 159     # TODO: Once we truly require C99, these restrict and inline checks should go
 160     # away.
 161     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 162                              int main() {return 0;}" HAVE_RESTRICT)
 163     IF(NOT HAVE_RESTRICT)
 164         SET(CPP_DEFS ${CPP_DEFS} "restrict=")
 165         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 166     ENDIF()
 167
 168     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 169                              int main() {return 0;}" HAVE_INLINE)
 170     IF(NOT HAVE_INLINE)
 171         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 172                                  int main() {return 0;}" HAVE___INLINE)
 173         IF(NOT HAVE___INLINE)
 174             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 175         ENDIF()
 176
 177         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 178         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 179     ENDIF()
 180 ENDIF()
 181
 182 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 183 IF(CMAKE_COMPILER_IS_GNUCC)
 184     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 185
 186     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 187     # Force no inlining for the next test.
 188     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 189
 190     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 191                              int main() {return foo();}" INLINE_IS_C99)
 192     IF(NOT INLINE_IS_C99)
 193         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 194                              Please update your compiler for better C99 compliance.")
 195     ENDIF()
 196
 197     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 198 ENDIF()
 199
 200 # Check if we have a proper timespec declaration
 201 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 202 IF(HAVE_STRUCT_TIMESPEC)
 203     # Define it here so we don't have to include config.h for it
 204     SET(CPP_DEFS ${CPP_DEFS} HAVE_STRUCT_TIMESPEC)
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Check if we have C99 bool
 232 CHECK_C_SOURCE_COMPILES(
 233 "int main(int argc, char *argv[])
 234  {
 235      volatile _Bool ret;
 236      ret = (argc > 1) ? 1 : 0;
 237      return ret ? -1 : 0;
 238  }"
 239 HAVE_C99_BOOL)
 240
 241 # Check if we have C11 static_assert
 242 CHECK_C_SOURCE_COMPILES(
 243 "int main()
 244  {
 245      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 246      return 0;
 247  }"
 248 HAVE_C11_STATIC_ASSERT)
 249
 250 # Check if we have C11 alignas
 251 CHECK_C_SOURCE_COMPILES(
 252 "_Alignas(16) int foo;
 253  int main()
 254  {
 255      return 0;
 256  }"
 257 HAVE_C11_ALIGNAS)
 258
 259 # Check if we have C11 _Atomic
 260 CHECK_C_SOURCE_COMPILES(
 261 "#include <stdatomic.h>
 262  int _Atomic foo = ATOMIC_VAR_INIT(0);
 263  int main()
 264  {
 265      atomic_fetch_add(&foo, 2);
 266      return 0;
 267  }"
 268 HAVE_C11_ATOMIC)
 269
 270 # Add definitions, compiler switches, etc.
 271 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 272
 273 IF(NOT CMAKE_BUILD_TYPE)
 274     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 275         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 276         FORCE)
 277 ENDIF()
 278 IF(NOT CMAKE_DEBUG_POSTFIX)
 279     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 280         "Library postfix for debug builds. Normally left blank."
 281         FORCE)
 282 ENDIF()
 283
 284 IF(MSVC)
 285     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 286     SET(C_FLAGS ${C_FLAGS} /wd4098)
 287
 288     IF(NOT DXSDK_DIR)
 289         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 290     ELSE()
 291         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 292     ENDIF()
 293     IF(DXSDK_DIR)
 294         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 295     ENDIF()
 296
 297     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 298     IF(FORCE_STATIC_VCRT)
 299         FOREACH(flag_var
 300                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 301                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 302             IF(${flag_var} MATCHES "/MD")
 303                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 304             ENDIF()
 305         ENDFOREACH(flag_var)
 306     ENDIF()
 307 ELSE()
 308     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 309     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 310     IF(HAVE_W_EXTRA)
 311         SET(C_FLAGS ${C_FLAGS} -Wextra)
 312     ENDIF()
 313
 314     IF(ALSOFT_WERROR)
 315         SET(C_FLAGS ${C_FLAGS} -Werror)
 316     ENDIF()
 317
 318     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 319     # instead of NDEBUG)
 320     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 321         IF(${flag_var} MATCHES "-DNDEBUG")
 322             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 323         ENDIF()
 324     ENDFOREACH()
 325
 326     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 327     IF(HAVE_FNO_MATH_ERRNO)
 328         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 329     ENDIF()
 330
 331     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 332                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 333
 334     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 335     if(ALSOFT_STATIC_LIBGCC)
 336         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 337         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 338         check_c_source_compiles(
 339 "#include <stdlib.h>
 340 int main()
 341 {
 342     return 0;
 343 }"
 344             HAVE_STATIC_LIBGCC_SWITCH
 345         )
 346         if(HAVE_STATIC_LIBGCC_SWITCH)
 347             SET(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 348         endif()
 349         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 350         unset(OLD_REQUIRED_LIBRARIES)
 351     endif()
 352 ENDIF()
 353
 354 # Set visibility/export options if available
 355 IF(WIN32)
 356     SET(EXPORT_DECL "__declspec(dllexport)")
 357     IF(NOT MINGW)
 358         SET(ALIGN_DECL "__declspec(align(x))")
 359     ELSE()
 360         SET(ALIGN_DECL "__declspec(aligned(x))")
 361     ENDIF()
 362 ELSE()
 363     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 364     # Yes GCC, really don't accept visibility modes you don't support
 365     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 366
 367     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 368                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 369     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 370         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 371     ELSE()
 372         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 373                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 374         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 375             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 376         ENDIF()
 377     ENDIF()
 378
 379     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 380         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 381         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 382             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 383         ENDIF()
 384     ENDIF()
 385
 386     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 387                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 388     IF(HAVE_ATTRIBUTE_ALIGNED)
 389         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 390     ENDIF()
 391
 392     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 393 ENDIF()
 394
 395 CHECK_C_SOURCE_COMPILES("
 396 int main()
 397 {
 398     float *ptr;
 399     ptr = __builtin_assume_aligned(ptr, 16);
 400     return 0;
 401 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 402 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 403     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 404 ELSE()
 405     SET(ASSUME_ALIGNED_DECL "x")
 406 ENDIF()
 407
 408 SET(SSE_SWITCH "")
 409 SET(SSE2_SWITCH "")
 410 SET(SSE3_SWITCH "")
 411 SET(SSE4_1_SWITCH "")
 412 SET(FPU_NEON_SWITCH "")
 413
 414 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 415 IF(HAVE_MSSE_SWITCH)
 416     SET(SSE_SWITCH "-msse")
 417 ENDIF()
 418 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 419 IF(HAVE_MSSE2_SWITCH)
 420     SET(SSE2_SWITCH "-msse2")
 421 ENDIF()
 422 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 423 IF(HAVE_MSSE3_SWITCH)
 424     SET(SSE3_SWITCH "-msse3")
 425 ENDIF()
 426 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 427 IF(HAVE_MSSE4_1_SWITCH)
 428     SET(SSE4_1_SWITCH "-msse4.1")
 429 ENDIF()
 430 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 431 IF(HAVE_MFPU_NEON_SWITCH)
 432     SET(FPU_NEON_SWITCH "-mfpu=neon")
 433 ENDIF()
 434
 435 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 436                          int main() {return 0;}" HAVE_GCC_FORMAT)
 437
 438 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 439 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 440 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 441 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 442 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 443 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 444 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 445 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 446 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 447 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 448 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 449 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 450 IF(NOT HAVE_GUIDDEF_H)
 451     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 452 ENDIF()
 453
 454 # Some systems need libm for some of the following math functions to work
 455 SET(MATH_LIB )
 456 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 457 IF(HAVE_LIBM)
 458     SET(MATH_LIB ${MATH_LIB} m)
 459     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 460 ENDIF()
 461
 462 # Check for the dlopen API (for dynamicly loading backend libs)
 463 IF(ALSOFT_DLOPEN)
 464     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 465     IF(HAVE_LIBDL)
 466         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 467         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 468     ENDIF()
 469
 470     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 471 ENDIF()
 472
 473 # Check for a cpuid intrinsic
 474 IF(HAVE_CPUID_H)
 475     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 476         int main()
 477         {
 478             unsigned int eax, ebx, ecx, edx;
 479             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 480         }" HAVE_GCC_GET_CPUID)
 481 ENDIF()
 482 IF(HAVE_INTRIN_H)
 483     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 484         int main()
 485         {
 486             int regs[4];
 487             __cpuid(regs, 0);
 488             return regs[0];
 489         }" HAVE_CPUID_INTRINSIC)
 490     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 491         int main()
 492         {
 493             unsigned long idx = 0;
 494             _BitScanForward64(&idx, 1);
 495             return idx;
 496         }" HAVE_BITSCANFORWARD64_INTRINSIC)
 497     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 498         int main()
 499         {
 500             unsigned long idx = 0;
 501             _BitScanForward(&idx, 1);
 502             return idx;
 503         }" HAVE_BITSCANFORWARD_INTRINSIC)
 504 ENDIF()
 505
 506 CHECK_SYMBOL_EXISTS(sysconf          unistd.h HAVE_SYSCONF)
 507 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 508 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 509 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 510 CHECK_SYMBOL_EXISTS(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 511 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 512 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 513 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 514 CHECK_SYMBOL_EXISTS(cbrtf  math.h HAVE_CBRTF)
 515
 516 IF(HAVE_FLOAT_H)
 517     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 518     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 519 ENDIF()
 520
 521 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 522 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 523 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 524 IF(NOT HAVE_STRCASECMP)
 525     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 526     IF(NOT HAVE__STRICMP)
 527         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 528     ENDIF()
 529
 530     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 531 ENDIF()
 532
 533 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 534 IF(NOT HAVE_STRNCASECMP)
 535     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 536     IF(NOT HAVE__STRNICMP)
 537         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 538     ENDIF()
 539
 540     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 541 ENDIF()
 542
 543 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 544 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 545 IF(NOT HAVE_SNPRINTF)
 546     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 547     IF(NOT HAVE__SNPRINTF)
 548         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 549     ENDIF()
 550
 551     SET(CPP_DEFS ${CPP_DEFS} snprintf=_snprintf)
 552 ENDIF()
 553
 554 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 555 IF(NOT HAVE_ISFINITE)
 556     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 557     IF(NOT HAVE_FINITE)
 558         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 559         IF(NOT HAVE__FINITE)
 560             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 561         ENDIF()
 562         SET(CPP_DEFS ${CPP_DEFS} isfinite=_finite)
 563     ELSE()
 564         SET(CPP_DEFS ${CPP_DEFS} isfinite=finite)
 565     ENDIF()
 566 ENDIF()
 567
 568 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 569 IF(NOT HAVE_ISNAN)
 570     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 571     IF(NOT HAVE__ISNAN)
 572         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 573     ENDIF()
 574
 575     SET(CPP_DEFS ${CPP_DEFS} isnan=_isnan)
 576 ENDIF()
 577
 578
 579 # Check if we have Windows headers
 580 SET(OLD_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS})
 581 SET(CMAKE_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS} -D_WIN32_WINNT=0x0502)
 582 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
 583 SET(CMAKE_REQUIRED_DEFINITIONS ${OLD_REQUIRED_DEFINITIONS})
 584 UNSET(OLD_REQUIRED_DEFINITIONS)
 585
 586 IF(NOT HAVE_WINDOWS_H)
 587     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 588     IF(NOT HAVE_GETTIMEOFDAY)
 589         MESSAGE(FATAL_ERROR "No timing function found!")
 590     ENDIF()
 591
 592     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 593     IF(NOT HAVE_NANOSLEEP)
 594         MESSAGE(FATAL_ERROR "No sleep function found!")
 595     ENDIF()
 596
 597     # We need pthreads outside of Windows
 598     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 599     IF(NOT HAVE_PTHREAD_H)
 600         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 601     ENDIF()
 602     # Some systems need pthread_np.h to get recursive mutexes
 603     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 604
 605     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 606     IF(HAVE_PTHREAD)
 607         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 608         SET(C_FLAGS ${C_FLAGS} -pthread)
 609         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 610     ENDIF()
 611
 612     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 613     IF(HAVE_LIBPTHREAD)
 614         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 615     ENDIF()
 616
 617     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 618
 619     IF(HAVE_PTHREAD_NP_H)
 620         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 621         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 622             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 623         ELSE()
 624             CHECK_C_SOURCE_COMPILES("
 625 #include <pthread.h>
 626 #include <pthread_np.h>
 627 int main()
 628 {
 629     pthread_setname_np(\"testname\");
 630     return 0;
 631 }"
 632                 PTHREAD_SETNAME_NP_ONE_PARAM
 633             )
 634             CHECK_C_SOURCE_COMPILES("
 635 #include <pthread.h>
 636 #include <pthread_np.h>
 637 int main()
 638 {
 639     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 640     return 0;
 641 }"
 642                 PTHREAD_SETNAME_NP_THREE_PARAMS
 643             )
 644         ENDIF()
 645         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 646     ELSE()
 647         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 648         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 649             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 650         ELSE()
 651             CHECK_C_SOURCE_COMPILES("
 652 #include <pthread.h>
 653 int main()
 654 {
 655     pthread_setname_np(\"testname\");
 656     return 0;
 657 }"
 658                 PTHREAD_SETNAME_NP_ONE_PARAM
 659             )
 660             CHECK_C_SOURCE_COMPILES("
 661 #include <pthread.h>
 662 int main()
 663 {
 664     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 665     return 0;
 666 }"
 667                 PTHREAD_SETNAME_NP_THREE_PARAMS
 668             )
 669         ENDIF()
 670         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 671     ENDIF()
 672
 673     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 674
 675     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 676     IF(HAVE_LIBRT)
 677         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 678     ENDIF()
 679 ENDIF()
 680
 681 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 682
 683 # Check for a 64-bit type
 684 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 685 IF(NOT HAVE_STDINT_H)
 686     IF(HAVE_WINDOWS_H)
 687         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 688                                  #include <windows.h>
 689                                  __int64 foo;
 690                                  int main() {return 0;}" HAVE___INT64)
 691     ENDIF()
 692     IF(NOT HAVE___INT64)
 693         IF(NOT SIZEOF_LONG MATCHES "8")
 694             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 695                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 696             ENDIF()
 697         ENDIF()
 698     ENDIF()
 699 ENDIF()
 700
 701
 702 SET(COMMON_OBJS
 703     common/alcomplex.c
 704     common/alcomplex.h
 705     common/align.h
 706     common/almalloc.c
 707     common/almalloc.h
 708     common/atomic.c
 709     common/atomic.h
 710     common/bool.h
 711     common/math_defs.h
 712     common/rwlock.c
 713     common/rwlock.h
 714     common/static_assert.h
 715     common/threads.c
 716     common/threads.h
 717     common/uintmap.c
 718     common/uintmap.h
 719 )
 720 SET(OPENAL_OBJS
 721     OpenAL32/Include/bs2b.h
 722     OpenAL32/Include/alMain.h
 723     OpenAL32/Include/alu.h
 724
 725     OpenAL32/Include/alAuxEffectSlot.h
 726     OpenAL32/alAuxEffectSlot.c
 727     OpenAL32/Include/alBuffer.h
 728     OpenAL32/alBuffer.c
 729     OpenAL32/Include/alEffect.h
 730     OpenAL32/alEffect.c
 731     OpenAL32/Include/alError.h
 732     OpenAL32/alError.c
 733     OpenAL32/alExtension.c
 734     OpenAL32/Include/alFilter.h
 735     OpenAL32/alFilter.c
 736     OpenAL32/Include/alListener.h
 737     OpenAL32/alListener.c
 738     OpenAL32/Include/alSource.h
 739     OpenAL32/alSource.c
 740     OpenAL32/alState.c
 741     OpenAL32/event.c
 742     OpenAL32/Include/sample_cvt.h
 743     OpenAL32/sample_cvt.c
 744 )
 745 SET(ALC_OBJS
 746     Alc/ALc.c
 747     Alc/ALu.c
 748     Alc/alconfig.c
 749     Alc/alconfig.h
 750     Alc/bs2b.c
 751     Alc/converter.c
 752     Alc/converter.h
 753     Alc/inprogext.h
 754     Alc/mastering.c
 755     Alc/mastering.h
 756     Alc/ringbuffer.c
 757     Alc/ringbuffer.h
 758     Alc/effects/chorus.c
 759     Alc/effects/compressor.c
 760     Alc/effects/dedicated.c
 761     Alc/effects/distortion.c
 762     Alc/effects/echo.c
 763     Alc/effects/equalizer.c
 764     Alc/effects/fshifter.c
 765     Alc/effects/modulator.c
 766     Alc/effects/null.c
 767     Alc/effects/pshifter.c
 768     Alc/effects/reverb.c
 769     Alc/filters/defs.h
 770     Alc/filters/filter.c
 771     Alc/filters/nfc.c
 772     Alc/filters/nfc.h
 773     Alc/filters/splitter.c
 774     Alc/filters/splitter.h
 775     Alc/helpers.c
 776     Alc/alstring.h
 777     Alc/compat.h
 778     Alc/cpu_caps.h
 779     Alc/fpu_modes.h
 780     Alc/logging.h
 781     Alc/vector.h
 782     Alc/hrtf.c
 783     Alc/hrtf.h
 784     Alc/uhjfilter.c
 785     Alc/uhjfilter.h
 786     Alc/ambdec.c
 787     Alc/ambdec.h
 788     Alc/bformatdec.c
 789     Alc/bformatdec.h
 790     Alc/panning.c
 791     Alc/polymorphism.h
 792     Alc/mixvoice.c
 793     Alc/mixer/defs.h
 794     Alc/mixer/mixer_c.c
 795 )
 796
 797
 798 SET(CPU_EXTS "Default")
 799 SET(HAVE_SSE        0)
 800 SET(HAVE_SSE2       0)
 801 SET(HAVE_SSE3       0)
 802 SET(HAVE_SSE4_1     0)
 803 SET(HAVE_NEON       0)
 804
 805 SET(HAVE_ALSA       0)
 806 SET(HAVE_OSS        0)
 807 SET(HAVE_SOLARIS    0)
 808 SET(HAVE_SNDIO      0)
 809 SET(HAVE_QSA        0)
 810 SET(HAVE_DSOUND     0)
 811 SET(HAVE_WASAPI     0)
 812 SET(HAVE_WINMM      0)
 813 SET(HAVE_PORTAUDIO  0)
 814 SET(HAVE_PULSEAUDIO 0)
 815 SET(HAVE_COREAUDIO  0)
 816 SET(HAVE_OPENSL     0)
 817 SET(HAVE_WAVE       0)
 818 SET(HAVE_SDL2       0)
 819
 820 # Check for SSE support
 821 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 822 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 823 IF(HAVE_XMMINTRIN_H)
 824     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 825     IF(ALSOFT_CPUEXT_SSE)
 826         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 827             SET(HAVE_SSE 1)
 828             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse.c)
 829             IF(SSE_SWITCH)
 830                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse.c PROPERTIES
 831                                             COMPILE_FLAGS "${SSE_SWITCH}")
 832             ENDIF()
 833             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 834         ENDIF()
 835     ENDIF()
 836 ENDIF()
 837 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 838     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 839 ENDIF()
 840
 841 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 842 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 843 IF(HAVE_EMMINTRIN_H)
 844     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 845     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 846         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 847             SET(HAVE_SSE2 1)
 848             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse2.c)
 849             IF(SSE2_SWITCH)
 850                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse2.c PROPERTIES
 851                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 852             ENDIF()
 853             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 854         ENDIF()
 855     ENDIF()
 856 ENDIF()
 857 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 858     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 859 ENDIF()
 860
 861 OPTION(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 862 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 863 IF(HAVE_EMMINTRIN_H)
 864     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 865     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 866         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 867             SET(HAVE_SSE3 1)
 868             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse3.c)
 869             IF(SSE2_SWITCH)
 870                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse3.c PROPERTIES
 871                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 872             ENDIF()
 873             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 874         ENDIF()
 875     ENDIF()
 876 ENDIF()
 877 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 878     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 879 ENDIF()
 880
 881 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 882 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 883 IF(HAVE_SMMINTRIN_H)
 884     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 885     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 886         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 887             SET(HAVE_SSE4_1 1)
 888             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse41.c)
 889             IF(SSE4_1_SWITCH)
 890                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse41.c PROPERTIES
 891                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 892             ENDIF()
 893             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 894         ENDIF()
 895     ENDIF()
 896 ENDIF()
 897 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 898     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 899 ENDIF()
 900
 901 # Check for ARM Neon support
 902 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 903 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 904 IF(HAVE_ARM_NEON_H)
 905     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 906     IF(ALSOFT_CPUEXT_NEON)
 907         SET(HAVE_NEON 1)
 908         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_neon.c)
 909         IF(FPU_NEON_SWITCH)
 910             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_neon.c PROPERTIES
 911                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 912         ENDIF()
 913         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 914     ENDIF()
 915 ENDIF()
 916 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 917     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 918 ENDIF()
 919
 920
 921 IF(WIN32 OR HAVE_DLFCN_H)
 922     SET(IS_LINKED "")
 923     MACRO(ADD_BACKEND_LIBS _LIBS)
 924     ENDMACRO()
 925 ELSE()
 926     SET(IS_LINKED " (linked)")
 927     MACRO(ADD_BACKEND_LIBS _LIBS)
 928         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 929     ENDMACRO()
 930 ENDIF()
 931
 932 SET(BACKENDS "")
 933 SET(ALC_OBJS  ${ALC_OBJS}
 934     Alc/backends/base.c
 935     Alc/backends/base.h
 936     # Default backends, always available
 937     Alc/backends/loopback.c
 938     Alc/backends/null.c
 939 )
 940
 941 # Check ALSA backend
 942 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 943 FIND_PACKAGE(ALSA)
 944 IF(ALSA_FOUND)
 945     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 946     IF(ALSOFT_BACKEND_ALSA)
 947         SET(HAVE_ALSA 1)
 948         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 949         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 950         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 951         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 952     ENDIF()
 953 ENDIF()
 954 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 955     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 956 ENDIF()
 957
 958 # Check OSS backend
 959 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 960 FIND_PACKAGE(OSS)
 961 IF(OSS_FOUND)
 962     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 963     IF(ALSOFT_BACKEND_OSS)
 964         SET(HAVE_OSS 1)
 965         SET(BACKENDS  "${BACKENDS} OSS,")
 966         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 967         IF(OSS_LIBRARIES)
 968             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 969         ENDIF()
 970         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 971     ENDIF()
 972 ENDIF()
 973 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 974     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 975 ENDIF()
 976
 977 # Check Solaris backend
 978 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 979 FIND_PACKAGE(AudioIO)
 980 IF(AUDIOIO_FOUND)
 981     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 982     IF(ALSOFT_BACKEND_SOLARIS)
 983         SET(HAVE_SOLARIS 1)
 984         SET(BACKENDS  "${BACKENDS} Solaris,")
 985         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 986         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 987     ENDIF()
 988 ENDIF()
 989 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 990     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 991 ENDIF()
 992
 993 # Check SndIO backend
 994 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 995 FIND_PACKAGE(SoundIO)
 996 IF(SOUNDIO_FOUND)
 997     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 998     IF(ALSOFT_BACKEND_SNDIO)
 999         SET(HAVE_SNDIO 1)
1000         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
1001         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
1002         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
1003         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
1004     ENDIF()
1005 ENDIF()
1006 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
1007     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
1008 ENDIF()
1009
1010 # Check QSA backend
1011 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
1012 FIND_PACKAGE(QSA)
1013 IF(QSA_FOUND)
1014     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
1015     IF(ALSOFT_BACKEND_QSA)
1016         SET(HAVE_QSA 1)
1017         SET(BACKENDS  "${BACKENDS} QSA (linked),")
1018         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
1019         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
1020         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
1021     ENDIF()
1022 ENDIF()
1023 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
1024     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
1025 ENDIF()
1026
1027 # Check Windows-only backends
1028 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
1029 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
1030 OPTION(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
1031 IF(HAVE_WINDOWS_H)
1032     SET(OLD_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS})
1033     SET(CMAKE_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS} -D_WIN32_WINNT=0x0502)
1034
1035     # Check MMSystem backend
1036     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H)
1037     IF(HAVE_MMSYSTEM_H)
1038         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
1039         IF(HAVE_LIBWINMM)
1040             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
1041             IF(ALSOFT_BACKEND_WINMM)
1042                 SET(HAVE_WINMM 1)
1043                 SET(BACKENDS  "${BACKENDS} WinMM,")
1044                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
1045                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
1046             ENDIF()
1047         ENDIF()
1048     ENDIF()
1049
1050     # Check DSound backend
1051     FIND_PACKAGE(DSound)
1052     IF(DSOUND_FOUND)
1053         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
1054         IF(ALSOFT_BACKEND_DSOUND)
1055             SET(HAVE_DSOUND 1)
1056             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
1057             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
1058             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
1059             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1060         ENDIF()
1061     ENDIF()
1062
1063     # Check for WASAPI backend
1064     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1065     IF(HAVE_MMDEVICEAPI_H)
1066         OPTION(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1067         IF(ALSOFT_BACKEND_WASAPI)
1068             SET(HAVE_WASAPI 1)
1069             SET(BACKENDS  "${BACKENDS} WASAPI,")
1070             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wasapi.c)
1071         ENDIF()
1072     ENDIF()
1073
1074     SET(CMAKE_REQUIRED_DEFINITIONS ${OLD_REQUIRED_DEFINITIONS})
1075     UNSET(OLD_REQUIRED_DEFINITIONS)
1076 ENDIF()
1077 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1078     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1079 ENDIF()
1080 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1081     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1082 ENDIF()
1083 IF(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1084     MESSAGE(FATAL_ERROR "Failed to enabled required WASAPI backend")
1085 ENDIF()
1086
1087 # Check PortAudio backend
1088 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1089 FIND_PACKAGE(PortAudio)
1090 IF(PORTAUDIO_FOUND)
1091     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1092     IF(ALSOFT_BACKEND_PORTAUDIO)
1093         SET(HAVE_PORTAUDIO 1)
1094         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1095         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1096         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1097         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1098     ENDIF()
1099 ENDIF()
1100 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1101     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1102 ENDIF()
1103
1104 # Check PulseAudio backend
1105 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1106 FIND_PACKAGE(PulseAudio)
1107 IF(PULSEAUDIO_FOUND)
1108     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1109     IF(ALSOFT_BACKEND_PULSEAUDIO)
1110         SET(HAVE_PULSEAUDIO 1)
1111         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1112         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1113         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1114         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1115     ENDIF()
1116 ENDIF()
1117 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1118     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1119 ENDIF()
1120
1121 # Check JACK backend
1122 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1123 FIND_PACKAGE(JACK)
1124 IF(JACK_FOUND)
1125     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1126     IF(ALSOFT_BACKEND_JACK)
1127         SET(HAVE_JACK 1)
1128         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1129         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1130         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1131         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1132     ENDIF()
1133 ENDIF()
1134 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1135     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1136 ENDIF()
1137
1138 # Check CoreAudio backend
1139 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1140 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1141              NAMES CoreAudio
1142              PATHS /System/Library/Frameworks
1143 )
1144 IF(COREAUDIO_FRAMEWORK)
1145     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1146     IF(ALSOFT_BACKEND_COREAUDIO)
1147         SET(HAVE_COREAUDIO 1)
1148         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1149         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1150         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1151         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1152         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1153
1154         # Some versions of OSX may need the AudioToolbox framework. Add it if
1155         # it's found.
1156         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1157                      NAMES AudioToolbox
1158                      PATHS ~/Library/Frameworks
1159                            /Library/Frameworks
1160                            /System/Library/Frameworks
1161                     )
1162         IF(AUDIOTOOLBOX_LIBRARY)
1163             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1164         ENDIF()
1165     ENDIF()
1166 ENDIF()
1167 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1168     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1169 ENDIF()
1170
1171 # Check for OpenSL (Android) backend
1172 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1173 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1174 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1175     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1176     IF(HAVE_LIBOPENSLES)
1177         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1178         IF(ALSOFT_BACKEND_OPENSL)
1179             SET(HAVE_OPENSL 1)
1180             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1181             SET(BACKENDS  "${BACKENDS} OpenSL,")
1182             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1183         ENDIF()
1184     ENDIF()
1185 ENDIF()
1186 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1187     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1188 ENDIF()
1189
1190 # Check for SDL2 backend
1191 OPTION(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1192 FIND_PACKAGE(SDL2)
1193 IF(SDL2_FOUND)
1194     # Off by default, since it adds a runtime dependency
1195     OPTION(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1196     IF(ALSOFT_BACKEND_SDL2)
1197         SET(HAVE_SDL2 1)
1198         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sdl2.c)
1199         SET(BACKENDS  "${BACKENDS} SDL2,")
1200         SET(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1201         SET(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1202     ENDIF()
1203 ENDIF()
1204 IF(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1205     MESSAGE(FATAL_ERROR "Failed to enabled required SDL2 backend")
1206 ENDIF()
1207
1208 # Optionally enable the Wave Writer backend
1209 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1210 IF(ALSOFT_BACKEND_WAVE)
1211     SET(HAVE_WAVE 1)
1212     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1213     SET(BACKENDS  "${BACKENDS} WaveFile,")
1214 ENDIF()
1215
1216 # This is always available
1217 SET(BACKENDS  "${BACKENDS} Null")
1218
1219
1220 FIND_PACKAGE(Git)
1221 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1222     # Get the current working branch and its latest abbreviated commit hash
1223     ADD_CUSTOM_TARGET(build_version
1224         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1225                          -D LIB_VERSION=${LIB_VERSION}
1226                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1227                          -D DST=${OpenAL_BINARY_DIR}/version.h
1228                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1229         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1230         VERBATIM
1231     )
1232 ELSE()
1233     SET(GIT_BRANCH "UNKNOWN")
1234     SET(GIT_COMMIT_HASH "unknown")
1235     CONFIGURE_FILE(
1236         "${OpenAL_SOURCE_DIR}/version.h.in"
1237         "${OpenAL_BINARY_DIR}/version.h")
1238 ENDIF()
1239
1240 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1241 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1242 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1243
1244 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1245 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1246 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1247     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1248     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1249     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1250     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1251     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1252     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1253                      C "${NATIVE_SRC_DIR}bsincgen.c"
1254     VERBATIM
1255 )
1256 ADD_CUSTOM_TARGET(native-tools
1257     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1258     VERBATIM
1259 )
1260
1261 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1262 if(ALSOFT_EMBED_HRTF_DATA)
1263     MACRO(make_hrtf_header FILENAME VARNAME)
1264         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1265         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1266
1267         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1268             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1269             DEPENDS native-tools "${infile}"
1270             VERBATIM
1271         )
1272         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1273     ENDMACRO()
1274
1275     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1276     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1277 endif()
1278
1279 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1280     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1281     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1282     VERBATIM
1283 )
1284 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1285
1286
1287 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1288     add_subdirectory(utils/alsoft-config)
1289 ENDIF()
1290 IF(ALSOFT_EXAMPLES)
1291     IF(NOT SDL2_FOUND)
1292         FIND_PACKAGE(SDL2)
1293     ENDIF()
1294     IF(SDL2_FOUND)
1295         FIND_PACKAGE(SDL_sound)
1296         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1297     ENDIF()
1298 ENDIF()
1299
1300 IF(NOT WIN32)
1301     SET(LIBNAME "openal")
1302 ELSE()
1303     SET(LIBNAME "OpenAL32")
1304 ENDIF()
1305
1306 # Needed for openal.pc.in
1307 SET(prefix ${CMAKE_INSTALL_PREFIX})
1308 SET(exec_prefix "\${prefix}")
1309 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1310 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1311 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1312 SET(PACKAGE_VERSION "${LIB_VERSION}")
1313 SET(PKG_CONFIG_CFLAGS )
1314 SET(PKG_CONFIG_PRIVATE_LIBS )
1315 IF(LIBTYPE STREQUAL "STATIC")
1316     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1317     FOREACH(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1318         # If this is already a linker flag, or is a full path+file, add it
1319         # as-is. Otherwise, it's a name intended to be dressed as -lname.
1320         IF(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1321             SET(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1322         ELSE()
1323             SET(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1324         ENDIF()
1325     ENDFOREACH()
1326 ENDIF()
1327
1328 # End configuration
1329 CONFIGURE_FILE(
1330     "${OpenAL_SOURCE_DIR}/config.h.in"
1331     "${OpenAL_BINARY_DIR}/config.h")
1332 CONFIGURE_FILE(
1333     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1334     "${OpenAL_BINARY_DIR}/openal.pc"
1335     @ONLY)
1336
1337
1338 # Add a static library with common functions used by multiple targets
1339 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1340 TARGET_COMPILE_DEFINITIONS(common PRIVATE ${CPP_DEFS})
1341 TARGET_COMPILE_OPTIONS(common PRIVATE ${C_FLAGS})
1342
1343
1344 UNSET(HAS_ROUTER)
1345 SET(IMPL_TARGET OpenAL)
1346 SET(COMMON_LIB )
1347 SET(SUBSYS_FLAG )
1348
1349 # Build main library
1350 IF(LIBTYPE STREQUAL "STATIC")
1351     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1352     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1353         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1354     ENDIF()
1355     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1356 ELSE()
1357     # Make sure to compile the common code with PIC, since it'll be linked into
1358     # shared libs that needs it.
1359     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1360     SET(COMMON_LIB common)
1361
1362     IF(WIN32)
1363         IF(MSVC)
1364             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1365         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1366             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1367         ENDIF()
1368     ENDIF()
1369
1370     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1371         ADD_LIBRARY(OpenAL SHARED router/router.c router/router.h router/alc.c router/al.c)
1372         TARGET_COMPILE_DEFINITIONS(OpenAL
1373             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1374         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1375         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${LINKER_FLAGS} ${COMMON_LIB})
1376         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1377         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1378         IF(TARGET build_version)
1379             ADD_DEPENDENCIES(OpenAL build_version)
1380         ENDIF()
1381         SET(HAS_ROUTER 1)
1382
1383         SET(LIBNAME "soft_oal")
1384         SET(IMPL_TARGET soft_oal)
1385     ENDIF()
1386
1387     ADD_LIBRARY(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1388     IF(WIN32)
1389         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1390     ENDIF()
1391 ENDIF()
1392 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1393     VERSION ${LIB_VERSION}
1394     SOVERSION ${LIB_MAJOR_VERSION}
1395 )
1396 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1397     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1398 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1399     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1400 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1401 TARGET_LINK_LIBRARIES(${IMPL_TARGET}
1402     PRIVATE ${LINKER_FLAGS} ${COMMON_LIB} ${EXTRA_LIBS} ${MATH_LIB})
1403 IF(TARGET build_version)
1404     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1405 ENDIF()
1406
1407 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1408     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1409     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1410     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1411         MESSAGE(STATUS "")
1412         IF(NOT SED_EXECUTABLE)
1413             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1414         ENDIF()
1415         IF(NOT DLLTOOL_EXECUTABLE)
1416             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1417         ENDIF()
1418     ELSE()
1419         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1420                         " -Wl,--output-def,OpenAL32.def")
1421         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1422             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1423             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1424             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1425             VERBATIM
1426         )
1427     ENDIF()
1428 ENDIF()
1429
1430 IF(ALSOFT_INSTALL)
1431     INSTALL(TARGETS OpenAL EXPORT OpenAL
1432             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1433             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1434             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1435             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1436     )
1437     EXPORT(TARGETS OpenAL
1438            NAMESPACE OpenAL::
1439            FILE OpenALConfig.cmake)
1440     INSTALL(EXPORT OpenAL
1441             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1442             NAMESPACE OpenAL::
1443             FILE OpenALConfig.cmake)
1444     INSTALL(FILES include/AL/al.h
1445                   include/AL/alc.h
1446                   include/AL/alext.h
1447                   include/AL/efx.h
1448                   include/AL/efx-creative.h
1449                   include/AL/efx-presets.h
1450             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1451     )
1452     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1453             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1454     IF(TARGET soft_oal)
1455         INSTALL(TARGETS soft_oal
1456                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1457         )
1458     ENDIF()
1459 ENDIF()
1460
1461
1462 if(HAS_ROUTER)
1463     message(STATUS "")
1464     message(STATUS "Building DLL router")
1465 endif()
1466
1467 MESSAGE(STATUS "")
1468 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1469 MESSAGE(STATUS "    ${BACKENDS}")
1470 MESSAGE(STATUS "")
1471 MESSAGE(STATUS "Building with support for CPU extensions:")
1472 MESSAGE(STATUS "    ${CPU_EXTS}")
1473 MESSAGE(STATUS "")
1474
1475 IF(WIN32)
1476     IF(NOT HAVE_DSOUND)
1477         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1478         MESSAGE(STATUS "         This is probably NOT what you want!")
1479         MESSAGE(STATUS "")
1480     ENDIF()
1481 ENDIF()
1482
1483 if(ALSOFT_EMBED_HRTF_DATA)
1484     message(STATUS "Embedding HRTF datasets")
1485     message(STATUS "")
1486 endif()
1487
1488 # Install alsoft.conf configuration file
1489 IF(ALSOFT_CONFIG)
1490     INSTALL(FILES alsoftrc.sample
1491             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1492     )
1493     MESSAGE(STATUS "Installing sample configuration")
1494     MESSAGE(STATUS "")
1495 ENDIF()
1496
1497 # Install HRTF definitions
1498 IF(ALSOFT_HRTF_DEFS)
1499     INSTALL(FILES hrtf/default-44100.mhr
1500                   hrtf/default-48000.mhr
1501             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1502     )
1503     MESSAGE(STATUS "Installing HRTF definitions")
1504     MESSAGE(STATUS "")
1505 ENDIF()
1506
1507 # Install AmbDec presets
1508 IF(ALSOFT_AMBDEC_PRESETS)
1509     INSTALL(FILES presets/3D7.1.ambdec
1510                   presets/hexagon.ambdec
1511                   presets/itu5.1.ambdec
1512                   presets/itu5.1-nocenter.ambdec
1513                   presets/rectangle.ambdec
1514                   presets/square.ambdec
1515                   presets/presets.txt
1516             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1517     )
1518     MESSAGE(STATUS "Installing AmbDec presets")
1519     MESSAGE(STATUS "")
1520 ENDIF()
1521
1522 IF(ALSOFT_UTILS)
1523     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1524     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1525     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1526
1527     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1528     IF(NOT HAVE_GETOPT)
1529         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c utils/getopt.h)
1530     ENDIF()
1531     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1532     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1533     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1534     IF(HAVE_LIBM)
1535         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1536     ENDIF()
1537
1538     IF(ALSOFT_INSTALL)
1539         INSTALL(TARGETS openal-info makehrtf
1540                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1541                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1542                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1543         )
1544     ENDIF()
1545
1546     MESSAGE(STATUS "Building utility programs")
1547     IF(TARGET alsoft-config)
1548         MESSAGE(STATUS "Building configuration program")
1549     ENDIF()
1550     MESSAGE(STATUS "")
1551 ENDIF()
1552
1553 IF(ALSOFT_TESTS)
1554     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1555
1556     ADD_EXECUTABLE(altonegen examples/altonegen.c ${TEST_COMMON_OBJS})
1557     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1558     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1559     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} common OpenAL ${MATH_LIB})
1560
1561     IF(ALSOFT_INSTALL)
1562         INSTALL(TARGETS altonegen
1563                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1564                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1565                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1566         )
1567     ENDIF()
1568
1569     MESSAGE(STATUS "Building test programs")
1570     MESSAGE(STATUS "")
1571 ENDIF()
1572
1573 IF(ALSOFT_EXAMPLES)
1574     ADD_EXECUTABLE(alrecord examples/alrecord.c)
1575     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1576     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1577     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} common OpenAL)
1578
1579     IF(ALSOFT_INSTALL)
1580         INSTALL(TARGETS alrecord
1581                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1582                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1583                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1584         )
1585     ENDIF()
1586
1587     MESSAGE(STATUS "Building example programs")
1588
1589     IF(SDL2_FOUND)
1590         IF(SDL_SOUND_FOUND)
1591             # Add a static library with common functions used by multiple targets
1592             ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c)
1593             TARGET_COMPILE_DEFINITIONS(ex-common PRIVATE ${CPP_DEFS})
1594             TARGET_COMPILE_OPTIONS(ex-common PRIVATE ${C_FLAGS})
1595
1596             ADD_EXECUTABLE(alplay examples/alplay.c)
1597             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1598             TARGET_INCLUDE_DIRECTORIES(alplay
1599                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1600             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1601             TARGET_LINK_LIBRARIES(alplay
1602                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1603                         OpenAL)
1604
1605             ADD_EXECUTABLE(alstream examples/alstream.c)
1606             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1607             TARGET_INCLUDE_DIRECTORIES(alstream
1608                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1609             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1610             TARGET_LINK_LIBRARIES(alstream
1611                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1612                         OpenAL)
1613
1614             ADD_EXECUTABLE(alreverb examples/alreverb.c)
1615             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1616             TARGET_INCLUDE_DIRECTORIES(alreverb
1617                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1618             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1619             TARGET_LINK_LIBRARIES(alreverb
1620                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1621                         OpenAL)
1622
1623             ADD_EXECUTABLE(almultireverb examples/almultireverb.c)
1624             TARGET_COMPILE_DEFINITIONS(almultireverb PRIVATE ${CPP_DEFS})
1625             TARGET_INCLUDE_DIRECTORIES(almultireverb
1626                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1627             TARGET_COMPILE_OPTIONS(almultireverb PRIVATE ${C_FLAGS})
1628             TARGET_LINK_LIBRARIES(almultireverb
1629                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1630                         OpenAL ${MATH_LIB})
1631
1632             ADD_EXECUTABLE(allatency examples/allatency.c)
1633             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1634             TARGET_INCLUDE_DIRECTORIES(allatency
1635                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1636             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1637             TARGET_LINK_LIBRARIES(allatency
1638                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1639                         OpenAL)
1640
1641             ADD_EXECUTABLE(alloopback examples/alloopback.c)
1642             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1643             TARGET_INCLUDE_DIRECTORIES(alloopback
1644                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1645             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1646             TARGET_LINK_LIBRARIES(alloopback
1647                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1648                         OpenAL ${MATH_LIB})
1649
1650             ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1651             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1652             TARGET_INCLUDE_DIRECTORIES(alhrtf
1653                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1654             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1655             TARGET_LINK_LIBRARIES(alhrtf
1656                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1657                         OpenAL ${MATH_LIB})
1658
1659             IF(ALSOFT_INSTALL)
1660                 INSTALL(TARGETS alplay alstream alreverb almultireverb allatency alloopback alhrtf
1661                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1662                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1663                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1664                 )
1665             ENDIF()
1666
1667             MESSAGE(STATUS "Building SDL_sound example programs")
1668         ENDIF()
1669
1670         SET(FFVER_OK FALSE)
1671         IF(FFMPEG_FOUND)
1672             SET(FFVER_OK TRUE)
1673             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1674                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1675                 SET(FFVER_OK FALSE)
1676             ENDIF()
1677             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1678                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1679                 SET(FFVER_OK FALSE)
1680             ENDIF()
1681             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1682                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1683                 SET(FFVER_OK FALSE)
1684             ENDIF()
1685             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1686                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1687                 SET(FFVER_OK FALSE)
1688             ENDIF()
1689             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1690                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1691                 SET(FFVER_OK FALSE)
1692             ENDIF()
1693         ENDIF()
1694         IF(FFVER_OK)
1695             ADD_EXECUTABLE(alffplay examples/alffplay.cpp)
1696             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1697             TARGET_INCLUDE_DIRECTORIES(alffplay
1698                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1699             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1700             TARGET_LINK_LIBRARIES(alffplay
1701                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} common OpenAL)
1702
1703             IF(ALSOFT_INSTALL)
1704                 INSTALL(TARGETS alffplay
1705                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1706                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1707                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1708                 )
1709             ENDIF()
1710             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1711         ENDIF()
1712         MESSAGE(STATUS "")
1713     ENDIF()
1714 ENDIF()