CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.5)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0042)
  11         CMAKE_POLICY(SET CMP0042 NEW)
  12     ENDIF(POLICY CMP0042)
  13 ENDIF(COMMAND CMAKE_POLICY)
  14
  15 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  16
  17 INCLUDE(CheckFunctionExists)
  18 INCLUDE(CheckLibraryExists)
  19 INCLUDE(CheckSharedFunctionExists)
  20 INCLUDE(CheckIncludeFile)
  21 INCLUDE(CheckIncludeFiles)
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCCompilerFlag)
  24 INCLUDE(CheckCSourceCompiles)
  25 INCLUDE(CheckTypeSize)
  26 include(CheckFileOffsetBits)
  27 include(GNUInstallDirs)
  28
  29
  30 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  31
  32
  33 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  34
  35 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  36
  37 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  38 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  39
  40 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  41 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  42
  43 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  44 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  45 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  46 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  47
  48 if(DEFINED SHARE_INSTALL_DIR)
  49     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  50     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  51 endif()
  52
  53 if(DEFINED LIB_SUFFIX)
  54     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  55 endif()
  56
  57
  58 IF(NOT WIN32)
  59     SET(LIBNAME openal)
  60 ELSE()
  61     SET(LIBNAME OpenAL32)
  62     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  63
  64     # This option is mainly for static linking OpenAL Soft into another project
  65     # that already defines the IDs. It is up to that project to ensure all
  66     # required IDs are defined.
  67     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  68
  69     IF(MINGW)
  70         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  71         IF(NOT DLLTOOL)
  72             IF(HOST)
  73                 SET(DLLTOOL "${HOST}-dlltool")
  74             ELSE()
  75                 SET(DLLTOOL "dlltool")
  76             ENDIF()
  77         ENDIF()
  78     ENDIF()
  79 ENDIF()
  80
  81
  82 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  83 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  84     ADD_DEFINITIONS("-I/usr/include")
  85     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  86 ENDIF()
  87
  88 IF(NOT LIBTYPE)
  89     SET(LIBTYPE SHARED)
  90 ENDIF()
  91
  92 SET(LIB_MAJOR_VERSION "1")
  93 SET(LIB_MINOR_VERSION "17")
  94 SET(LIB_REVISION "2")
  95 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  96
  97 SET(EXPORT_DECL "")
  98 SET(ALIGN_DECL "")
  99
 100
 101 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 102 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 103
 104
 105 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 106 IF(HAVE_STD_C11)
 107     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 108 ELSE()
 109     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 110     IF(HAVE_STD_C99)
 111         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 112     ENDIF()
 113 ENDIF()
 114
 115 if(NOT WIN32)
 116     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 117     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 118     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 119         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 120         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=500")
 121         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 122         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 123             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 124         ELSE()
 125             ADD_DEFINITIONS(-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=500)
 126         ENDIF()
 127     ENDIF()
 128     UNSET(OLD_REQUIRED_FLAGS)
 129 ENDIF()
 130
 131 # Set defines for large file support
 132 CHECK_FILE_OFFSET_BITS()
 133 IF(_FILE_OFFSET_BITS)
 134     ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS})
 135     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 136 ENDIF()
 137 ADD_DEFINITIONS(-D_LARGEFILE_SOURCE -D_LARGE_FILES)
 138 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 139
 140 # MSVC may need workarounds for C99 restrict and inline
 141 IF(MSVC)
 142     # TODO: Once we truly require C99, these restrict and inline checks should go
 143     # away.
 144     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 145                              int main() {return 0;}" HAVE_RESTRICT)
 146     IF(NOT HAVE_RESTRICT)
 147         ADD_DEFINITIONS("-Drestrict=")
 148         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 149     ENDIF()
 150
 151     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 152                              int main() {return 0;}" HAVE_INLINE)
 153     IF(NOT HAVE_INLINE)
 154         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 155                                  int main() {return 0;}" HAVE___INLINE)
 156         IF(NOT HAVE___INLINE)
 157             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 158         ENDIF()
 159
 160         ADD_DEFINITIONS(-Dinline=__inline)
 161         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 162     ENDIF()
 163 ENDIF()
 164
 165 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 166 IF(CMAKE_COMPILER_IS_GNUCC)
 167     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 168     # Force no inlining for the next test.
 169     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 170
 171     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 172                              int main() {return foo();}" INLINE_IS_C99)
 173     IF(NOT INLINE_IS_C99)
 174         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 175                              Please update your compiler for better C99 compliance.")
 176     ENDIF()
 177
 178     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 179 ENDIF()
 180
 181 # Some systems may need libatomic for C11 atomic functions to work
 182 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 183 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 184 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 185 int _Atomic foo = ATOMIC_VAR_INIT(0);
 186 int main()
 187 {
 188     return atomic_fetch_add(&foo, 2);
 189 }"
 190 HAVE_LIBATOMIC)
 191 IF(NOT HAVE_LIBATOMIC)
 192     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 193 ELSE()
 194     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 195 ENDIF()
 196 UNSET(OLD_REQUIRED_LIBRARIES)
 197
 198 # Check if we have C99 variable length arrays
 199 CHECK_C_SOURCE_COMPILES(
 200 "int main(int argc, char *argv[])
 201  {
 202      volatile int tmp[argc];
 203      tmp[0] = argv[0][0];
 204      return tmp[0];
 205  }"
 206 HAVE_C99_VLA)
 207
 208 # Check if we have C99 bool
 209 CHECK_C_SOURCE_COMPILES(
 210 "int main(int argc, char *argv[])
 211  {
 212      volatile _Bool ret;
 213      ret = (argc > 1) ? 1 : 0;
 214      return ret ? -1 : 0;
 215  }"
 216 HAVE_C99_BOOL)
 217
 218 # Check if we have C11 static_assert
 219 CHECK_C_SOURCE_COMPILES(
 220 "int main()
 221  {
 222      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 223      return 0;
 224  }"
 225 HAVE_C11_STATIC_ASSERT)
 226
 227 # Check if we have C11 alignas
 228 CHECK_C_SOURCE_COMPILES(
 229 "_Alignas(16) int foo;
 230  int main()
 231  {
 232      return 0;
 233  }"
 234 HAVE_C11_ALIGNAS)
 235
 236 # Check if we have C11 _Atomic
 237 CHECK_C_SOURCE_COMPILES(
 238 "#include <stdatomic.h>
 239  const int _Atomic foo = ATOMIC_VAR_INIT(~0);
 240  int _Atomic bar = ATOMIC_VAR_INIT(0);
 241  int main()
 242  {
 243      atomic_fetch_add(&bar, 2);
 244      return atomic_load(&foo);
 245  }"
 246 HAVE_C11_ATOMIC)
 247
 248 # Add definitions, compiler switches, etc.
 249 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 250 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 251     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 252     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 253         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 254     ENDIF()
 255 ENDIF()
 256
 257 IF(NOT CMAKE_BUILD_TYPE)
 258     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 259         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 260         FORCE)
 261 ENDIF()
 262 IF(NOT CMAKE_DEBUG_POSTFIX)
 263     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 264         "Library postfix for debug builds. Normally left blank."
 265         FORCE)
 266 ENDIF()
 267
 268 SET(EXTRA_CFLAGS "")
 269 IF(MSVC)
 270     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 271     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 272     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} /wd4098")
 273
 274     IF(NOT DXSDK_DIR)
 275         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 276     ELSE()
 277         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 278     ENDIF()
 279     IF(DXSDK_DIR)
 280         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 281     ENDIF()
 282
 283     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 284     IF(FORCE_STATIC_VCRT)
 285         FOREACH(flag_var
 286                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 287                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 288             IF(${flag_var} MATCHES "/MD")
 289                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 290             ENDIF()
 291         ENDFOREACH(flag_var)
 292     ENDIF()
 293 ELSE()
 294     SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Winline -Wall")
 295     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 296     IF(HAVE_W_EXTRA)
 297         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wextra")
 298     ENDIF()
 299
 300     IF(ALSOFT_WERROR)
 301         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
 302     ENDIF()
 303
 304     # Force enable -fPIC for CMake versions before 2.8.9 (later versions have
 305     # the POSITION_INDEPENDENT_CODE target property). The static common library
 306     # will be linked into the dynamic openal library, which requires all its
 307     # code to be position-independent.
 308     IF(CMAKE_VERSION VERSION_LESS "2.8.9" AND NOT WIN32)
 309         CHECK_C_COMPILER_FLAG(-fPIC HAVE_FPIC_SWITCH)
 310         IF(HAVE_FPIC_SWITCH)
 311             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fPIC")
 312         ENDIF()
 313     ENDIF()
 314
 315     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 316     # instead of NDEBUG)
 317     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 318         IF(${flag_var} MATCHES "-DNDEBUG")
 319             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 320         ENDIF()
 321     ENDFOREACH()
 322
 323     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 324                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 325
 326     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 327     if(ALSOFT_STATIC_LIBGCC)
 328         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 329         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 330         check_c_source_compiles(
 331 "#include <stdlib.h>
 332 int main()
 333 {
 334     return 0;
 335 }"
 336             HAVE_STATIC_LIBGCC_SWITCH
 337         )
 338         if(HAVE_STATIC_LIBGCC_SWITCH)
 339             set(EXTRA_LIBS ${EXTRA_LIBS} -static-libgcc)
 340         endif()
 341         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 342         unset(OLD_REQUIRED_LIBRARIES)
 343     endif()
 344 ENDIF()
 345
 346 # Set visibility/export options if available
 347 SET(HIDDEN_DECL "")
 348 IF(WIN32)
 349     SET(EXPORT_DECL "__declspec(dllexport)")
 350     IF(NOT MINGW)
 351         SET(ALIGN_DECL "__declspec(align(x))")
 352     ELSE()
 353         SET(ALIGN_DECL "__declspec(aligned(x))")
 354     ENDIF()
 355 ELSE()
 356     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 357     # Yes GCC, really don't accept visibility modes you don't support
 358     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 359
 360     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 361                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 362     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 363         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 364     ELSE()
 365         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 366                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 367         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 368             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 369         ENDIF()
 370     ENDIF()
 371
 372     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 373         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 374         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 375             SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
 376             SET(HIDDEN_DECL "__attribute__((visibility(\"hidden\")))")
 377         ENDIF()
 378     ENDIF()
 379
 380     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 381                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 382     IF(HAVE_ATTRIBUTE_ALIGNED)
 383         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 384     ENDIF()
 385
 386     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 387 ENDIF()
 388
 389 SET(SSE_SWITCH "")
 390 SET(SSE2_SWITCH "")
 391 SET(SSE3_SWITCH "")
 392 SET(SSE4_1_SWITCH "")
 393 SET(FPU_NEON_SWITCH "")
 394 IF(NOT MSVC)
 395     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 396     IF(HAVE_MSSE_SWITCH)
 397         SET(SSE_SWITCH "-msse")
 398     ENDIF()
 399     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 400     IF(HAVE_MSSE2_SWITCH)
 401         SET(SSE2_SWITCH "-msse2")
 402     ENDIF()
 403     CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 404     IF(HAVE_MSSE3_SWITCH)
 405         SET(SSE3_SWITCH "-msse3")
 406     ENDIF()
 407     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 408     IF(HAVE_MSSE4_1_SWITCH)
 409         SET(SSE4_1_SWITCH "-msse4.1")
 410     ENDIF()
 411     CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 412     IF(HAVE_MFPU_NEON_SWITCH)
 413         SET(FPU_NEON_SWITCH "-mfpu=neon")
 414     ENDIF()
 415 ENDIF()
 416
 417 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 418                          int main() {return 0;}" HAVE_GCC_FORMAT)
 419
 420 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 421 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 422 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 423 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 424 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 425 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 426 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 427 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 428 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 429 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 430 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 431 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 432 IF(NOT HAVE_GUIDDEF_H)
 433     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 434 ENDIF()
 435
 436 # Some systems need libm for some of the following math functions to work
 437 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 438 IF(HAVE_LIBM)
 439     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 440     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 441 ENDIF()
 442
 443 # Check for the dlopen API (for dynamicly loading backend libs)
 444 IF(ALSOFT_DLOPEN)
 445     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 446     IF(HAVE_LIBDL)
 447         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 448         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 449     ENDIF()
 450
 451     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 452 ENDIF()
 453
 454 # Check for a cpuid intrinsic
 455 IF(HAVE_CPUID_H)
 456     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 457         int main()
 458         {
 459             unsigned int eax, ebx, ecx, edx;
 460             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 461         }" HAVE_GCC_GET_CPUID)
 462 ENDIF()
 463 IF(HAVE_INTRIN_H)
 464     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 465         int main()
 466         {
 467             int regs[4];
 468             __cpuid(regs, 0);
 469             return regs[0];
 470         }" HAVE_CPUID_INTRINSIC)
 471 ENDIF()
 472
 473 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 474 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 475 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 476 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 477 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 478 IF(NOT HAVE_C99_VLA)
 479     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 480     IF(NOT HAVE_ALLOCA)
 481         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 482     ENDIF()
 483 ENDIF()
 484
 485 IF(HAVE_FLOAT_H)
 486     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 487     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 488 ENDIF()
 489
 490 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 491 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 492 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 493 IF(NOT HAVE_STRCASECMP)
 494     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 495     IF(NOT HAVE__STRICMP)
 496         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 497     ENDIF()
 498
 499     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 500 ENDIF()
 501
 502 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 503 IF(NOT HAVE_STRNCASECMP)
 504     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 505     IF(NOT HAVE__STRNICMP)
 506         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 507     ENDIF()
 508
 509     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 510 ENDIF()
 511
 512 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 513 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 514 IF(NOT HAVE_SNPRINTF)
 515     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 516     IF(NOT HAVE__SNPRINTF)
 517         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 518     ENDIF()
 519
 520     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 521 ENDIF()
 522
 523 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 524 IF(NOT HAVE_ISFINITE)
 525     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 526     IF(NOT HAVE_FINITE)
 527         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 528         IF(NOT HAVE__FINITE)
 529             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 530         ENDIF()
 531         ADD_DEFINITIONS(-Disfinite=_finite)
 532     ELSE()
 533         ADD_DEFINITIONS(-Disfinite=finite)
 534     ENDIF()
 535 ENDIF()
 536
 537 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 538 IF(NOT HAVE_ISNAN)
 539     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 540     IF(NOT HAVE__ISNAN)
 541         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 542     ENDIF()
 543
 544     ADD_DEFINITIONS(-Disnan=_isnan)
 545 ENDIF()
 546
 547
 548 # Check if we have Windows headers
 549 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 550 IF(NOT HAVE_WINDOWS_H)
 551     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 552     IF(NOT HAVE_GETTIMEOFDAY)
 553         MESSAGE(FATAL_ERROR "No timing function found!")
 554     ENDIF()
 555
 556     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 557     IF(NOT HAVE_NANOSLEEP)
 558         MESSAGE(FATAL_ERROR "No sleep function found!")
 559     ENDIF()
 560
 561     # We need pthreads outside of Windows
 562     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 563     IF(NOT HAVE_PTHREAD_H)
 564         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 565     ENDIF()
 566     # Some systems need pthread_np.h to get recursive mutexes
 567     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 568
 569     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 570     IF(HAVE_PTHREAD)
 571         SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -pthread")
 572         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 573         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 574     ENDIF()
 575
 576     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 577     IF(HAVE_LIBPTHREAD)
 578         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 579     ENDIF()
 580
 581     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 582
 583     IF(HAVE_PTHREAD_NP_H)
 584         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 585         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 586             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 587         ELSE()
 588             CHECK_C_SOURCE_COMPILES("
 589 #include <pthread.h>
 590 #include <pthread_np.h>
 591 int main()
 592 {
 593     pthread_setname_np(\"testname\");
 594     return 0;
 595 }"
 596                 PTHREAD_SETNAME_NP_ONE_PARAM
 597             )
 598         ENDIF()
 599         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 600     ELSE()
 601         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 602         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 603             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 604         ELSE()
 605             CHECK_C_SOURCE_COMPILES("
 606 #include <pthread.h>
 607 int main()
 608 {
 609     pthread_setname_np(\"testname\");
 610     return 0;
 611 }"
 612                 PTHREAD_SETNAME_NP_ONE_PARAM
 613             )
 614         ENDIF()
 615         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 616     ENDIF()
 617
 618     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 619
 620     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 621     IF(HAVE_LIBRT)
 622         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 623     ENDIF()
 624 ENDIF()
 625
 626 # Check for a 64-bit type
 627 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 628 IF(NOT HAVE_STDINT_H)
 629     IF(HAVE_WINDOWS_H)
 630         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 631                                  #include <windows.h>
 632                                  __int64 foo;
 633                                  int main() {return 0;}" HAVE___INT64)
 634     ENDIF()
 635     IF(NOT HAVE___INT64)
 636         IF(NOT SIZEOF_LONG MATCHES "8")
 637             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 638                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 639             ENDIF()
 640         ENDIF()
 641     ENDIF()
 642 ENDIF()
 643
 644
 645 SET(COMMON_OBJS  common/almalloc.c
 646                  common/atomic.c
 647                  common/rwlock.c
 648                  common/threads.c
 649                  common/uintmap.c
 650 )
 651 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 652                  OpenAL32/alBuffer.c
 653                  OpenAL32/alEffect.c
 654                  OpenAL32/alError.c
 655                  OpenAL32/alExtension.c
 656                  OpenAL32/alFilter.c
 657                  OpenAL32/alListener.c
 658                  OpenAL32/alSource.c
 659                  OpenAL32/alState.c
 660                  OpenAL32/alThunk.c
 661                  OpenAL32/sample_cvt.c
 662 )
 663 SET(ALC_OBJS  Alc/ALc.c
 664               Alc/ALu.c
 665               Alc/alcConfig.c
 666               Alc/alcRing.c
 667               Alc/bs2b.c
 668               Alc/effects/chorus.c
 669               Alc/effects/compressor.c
 670               Alc/effects/dedicated.c
 671               Alc/effects/distortion.c
 672               Alc/effects/echo.c
 673               Alc/effects/equalizer.c
 674               Alc/effects/flanger.c
 675               Alc/effects/modulator.c
 676               Alc/effects/null.c
 677               Alc/effects/reverb.c
 678               Alc/helpers.c
 679               Alc/bsinc.c
 680               Alc/hrtf.c
 681               Alc/uhjfilter.c
 682               Alc/ambdec.c
 683               Alc/bformatdec.c
 684               Alc/panning.c
 685               Alc/mixer.c
 686               Alc/mixer_c.c
 687 )
 688
 689
 690 SET(CPU_EXTS "Default")
 691 SET(HAVE_SSE        0)
 692 SET(HAVE_SSE2       0)
 693 SET(HAVE_SSE3       0)
 694 SET(HAVE_SSE4_1     0)
 695 SET(HAVE_NEON       0)
 696
 697 SET(HAVE_ALSA       0)
 698 SET(HAVE_OSS        0)
 699 SET(HAVE_SOLARIS    0)
 700 SET(HAVE_SNDIO      0)
 701 SET(HAVE_QSA        0)
 702 SET(HAVE_DSOUND     0)
 703 SET(HAVE_MMDEVAPI   0)
 704 SET(HAVE_WINMM      0)
 705 SET(HAVE_PORTAUDIO  0)
 706 SET(HAVE_PULSEAUDIO 0)
 707 SET(HAVE_COREAUDIO  0)
 708 SET(HAVE_OPENSL     0)
 709 SET(HAVE_WAVE       0)
 710
 711 # Check for SSE support
 712 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 713 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 714 IF(HAVE_XMMINTRIN_H)
 715     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 716     IF(ALSOFT_CPUEXT_SSE)
 717         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 718             SET(HAVE_SSE 1)
 719             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 720             IF(SSE_SWITCH)
 721                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 722                                             COMPILE_FLAGS "${SSE_SWITCH}")
 723             ENDIF()
 724             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 725         ENDIF()
 726     ENDIF()
 727 ENDIF()
 728 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 729     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 730 ENDIF()
 731
 732 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 733 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 734 IF(HAVE_EMMINTRIN_H)
 735     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 736     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 737         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 738             SET(HAVE_SSE2 1)
 739             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 740             IF(SSE2_SWITCH)
 741                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 742                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 743             ENDIF()
 744             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 745         ENDIF()
 746     ENDIF()
 747 ENDIF()
 748 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 749     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 750 ENDIF()
 751
 752 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 753 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 754 IF(HAVE_EMMINTRIN_H)
 755     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 756     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 757         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 758             SET(HAVE_SSE3 1)
 759             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse3.c)
 760             IF(SSE2_SWITCH)
 761                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse3.c PROPERTIES
 762                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 763             ENDIF()
 764             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 765         ENDIF()
 766     ENDIF()
 767 ENDIF()
 768 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 769     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 770 ENDIF()
 771
 772 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 773 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 774 IF(HAVE_SMMINTRIN_H)
 775     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 776     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 777         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 778             SET(HAVE_SSE4_1 1)
 779             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 780             IF(SSE4_1_SWITCH)
 781                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 782                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 783             ENDIF()
 784             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 785         ENDIF()
 786     ENDIF()
 787 ENDIF()
 788 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 789     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 790 ENDIF()
 791
 792 # Check for ARM Neon support
 793 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 794 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 795 IF(HAVE_ARM_NEON_H)
 796     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 797     IF(ALSOFT_CPUEXT_NEON)
 798         SET(HAVE_NEON 1)
 799         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 800         IF(FPU_NEON_SWITCH)
 801             SET_SOURCE_FILES_PROPERTIES(Alc/mixer_neon.c PROPERTIES
 802                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 803         ENDIF()
 804         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 805     ENDIF()
 806 ENDIF()
 807 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 808     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 809 ENDIF()
 810
 811
 812 IF(WIN32 OR HAVE_DLFCN_H)
 813     SET(IS_LINKED "")
 814     MACRO(ADD_BACKEND_LIBS _LIBS)
 815     ENDMACRO()
 816 ELSE()
 817     SET(IS_LINKED " (linked)")
 818     MACRO(ADD_BACKEND_LIBS _LIBS)
 819         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 820     ENDMACRO()
 821 ENDIF()
 822
 823 SET(BACKENDS "")
 824 SET(ALC_OBJS  ${ALC_OBJS}
 825               Alc/backends/base.c
 826               # Default backends, always available
 827               Alc/backends/loopback.c
 828               Alc/backends/null.c
 829 )
 830
 831 # Check ALSA backend
 832 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 833 FIND_PACKAGE(ALSA)
 834 IF(ALSA_FOUND)
 835     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 836     IF(ALSOFT_BACKEND_ALSA)
 837         SET(HAVE_ALSA 1)
 838         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 839         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 840         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 841         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 842             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 843         ENDIF()
 844     ENDIF()
 845 ENDIF()
 846 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 847     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 848 ENDIF()
 849
 850 # Check OSS backend
 851 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 852 FIND_PACKAGE(OSS)
 853 IF(OSS_FOUND)
 854     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 855     IF(ALSOFT_BACKEND_OSS)
 856         SET(HAVE_OSS 1)
 857         SET(BACKENDS  "${BACKENDS} OSS,")
 858         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 859         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 860             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 861         ENDIF()
 862     ENDIF()
 863 ENDIF()
 864 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 865     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 866 ENDIF()
 867
 868 # Check Solaris backend
 869 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 870 FIND_PACKAGE(AudioIO)
 871 IF(AUDIOIO_FOUND)
 872     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 873     IF(ALSOFT_BACKEND_SOLARIS)
 874         SET(HAVE_SOLARIS 1)
 875         SET(BACKENDS  "${BACKENDS} Solaris,")
 876         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 877         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 878             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 879         ENDIF()
 880     ENDIF()
 881 ENDIF()
 882 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 883     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 884 ENDIF()
 885
 886 # Check SndIO backend
 887 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 888 FIND_PACKAGE(SoundIO)
 889 IF(SOUNDIO_FOUND)
 890     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 891     IF(ALSOFT_BACKEND_SNDIO)
 892         SET(HAVE_SNDIO 1)
 893         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 894         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 895         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 896         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 897             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 898         ENDIF()
 899     ENDIF()
 900 ENDIF()
 901 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 902     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 903 ENDIF()
 904
 905 # Check QSA backend
 906 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 907 FIND_PACKAGE(QSA)
 908 IF(QSA_FOUND)
 909     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 910     IF(ALSOFT_BACKEND_QSA)
 911         SET(HAVE_QSA 1)
 912         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 913         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 914         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 915         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 916             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 917         ENDIF()
 918     ENDIF()
 919 ENDIF()
 920 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 921     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 922 ENDIF()
 923
 924 # Check Windows-only backends
 925 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 926 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 927 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 928 IF(HAVE_WINDOWS_H)
 929     # Check MMSystem backend
 930     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 931     IF(HAVE_MMSYSTEM_H)
 932         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 933         IF(HAVE_LIBWINMM)
 934             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 935             IF(ALSOFT_BACKEND_WINMM)
 936                 SET(HAVE_WINMM 1)
 937                 SET(BACKENDS  "${BACKENDS} WinMM,")
 938                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 939                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 940             ENDIF()
 941         ENDIF()
 942     ENDIF()
 943
 944     # Check DSound backend
 945     FIND_PACKAGE(DSound)
 946     IF(DSOUND_FOUND)
 947         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 948         IF(ALSOFT_BACKEND_DSOUND)
 949             SET(HAVE_DSOUND 1)
 950             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 951             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 952             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 953             IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 954                 INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 955             ENDIF()
 956         ENDIF()
 957     ENDIF()
 958
 959     # Check for MMDevApi backend
 960     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 961     IF(HAVE_MMDEVICEAPI_H)
 962         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 963         IF(ALSOFT_BACKEND_MMDEVAPI)
 964             SET(HAVE_MMDEVAPI 1)
 965             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 966             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 967         ENDIF()
 968     ENDIF()
 969 ENDIF()
 970 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 971     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 972 ENDIF()
 973 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 974     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 975 ENDIF()
 976 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 977     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 978 ENDIF()
 979
 980 # Check PortAudio backend
 981 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 982 FIND_PACKAGE(PortAudio)
 983 IF(PORTAUDIO_FOUND)
 984     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 985     IF(ALSOFT_BACKEND_PORTAUDIO)
 986         SET(HAVE_PORTAUDIO 1)
 987         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 988         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 989         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 990         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 991             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 992         ENDIF()
 993     ENDIF()
 994 ENDIF()
 995 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 996     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 997 ENDIF()
 998
 999 # Check PulseAudio backend
1000 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1001 FIND_PACKAGE(PulseAudio)
1002 IF(PULSEAUDIO_FOUND)
1003     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1004     IF(ALSOFT_BACKEND_PULSEAUDIO)
1005         SET(HAVE_PULSEAUDIO 1)
1006         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1007         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1008         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1009         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
1010             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
1011         ENDIF()
1012     ENDIF()
1013 ENDIF()
1014 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1015     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1016 ENDIF()
1017
1018 # Check JACK backend
1019 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1020 FIND_PACKAGE(JACK)
1021 IF(JACK_FOUND)
1022     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1023     IF(ALSOFT_BACKEND_JACK)
1024         SET(HAVE_JACK 1)
1025         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1026         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1027         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1028         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
1029             INCLUDE_DIRECTORIES(${JACK_INCLUDE_DIRS})
1030         ENDIF()
1031     ENDIF()
1032 ENDIF()
1033 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1034     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1035 ENDIF()
1036
1037 # Check CoreAudio backend
1038 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1039 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1040              NAMES CoreAudio
1041              PATHS /System/Library/Frameworks
1042 )
1043 IF(COREAUDIO_FRAMEWORK)
1044     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1045     IF(ALSOFT_BACKEND_COREAUDIO)
1046         SET(HAVE_COREAUDIO 1)
1047         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1048         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1049         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1050         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1051         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1052
1053         # Some versions of OSX may need the AudioToolbox framework. Add it if
1054         # it's found.
1055         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1056                      NAMES AudioToolbox
1057                      PATHS ~/Library/Frameworks
1058                            /Library/Frameworks
1059                            /System/Library/Frameworks
1060                     )
1061         IF(AUDIOTOOLBOX_LIBRARY)
1062             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1063         ENDIF()
1064     ENDIF()
1065 ENDIF()
1066 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1067     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1068 ENDIF()
1069
1070 # Check for OpenSL (Android) backend
1071 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1072 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1073 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1074     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1075     IF(HAVE_LIBOPENSLES)
1076         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1077         IF(ALSOFT_BACKEND_OPENSL)
1078             SET(HAVE_OPENSL 1)
1079             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1080             SET(BACKENDS  "${BACKENDS} OpenSL,")
1081             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1082         ENDIF()
1083     ENDIF()
1084 ENDIF()
1085 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1086     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1087 ENDIF()
1088
1089 # Optionally enable the Wave Writer backend
1090 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1091 IF(ALSOFT_BACKEND_WAVE)
1092     SET(HAVE_WAVE 1)
1093     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1094     SET(BACKENDS  "${BACKENDS} WaveFile,")
1095 ENDIF()
1096
1097 # This is always available
1098 SET(BACKENDS  "${BACKENDS} Null")
1099
1100 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1101 if(ALSOFT_EMBED_HRTF_DATA)
1102     if(WIN32)
1103         set(ALC_OBJS  ${ALC_OBJS} Alc/hrtf_res.rc)
1104     else()
1105         set(FILENAMES default-44100.mhr default-48000.mhr)
1106         foreach(FILENAME ${FILENAMES})
1107             set(outfile ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${FILENAME}${CMAKE_C_OUTPUT_EXTENSION})
1108             add_custom_command(OUTPUT ${outfile}
1109                 DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/hrtf/${FILENAME}"
1110                 WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/hrtf"
1111                 COMMAND "${CMAKE_LINKER}" -r -b binary -o "${outfile}" ${FILENAME}
1112                 COMMAND "${CMAKE_OBJCOPY}" --rename-section .data=.rodata,alloc,load,readonly,data,contents "${outfile}" "${outfile}"
1113                 COMMENT "Generating ${FILENAME}${CMAKE_C_OUTPUT_EXTENSION}"
1114                 VERBATIM
1115             )
1116             set(ALC_OBJS  ${ALC_OBJS} ${outfile})
1117         endforeach()
1118         unset(outfile)
1119         unset(FILENAMES)
1120     endif()
1121 endif()
1122
1123
1124 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1125     add_subdirectory(utils/alsoft-config)
1126 ENDIF()
1127 IF(ALSOFT_EXAMPLES)
1128     FIND_PACKAGE(SDL2)
1129     IF(SDL2_FOUND)
1130         FIND_PACKAGE(SDL_sound)
1131         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
1132             INCLUDE_DIRECTORIES(${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1133         ENDIF()
1134         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1135         IF(FFMPEG_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
1136             INCLUDE_DIRECTORIES(${FFMPEG_INCLUDE_DIRS})
1137         ENDIF()
1138     ENDIF()
1139 ENDIF()
1140
1141 IF(LIBTYPE STREQUAL "STATIC")
1142     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
1143     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1144 ENDIF()
1145
1146 # Needed for openal.pc.in
1147 SET(prefix ${CMAKE_INSTALL_PREFIX})
1148 SET(exec_prefix "\${prefix}")
1149 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1150 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1151 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1152 SET(PACKAGE_VERSION "${LIB_VERSION}")
1153
1154 # End configuration
1155 CONFIGURE_FILE(
1156     "${OpenAL_SOURCE_DIR}/config.h.in"
1157     "${OpenAL_BINARY_DIR}/config.h")
1158 CONFIGURE_FILE(
1159     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1160     "${OpenAL_BINARY_DIR}/openal.pc"
1161     @ONLY)
1162
1163 # Build a common library with reusable helpers
1164 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1165 SET_PROPERTY(TARGET common APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1166 IF(NOT LIBTYPE STREQUAL "STATIC")
1167     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1168 ENDIF()
1169
1170 # Build main library
1171 IF(LIBTYPE STREQUAL "STATIC")
1172     ADD_LIBRARY(${LIBNAME} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1173 ELSE()
1174     ADD_LIBRARY(${LIBNAME} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1175 ENDIF()
1176 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1177 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
1178 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1179     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
1180 ENDIF()
1181 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1182 IF(HAVE_ALSA)
1183     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1184 ENDIF()
1185 IF(HAVE_OSS)
1186     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1187 ENDIF()
1188 IF(HAVE_SOLARIS)
1189     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1190 ENDIF()
1191 IF(HAVE_SNDIO)
1192     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1193 ENDIF()
1194 IF(HAVE_QSA)
1195     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1196 ENDIF()
1197 IF(HAVE_DSOUND)
1198     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1199 ENDIF()
1200 IF(HAVE_PORTAUDIO)
1201     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1202 ENDIF()
1203 IF(HAVE_PULSEAUDIO)
1204     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1205 ENDIF()
1206 IF(HAVE_JACK)
1207     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${JACK_INCLUDE_DIRS})
1208 ENDIF()
1209 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
1210                                             SOVERSION ${LIB_MAJOR_VERSION})
1211 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1212     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
1213
1214     IF(MINGW AND ALSOFT_BUILD_IMPORT_LIB)
1215         FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1216         FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1217         IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1218             MESSAGE(STATUS "")
1219             IF(NOT SED_EXECUTABLE)
1220                 MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1221             ENDIF()
1222             IF(NOT DLLTOOL_EXECUTABLE)
1223                 MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1224             ENDIF()
1225         ELSE()
1226             SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES LINK_FLAGS "-Wl,--output-def,${LIBNAME}.def")
1227             ADD_CUSTOM_COMMAND(TARGET ${LIBNAME} POST_BUILD
1228                 COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" ${LIBNAME}.def
1229                 COMMAND "${DLLTOOL_EXECUTABLE}" -d ${LIBNAME}.def -l ${LIBNAME}.lib -D ${LIBNAME}.dll
1230                 COMMENT "Stripping ordinals from ${LIBNAME}.def and generating ${LIBNAME}.lib..."
1231                 VERBATIM
1232             )
1233         ENDIF()
1234     ENDIF()
1235 ENDIF()
1236
1237 TARGET_LINK_LIBRARIES(${LIBNAME} common ${EXTRA_LIBS})
1238
1239 IF(ALSOFT_INSTALL)
1240     # Add an install target here
1241     INSTALL(TARGETS ${LIBNAME}
1242             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1243             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1244             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1245     )
1246     INSTALL(FILES include/AL/al.h
1247                   include/AL/alc.h
1248                   include/AL/alext.h
1249                   include/AL/efx.h
1250                   include/AL/efx-creative.h
1251                   include/AL/efx-presets.h
1252             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1253     )
1254     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1255             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1256 ENDIF()
1257
1258
1259 MESSAGE(STATUS "")
1260 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1261 MESSAGE(STATUS "    ${BACKENDS}")
1262 MESSAGE(STATUS "")
1263 MESSAGE(STATUS "Building with support for CPU extensions:")
1264 MESSAGE(STATUS "    ${CPU_EXTS}")
1265 MESSAGE(STATUS "")
1266
1267 IF(WIN32)
1268     IF(NOT HAVE_DSOUND)
1269         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1270         MESSAGE(STATUS "         This is probably NOT what you want!")
1271         MESSAGE(STATUS "")
1272     ENDIF()
1273 ENDIF()
1274
1275 if(ALSOFT_EMBED_HRTF_DATA)
1276     message(STATUS "Embedding HRTF datasets")
1277     message(STATUS "")
1278 endif()
1279
1280 # Install alsoft.conf configuration file
1281 IF(ALSOFT_CONFIG)
1282     INSTALL(FILES alsoftrc.sample
1283             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1284     )
1285     MESSAGE(STATUS "Installing sample configuration")
1286     MESSAGE(STATUS "")
1287 ENDIF()
1288
1289 # Install HRTF definitions
1290 IF(ALSOFT_HRTF_DEFS)
1291     INSTALL(FILES hrtf/default-44100.mhr
1292                   hrtf/default-48000.mhr
1293             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1294     )
1295     MESSAGE(STATUS "Installing HRTF definitions")
1296     MESSAGE(STATUS "")
1297 ENDIF()
1298
1299 # Install AmbDec presets
1300 IF(ALSOFT_AMBDEC_PRESETS)
1301     INSTALL(FILES presets/3D7.1.ambdec
1302                   presets/hexagon.ambdec
1303                   presets/itu5.1.ambdec
1304                   presets/rectangle.ambdec
1305                   presets/square.ambdec
1306                   presets/presets.txt
1307             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1308     )
1309     MESSAGE(STATUS "Installing AmbDec presets")
1310     MESSAGE(STATUS "")
1311 ENDIF()
1312
1313 IF(ALSOFT_UTILS)
1314     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1315     SET_PROPERTY(TARGET openal-info APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1316     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1317
1318     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1319     SET_PROPERTY(TARGET makehrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1320     IF(HAVE_LIBM)
1321         TARGET_LINK_LIBRARIES(makehrtf m)
1322     ENDIF()
1323
1324     ADD_EXECUTABLE(bsincgen utils/bsincgen.c)
1325     SET_PROPERTY(TARGET bsincgen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1326     IF(HAVE_LIBM)
1327         TARGET_LINK_LIBRARIES(bsincgen m)
1328     ENDIF()
1329
1330     IF(ALSOFT_INSTALL)
1331         INSTALL(TARGETS openal-info makehrtf bsincgen
1332                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1333                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1334                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1335         )
1336     ENDIF()
1337
1338     MESSAGE(STATUS "Building utility programs")
1339     IF(TARGET alsoft-config)
1340         MESSAGE(STATUS "Building configuration program")
1341     ENDIF()
1342     MESSAGE(STATUS "")
1343 ENDIF()
1344
1345 IF(ALSOFT_TESTS)
1346     ADD_LIBRARY(test-common STATIC examples/common/alhelpers.c)
1347     SET_PROPERTY(TARGET test-common APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1348
1349     ADD_EXECUTABLE(altonegen examples/altonegen.c)
1350     TARGET_LINK_LIBRARIES(altonegen test-common ${LIBNAME})
1351     SET_PROPERTY(TARGET altonegen APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1352
1353     IF(ALSOFT_INSTALL)
1354         INSTALL(TARGETS altonegen
1355                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1356                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1357                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1358         )
1359     ENDIF()
1360
1361     MESSAGE(STATUS "Building test programs")
1362     MESSAGE(STATUS "")
1363 ENDIF()
1364
1365 IF(ALSOFT_EXAMPLES)
1366     IF(SDL2_FOUND AND SDL_SOUND_FOUND)
1367         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1368                                      examples/common/sdl_sound.c)
1369         SET_PROPERTY(TARGET ex-common APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1370         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1371                                                                           ${SDL_SOUND_INCLUDE_DIR})
1372
1373         ADD_EXECUTABLE(alstream examples/alstream.c)
1374         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1375                                        common ${LIBNAME})
1376         SET_PROPERTY(TARGET alstream APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1377         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1378                                                                          ${SDL_SOUND_INCLUDE_DIR})
1379
1380         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1381         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1382                                        common ${LIBNAME})
1383         SET_PROPERTY(TARGET alreverb APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1384         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1385                                                                          ${SDL_SOUND_INCLUDE_DIR})
1386
1387         ADD_EXECUTABLE(allatency examples/allatency.c)
1388         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1389                                         common ${LIBNAME})
1390         SET_PROPERTY(TARGET allatency APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1391         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1392                                                                           ${SDL_SOUND_INCLUDE_DIR})
1393
1394         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1395         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1396                                          common ${LIBNAME})
1397         SET_PROPERTY(TARGET alloopback APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1398         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1399                                                                            ${SDL_SOUND_INCLUDE_DIR})
1400
1401         ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1402         TARGET_LINK_LIBRARIES(alhrtf ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY}
1403                                      common ${LIBNAME})
1404         SET_PROPERTY(TARGET alhrtf APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1405         SET_PROPERTY(TARGET alhrtf APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1406                                                                        ${SDL_SOUND_INCLUDE_DIR})
1407
1408         IF(ALSOFT_INSTALL)
1409             INSTALL(TARGETS alstream alreverb allatency alloopback alhrtf
1410                     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1411                     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1412                     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1413             )
1414         ENDIF()
1415
1416         SET(FFVER_OK FALSE)
1417         IF(FFMPEG_FOUND)
1418             SET(FFVER_OK TRUE)
1419             IF(AVFORMAT_VERSION VERSION_LESS "55.33.100")
1420                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 55.33.100)")
1421                 SET(FFVER_OK FALSE)
1422             ENDIF()
1423             IF(AVCODEC_VERSION VERSION_LESS "55.52.102")
1424                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 55.52.102)")
1425                 SET(FFVER_OK FALSE)
1426             ENDIF()
1427             IF(AVUTIL_VERSION VERSION_LESS "52.66.100")
1428                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 52.66.100)")
1429                 SET(FFVER_OK FALSE)
1430             ENDIF()
1431             IF(SWSCALE_VERSION VERSION_LESS "2.5.102")
1432                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 2.5.102)")
1433                 SET(FFVER_OK FALSE)
1434             ENDIF()
1435             IF(SWRESAMPLE_VERSION VERSION_LESS "0.18.100")
1436                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 0.18.100)")
1437                 SET(FFVER_OK FALSE)
1438             ENDIF()
1439         ENDIF()
1440         IF(FFVER_OK AND NOT MSVC)
1441             ADD_EXECUTABLE(alffplay examples/alffplay.c)
1442             TARGET_LINK_LIBRARIES(alffplay common ex-common ${SDL2_LIBRARY} ${LIBNAME} ${FFMPEG_LIBRARIES})
1443             SET_PROPERTY(TARGET alffplay APPEND PROPERTY COMPILE_FLAGS ${EXTRA_CFLAGS})
1444             SET_PROPERTY(TARGET alffplay APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1445                                                                              ${FFMPEG_INCLUDE_DIRS})
1446
1447             IF(ALSOFT_INSTALL)
1448                 INSTALL(TARGETS alffplay
1449                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1450                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1451                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1452                 )
1453             ENDIF()
1454             MESSAGE(STATUS "Building SDL and FFmpeg example programs")
1455         ELSE()
1456             MESSAGE(STATUS "Building SDL example programs")
1457         ENDIF()
1458         MESSAGE(STATUS "")
1459     ENDIF()
1460 ENDIF()