cmake/FindSDL_sound.cmake

   1 # - Locates the SDL_sound library
   2 #
   3 # This module depends on SDL being found and
   4 # must be called AFTER FindSDL.cmake or FindSDL2.cmake is called.
   5 #
   6 # This module defines
   7 #  SDL_SOUND_INCLUDE_DIR, where to find SDL_sound.h
   8 #  SDL_SOUND_FOUND, if false, do not try to link to SDL_sound
   9 #  SDL_SOUND_LIBRARIES, this contains the list of libraries that you need
  10 #    to link against. This is a read-only variable and is marked INTERNAL.
  11 #  SDL_SOUND_EXTRAS, this is an optional variable for you to add your own
  12 #    flags to SDL_SOUND_LIBRARIES. This is prepended to SDL_SOUND_LIBRARIES.
  13 #    This is available mostly for cases this module failed to anticipate for
  14 #    and you must add additional flags. This is marked as ADVANCED.
  15 #  SDL_SOUND_VERSION_STRING, human-readable string containing the version of SDL_sound
  16 #
  17 # This module also defines (but you shouldn't need to use directly)
  18 #   SDL_SOUND_LIBRARY, the name of just the SDL_sound library you would link
  19 #   against. Use SDL_SOUND_LIBRARIES for you link instructions and not this one.
  20 # And might define the following as needed
  21 #   MIKMOD_LIBRARY
  22 #   MODPLUG_LIBRARY
  23 #   OGG_LIBRARY
  24 #   VORBIS_LIBRARY
  25 #   SMPEG_LIBRARY
  26 #   FLAC_LIBRARY
  27 #   SPEEX_LIBRARY
  28 #
  29 # Typically, you should not use these variables directly, and you should use
  30 # SDL_SOUND_LIBRARIES which contains SDL_SOUND_LIBRARY and the other audio libraries
  31 # (if needed) to successfully compile on your system.
  32 #
  33 # Created by Eric Wing.
  34 # This module is a bit more complicated than the other FindSDL* family modules.
  35 # The reason is that SDL_sound can be compiled in a large variety of different ways
  36 # which are independent of platform. SDL_sound may dynamically link against other 3rd
  37 # party libraries to get additional codec support, such as Ogg Vorbis, SMPEG, ModPlug,
  38 # MikMod, FLAC, Speex, and potentially others.
  39 # Under some circumstances which I don't fully understand,
  40 # there seems to be a requirement
  41 # that dependent libraries of libraries you use must also be explicitly
  42 # linked against in order to successfully compile. SDL_sound does not currently
  43 # have any system in place to know how it was compiled.
  44 # So this CMake module does the hard work in trying to discover which 3rd party
  45 # libraries are required for building (if any).
  46 # This module uses a brute force approach to create a test program that uses SDL_sound,
  47 # and then tries to build it. If the build fails, it parses the error output for
  48 # known symbol names to figure out which libraries are needed.
  49 #
  50 # Responds to the $SDLDIR and $SDLSOUNDDIR environmental variable that would
  51 # correspond to the ./configure --prefix=$SDLDIR used in building SDL.
  52 #
  53 # On OSX, this will prefer the Framework version (if found) over others.
  54 # People will have to manually change the cache values of
  55 # SDL_LIBRARY or SDL2_LIBRARY to override this selection or set the CMake
  56 # environment CMAKE_INCLUDE_PATH to modify the search paths.
  57
  58 #=============================================================================
  59 # Copyright 2005-2009 Kitware, Inc.
  60 # Copyright 2012 Benjamin Eikel
  61 #
  62 # Distributed under the OSI-approved BSD License (the "License");
  63 # see accompanying file Copyright.txt for details.
  64 #
  65 # This software is distributed WITHOUT ANY WARRANTY; without even the
  66 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  67 # See the License for more information.
  68 #=============================================================================
  69 # (To distribute this file outside of CMake, substitute the full
  70 #  License text for the above reference.)
  71
  72 set(SDL_SOUND_EXTRAS "" CACHE STRING "SDL_sound extra flags")
  73 mark_as_advanced(SDL_SOUND_EXTRAS)
  74
  75 # Find SDL_sound.h
  76 find_path(SDL_SOUND_INCLUDE_DIR SDL_sound.h
  77     HINTS
  78         ENV SDLSOUNDDIR
  79         ENV SDLDIR
  80     PATH_SUFFIXES SDL SDL12 SDL11
  81 )
  82
  83 find_library(SDL_SOUND_LIBRARY
  84     NAMES SDL_sound
  85     HINTS
  86         ENV SDLSOUNDDIR
  87         ENV SDLDIR
  88 )
  89
  90 if(SDL2_FOUND OR SDL_FOUND)
  91     if(SDL_SOUND_INCLUDE_DIR AND SDL_SOUND_LIBRARY)
  92         # CMake is giving me problems using TRY_COMPILE with the CMAKE_FLAGS
  93         # for the :STRING syntax if I have multiple values contained in a
  94         # single variable. This is a problem for the SDL2_LIBRARY variable
  95         # because it does just that. When I feed this variable to the command,
  96         # only the first value gets the appropriate modifier (e.g. -I) and
  97         # the rest get dropped.
  98         # To get multiple single variables to work, I must separate them with a "\;"
  99         # I could go back and modify the FindSDL2.cmake module, but that's kind of painful.
 100         # The solution would be to try something like:
 101         # set(SDL2_TRY_COMPILE_LIBRARY_LIST "${SDL2_TRY_COMPILE_LIBRARY_LIST}\;${CMAKE_THREAD_LIBS_INIT}")
 102         # Instead, it was suggested on the mailing list to write a temporary CMakeLists.txt
 103         # with a temporary test project and invoke that with TRY_COMPILE.
 104         # See message thread "Figuring out dependencies for a library in order to build"
 105         # 2005-07-16
 106         #     try_compile(
 107         #             MY_RESULT
 108         #             ${CMAKE_BINARY_DIR}
 109         #             ${PROJECT_SOURCE_DIR}/DetermineSoundLibs.c
 110         #             CMAKE_FLAGS
 111         #                     -DINCLUDE_DIRECTORIES:STRING=${SDL2_INCLUDE_DIR}\;${SDL_SOUND_INCLUDE_DIR}
 112         #                     -DLINK_LIBRARIES:STRING=${SDL_SOUND_LIBRARY}\;${SDL2_LIBRARY}
 113         #             OUTPUT_VARIABLE MY_OUTPUT
 114         #     )
 115
 116         # To minimize external dependencies, create a sdlsound test program
 117         # which will be used to figure out if additional link dependencies are
 118         # required for the link phase.
 119         file(WRITE ${PROJECT_BINARY_DIR}/CMakeTmp/DetermineSoundLibs.c
 120             "#include \"SDL_sound.h\"
 121             #include \"SDL.h\"
 122             int main(int argc, char* argv[])
 123             {
 124                 Sound_AudioInfo desired;
 125                 Sound_Sample* sample;
 126
 127                 SDL_Init(0);
 128                 Sound_Init();
 129
 130                 /* This doesn't actually have to work, but Init() is a no-op
 131                  * for some of the decoders, so this should force more symbols
 132                  * to be pulled in.
 133                  */
 134                 sample = Sound_NewSampleFromFile(argv[1], &desired, 4096);
 135
 136                 Sound_Quit();
 137                 SDL_Quit();
 138                 return 0;
 139             }"
 140         )
 141
 142         # Calling
 143         # target_link_libraries(DetermineSoundLibs "${SDL_SOUND_LIBRARY} ${SDL2_LIBRARY})
 144         # causes problems when SDL2_LIBRARY looks like
 145         # /Library/Frameworks/SDL2.framework;-framework Cocoa
 146         # The ;-framework Cocoa seems to be confusing CMake once the OS X
 147         # framework support was added. I was told that breaking up the list
 148         # would fix the problem.
 149         set(TMP_TRY_LIBS)
 150         if(SDL2_FOUND)
 151             foreach(lib ${SDL_SOUND_LIBRARY} ${SDL2_LIBRARY})
 152                 set(TMP_TRY_LIBS "${TMP_TRY_LIBS} \"${lib}\"")
 153             endforeach()
 154             set(TMP_INCLUDE_DIRS ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 155         else()
 156             foreach(lib ${SDL_SOUND_LIBRARY} ${SDL_LIBRARY})
 157                 set(TMP_TRY_LIBS "${TMP_TRY_LIBS} \"${lib}\"")
 158             endforeach()
 159             set(TMP_INCLUDE_DIRS ${SDL_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 160         endif()
 161
 162         # message("TMP_TRY_LIBS ${TMP_TRY_LIBS}")
 163
 164         # Write the CMakeLists.txt and test project
 165         # Weird, this is still sketchy. If I don't quote the variables
 166         # in the TARGET_LINK_LIBRARIES, I seem to loose everything
 167         # in the SDL2_LIBRARY string after the "-framework".
 168         # But if I quote the stuff in INCLUDE_DIRECTORIES, it doesn't work.
 169         file(WRITE ${PROJECT_BINARY_DIR}/CMakeTmp/CMakeLists.txt
 170             "cmake_minimum_required(VERSION 2.8)
 171             project(DetermineSoundLibs C)
 172             include_directories(${TMP_INCLUDE_DIRS})
 173             add_executable(DetermineSoundLibs DetermineSoundLibs.c)
 174             target_link_libraries(DetermineSoundLibs ${TMP_TRY_LIBS})"
 175         )
 176         unset(TMP_INCLUDE_DIRS)
 177         unset(TMP_TRY_LIBS)
 178
 179         try_compile(
 180             MY_RESULT
 181             ${PROJECT_BINARY_DIR}/CMakeTmp
 182             ${PROJECT_BINARY_DIR}/CMakeTmp
 183             DetermineSoundLibs
 184             OUTPUT_VARIABLE MY_OUTPUT
 185         )
 186         # message("${MY_RESULT}")
 187         # message(${MY_OUTPUT})
 188
 189         if(NOT MY_RESULT)
 190             # I expect that MPGLIB, VOC, WAV, AIFF, and SHN are compiled in statically.
 191             # I think Timidity is also compiled in statically.
 192             # I've never had to explcitly link against Quicktime, so I'll skip that for now.
 193
 194             set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARY})
 195
 196             # Find MikMod
 197             if("${MY_OUTPUT}" MATCHES "MikMod_")
 198                 find_library(MIKMOD_LIBRARY
 199                     NAMES libmikmod-coreaudio mikmod
 200                     PATHS
 201                         ENV MIKMODDIR
 202                         ENV SDLSOUNDDIR
 203                         ENV SDLDIR
 204                         /sw
 205                         /opt/local
 206                         /opt/csw
 207                         /opt
 208                     PATH_SUFFIXES lib
 209                 )
 210                 if(MIKMOD_LIBRARY)
 211                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${MIKMOD_LIBRARY})
 212                 endif(MIKMOD_LIBRARY)
 213             endif("${MY_OUTPUT}" MATCHES "MikMod_")
 214
 215             # Find ModPlug
 216             if("${MY_OUTPUT}" MATCHES "MODPLUG_")
 217                 find_library(MODPLUG_LIBRARY
 218                     NAMES modplug
 219                     PATHS
 220                         ENV MODPLUGDIR
 221                         ENV SDLSOUNDDIR
 222                         ENV SDLDIR
 223                         /sw
 224                         /opt/local
 225                         /opt/csw
 226                         /opt
 227                     PATH_SUFFIXES lib
 228                 )
 229                 if(MODPLUG_LIBRARY)
 230                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${MODPLUG_LIBRARY})
 231                 endif()
 232             endif()
 233
 234             # Find Ogg and Vorbis
 235             if("${MY_OUTPUT}" MATCHES "ov_")
 236                 find_library(VORBIS_LIBRARY
 237                     NAMES vorbis Vorbis VORBIS
 238                     PATHS
 239                         ENV VORBISDIR
 240                         ENV OGGDIR
 241                         ENV SDLSOUNDDIR
 242                         ENV SDLDIR
 243                         /sw
 244                         /opt/local
 245                         /opt/csw
 246                         /opt
 247                     PATH_SUFFIXES lib
 248                 )
 249                 if(VORBIS_LIBRARY)
 250                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${VORBIS_LIBRARY})
 251                 endif()
 252                 find_library(OGG_LIBRARY
 253                     NAMES ogg Ogg OGG
 254                     PATHS
 255                         ENV OGGDIR
 256                         ENV VORBISDIR
 257                         ENV SDLSOUNDDIR
 258                         ENV SDLDIR
 259                         /sw
 260                         /opt/local
 261                         /opt/csw
 262                         /opt
 263                     PATH_SUFFIXES lib
 264                 )
 265                 if(OGG_LIBRARY)
 266                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${OGG_LIBRARY})
 267                 endif()
 268             endif()
 269
 270             # Find SMPEG
 271             if("${MY_OUTPUT}" MATCHES "SMPEG_")
 272                 find_library(SMPEG_LIBRARY
 273                     NAMES smpeg SMPEG Smpeg SMpeg
 274                     PATHS
 275                         ENV SMPEGDIR
 276                         ENV SDLSOUNDDIR
 277                         ENV SDLDIR
 278                         /sw
 279                         /opt/local
 280                         /opt/csw
 281                         /opt
 282                     PATH_SUFFIXES lib
 283                 )
 284                 if(SMPEG_LIBRARY)
 285                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${SMPEG_LIBRARY})
 286                 endif()
 287             endif()
 288
 289
 290             # Find FLAC
 291             if("${MY_OUTPUT}" MATCHES "FLAC_")
 292                 find_library(FLAC_LIBRARY
 293                     NAMES flac FLAC
 294                     PATHS
 295                         ENV FLACDIR
 296                         ENV SDLSOUNDDIR
 297                         ENV SDLDIR
 298                         /sw
 299                         /opt/local
 300                         /opt/csw
 301                         /opt
 302                     PATH_SUFFIXES lib
 303                 )
 304                 if(FLAC_LIBRARY)
 305                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${FLAC_LIBRARY})
 306                 endif()
 307             endif()
 308
 309
 310             # Hmmm...Speex seems to depend on Ogg. This might be a problem if
 311             # the TRY_COMPILE attempt gets blocked at SPEEX before it can pull
 312             # in the Ogg symbols. I'm not sure if I should duplicate the ogg stuff
 313             # above for here or if two ogg entries will screw up things.
 314             if("${MY_OUTPUT}" MATCHES "speex_")
 315                 find_library(SPEEX_LIBRARY
 316                     NAMES speex SPEEX
 317                     PATHS
 318                         ENV SPEEXDIR
 319                         ENV SDLSOUNDDIR
 320                         ENV SDLDIR
 321                         /sw
 322                         /opt/local
 323                         /opt/csw
 324                         /opt
 325                     PATH_SUFFIXES lib
 326                 )
 327                 if(SPEEX_LIBRARY)
 328                     set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${SPEEX_LIBRARY})
 329                 endif()
 330
 331                 # Find OGG (needed for Speex)
 332                 # We might have already found Ogg for Vorbis, so skip it if so.
 333                 if(NOT OGG_LIBRARY)
 334                     find_library(OGG_LIBRARY
 335                         NAMES ogg Ogg OGG
 336                         PATHS
 337                             ENV OGGDIR
 338                             ENV VORBISDIR
 339                             ENV SPEEXDIR
 340                             ENV SDLSOUNDDIR
 341                             ENV SDLDIR
 342                             /sw
 343                             /opt/local
 344                             /opt/csw
 345                             /opt
 346                         PATH_SUFFIXES lib
 347                     )
 348                     if(OGG_LIBRARY)
 349                         set(SDL_SOUND_LIBRARIES_TMP ${SDL_SOUND_LIBRARIES_TMP} ${OGG_LIBRARY})
 350                     endif()
 351                 endif()
 352             endif()
 353
 354             set(SDL_SOUND_LIBRARIES ${SDL_SOUND_EXTRAS} ${SDL_SOUND_LIBRARIES_TMP} CACHE INTERNAL "SDL_sound and dependent libraries")
 355         else()
 356             set(SDL_SOUND_LIBRARIES ${SDL_SOUND_EXTRAS} ${SDL_SOUND_LIBRARY} CACHE INTERNAL "SDL_sound and dependent libraries")
 357         endif()
 358     endif()
 359 endif()
 360
 361 if(SDL_SOUND_INCLUDE_DIR AND EXISTS "${SDL_SOUND_INCLUDE_DIR}/SDL_sound.h")
 362   file(STRINGS "${SDL_SOUND_INCLUDE_DIR}/SDL_sound.h" SDL_SOUND_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SOUND_VER_MAJOR[ \t]+[0-9]+$")
 363   file(STRINGS "${SDL_SOUND_INCLUDE_DIR}/SDL_sound.h" SDL_SOUND_VERSION_MINOR_LINE REGEX "^#define[ \t]+SOUND_VER_MINOR[ \t]+[0-9]+$")
 364   file(STRINGS "${SDL_SOUND_INCLUDE_DIR}/SDL_sound.h" SDL_SOUND_VERSION_PATCH_LINE REGEX "^#define[ \t]+SOUND_VER_PATCH[ \t]+[0-9]+$")
 365   string(REGEX REPLACE "^#define[ \t]+SOUND_VER_MAJOR[ \t]+([0-9]+)$" "\\1" SDL_SOUND_VERSION_MAJOR "${SDL_SOUND_VERSION_MAJOR_LINE}")
 366   string(REGEX REPLACE "^#define[ \t]+SOUND_VER_MINOR[ \t]+([0-9]+)$" "\\1" SDL_SOUND_VERSION_MINOR "${SDL_SOUND_VERSION_MINOR_LINE}")
 367   string(REGEX REPLACE "^#define[ \t]+SOUND_VER_PATCH[ \t]+([0-9]+)$" "\\1" SDL_SOUND_VERSION_PATCH "${SDL_SOUND_VERSION_PATCH_LINE}")
 368   set(SDL_SOUND_VERSION_STRING ${SDL_SOUND_VERSION_MAJOR}.${SDL_SOUND_VERSION_MINOR}.${SDL_SOUND_VERSION_PATCH})
 369   unset(SDL_SOUND_VERSION_MAJOR_LINE)
 370   unset(SDL_SOUND_VERSION_MINOR_LINE)
 371   unset(SDL_SOUND_VERSION_PATCH_LINE)
 372   unset(SDL_SOUND_VERSION_MAJOR)
 373   unset(SDL_SOUND_VERSION_MINOR)
 374   unset(SDL_SOUND_VERSION_PATCH)
 375 endif()
 376
 377 include(FindPackageHandleStandardArgs)
 378 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_sound
 379                                   REQUIRED_VARS SDL_SOUND_LIBRARIES SDL_SOUND_INCLUDE_DIR
 380                                   VERSION_VAR SDL_SOUND_VERSION_STRING)