CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 IF(WIN32)
  66     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  67
  68     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  69
  70     # This option is mainly for static linking OpenAL Soft into another project
  71     # that already defines the IDs. It is up to that project to ensure all
  72     # required IDs are defined.
  73     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  74
  75     IF(MINGW)
  76         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  77         IF(NOT DLLTOOL)
  78             IF(HOST)
  79                 SET(DLLTOOL "${HOST}-dlltool")
  80             ELSE()
  81                 SET(DLLTOOL "dlltool")
  82             ENDIF()
  83         ENDIF()
  84     ENDIF()
  85 ENDIF()
  86
  87
  88 SET(EXTRA_LIBS "")
  89 SET(EXTRA_LDFLAGS "")
  90
  91 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  92 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  93     ADD_DEFINITIONS("-I/usr/include")
  94     SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -L/usr/lib")
  95 ENDIF()
  96
  97 IF(NOT LIBTYPE)
  98     SET(LIBTYPE SHARED)
  99 ENDIF()
 100
 101 SET(LIB_MAJOR_VERSION "1")
 102 SET(LIB_MINOR_VERSION "18")
 103 SET(LIB_REVISION "1")
 104 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 105
 106 SET(EXPORT_DECL "")
 107 SET(ALIGN_DECL "")
 108
 109
 110 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 111 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 112
 113
 114 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 115 IF(HAVE_STD_C11)
 116     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 117 ELSE()
 118     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 119     IF(HAVE_STD_C99)
 120         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 121     ENDIF()
 122 ENDIF()
 123
 124 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 125 IF(HAVE_STD_CXX11)
 126     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 127 ENDIF()
 128
 129 if(NOT WIN32)
 130     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 131     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 132     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 133         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 134         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 135         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 136         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 137             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 138         ELSE()
 139             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600)
 140         ENDIF()
 141     ENDIF()
 142     UNSET(OLD_REQUIRED_FLAGS)
 143 ENDIF()
 144
 145 # Set defines for large file support
 146 CHECK_FILE_OFFSET_BITS()
 147 IF(_FILE_OFFSET_BITS)
 148     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 149     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 150 ENDIF()
 151 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 152 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 153
 154 # MSVC may need workarounds for C99 restrict and inline
 155 IF(MSVC)
 156     # TODO: Once we truly require C99, these restrict and inline checks should go
 157     # away.
 158     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 159                              int main() {return 0;}" HAVE_RESTRICT)
 160     IF(NOT HAVE_RESTRICT)
 161         ADD_DEFINITIONS("-Drestrict=")
 162         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 163     ENDIF()
 164
 165     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 166                              int main() {return 0;}" HAVE_INLINE)
 167     IF(NOT HAVE_INLINE)
 168         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 169                                  int main() {return 0;}" HAVE___INLINE)
 170         IF(NOT HAVE___INLINE)
 171             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 172         ENDIF()
 173
 174         ADD_DEFINITIONS(-Dinline=__inline)
 175         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 176     ENDIF()
 177 ENDIF()
 178
 179 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 180 IF(CMAKE_COMPILER_IS_GNUCC)
 181     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 182
 183     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 184     # Force no inlining for the next test.
 185     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 186
 187     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 188                              int main() {return foo();}" INLINE_IS_C99)
 189     IF(NOT INLINE_IS_C99)
 190         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 191                              Please update your compiler for better C99 compliance.")
 192     ENDIF()
 193
 194     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 195 ENDIF()
 196
 197 # Check if we have a proper timespec declaration
 198 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 199 IF(HAVE_STRUCT_TIMESPEC)
 200     # Define it here so we don't have to include config.h for it
 201     ADD_DEFINITIONS("-DHAVE_STRUCT_TIMESPEC")
 202 ENDIF()
 203
 204 # Some systems may need libatomic for C11 atomic functions to work
 205 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 206 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 207 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 208 int _Atomic foo = ATOMIC_VAR_INIT(0);
 209 int main()
 210 {
 211     return atomic_fetch_add(&foo, 2);
 212 }"
 213 HAVE_LIBATOMIC)
 214 IF(NOT HAVE_LIBATOMIC)
 215     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 216 ELSE()
 217     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 218 ENDIF()
 219 UNSET(OLD_REQUIRED_LIBRARIES)
 220
 221 # Include liblog for Android logging
 222 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 223 IF(HAVE_LIBLOG)
 224     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 225     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 226 ENDIF()
 227
 228 # Check if we have C99 variable length arrays
 229 CHECK_C_SOURCE_COMPILES(
 230 "int main(int argc, char *argv[])
 231  {
 232      volatile int tmp[argc];
 233      tmp[0] = argv[0][0];
 234      return tmp[0];
 235  }"
 236 HAVE_C99_VLA)
 237
 238 # Check if we have C99 bool
 239 CHECK_C_SOURCE_COMPILES(
 240 "int main(int argc, char *argv[])
 241  {
 242      volatile _Bool ret;
 243      ret = (argc > 1) ? 1 : 0;
 244      return ret ? -1 : 0;
 245  }"
 246 HAVE_C99_BOOL)
 247
 248 # Check if we have C11 static_assert
 249 CHECK_C_SOURCE_COMPILES(
 250 "int main()
 251  {
 252      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 253      return 0;
 254  }"
 255 HAVE_C11_STATIC_ASSERT)
 256
 257 # Check if we have C11 alignas
 258 CHECK_C_SOURCE_COMPILES(
 259 "_Alignas(16) int foo;
 260  int main()
 261  {
 262      return 0;
 263  }"
 264 HAVE_C11_ALIGNAS)
 265
 266 # Check if we have C11 _Atomic
 267 CHECK_C_SOURCE_COMPILES(
 268 "#include <stdatomic.h>
 269  int _Atomic foo = ATOMIC_VAR_INIT(0);
 270  int main()
 271  {
 272      atomic_fetch_add(&foo, 2);
 273      return 0;
 274  }"
 275 HAVE_C11_ATOMIC)
 276
 277 # Add definitions, compiler switches, etc.
 278 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 279
 280 IF(NOT CMAKE_BUILD_TYPE)
 281     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 282         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 283         FORCE)
 284 ENDIF()
 285 IF(NOT CMAKE_DEBUG_POSTFIX)
 286     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 287         "Library postfix for debug builds. Normally left blank."
 288         FORCE)
 289 ENDIF()
 290
 291 SET(EXTRA_CFLAGS "")
 292 IF(MSVC)
 293     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 294     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 295     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 296
 297     IF(NOT DXSDK_DIR)
 298         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 299     ELSE()
 300         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 301     ENDIF()
 302     IF(DXSDK_DIR)
 303         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 304     ENDIF()
 305
 306     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 307     IF(FORCE_STATIC_VCRT)
 308         FOREACH(flag_var
 309                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 310                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 311             IF(${flag_var} MATCHES "/MD")
 312                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 313             ENDIF()
 314         ENDFOREACH(flag_var)
 315     ENDIF()
 316 ELSE()
 317     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 318     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 319     IF(HAVE_W_EXTRA)
 320         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 321     ENDIF()
 322
 323     IF(ALSOFT_WERROR)
 324         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 325     ENDIF()
 326
 327     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 328     # instead of NDEBUG)
 329     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 330         IF(${flag_var} MATCHES "-DNDEBUG")
 331             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 332         ENDIF()
 333     ENDFOREACH()
 334
 335     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 336     IF(HAVE_FNO_MATH_ERRNO)
 337         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fno-math-errno")
 338     ENDIF()
 339
 340     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 341                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 342
 343     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 344     if(ALSOFT_STATIC_LIBGCC)
 345         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 346         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 347         check_c_source_compiles(
 348 "#include <stdlib.h>
 349 int main()
 350 {
 351     return 0;
 352 }"
 353             HAVE_STATIC_LIBGCC_SWITCH
 354         )
 355         if(HAVE_STATIC_LIBGCC_SWITCH)
 356             set(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -static-libgcc")
 357         endif()
 358         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 359         unset(OLD_REQUIRED_LIBRARIES)
 360     endif()
 361 ENDIF()
 362
 363 # Set visibility/export options if available
 364 IF(WIN32)
 365     SET(EXPORT_DECL "__declspec(dllexport)")
 366     IF(NOT MINGW)
 367         SET(ALIGN_DECL "__declspec(align(x))")
 368     ELSE()
 369         SET(ALIGN_DECL "__declspec(aligned(x))")
 370     ENDIF()
 371 ELSE()
 372     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 373     # Yes GCC, really don't accept visibility modes you don't support
 374     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 375
 376     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 377                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 378     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 379         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 380     ELSE()
 381         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 382                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 383         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 384             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 385         ENDIF()
 386     ENDIF()
 387
 388     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 389         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 390         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 391             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 392         ENDIF()
 393     ENDIF()
 394
 395     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 396                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 397     IF(HAVE_ATTRIBUTE_ALIGNED)
 398         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 399     ENDIF()
 400
 401     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 402 ENDIF()
 403
 404 CHECK_C_SOURCE_COMPILES("
 405 int main()
 406 {
 407     float *ptr;
 408     ptr = __builtin_assume_aligned(ptr, 16);
 409     return 0;
 410 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 411 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 412     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 413 ELSE()
 414     SET(ASSUME_ALIGNED_DECL "x")
 415 ENDIF()
 416
 417 SET(SSE_SWITCH "")
 418 SET(SSE2_SWITCH "")
 419 SET(SSE3_SWITCH "")
 420 SET(SSE4_1_SWITCH "")
 421 SET(FPU_NEON_SWITCH "")
 422 IF(NOT MSVC)
 423     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 424     IF(HAVE_MSSE_SWITCH)
 425         SET(SSE_SWITCH "-msse")
 426     ENDIF()
 427     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 428     IF(HAVE_MSSE2_SWITCH)
 429         SET(SSE2_SWITCH "-msse2")
 430     ENDIF()
 431     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 432     IF(HAVE_MSSE3_SWITCH)
 433         SET(SSE3_SWITCH "-msse3")
 434     ENDIF()
 435     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 436     IF(HAVE_MSSE4_1_SWITCH)
 437         SET(SSE4_1_SWITCH "-msse4.1")
 438     ENDIF()
 439     CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 440     IF(HAVE_MFPU_NEON_SWITCH)
 441         SET(FPU_NEON_SWITCH "-mfpu=neon")
 442     ENDIF()
 443 ENDIF()
 444
 445 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 446                          int main() {return 0;}" HAVE_GCC_FORMAT)
 447
 448 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 449 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 450 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 451 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 452 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 453 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 454 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 455 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 456 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 457 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 458 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 459 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 460 IF(NOT HAVE_GUIDDEF_H)
 461     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 462 ENDIF()
 463
 464 # Some systems need libm for some of the following math functions to work
 465 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 466 IF(HAVE_LIBM)
 467     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 468     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 469 ENDIF()
 470
 471 # Check for the dlopen API (for dynamicly loading backend libs)
 472 IF(ALSOFT_DLOPEN)
 473     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 474     IF(HAVE_LIBDL)
 475         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 476         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 477     ENDIF()
 478
 479     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 480 ENDIF()
 481
 482 # Check for a cpuid intrinsic
 483 IF(HAVE_CPUID_H)
 484     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 485         int main()
 486         {
 487             unsigned int eax, ebx, ecx, edx;
 488             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 489         }" HAVE_GCC_GET_CPUID)
 490 ENDIF()
 491 IF(HAVE_INTRIN_H)
 492     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 493         int main()
 494         {
 495             int regs[4];
 496             __cpuid(regs, 0);
 497             return regs[0];
 498         }" HAVE_CPUID_INTRINSIC)
 499 ENDIF()
 500
 501 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 502 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 503 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 504 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 505 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 506 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 507 IF(NOT HAVE_C99_VLA)
 508     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 509     IF(NOT HAVE_ALLOCA)
 510         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 511     ENDIF()
 512 ENDIF()
 513
 514 IF(HAVE_FLOAT_H)
 515     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 516     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 517 ENDIF()
 518
 519 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 520 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 521 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 522 IF(NOT HAVE_STRCASECMP)
 523     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 524     IF(NOT HAVE__STRICMP)
 525         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 526     ENDIF()
 527
 528     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 529 ENDIF()
 530
 531 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 532 IF(NOT HAVE_STRNCASECMP)
 533     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 534     IF(NOT HAVE__STRNICMP)
 535         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 536     ENDIF()
 537
 538     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 539 ENDIF()
 540
 541 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 542 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 543 IF(NOT HAVE_SNPRINTF)
 544     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 545     IF(NOT HAVE__SNPRINTF)
 546         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 547     ENDIF()
 548
 549     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 550 ENDIF()
 551
 552 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 553 IF(NOT HAVE_ISFINITE)
 554     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 555     IF(NOT HAVE_FINITE)
 556         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 557         IF(NOT HAVE__FINITE)
 558             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 559         ENDIF()
 560         ADD_DEFINITIONS(-Disfinite=_finite)
 561     ELSE()
 562         ADD_DEFINITIONS(-Disfinite=finite)
 563     ENDIF()
 564 ENDIF()
 565
 566 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 567 IF(NOT HAVE_ISNAN)
 568     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 569     IF(NOT HAVE__ISNAN)
 570         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 571     ENDIF()
 572
 573     ADD_DEFINITIONS(-Disnan=_isnan)
 574 ENDIF()
 575
 576
 577 # Check if we have Windows headers
 578 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 579 IF(NOT HAVE_WINDOWS_H)
 580     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 581     IF(NOT HAVE_GETTIMEOFDAY)
 582         MESSAGE(FATAL_ERROR "No timing function found!")
 583     ENDIF()
 584
 585     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 586     IF(NOT HAVE_NANOSLEEP)
 587         MESSAGE(FATAL_ERROR "No sleep function found!")
 588     ENDIF()
 589
 590     # We need pthreads outside of Windows
 591     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 592     IF(NOT HAVE_PTHREAD_H)
 593         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 594     ENDIF()
 595     # Some systems need pthread_np.h to get recursive mutexes
 596     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 597
 598     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 599     IF(HAVE_PTHREAD)
 600         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 601         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 602         SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -pthread")
 603     ENDIF()
 604
 605     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 606     IF(HAVE_LIBPTHREAD)
 607         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 608     ENDIF()
 609
 610     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 611
 612     IF(HAVE_PTHREAD_NP_H)
 613         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 614         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 615             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 616         ELSE()
 617             CHECK_C_SOURCE_COMPILES("
 618 #include <pthread.h>
 619 #include <pthread_np.h>
 620 int main()
 621 {
 622     pthread_setname_np(\"testname\");
 623     return 0;
 624 }"
 625                 PTHREAD_SETNAME_NP_ONE_PARAM
 626             )
 627         ENDIF()
 628         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 629     ELSE()
 630         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 631         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 632             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 633         ELSE()
 634             CHECK_C_SOURCE_COMPILES("
 635 #include <pthread.h>
 636 int main()
 637 {
 638     pthread_setname_np(\"testname\");
 639     return 0;
 640 }"
 641                 PTHREAD_SETNAME_NP_ONE_PARAM
 642             )
 643         ENDIF()
 644         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 645     ENDIF()
 646
 647     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 648
 649     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 650     IF(HAVE_LIBRT)
 651         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 652     ENDIF()
 653 ENDIF()
 654
 655 # Check for a 64-bit type
 656 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 657 IF(NOT HAVE_STDINT_H)
 658     IF(HAVE_WINDOWS_H)
 659         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 660                                  #include <windows.h>
 661                                  __int64 foo;
 662                                  int main() {return 0;}" HAVE___INT64)
 663     ENDIF()
 664     IF(NOT HAVE___INT64)
 665         IF(NOT SIZEOF_LONG MATCHES "8")
 666             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 667                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 668             ENDIF()
 669         ENDIF()
 670     ENDIF()
 671 ENDIF()
 672
 673
 674 SET(COMMON_OBJS  common/almalloc.c
 675                  common/atomic.c
 676                  common/rwlock.c
 677                  common/threads.c
 678                  common/uintmap.c
 679 )
 680 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 681                  OpenAL32/alBuffer.c
 682                  OpenAL32/alEffect.c
 683                  OpenAL32/alError.c
 684                  OpenAL32/alExtension.c
 685                  OpenAL32/alFilter.c
 686                  OpenAL32/alListener.c
 687                  OpenAL32/alSource.c
 688                  OpenAL32/alState.c
 689                  OpenAL32/alThunk.c
 690                  OpenAL32/sample_cvt.c
 691 )
 692 SET(ALC_OBJS  Alc/ALc.c
 693               Alc/ALu.c
 694               Alc/alcConfig.c
 695               Alc/alcRing.c
 696               Alc/bs2b.c
 697               Alc/converter.c
 698               Alc/mastering.c
 699               Alc/effects/chorus.c
 700               Alc/effects/compressor.c
 701               Alc/effects/dedicated.c
 702               Alc/effects/distortion.c
 703               Alc/effects/echo.c
 704               Alc/effects/equalizer.c
 705               Alc/effects/flanger.c
 706               Alc/effects/modulator.c
 707               Alc/effects/null.c
 708               Alc/effects/reverb.c
 709               Alc/helpers.c
 710               Alc/hrtf.c
 711               Alc/uhjfilter.c
 712               Alc/ambdec.c
 713               Alc/bformatdec.c
 714               Alc/nfcfilter.c
 715               Alc/panning.c
 716               Alc/mixer.c
 717               Alc/mixer_c.c
 718 )
 719
 720
 721 SET(CPU_EXTS "Default")
 722 SET(HAVE_SSE        0)
 723 SET(HAVE_SSE2       0)
 724 SET(HAVE_SSE3       0)
 725 SET(HAVE_SSE4_1     0)
 726 SET(HAVE_NEON       0)
 727
 728 SET(HAVE_ALSA       0)
 729 SET(HAVE_OSS        0)
 730 SET(HAVE_SOLARIS    0)
 731 SET(HAVE_SNDIO      0)
 732 SET(HAVE_QSA        0)
 733 SET(HAVE_DSOUND     0)
 734 SET(HAVE_MMDEVAPI   0)
 735 SET(HAVE_WINMM      0)
 736 SET(HAVE_PORTAUDIO  0)
 737 SET(HAVE_PULSEAUDIO 0)
 738 SET(HAVE_COREAUDIO  0)
 739 SET(HAVE_OPENSL     0)
 740 SET(HAVE_WAVE       0)
 741
 742 # Check for SSE support
 743 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 744 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 745 IF(HAVE_XMMINTRIN_H)
 746     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 747     IF(ALSOFT_CPUEXT_SSE)
 748         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 749             SET(HAVE_SSE 1)
 750             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 751             IF(SSE_SWITCH)
 752                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 753                                             COMPILE_FLAGS "${SSE_SWITCH}")
 754             ENDIF()
 755             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 756         ENDIF()
 757     ENDIF()
 758 ENDIF()
 759 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 760     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 761 ENDIF()
 762
 763 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 764 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 765 IF(HAVE_EMMINTRIN_H)
 766     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 767     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 768         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 769             SET(HAVE_SSE2 1)
 770             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 771             IF(SSE2_SWITCH)
 772                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 773                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 774             ENDIF()
 775             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 776         ENDIF()
 777     ENDIF()
 778 ENDIF()
 779 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 780     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 781 ENDIF()
 782
 783 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 784 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 785 IF(HAVE_EMMINTRIN_H)
 786     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 787     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 788         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 789             SET(HAVE_SSE3 1)
 790             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 791             IF(SSE2_SWITCH)
 792                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 793                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 794             ENDIF()
 795             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 796         ENDIF()
 797     ENDIF()
 798 ENDIF()
 799 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 800     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 801 ENDIF()
 802
 803 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 804 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 805 IF(HAVE_SMMINTRIN_H)
 806     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 807     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 808         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 809             SET(HAVE_SSE4_1 1)
 810             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 811             IF(SSE4_1_SWITCH)
 812                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 813                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 814             ENDIF()
 815             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 816         ENDIF()
 817     ENDIF()
 818 ENDIF()
 819 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 820     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 821 ENDIF()
 822
 823 # Check for ARM Neon support
 824 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 825 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 826 IF(HAVE_ARM_NEON_H)
 827     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 828     IF(ALSOFT_CPUEXT_NEON)
 829         SET(HAVE_NEON 1)
 830         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 831         IF(FPU_NEON_SWITCH)
 832             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 833                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 834         ENDIF()
 835         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 836     ENDIF()
 837 ENDIF()
 838 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 839     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 840 ENDIF()
 841
 842
 843 IF(WIN32 OR HAVE_DLFCN_H)
 844     SET(IS_LINKED "")
 845     MACRO(ADD_BACKEND_LIBS _LIBS)
 846     ENDMACRO()
 847 ELSE()
 848     SET(IS_LINKED " (linked)")
 849     MACRO(ADD_BACKEND_LIBS _LIBS)
 850         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 851     ENDMACRO()
 852 ENDIF()
 853
 854 SET(BACKENDS "")
 855 SET(ALC_OBJS  ${ALC_OBJS}
 856               Alc/backends/base.c
 857               # Default backends, always available
 858               Alc/backends/loopback.c
 859               Alc/backends/null.c
 860 )
 861
 862 # Check ALSA backend
 863 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 864 FIND_PACKAGE(ALSA)
 865 IF(ALSA_FOUND)
 866     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 867     IF(ALSOFT_BACKEND_ALSA)
 868         SET(HAVE_ALSA 1)
 869         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 870         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 871         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 872     ENDIF()
 873 ENDIF()
 874 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 875     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 876 ENDIF()
 877
 878 # Check OSS backend
 879 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 880 FIND_PACKAGE(OSS)
 881 IF(OSS_FOUND)
 882     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 883     IF(ALSOFT_BACKEND_OSS)
 884         SET(HAVE_OSS 1)
 885         SET(BACKENDS  "${BACKENDS} OSS,")
 886         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 887     ENDIF()
 888 ENDIF()
 889 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 890     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 891 ENDIF()
 892
 893 # Check Solaris backend
 894 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 895 FIND_PACKAGE(AudioIO)
 896 IF(AUDIOIO_FOUND)
 897     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 898     IF(ALSOFT_BACKEND_SOLARIS)
 899         SET(HAVE_SOLARIS 1)
 900         SET(BACKENDS  "${BACKENDS} Solaris,")
 901         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 902     ENDIF()
 903 ENDIF()
 904 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 905     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 906 ENDIF()
 907
 908 # Check SndIO backend
 909 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 910 FIND_PACKAGE(SoundIO)
 911 IF(SOUNDIO_FOUND)
 912     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 913     IF(ALSOFT_BACKEND_SNDIO)
 914         SET(HAVE_SNDIO 1)
 915         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 916         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 917         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 918     ENDIF()
 919 ENDIF()
 920 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 921     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 922 ENDIF()
 923
 924 # Check QSA backend
 925 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 926 FIND_PACKAGE(QSA)
 927 IF(QSA_FOUND)
 928     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 929     IF(ALSOFT_BACKEND_QSA)
 930         SET(HAVE_QSA 1)
 931         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 932         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 933         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 934     ENDIF()
 935 ENDIF()
 936 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 937     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 938 ENDIF()
 939
 940 # Check Windows-only backends
 941 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 942 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 943 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 944 IF(HAVE_WINDOWS_H)
 945     # Check MMSystem backend
 946     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 947     IF(HAVE_MMSYSTEM_H)
 948         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 949         IF(HAVE_LIBWINMM)
 950             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 951             IF(ALSOFT_BACKEND_WINMM)
 952                 SET(HAVE_WINMM 1)
 953                 SET(BACKENDS  "${BACKENDS} WinMM,")
 954                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 955                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 956             ENDIF()
 957         ENDIF()
 958     ENDIF()
 959
 960     # Check DSound backend
 961     FIND_PACKAGE(DSound)
 962     IF(DSOUND_FOUND)
 963         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 964         IF(ALSOFT_BACKEND_DSOUND)
 965             SET(HAVE_DSOUND 1)
 966             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 967             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 968             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 969         ENDIF()
 970     ENDIF()
 971
 972     # Check for MMDevApi backend
 973     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 974     IF(HAVE_MMDEVICEAPI_H)
 975         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 976         IF(ALSOFT_BACKEND_MMDEVAPI)
 977             SET(HAVE_MMDEVAPI 1)
 978             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 979             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 980         ENDIF()
 981     ENDIF()
 982 ENDIF()
 983 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 984     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 985 ENDIF()
 986 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 987     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 988 ENDIF()
 989 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 990     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 991 ENDIF()
 992
 993 # Check PortAudio backend
 994 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 995 FIND_PACKAGE(PortAudio)
 996 IF(PORTAUDIO_FOUND)
 997     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 998     IF(ALSOFT_BACKEND_PORTAUDIO)
 999         SET(HAVE_PORTAUDIO 1)
1000         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1001         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1002         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1003     ENDIF()
1004 ENDIF()
1005 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1006     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1007 ENDIF()
1008
1009 # Check PulseAudio backend
1010 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1011 FIND_PACKAGE(PulseAudio)
1012 IF(PULSEAUDIO_FOUND)
1013     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1014     IF(ALSOFT_BACKEND_PULSEAUDIO)
1015         SET(HAVE_PULSEAUDIO 1)
1016         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1017         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1018         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1019     ENDIF()
1020 ENDIF()
1021 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1022     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1023 ENDIF()
1024
1025 # Check JACK backend
1026 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1027 FIND_PACKAGE(JACK)
1028 IF(JACK_FOUND)
1029     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1030     IF(ALSOFT_BACKEND_JACK)
1031         SET(HAVE_JACK 1)
1032         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1033         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1034         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1035     ENDIF()
1036 ENDIF()
1037 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1038     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1039 ENDIF()
1040
1041 # Check CoreAudio backend
1042 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1043 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1044              NAMES CoreAudio
1045              PATHS /System/Library/Frameworks
1046 )
1047 IF(COREAUDIO_FRAMEWORK)
1048     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1049     IF(ALSOFT_BACKEND_COREAUDIO)
1050         SET(HAVE_COREAUDIO 1)
1051         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1052         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1053         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1054         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1055         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1056
1057         # Some versions of OSX may need the AudioToolbox framework. Add it if
1058         # it's found.
1059         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1060                      NAMES AudioToolbox
1061                      PATHS ~/Library/Frameworks
1062                            /Library/Frameworks
1063                            /System/Library/Frameworks
1064                     )
1065         IF(AUDIOTOOLBOX_LIBRARY)
1066             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1067         ENDIF()
1068     ENDIF()
1069 ENDIF()
1070 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1071     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1072 ENDIF()
1073
1074 # Check for OpenSL (Android) backend
1075 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1076 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1077 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1078     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1079     IF(HAVE_LIBOPENSLES)
1080         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1081         IF(ALSOFT_BACKEND_OPENSL)
1082             SET(HAVE_OPENSL 1)
1083             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1084             SET(BACKENDS  "${BACKENDS} OpenSL,")
1085             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1086         ENDIF()
1087     ENDIF()
1088 ENDIF()
1089 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1090     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1091 ENDIF()
1092
1093 # Optionally enable the Wave Writer backend
1094 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1095 IF(ALSOFT_BACKEND_WAVE)
1096     SET(HAVE_WAVE 1)
1097     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1098     SET(BACKENDS  "${BACKENDS} WaveFile,")
1099 ENDIF()
1100
1101 # This is always available
1102 SET(BACKENDS  "${BACKENDS} Null")
1103
1104 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1105 if(ALSOFT_EMBED_HRTF_DATA)
1106     SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1107     SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1108     FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1109
1110     SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1111     ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}"
1112         COMMAND ${CMAKE_COMMAND} "${NATIVE_SRC_DIR}"
1113         COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1114         WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1115         DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt" "${NATIVE_SRC_DIR}bin2h.c"
1116         VERBATIM
1117     )
1118
1119     MACRO(make_hrtf_header FILENAME VARNAME)
1120         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1121         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1122
1123         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1124             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1125             DEPENDS "${BIN2H_COMMAND}" "${infile}"
1126             COMMENT "Generating ${FILENAME}.h"
1127             VERBATIM
1128         )
1129
1130         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1131     ENDMACRO()
1132
1133     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1134     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1135 endif()
1136
1137
1138 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1139     add_subdirectory(utils/alsoft-config)
1140 ENDIF()
1141 IF(ALSOFT_EXAMPLES)
1142     FIND_PACKAGE(SDL2)
1143     IF(SDL2_FOUND)
1144         FIND_PACKAGE(SDL_sound)
1145         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1146     ENDIF()
1147 ENDIF()
1148
1149 IF(LIBTYPE STREQUAL "STATIC")
1150     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1151     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1152 ENDIF()
1153
1154 IF(NOT WIN32)
1155     SET(LIBNAME "openal")
1156 ELSE()
1157     SET(LIBNAME "OpenAL32")
1158 ENDIF()
1159
1160 FIND_PACKAGE(Git)
1161 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1162     # Get the current working branch and its latest abbreviated commit hash
1163     ADD_CUSTOM_TARGET(build_version
1164         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1165                          -D LIB_VERSION=${LIB_VERSION}
1166                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1167                          -D DST=${OpenAL_BINARY_DIR}/version.h
1168                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1169         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1170         VERBATIM
1171     )
1172 ELSE()
1173     SET(GIT_BRANCH "UNKNOWN")
1174     SET(GIT_COMMIT_HASH "unknown")
1175     CONFIGURE_FILE(
1176         "${OpenAL_SOURCE_DIR}/version.h.in"
1177         "${OpenAL_BINARY_DIR}/version.h")
1178 ENDIF()
1179
1180 # Needed for openal.pc.in
1181 SET(prefix ${CMAKE_INSTALL_PREFIX})
1182 SET(exec_prefix "\${prefix}")
1183 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1184 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1185 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1186 SET(PACKAGE_VERSION "${LIB_VERSION}")
1187
1188 # End configuration
1189 CONFIGURE_FILE(
1190     "${OpenAL_SOURCE_DIR}/config.h.in"
1191     "${OpenAL_BINARY_DIR}/config.h")
1192 CONFIGURE_FILE(
1193     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1194     "${OpenAL_BINARY_DIR}/openal.pc"
1195     @ONLY)
1196
1197 MACRO(ADD_INCLUDE_DIRS TRGT TESTVAR INCVAR)
1198     IF(${TESTVAR})
1199         SET_PROPERTY(TARGET ${TRGT} APPEND PROPERTY INCLUDE_DIRECTORIES ${${INCVAR}})
1200     ENDIF()
1201 ENDMACRO()
1202
1203 UNSET(HAS_ROUTER)
1204 SET(IMPL_TARGET OpenAL)
1205
1206 # Build main library
1207 IF(LIBTYPE STREQUAL "STATIC")
1208     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1209 ELSE()
1210     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1211         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c ${COMMON_OBJS})
1212         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1213         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY
1214             COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1215         )
1216         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1217         IF(MSVC)
1218             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1219         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1220             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1221         ENDIF()
1222         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1223         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1224         IF(TARGET build_version)
1225             ADD_DEPENDENCIES(OpenAL build_version)
1226         ENDIF()
1227         SET(HAS_ROUTER 1)
1228
1229         SET(LIBNAME "soft_oal")
1230         SET(IMPL_TARGET soft_oal)
1231     ENDIF()
1232
1233     ADD_LIBRARY(${IMPL_TARGET} SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1234     IF(WIN32)
1235         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1236     ENDIF()
1237 ENDIF()
1238 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1239     VERSION ${LIB_VERSION}
1240     SOVERSION ${LIB_MAJOR_VERSION}
1241 )
1242 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY INCLUDE_DIRECTORIES
1243     "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc"
1244 )
1245 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_ALSA       ALSA_INCLUDE_DIRS)
1246 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_OSS        OSS_INCLUDE_DIRS)
1247 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SOLARIS    AUDIOIO_INCLUDE_DIRS)
1248 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SNDIO      SOUNDIO_INCLUDE_DIRS)
1249 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_QSA        QSA_INCLUDE_DIRS)
1250 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_DSOUND     DSOUND_INCLUDE_DIRS)
1251 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PORTAUDIO  PORTAUDIO_INCLUDE_DIRS)
1252 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PULSEAUDIO PULSEAUDIO_INCLUDE_DIRS)
1253 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_JACK       JACK_INCLUDE_DIRS)
1254 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY
1255     COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1256 )
1257 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1258     SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1259 ENDIF()
1260 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1261 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1262
1263 TARGET_LINK_LIBRARIES(${IMPL_TARGET} ${EXTRA_LIBS})
1264 IF(TARGET build_version)
1265     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1266 ENDIF()
1267
1268 IF(WIN32)
1269     IF(MSVC)
1270         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1271     ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1272         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1273     ENDIF()
1274
1275     if(NOT LIBTYPE STREQUAL "STATIC")
1276         IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1277             FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1278             FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1279             IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1280                 MESSAGE(STATUS "")
1281                 IF(NOT SED_EXECUTABLE)
1282                     MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1283                 ENDIF()
1284                 IF(NOT DLLTOOL_EXECUTABLE)
1285                     MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1286                 ENDIF()
1287             ELSE()
1288                 SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1289                              " -Wl,--output-def,OpenAL32.def")
1290                 ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1291                     COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1292                     COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1293                     COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1294                     VERBATIM
1295                 )
1296             ENDIF()
1297         ENDIF()
1298     ENDIF()
1299 ENDIF()
1300
1301 IF(ALSOFT_INSTALL)
1302     INSTALL(TARGETS OpenAL EXPORT OpenAL
1303             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1304             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1305             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1306             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1307     )
1308     EXPORT(TARGETS OpenAL
1309            NAMESPACE OpenAL::
1310            FILE OpenALConfig.cmake)
1311     INSTALL(EXPORT OpenAL
1312             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1313             NAMESPACE OpenAL::
1314             FILE OpenALConfig.cmake)
1315     INSTALL(FILES include/AL/al.h
1316                   include/AL/alc.h
1317                   include/AL/alext.h
1318                   include/AL/efx.h
1319                   include/AL/efx-creative.h
1320                   include/AL/efx-presets.h
1321             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1322     )
1323     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1324             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1325     IF(TARGET soft_oal)
1326         INSTALL(TARGETS soft_oal
1327                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1328         )
1329     ENDIF()
1330 ENDIF()
1331
1332
1333 if(HAS_ROUTER)
1334     message(STATUS "")
1335     message(STATUS "Building DLL router")
1336 endif()
1337
1338 MESSAGE(STATUS "")
1339 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1340 MESSAGE(STATUS "    ${BACKENDS}")
1341 MESSAGE(STATUS "")
1342 MESSAGE(STATUS "Building with support for CPU extensions:")
1343 MESSAGE(STATUS "    ${CPU_EXTS}")
1344 MESSAGE(STATUS "")
1345
1346 IF(WIN32)
1347     IF(NOT HAVE_DSOUND)
1348         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1349         MESSAGE(STATUS "         This is probably NOT what you want!")
1350         MESSAGE(STATUS "")
1351     ENDIF()
1352 ENDIF()
1353
1354 if(ALSOFT_EMBED_HRTF_DATA)
1355     message(STATUS "Embedding HRTF datasets")
1356     message(STATUS "")
1357 endif()
1358
1359 # Install alsoft.conf configuration file
1360 IF(ALSOFT_CONFIG)
1361     INSTALL(FILES alsoftrc.sample
1362             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1363     )
1364     MESSAGE(STATUS "Installing sample configuration")
1365     MESSAGE(STATUS "")
1366 ENDIF()
1367
1368 # Install HRTF definitions
1369 IF(ALSOFT_HRTF_DEFS)
1370     INSTALL(FILES hrtf/default-44100.mhr
1371                   hrtf/default-48000.mhr
1372             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1373     )
1374     MESSAGE(STATUS "Installing HRTF definitions")
1375     MESSAGE(STATUS "")
1376 ENDIF()
1377
1378 # Install AmbDec presets
1379 IF(ALSOFT_AMBDEC_PRESETS)
1380     INSTALL(FILES presets/3D7.1.ambdec
1381                   presets/hexagon.ambdec
1382                   presets/itu5.1.ambdec
1383                   presets/rectangle.ambdec
1384                   presets/square.ambdec
1385                   presets/presets.txt
1386             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1387     )
1388     MESSAGE(STATUS "Installing AmbDec presets")
1389     MESSAGE(STATUS "")
1390 ENDIF()
1391
1392 IF(ALSOFT_UTILS)
1393     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1394     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1395     TARGET_LINK_LIBRARIES(openal-info OpenAL)
1396
1397     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1398     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1399     IF(HAVE_LIBM)
1400         TARGET_LINK_LIBRARIES(makehrtf m)
1401     ENDIF()
1402
1403     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1404     SET_PROPERTY(TARGET bsincgen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1405     IF(HAVE_LIBM)
1406         TARGET_LINK_LIBRARIES(bsincgen m)
1407     ENDIF()
1408
1409     IF(ALSOFT_INSTALL)
1410         INSTALL(TARGETS openal-info makehrtf bsincgen
1411                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1412                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1413                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1414         )
1415     ENDIF()
1416
1417     MESSAGE(STATUS "Building utility programs")
1418     IF(TARGET alsoft-config)
1419         MESSAGE(STATUS "Building configuration program")
1420     ENDIF()
1421     MESSAGE(STATUS "")
1422 ENDIF()
1423
1424 IF(ALSOFT_TESTS)
1425     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1426
1427     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1428     TARGET_LINK_LIBRARIES(altonegen OpenAL)
1429     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1430
1431     IF(ALSOFT_INSTALL)
1432         INSTALL(TARGETS altonegen
1433                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1434                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1435                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1436         )
1437     ENDIF()
1438
1439     MESSAGE(STATUS "Building test programs")
1440     MESSAGE(STATUS "")
1441 ENDIF()
1442
1443 IF(ALSOFT_EXAMPLES)
1444     ADD_EXECUTABLE(alrecord examples/alrecord.c ${COMMON_OBJS})
1445     TARGET_LINK_LIBRARIES(alrecord OpenAL)
1446     SET_PROPERTY(TARGET alrecord APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1447
1448     IF(ALSOFT_INSTALL)
1449         INSTALL(TARGETS alrecord
1450                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1451                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1452                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1453         )
1454     ENDIF()
1455
1456     MESSAGE(STATUS "Building example programs")
1457
1458     IF(SDL2_FOUND)
1459         IF(SDL_SOUND_FOUND)
1460             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1461
1462             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1463             TARGET_LINK_LIBRARIES(alstream ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1464             SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1465             SET_PROPERTY(TARGET alstream APPEND PROPERTY
1466                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1467             )
1468
1469             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1470             TARGET_LINK_LIBRARIES(alreverb ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1471             SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1472             SET_PROPERTY(TARGET alreverb APPEND PROPERTY
1473                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1474             )
1475
1476             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1477             TARGET_LINK_LIBRARIES(allatency ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1478             SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1479             SET_PROPERTY(TARGET allatency APPEND PROPERTY
1480                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1481             )
1482
1483             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1484             TARGET_LINK_LIBRARIES(alloopback ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1485             SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1486             SET_PROPERTY(TARGET alloopback APPEND PROPERTY
1487                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1488             )
1489
1490             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1491             TARGET_LINK_LIBRARIES(alhrtf ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1492             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1493             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY
1494                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1495             )
1496
1497             IF(ALSOFT_INSTALL)
1498                 INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1499                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1500                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1501                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1502                 )
1503             ENDIF()
1504
1505             MESSAGE(STATUS "Building SDL_sound example programs")
1506         ENDIF()
1507
1508         SET(FFVER_OK FALSE)
1509         IF(FFMPEG_FOUND)
1510             SET(FFVER_OK TRUE)
1511             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1512                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1513                 SET(FFVER_OK FALSE)
1514             ENDIF()
1515             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1516                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1517                 SET(FFVER_OK FALSE)
1518             ENDIF()
1519             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1520                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1521                 SET(FFVER_OK FALSE)
1522             ENDIF()
1523             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1524                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1525                 SET(FFVER_OK FALSE)
1526             ENDIF()
1527             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1528                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1529                 SET(FFVER_OK FALSE)
1530             ENDIF()
1531         ENDIF()
1532         IF(FFVER_OK)
1533             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1534             TARGET_LINK_LIBRARIES(alffplay ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} OpenAL)
1535             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1536             SET_PROPERTY(TARGET alffplay APPEND PROPERTY
1537                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS}
1538             )
1539
1540             IF(ALSOFT_INSTALL)
1541                 INSTALL(TARGETS alffplay
1542                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1543                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1544                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1545                 )
1546             ENDIF()
1547             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1548         ENDIF()
1549         MESSAGE(STATUS "")
1550     ENDIF()
1551 ENDIF()