CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 IF(WIN32)
  66     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  67
  68     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  69
  70     # This option is mainly for static linking OpenAL Soft into another project
  71     # that already defines the IDs. It is up to that project to ensure all
  72     # required IDs are defined.
  73     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  74
  75     IF(MINGW)
  76         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  77         IF(NOT DLLTOOL)
  78             IF(HOST)
  79                 SET(DLLTOOL "${HOST}-dlltool")
  80             ELSE()
  81                 SET(DLLTOOL "dlltool")
  82             ENDIF()
  83         ENDIF()
  84     ENDIF()
  85 ENDIF()
  86
  87
  88 SET(EXTRA_LIBS "")
  89 SET(EXTRA_LDFLAGS "")
  90
  91 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  92 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  93     ADD_DEFINITIONS("-I/usr/include")
  94     SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -L/usr/lib")
  95 ENDIF()
  96
  97 IF(NOT LIBTYPE)
  98     SET(LIBTYPE SHARED)
  99 ENDIF()
 100
 101 SET(LIB_MAJOR_VERSION "1")
 102 SET(LIB_MINOR_VERSION "18")
 103 SET(LIB_REVISION "1")
 104 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 105
 106 SET(EXPORT_DECL "")
 107 SET(ALIGN_DECL "")
 108
 109
 110 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 111 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 112
 113
 114 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 115 IF(HAVE_STD_C11)
 116     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 117 ELSE()
 118     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 119     IF(HAVE_STD_C99)
 120         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 121     ENDIF()
 122 ENDIF()
 123
 124 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 125 IF(HAVE_STD_CXX11)
 126     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 127 ENDIF()
 128
 129 if(NOT WIN32)
 130     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 131     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 132     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 133         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 134         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 135         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 136         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 137             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 138         ELSE()
 139             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600)
 140         ENDIF()
 141     ENDIF()
 142     UNSET(OLD_REQUIRED_FLAGS)
 143 ENDIF()
 144
 145 # Set defines for large file support
 146 CHECK_FILE_OFFSET_BITS()
 147 IF(_FILE_OFFSET_BITS)
 148     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 149     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 150 ENDIF()
 151 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 152 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 153
 154 # MSVC may need workarounds for C99 restrict and inline
 155 IF(MSVC)
 156     # TODO: Once we truly require C99, these restrict and inline checks should go
 157     # away.
 158     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 159                              int main() {return 0;}" HAVE_RESTRICT)
 160     IF(NOT HAVE_RESTRICT)
 161         ADD_DEFINITIONS("-Drestrict=")
 162         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 163     ENDIF()
 164
 165     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 166                              int main() {return 0;}" HAVE_INLINE)
 167     IF(NOT HAVE_INLINE)
 168         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 169                                  int main() {return 0;}" HAVE___INLINE)
 170         IF(NOT HAVE___INLINE)
 171             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 172         ENDIF()
 173
 174         ADD_DEFINITIONS(-Dinline=__inline)
 175         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 176     ENDIF()
 177 ENDIF()
 178
 179 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 180 IF(CMAKE_COMPILER_IS_GNUCC)
 181     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 182
 183     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 184     # Force no inlining for the next test.
 185     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 186
 187     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 188                              int main() {return foo();}" INLINE_IS_C99)
 189     IF(NOT INLINE_IS_C99)
 190         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 191                              Please update your compiler for better C99 compliance.")
 192     ENDIF()
 193
 194     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 195 ENDIF()
 196
 197 # Check if we have a proper timespec declaration
 198 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 199 IF(HAVE_STRUCT_TIMESPEC)
 200     # Define it here so we don't have to include config.h for it
 201     ADD_DEFINITIONS("-DHAVE_STRUCT_TIMESPEC")
 202 ENDIF()
 203
 204 # Some systems may need libatomic for C11 atomic functions to work
 205 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 206 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 207 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 208 int _Atomic foo = ATOMIC_VAR_INIT(0);
 209 int main()
 210 {
 211     return atomic_fetch_add(&foo, 2);
 212 }"
 213 HAVE_LIBATOMIC)
 214 IF(NOT HAVE_LIBATOMIC)
 215     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 216 ELSE()
 217     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 218 ENDIF()
 219 UNSET(OLD_REQUIRED_LIBRARIES)
 220
 221 # Include liblog for Android logging
 222 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 223 IF(HAVE_LIBLOG)
 224     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 225     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 226 ENDIF()
 227
 228 # Check if we have C99 variable length arrays
 229 CHECK_C_SOURCE_COMPILES(
 230 "int main(int argc, char *argv[])
 231  {
 232      volatile int tmp[argc];
 233      tmp[0] = argv[0][0];
 234      return tmp[0];
 235  }"
 236 HAVE_C99_VLA)
 237
 238 # Check if we have C99 bool
 239 CHECK_C_SOURCE_COMPILES(
 240 "int main(int argc, char *argv[])
 241  {
 242      volatile _Bool ret;
 243      ret = (argc > 1) ? 1 : 0;
 244      return ret ? -1 : 0;
 245  }"
 246 HAVE_C99_BOOL)
 247
 248 # Check if we have C11 static_assert
 249 CHECK_C_SOURCE_COMPILES(
 250 "int main()
 251  {
 252      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 253      return 0;
 254  }"
 255 HAVE_C11_STATIC_ASSERT)
 256
 257 # Check if we have C11 alignas
 258 CHECK_C_SOURCE_COMPILES(
 259 "_Alignas(16) int foo;
 260  int main()
 261  {
 262      return 0;
 263  }"
 264 HAVE_C11_ALIGNAS)
 265
 266 # Check if we have C11 _Atomic
 267 CHECK_C_SOURCE_COMPILES(
 268 "#include <stdatomic.h>
 269  int _Atomic foo = ATOMIC_VAR_INIT(0);
 270  int main()
 271  {
 272      atomic_fetch_add(&foo, 2);
 273      return 0;
 274  }"
 275 HAVE_C11_ATOMIC)
 276
 277 # Add definitions, compiler switches, etc.
 278 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 279
 280 IF(NOT CMAKE_BUILD_TYPE)
 281     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 282         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 283         FORCE)
 284 ENDIF()
 285 IF(NOT CMAKE_DEBUG_POSTFIX)
 286     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 287         "Library postfix for debug builds. Normally left blank."
 288         FORCE)
 289 ENDIF()
 290
 291 SET(EXTRA_CFLAGS "")
 292 IF(MSVC)
 293     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 294     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 295     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 296
 297     IF(NOT DXSDK_DIR)
 298         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 299     ELSE()
 300         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 301     ENDIF()
 302     IF(DXSDK_DIR)
 303         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 304     ENDIF()
 305
 306     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 307     IF(FORCE_STATIC_VCRT)
 308         FOREACH(flag_var
 309                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 310                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 311             IF(${flag_var} MATCHES "/MD")
 312                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 313             ENDIF()
 314         ENDFOREACH(flag_var)
 315     ENDIF()
 316 ELSE()
 317     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 318     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 319     IF(HAVE_W_EXTRA)
 320         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 321     ENDIF()
 322
 323     IF(ALSOFT_WERROR)
 324         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 325     ENDIF()
 326
 327     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 328     # instead of NDEBUG)
 329     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 330         IF(${flag_var} MATCHES "-DNDEBUG")
 331             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 332         ENDIF()
 333     ENDFOREACH()
 334
 335     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 336     IF(HAVE_FNO_MATH_ERRNO)
 337         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fno-math-errno")
 338     ENDIF()
 339
 340     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 341                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 342
 343     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 344     if(ALSOFT_STATIC_LIBGCC)
 345         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 346         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 347         check_c_source_compiles(
 348 "#include <stdlib.h>
 349 int main()
 350 {
 351     return 0;
 352 }"
 353             HAVE_STATIC_LIBGCC_SWITCH
 354         )
 355         if(HAVE_STATIC_LIBGCC_SWITCH)
 356             set(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -static-libgcc")
 357         endif()
 358         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 359         unset(OLD_REQUIRED_LIBRARIES)
 360     endif()
 361 ENDIF()
 362
 363 # Set visibility/export options if available
 364 IF(WIN32)
 365     SET(EXPORT_DECL "__declspec(dllexport)")
 366     IF(NOT MINGW)
 367         SET(ALIGN_DECL "__declspec(align(x))")
 368     ELSE()
 369         SET(ALIGN_DECL "__declspec(aligned(x))")
 370     ENDIF()
 371 ELSE()
 372     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 373     # Yes GCC, really don't accept visibility modes you don't support
 374     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 375
 376     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 377                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 378     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 379         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 380     ELSE()
 381         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 382                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 383         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 384             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 385         ENDIF()
 386     ENDIF()
 387
 388     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 389         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 390         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 391             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 392         ENDIF()
 393     ENDIF()
 394
 395     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 396                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 397     IF(HAVE_ATTRIBUTE_ALIGNED)
 398         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 399     ENDIF()
 400
 401     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 402 ENDIF()
 403
 404 CHECK_C_SOURCE_COMPILES("
 405 int main()
 406 {
 407     float *ptr;
 408     ptr = __builtin_assume_aligned(ptr, 16);
 409     return 0;
 410 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 411 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 412     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 413 ELSE()
 414     SET(ASSUME_ALIGNED_DECL "x")
 415 ENDIF()
 416
 417 SET(SSE_SWITCH "")
 418 SET(SSE2_SWITCH "")
 419 SET(SSE3_SWITCH "")
 420 SET(SSE4_1_SWITCH "")
 421 SET(FPU_NEON_SWITCH "")
 422
 423 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 424 IF(HAVE_MSSE_SWITCH)
 425     SET(SSE_SWITCH "-msse")
 426 ENDIF()
 427 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 428 IF(HAVE_MSSE2_SWITCH)
 429     SET(SSE2_SWITCH "-msse2")
 430 ENDIF()
 431 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 432 IF(HAVE_MSSE3_SWITCH)
 433     SET(SSE3_SWITCH "-msse3")
 434 ENDIF()
 435 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 436 IF(HAVE_MSSE4_1_SWITCH)
 437     SET(SSE4_1_SWITCH "-msse4.1")
 438 ENDIF()
 439 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 440 IF(HAVE_MFPU_NEON_SWITCH)
 441     SET(FPU_NEON_SWITCH "-mfpu=neon")
 442 ENDIF()
 443
 444 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 445                          int main() {return 0;}" HAVE_GCC_FORMAT)
 446
 447 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 448 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 449 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 450 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 451 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 452 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 453 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 454 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 455 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 456 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 457 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 458 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 459 IF(NOT HAVE_GUIDDEF_H)
 460     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 461 ENDIF()
 462
 463 # Some systems need libm for some of the following math functions to work
 464 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 465 IF(HAVE_LIBM)
 466     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 467     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 468 ENDIF()
 469
 470 # Check for the dlopen API (for dynamicly loading backend libs)
 471 IF(ALSOFT_DLOPEN)
 472     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 473     IF(HAVE_LIBDL)
 474         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 475         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 476     ENDIF()
 477
 478     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 479 ENDIF()
 480
 481 # Check for a cpuid intrinsic
 482 IF(HAVE_CPUID_H)
 483     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 484         int main()
 485         {
 486             unsigned int eax, ebx, ecx, edx;
 487             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 488         }" HAVE_GCC_GET_CPUID)
 489 ENDIF()
 490 IF(HAVE_INTRIN_H)
 491     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 492         int main()
 493         {
 494             int regs[4];
 495             __cpuid(regs, 0);
 496             return regs[0];
 497         }" HAVE_CPUID_INTRINSIC)
 498 ENDIF()
 499
 500 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 501 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 502 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 503 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 504 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 505 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 506 IF(NOT HAVE_C99_VLA)
 507     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 508     IF(NOT HAVE_ALLOCA)
 509         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 510     ENDIF()
 511 ENDIF()
 512
 513 IF(HAVE_FLOAT_H)
 514     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 515     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 516 ENDIF()
 517
 518 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 519 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 520 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 521 IF(NOT HAVE_STRCASECMP)
 522     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 523     IF(NOT HAVE__STRICMP)
 524         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 525     ENDIF()
 526
 527     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 528 ENDIF()
 529
 530 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 531 IF(NOT HAVE_STRNCASECMP)
 532     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 533     IF(NOT HAVE__STRNICMP)
 534         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 535     ENDIF()
 536
 537     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 538 ENDIF()
 539
 540 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 541 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 542 IF(NOT HAVE_SNPRINTF)
 543     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 544     IF(NOT HAVE__SNPRINTF)
 545         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 546     ENDIF()
 547
 548     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 549 ENDIF()
 550
 551 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 552 IF(NOT HAVE_ISFINITE)
 553     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 554     IF(NOT HAVE_FINITE)
 555         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 556         IF(NOT HAVE__FINITE)
 557             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 558         ENDIF()
 559         ADD_DEFINITIONS(-Disfinite=_finite)
 560     ELSE()
 561         ADD_DEFINITIONS(-Disfinite=finite)
 562     ENDIF()
 563 ENDIF()
 564
 565 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 566 IF(NOT HAVE_ISNAN)
 567     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 568     IF(NOT HAVE__ISNAN)
 569         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 570     ENDIF()
 571
 572     ADD_DEFINITIONS(-Disnan=_isnan)
 573 ENDIF()
 574
 575
 576 # Check if we have Windows headers
 577 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 578 IF(NOT HAVE_WINDOWS_H)
 579     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 580     IF(NOT HAVE_GETTIMEOFDAY)
 581         MESSAGE(FATAL_ERROR "No timing function found!")
 582     ENDIF()
 583
 584     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 585     IF(NOT HAVE_NANOSLEEP)
 586         MESSAGE(FATAL_ERROR "No sleep function found!")
 587     ENDIF()
 588
 589     # We need pthreads outside of Windows
 590     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 591     IF(NOT HAVE_PTHREAD_H)
 592         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 593     ENDIF()
 594     # Some systems need pthread_np.h to get recursive mutexes
 595     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 596
 597     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 598     IF(HAVE_PTHREAD)
 599         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 600         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 601         SET(EXTRA_LDFLAGS "${EXTRA_LDFLAGS} -pthread")
 602     ENDIF()
 603
 604     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 605     IF(HAVE_LIBPTHREAD)
 606         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 607     ENDIF()
 608
 609     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 610
 611     IF(HAVE_PTHREAD_NP_H)
 612         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 613         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 614             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 615         ELSE()
 616             CHECK_C_SOURCE_COMPILES("
 617 #include <pthread.h>
 618 #include <pthread_np.h>
 619 int main()
 620 {
 621     pthread_setname_np(\"testname\");
 622     return 0;
 623 }"
 624                 PTHREAD_SETNAME_NP_ONE_PARAM
 625             )
 626             CHECK_C_SOURCE_COMPILES("
 627 #include <pthread.h>
 628 #include <pthread_np.h>
 629 int main()
 630 {
 631     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 632     return 0;
 633 }"
 634                 PTHREAD_SETNAME_NP_THREE_PARAMS
 635             )
 636         ENDIF()
 637         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 638     ELSE()
 639         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 640         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 641             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 642         ELSE()
 643             CHECK_C_SOURCE_COMPILES("
 644 #include <pthread.h>
 645 int main()
 646 {
 647     pthread_setname_np(\"testname\");
 648     return 0;
 649 }"
 650                 PTHREAD_SETNAME_NP_ONE_PARAM
 651             )
 652             CHECK_C_SOURCE_COMPILES("
 653 #include <pthread.h>
 654 int main()
 655 {
 656     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 657     return 0;
 658 }"
 659                 PTHREAD_SETNAME_NP_THREE_PARAMS
 660             )
 661         ENDIF()
 662         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 663     ENDIF()
 664
 665     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 666
 667     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 668     IF(HAVE_LIBRT)
 669         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 670     ENDIF()
 671 ENDIF()
 672
 673 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 674
 675 # Check for a 64-bit type
 676 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 677 IF(NOT HAVE_STDINT_H)
 678     IF(HAVE_WINDOWS_H)
 679         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 680                                  #include <windows.h>
 681                                  __int64 foo;
 682                                  int main() {return 0;}" HAVE___INT64)
 683     ENDIF()
 684     IF(NOT HAVE___INT64)
 685         IF(NOT SIZEOF_LONG MATCHES "8")
 686             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 687                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 688             ENDIF()
 689         ENDIF()
 690     ENDIF()
 691 ENDIF()
 692
 693
 694 SET(COMMON_OBJS  common/almalloc.c
 695                  common/atomic.c
 696                  common/rwlock.c
 697                  common/threads.c
 698                  common/uintmap.c
 699 )
 700 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 701                  OpenAL32/alBuffer.c
 702                  OpenAL32/alEffect.c
 703                  OpenAL32/alError.c
 704                  OpenAL32/alExtension.c
 705                  OpenAL32/alFilter.c
 706                  OpenAL32/alListener.c
 707                  OpenAL32/alSource.c
 708                  OpenAL32/alState.c
 709                  OpenAL32/alThunk.c
 710                  OpenAL32/sample_cvt.c
 711 )
 712 SET(ALC_OBJS  Alc/ALc.c
 713               Alc/ALu.c
 714               Alc/alcConfig.c
 715               Alc/alcRing.c
 716               Alc/bs2b.c
 717               Alc/converter.c
 718               Alc/mastering.c
 719               Alc/effects/chorus.c
 720               Alc/effects/compressor.c
 721               Alc/effects/dedicated.c
 722               Alc/effects/distortion.c
 723               Alc/effects/echo.c
 724               Alc/effects/equalizer.c
 725               Alc/effects/flanger.c
 726               Alc/effects/modulator.c
 727               Alc/effects/null.c
 728               Alc/effects/reverb.c
 729               Alc/helpers.c
 730               Alc/hrtf.c
 731               Alc/uhjfilter.c
 732               Alc/ambdec.c
 733               Alc/bformatdec.c
 734               Alc/nfcfilter.c
 735               Alc/panning.c
 736               Alc/mixer.c
 737               Alc/mixer_c.c
 738 )
 739
 740
 741 SET(CPU_EXTS "Default")
 742 SET(HAVE_SSE        0)
 743 SET(HAVE_SSE2       0)
 744 SET(HAVE_SSE3       0)
 745 SET(HAVE_SSE4_1     0)
 746 SET(HAVE_NEON       0)
 747
 748 SET(HAVE_ALSA       0)
 749 SET(HAVE_OSS        0)
 750 SET(HAVE_SOLARIS    0)
 751 SET(HAVE_SNDIO      0)
 752 SET(HAVE_QSA        0)
 753 SET(HAVE_DSOUND     0)
 754 SET(HAVE_MMDEVAPI   0)
 755 SET(HAVE_WINMM      0)
 756 SET(HAVE_PORTAUDIO  0)
 757 SET(HAVE_PULSEAUDIO 0)
 758 SET(HAVE_COREAUDIO  0)
 759 SET(HAVE_OPENSL     0)
 760 SET(HAVE_WAVE       0)
 761
 762 # Check for SSE support
 763 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 764 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 765 IF(HAVE_XMMINTRIN_H)
 766     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 767     IF(ALSOFT_CPUEXT_SSE)
 768         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 769             SET(HAVE_SSE 1)
 770             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 771             IF(SSE_SWITCH)
 772                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 773                                             COMPILE_FLAGS "${SSE_SWITCH}")
 774             ENDIF()
 775             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 776         ENDIF()
 777     ENDIF()
 778 ENDIF()
 779 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 780     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 781 ENDIF()
 782
 783 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 784 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 785 IF(HAVE_EMMINTRIN_H)
 786     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 787     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 788         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 789             SET(HAVE_SSE2 1)
 790             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 791             IF(SSE2_SWITCH)
 792                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 793                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 794             ENDIF()
 795             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 796         ENDIF()
 797     ENDIF()
 798 ENDIF()
 799 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 800     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 801 ENDIF()
 802
 803 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 804 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 805 IF(HAVE_EMMINTRIN_H)
 806     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 807     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 808         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 809             SET(HAVE_SSE3 1)
 810             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 811             IF(SSE2_SWITCH)
 812                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 813                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 814             ENDIF()
 815             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 816         ENDIF()
 817     ENDIF()
 818 ENDIF()
 819 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 820     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 821 ENDIF()
 822
 823 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 824 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 825 IF(HAVE_SMMINTRIN_H)
 826     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 827     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 828         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 829             SET(HAVE_SSE4_1 1)
 830             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 831             IF(SSE4_1_SWITCH)
 832                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 833                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 834             ENDIF()
 835             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 836         ENDIF()
 837     ENDIF()
 838 ENDIF()
 839 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 840     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 841 ENDIF()
 842
 843 # Check for ARM Neon support
 844 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 845 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 846 IF(HAVE_ARM_NEON_H)
 847     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 848     IF(ALSOFT_CPUEXT_NEON)
 849         SET(HAVE_NEON 1)
 850         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 851         IF(FPU_NEON_SWITCH)
 852             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 853                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 854         ENDIF()
 855         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 856     ENDIF()
 857 ENDIF()
 858 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 859     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 860 ENDIF()
 861
 862
 863 IF(WIN32 OR HAVE_DLFCN_H)
 864     SET(IS_LINKED "")
 865     MACRO(ADD_BACKEND_LIBS _LIBS)
 866     ENDMACRO()
 867 ELSE()
 868     SET(IS_LINKED " (linked)")
 869     MACRO(ADD_BACKEND_LIBS _LIBS)
 870         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 871     ENDMACRO()
 872 ENDIF()
 873
 874 SET(BACKENDS "")
 875 SET(ALC_OBJS  ${ALC_OBJS}
 876               Alc/backends/base.c
 877               # Default backends, always available
 878               Alc/backends/loopback.c
 879               Alc/backends/null.c
 880 )
 881
 882 # Check ALSA backend
 883 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 884 FIND_PACKAGE(ALSA)
 885 IF(ALSA_FOUND)
 886     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 887     IF(ALSOFT_BACKEND_ALSA)
 888         SET(HAVE_ALSA 1)
 889         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 890         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 891         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 892     ENDIF()
 893 ENDIF()
 894 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 895     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 896 ENDIF()
 897
 898 # Check OSS backend
 899 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 900 FIND_PACKAGE(OSS)
 901 IF(OSS_FOUND)
 902     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 903     IF(ALSOFT_BACKEND_OSS)
 904         SET(HAVE_OSS 1)
 905         SET(BACKENDS  "${BACKENDS} OSS,")
 906         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 907         IF(OSS_LIBRARIES)
 908             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 909         ENDIF()
 910     ENDIF()
 911 ENDIF()
 912 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 913     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 914 ENDIF()
 915
 916 # Check Solaris backend
 917 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 918 FIND_PACKAGE(AudioIO)
 919 IF(AUDIOIO_FOUND)
 920     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 921     IF(ALSOFT_BACKEND_SOLARIS)
 922         SET(HAVE_SOLARIS 1)
 923         SET(BACKENDS  "${BACKENDS} Solaris,")
 924         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 925     ENDIF()
 926 ENDIF()
 927 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 928     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 929 ENDIF()
 930
 931 # Check SndIO backend
 932 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 933 FIND_PACKAGE(SoundIO)
 934 IF(SOUNDIO_FOUND)
 935     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 936     IF(ALSOFT_BACKEND_SNDIO)
 937         SET(HAVE_SNDIO 1)
 938         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 939         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 940         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 941     ENDIF()
 942 ENDIF()
 943 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 944     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 945 ENDIF()
 946
 947 # Check QSA backend
 948 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 949 FIND_PACKAGE(QSA)
 950 IF(QSA_FOUND)
 951     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 952     IF(ALSOFT_BACKEND_QSA)
 953         SET(HAVE_QSA 1)
 954         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 955         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 956         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 957     ENDIF()
 958 ENDIF()
 959 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 960     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 961 ENDIF()
 962
 963 # Check Windows-only backends
 964 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 965 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 966 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 967 IF(HAVE_WINDOWS_H)
 968     # Check MMSystem backend
 969     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 970     IF(HAVE_MMSYSTEM_H)
 971         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 972         IF(HAVE_LIBWINMM)
 973             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 974             IF(ALSOFT_BACKEND_WINMM)
 975                 SET(HAVE_WINMM 1)
 976                 SET(BACKENDS  "${BACKENDS} WinMM,")
 977                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 978                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 979             ENDIF()
 980         ENDIF()
 981     ENDIF()
 982
 983     # Check DSound backend
 984     FIND_PACKAGE(DSound)
 985     IF(DSOUND_FOUND)
 986         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 987         IF(ALSOFT_BACKEND_DSOUND)
 988             SET(HAVE_DSOUND 1)
 989             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 990             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 991             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 992         ENDIF()
 993     ENDIF()
 994
 995     # Check for MMDevApi backend
 996     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 997     IF(HAVE_MMDEVICEAPI_H)
 998         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 999         IF(ALSOFT_BACKEND_MMDEVAPI)
1000             SET(HAVE_MMDEVAPI 1)
1001             SET(BACKENDS  "${BACKENDS} MMDevApi,")
1002             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
1003         ENDIF()
1004     ENDIF()
1005 ENDIF()
1006 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1007     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1008 ENDIF()
1009 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1010     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1011 ENDIF()
1012 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
1013     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
1014 ENDIF()
1015
1016 # Check PortAudio backend
1017 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1018 FIND_PACKAGE(PortAudio)
1019 IF(PORTAUDIO_FOUND)
1020     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1021     IF(ALSOFT_BACKEND_PORTAUDIO)
1022         SET(HAVE_PORTAUDIO 1)
1023         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1024         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1025         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1026     ENDIF()
1027 ENDIF()
1028 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1029     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1030 ENDIF()
1031
1032 # Check PulseAudio backend
1033 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1034 FIND_PACKAGE(PulseAudio)
1035 IF(PULSEAUDIO_FOUND)
1036     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1037     IF(ALSOFT_BACKEND_PULSEAUDIO)
1038         SET(HAVE_PULSEAUDIO 1)
1039         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1040         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1041         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1042     ENDIF()
1043 ENDIF()
1044 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1045     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1046 ENDIF()
1047
1048 # Check JACK backend
1049 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1050 FIND_PACKAGE(JACK)
1051 IF(JACK_FOUND)
1052     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1053     IF(ALSOFT_BACKEND_JACK)
1054         SET(HAVE_JACK 1)
1055         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1056         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1057         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1058     ENDIF()
1059 ENDIF()
1060 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1061     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1062 ENDIF()
1063
1064 # Check CoreAudio backend
1065 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1066 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1067              NAMES CoreAudio
1068              PATHS /System/Library/Frameworks
1069 )
1070 IF(COREAUDIO_FRAMEWORK)
1071     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1072     IF(ALSOFT_BACKEND_COREAUDIO)
1073         SET(HAVE_COREAUDIO 1)
1074         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1075         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1076         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1077         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1078         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1079
1080         # Some versions of OSX may need the AudioToolbox framework. Add it if
1081         # it's found.
1082         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1083                      NAMES AudioToolbox
1084                      PATHS ~/Library/Frameworks
1085                            /Library/Frameworks
1086                            /System/Library/Frameworks
1087                     )
1088         IF(AUDIOTOOLBOX_LIBRARY)
1089             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1090         ENDIF()
1091     ENDIF()
1092 ENDIF()
1093 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1094     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1095 ENDIF()
1096
1097 # Check for OpenSL (Android) backend
1098 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1099 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1100 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1101     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1102     IF(HAVE_LIBOPENSLES)
1103         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1104         IF(ALSOFT_BACKEND_OPENSL)
1105             SET(HAVE_OPENSL 1)
1106             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1107             SET(BACKENDS  "${BACKENDS} OpenSL,")
1108             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1109         ENDIF()
1110     ENDIF()
1111 ENDIF()
1112 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1113     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1114 ENDIF()
1115
1116 # Optionally enable the Wave Writer backend
1117 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1118 IF(ALSOFT_BACKEND_WAVE)
1119     SET(HAVE_WAVE 1)
1120     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1121     SET(BACKENDS  "${BACKENDS} WaveFile,")
1122 ENDIF()
1123
1124 # This is always available
1125 SET(BACKENDS  "${BACKENDS} Null")
1126
1127
1128 FIND_PACKAGE(Git)
1129 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1130     # Get the current working branch and its latest abbreviated commit hash
1131     ADD_CUSTOM_TARGET(build_version
1132         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1133                          -D LIB_VERSION=${LIB_VERSION}
1134                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1135                          -D DST=${OpenAL_BINARY_DIR}/version.h
1136                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1137         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1138         VERBATIM
1139     )
1140 ELSE()
1141     SET(GIT_BRANCH "UNKNOWN")
1142     SET(GIT_COMMIT_HASH "unknown")
1143     CONFIGURE_FILE(
1144         "${OpenAL_SOURCE_DIR}/version.h.in"
1145         "${OpenAL_BINARY_DIR}/version.h")
1146 ENDIF()
1147
1148 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1149 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1150 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1151
1152 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1153 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1154 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1155     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1156     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1157     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1158     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1159     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1160     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1161                      C "${NATIVE_SRC_DIR}bsincgen.c"
1162     VERBATIM
1163 )
1164 ADD_CUSTOM_TARGET(native-tools
1165     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1166     VERBATIM
1167 )
1168
1169 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1170 if(ALSOFT_EMBED_HRTF_DATA)
1171     MACRO(make_hrtf_header FILENAME VARNAME)
1172         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1173         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1174
1175         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1176             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1177             DEPENDS native-tools "${infile}"
1178             VERBATIM
1179         )
1180         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1181     ENDMACRO()
1182
1183     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1184     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1185 endif()
1186
1187 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1188     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1189     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1190     VERBATIM
1191 )
1192 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1193
1194
1195 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1196     add_subdirectory(utils/alsoft-config)
1197 ENDIF()
1198 IF(ALSOFT_EXAMPLES)
1199     FIND_PACKAGE(SDL2)
1200     IF(SDL2_FOUND)
1201         FIND_PACKAGE(SDL_sound)
1202         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1203     ENDIF()
1204 ENDIF()
1205
1206 IF(LIBTYPE STREQUAL "STATIC")
1207     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1208     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1209 ENDIF()
1210
1211 IF(NOT WIN32)
1212     SET(LIBNAME "openal")
1213 ELSE()
1214     SET(LIBNAME "OpenAL32")
1215 ENDIF()
1216
1217 # Needed for openal.pc.in
1218 SET(prefix ${CMAKE_INSTALL_PREFIX})
1219 SET(exec_prefix "\${prefix}")
1220 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1221 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1222 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1223 SET(PACKAGE_VERSION "${LIB_VERSION}")
1224
1225 # End configuration
1226 CONFIGURE_FILE(
1227     "${OpenAL_SOURCE_DIR}/config.h.in"
1228     "${OpenAL_BINARY_DIR}/config.h")
1229 CONFIGURE_FILE(
1230     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1231     "${OpenAL_BINARY_DIR}/openal.pc"
1232     @ONLY)
1233
1234 MACRO(ADD_INCLUDE_DIRS TRGT TESTVAR INCVAR)
1235     IF(${TESTVAR})
1236         SET_PROPERTY(TARGET ${TRGT} APPEND PROPERTY INCLUDE_DIRECTORIES ${${INCVAR}})
1237     ENDIF()
1238 ENDMACRO()
1239
1240 UNSET(HAS_ROUTER)
1241 SET(IMPL_TARGET OpenAL)
1242
1243 # Build main library
1244 IF(LIBTYPE STREQUAL "STATIC")
1245     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1246 ELSE()
1247     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1248         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c ${COMMON_OBJS})
1249         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1250         SET_PROPERTY(TARGET OpenAL APPEND PROPERTY
1251             COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1252         )
1253         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1254         IF(MSVC)
1255             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1256         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1257             SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1258         ENDIF()
1259         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1260         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1261         IF(TARGET build_version)
1262             ADD_DEPENDENCIES(OpenAL build_version)
1263         ENDIF()
1264         SET(HAS_ROUTER 1)
1265
1266         SET(LIBNAME "soft_oal")
1267         SET(IMPL_TARGET soft_oal)
1268     ENDIF()
1269
1270     ADD_LIBRARY(${IMPL_TARGET} SHARED ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1271     IF(WIN32)
1272         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1273     ENDIF()
1274 ENDIF()
1275 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1276     VERSION ${LIB_VERSION}
1277     SOVERSION ${LIB_MAJOR_VERSION}
1278 )
1279 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY INCLUDE_DIRECTORIES
1280     "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc"
1281 )
1282 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_ALSA       ALSA_INCLUDE_DIRS)
1283 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_OSS        OSS_INCLUDE_DIRS)
1284 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SOLARIS    AUDIOIO_INCLUDE_DIRS)
1285 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_SNDIO      SOUNDIO_INCLUDE_DIRS)
1286 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_QSA        QSA_INCLUDE_DIRS)
1287 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_DSOUND     DSOUND_INCLUDE_DIRS)
1288 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PORTAUDIO  PORTAUDIO_INCLUDE_DIRS)
1289 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_PULSEAUDIO PULSEAUDIO_INCLUDE_DIRS)
1290 ADD_INCLUDE_DIRS(${IMPL_TARGET} HAVE_JACK       JACK_INCLUDE_DIRS)
1291 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY
1292     COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES
1293 )
1294 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1295     SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1296 ENDIF()
1297 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1298 SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS ${EXTRA_LDFLAGS})
1299
1300 TARGET_LINK_LIBRARIES(${IMPL_TARGET} ${EXTRA_LIBS})
1301 IF(TARGET build_version)
1302     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1303 ENDIF()
1304
1305 IF(WIN32)
1306     IF(MSVC)
1307         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " /SUBSYSTEM:WINDOWS")
1308     ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1309         SET_PROPERTY(TARGET ${IMPL_TARGET} APPEND_STRING PROPERTY LINK_FLAGS " -mwindows")
1310     ENDIF()
1311
1312     if(NOT LIBTYPE STREQUAL "STATIC")
1313         IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1314             FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1315             FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1316             IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1317                 MESSAGE(STATUS "")
1318                 IF(NOT SED_EXECUTABLE)
1319                     MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1320                 ENDIF()
1321                 IF(NOT DLLTOOL_EXECUTABLE)
1322                     MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1323                 ENDIF()
1324             ELSE()
1325                 SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1326                              " -Wl,--output-def,OpenAL32.def")
1327                 ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1328                     COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1329                     COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1330                     COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1331                     VERBATIM
1332                 )
1333             ENDIF()
1334         ENDIF()
1335     ENDIF()
1336 ENDIF()
1337
1338 IF(ALSOFT_INSTALL)
1339     INSTALL(TARGETS OpenAL EXPORT OpenAL
1340             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1341             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1342             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1343             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1344     )
1345     EXPORT(TARGETS OpenAL
1346            NAMESPACE OpenAL::
1347            FILE OpenALConfig.cmake)
1348     INSTALL(EXPORT OpenAL
1349             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1350             NAMESPACE OpenAL::
1351             FILE OpenALConfig.cmake)
1352     INSTALL(FILES include/AL/al.h
1353                   include/AL/alc.h
1354                   include/AL/alext.h
1355                   include/AL/efx.h
1356                   include/AL/efx-creative.h
1357                   include/AL/efx-presets.h
1358             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1359     )
1360     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1361             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1362     IF(TARGET soft_oal)
1363         INSTALL(TARGETS soft_oal
1364                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1365         )
1366     ENDIF()
1367 ENDIF()
1368
1369
1370 if(HAS_ROUTER)
1371     message(STATUS "")
1372     message(STATUS "Building DLL router")
1373 endif()
1374
1375 MESSAGE(STATUS "")
1376 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1377 MESSAGE(STATUS "    ${BACKENDS}")
1378 MESSAGE(STATUS "")
1379 MESSAGE(STATUS "Building with support for CPU extensions:")
1380 MESSAGE(STATUS "    ${CPU_EXTS}")
1381 MESSAGE(STATUS "")
1382
1383 IF(WIN32)
1384     IF(NOT HAVE_DSOUND)
1385         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1386         MESSAGE(STATUS "         This is probably NOT what you want!")
1387         MESSAGE(STATUS "")
1388     ENDIF()
1389 ENDIF()
1390
1391 if(ALSOFT_EMBED_HRTF_DATA)
1392     message(STATUS "Embedding HRTF datasets")
1393     message(STATUS "")
1394 endif()
1395
1396 # Install alsoft.conf configuration file
1397 IF(ALSOFT_CONFIG)
1398     INSTALL(FILES alsoftrc.sample
1399             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1400     )
1401     MESSAGE(STATUS "Installing sample configuration")
1402     MESSAGE(STATUS "")
1403 ENDIF()
1404
1405 # Install HRTF definitions
1406 IF(ALSOFT_HRTF_DEFS)
1407     INSTALL(FILES hrtf/default-44100.mhr
1408                   hrtf/default-48000.mhr
1409             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1410     )
1411     MESSAGE(STATUS "Installing HRTF definitions")
1412     MESSAGE(STATUS "")
1413 ENDIF()
1414
1415 # Install AmbDec presets
1416 IF(ALSOFT_AMBDEC_PRESETS)
1417     INSTALL(FILES presets/3D7.1.ambdec
1418                   presets/hexagon.ambdec
1419                   presets/itu5.1.ambdec
1420                   presets/itu5.1-nocenter.ambdec
1421                   presets/rectangle.ambdec
1422                   presets/square.ambdec
1423                   presets/presets.txt
1424             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1425     )
1426     MESSAGE(STATUS "Installing AmbDec presets")
1427     MESSAGE(STATUS "")
1428 ENDIF()
1429
1430 IF(ALSOFT_UTILS)
1431     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1432     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1433     TARGET_LINK_LIBRARIES(openal-info OpenAL)
1434
1435     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1436     IF(NOT HAVE_GETOPT)
1437         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c)
1438     ENDIF()
1439     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1440     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1441     IF(HAVE_LIBM)
1442         TARGET_LINK_LIBRARIES(makehrtf m)
1443     ENDIF()
1444
1445     IF(ALSOFT_INSTALL)
1446         INSTALL(TARGETS openal-info makehrtf
1447                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1448                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1449                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1450         )
1451     ENDIF()
1452
1453     MESSAGE(STATUS "Building utility programs")
1454     IF(TARGET alsoft-config)
1455         MESSAGE(STATUS "Building configuration program")
1456     ENDIF()
1457     MESSAGE(STATUS "")
1458 ENDIF()
1459
1460 IF(ALSOFT_TESTS)
1461     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1462
1463     ADD_EXECUTABLE(altonegen examples/altonegen.c ${COMMON_OBJS} ${TEST_COMMON_OBJS})
1464     TARGET_LINK_LIBRARIES(altonegen OpenAL)
1465     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1466
1467     IF(ALSOFT_INSTALL)
1468         INSTALL(TARGETS altonegen
1469                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1470                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1471                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1472         )
1473     ENDIF()
1474
1475     MESSAGE(STATUS "Building test programs")
1476     MESSAGE(STATUS "")
1477 ENDIF()
1478
1479 IF(ALSOFT_EXAMPLES)
1480     ADD_EXECUTABLE(alrecord examples/alrecord.c ${COMMON_OBJS})
1481     TARGET_LINK_LIBRARIES(alrecord OpenAL)
1482     SET_PROPERTY(TARGET alrecord APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1483
1484     IF(ALSOFT_INSTALL)
1485         INSTALL(TARGETS alrecord
1486                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1487                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1488                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1489         )
1490     ENDIF()
1491
1492     MESSAGE(STATUS "Building example programs")
1493
1494     IF(SDL2_FOUND)
1495         IF(SDL_SOUND_FOUND)
1496             SET(EX_COMMON_OBJS  examples/common/alhelpers.c)
1497
1498             ADD_EXECUTABLE(alstream examples/alstream.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1499             TARGET_LINK_LIBRARIES(alstream ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1500             SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1501             SET_PROPERTY(TARGET alstream APPEND PROPERTY
1502                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1503             )
1504
1505             ADD_EXECUTABLE(alreverb examples/alreverb.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1506             TARGET_LINK_LIBRARIES(alreverb ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1507             SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1508             SET_PROPERTY(TARGET alreverb APPEND PROPERTY
1509                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1510             )
1511
1512             ADD_EXECUTABLE(allatency examples/allatency.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1513             TARGET_LINK_LIBRARIES(allatency ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1514             SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1515             SET_PROPERTY(TARGET allatency APPEND PROPERTY
1516                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1517             )
1518
1519             ADD_EXECUTABLE(alloopback examples/alloopback.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1520             TARGET_LINK_LIBRARIES(alloopback ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1521             SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1522             SET_PROPERTY(TARGET alloopback APPEND PROPERTY
1523                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1524             )
1525
1526             ADD_EXECUTABLE(alhrtf examples/alhrtf.c ${COMMON_OBJS} ${EX_COMMON_OBJS})
1527             TARGET_LINK_LIBRARIES(alhrtf ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} OpenAL)
1528             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1529             SET_PROPERTY(TARGET alhrtf APPEND PROPERTY
1530                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR}
1531             )
1532
1533             IF(ALSOFT_INSTALL)
1534                 INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1535                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1536                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1537                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1538                 )
1539             ENDIF()
1540
1541             MESSAGE(STATUS "Building SDL_sound example programs")
1542         ENDIF()
1543
1544         SET(FFVER_OK FALSE)
1545         IF(FFMPEG_FOUND)
1546             SET(FFVER_OK TRUE)
1547             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1548                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1549                 SET(FFVER_OK FALSE)
1550             ENDIF()
1551             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1552                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1553                 SET(FFVER_OK FALSE)
1554             ENDIF()
1555             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1556                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1557                 SET(FFVER_OK FALSE)
1558             ENDIF()
1559             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1560                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1561                 SET(FFVER_OK FALSE)
1562             ENDIF()
1563             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1564                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1565                 SET(FFVER_OK FALSE)
1566             ENDIF()
1567         ENDIF()
1568         IF(FFVER_OK)
1569             ADD_EXECUTABLE(alffplay examples/alffplay.cpp ${COMMON_OBJS})
1570             TARGET_LINK_LIBRARIES(alffplay ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} OpenAL)
1571             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1572             SET_PROPERTY(TARGET alffplay APPEND PROPERTY
1573                 INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS}
1574             )
1575
1576             IF(ALSOFT_INSTALL)
1577                 INSTALL(TARGETS alffplay
1578                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1579                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1580                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1581                 )
1582             ENDIF()
1583             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1584         ENDIF()
1585         MESSAGE(STATUS "")
1586     ENDIF()
1587 ENDIF()