CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 3.0.2)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8     CMAKE_POLICY(SET CMP0003 NEW)
   9     CMAKE_POLICY(SET CMP0005 NEW)
  10     IF(POLICY CMP0020)
  11         CMAKE_POLICY(SET CMP0020 NEW)
  12     ENDIF(POLICY CMP0020)
  13     IF(POLICY CMP0042)
  14         CMAKE_POLICY(SET CMP0042 NEW)
  15     ENDIF(POLICY CMP0042)
  16     IF(POLICY CMP0054)
  17         CMAKE_POLICY(SET CMP0054 NEW)
  18     ENDIF(POLICY CMP0054)
  19 ENDIF(COMMAND CMAKE_POLICY)
  20
  21 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  22
  23 INCLUDE(CheckFunctionExists)
  24 INCLUDE(CheckLibraryExists)
  25 INCLUDE(CheckSharedFunctionExists)
  26 INCLUDE(CheckIncludeFile)
  27 INCLUDE(CheckIncludeFiles)
  28 INCLUDE(CheckSymbolExists)
  29 INCLUDE(CheckCCompilerFlag)
  30 INCLUDE(CheckCXXCompilerFlag)
  31 INCLUDE(CheckCSourceCompiles)
  32 INCLUDE(CheckTypeSize)
  33 include(CheckStructHasMember)
  34 include(CheckFileOffsetBits)
  35 include(GNUInstallDirs)
  36
  37 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48 OPTION(ALSOFT_TESTS     "Build and install test programs"     ON)
  49
  50 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  51 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  52 OPTION(ALSOFT_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  53 OPTION(ALSOFT_INSTALL "Install headers and libraries" ON)
  54
  55 if(DEFINED SHARE_INSTALL_DIR)
  56     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  57     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  58 endif()
  59
  60 if(DEFINED LIB_SUFFIX)
  61     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  62 endif()
  63
  64
  65 SET(CPP_DEFS ) # C pre-process, not C++
  66 SET(INC_PATHS )
  67 SET(C_FLAGS )
  68 SET(LINKER_FLAGS )
  69 SET(EXTRA_LIBS )
  70
  71 IF(WIN32)
  72     SET(CPP_DEFS ${CPP_DEFS} _WIN32 _WIN32_WINNT=0x0502)
  73
  74     OPTION(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
  75
  76     # This option is mainly for static linking OpenAL Soft into another project
  77     # that already defines the IDs. It is up to that project to ensure all
  78     # required IDs are defined.
  79     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  80
  81     IF(MINGW)
  82         OPTION(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
  83         IF(NOT DLLTOOL)
  84             IF(HOST)
  85                 SET(DLLTOOL "${HOST}-dlltool")
  86             ELSE()
  87                 SET(DLLTOOL "dlltool")
  88             ENDIF()
  89         ENDIF()
  90     ENDIF()
  91 ENDIF()
  92
  93
  94 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  95 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  96     SET(INC_PATHS ${INC_PATHS} /usr/include)
  97     SET(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
  98 ENDIF()
  99
 100 IF(NOT LIBTYPE)
 101     SET(LIBTYPE SHARED)
 102 ENDIF()
 103
 104 SET(LIB_MAJOR_VERSION "1")
 105 SET(LIB_MINOR_VERSION "18")
 106 SET(LIB_REVISION "2")
 107 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 108
 109 SET(EXPORT_DECL "")
 110 SET(ALIGN_DECL "")
 111
 112
 113 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
 114 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
 115
 116
 117 CHECK_C_COMPILER_FLAG(-std=c11 HAVE_STD_C11)
 118 IF(HAVE_STD_C11)
 119     SET(CMAKE_C_FLAGS "-std=c11 ${CMAKE_C_FLAGS}")
 120 ELSE()
 121     CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
 122     IF(HAVE_STD_C99)
 123         SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
 124     ENDIF()
 125 ENDIF()
 126
 127 CHECK_CXX_COMPILER_FLAG(-std=c++11 HAVE_STD_CXX11)
 128 IF(HAVE_STD_CXX11)
 129     SET(CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 130 ENDIF()
 131
 132 if(NOT WIN32)
 133     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 134     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 135     IF(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 136         SET(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 137         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 138         CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 139         IF(NOT HAVE_POSIX_MEMALIGN_POSIX)
 140             SET(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 141         ELSE()
 142             SET(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 143         ENDIF()
 144     ENDIF()
 145     UNSET(OLD_REQUIRED_FLAGS)
 146 ENDIF()
 147
 148 # Set defines for large file support
 149 CHECK_FILE_OFFSET_BITS()
 150 IF(_FILE_OFFSET_BITS)
 151     SET(CPP_DEFS ${CPP_DEFS} "_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 152     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_FILE_OFFSET_BITS=${_FILE_OFFSET_BITS}")
 153 ENDIF()
 154 SET(CPP_DEFS ${CPP_DEFS} _LARGEFILE_SOURCE _LARGE_FILES)
 155 SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_LARGEFILE_SOURCE -D_LARGE_FILES")
 156
 157 # MSVC may need workarounds for C99 restrict and inline
 158 IF(MSVC)
 159     # TODO: Once we truly require C99, these restrict and inline checks should go
 160     # away.
 161     CHECK_C_SOURCE_COMPILES("int *restrict foo;
 162                              int main() {return 0;}" HAVE_RESTRICT)
 163     IF(NOT HAVE_RESTRICT)
 164         SET(CPP_DEFS ${CPP_DEFS} "restrict=")
 165         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
 166     ENDIF()
 167
 168     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 169                              int main() {return 0;}" HAVE_INLINE)
 170     IF(NOT HAVE_INLINE)
 171         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 172                                  int main() {return 0;}" HAVE___INLINE)
 173         IF(NOT HAVE___INLINE)
 174             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 175         ENDIF()
 176
 177         SET(CPP_DEFS ${CPP_DEFS} inline=__inline)
 178         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 179     ENDIF()
 180 ENDIF()
 181
 182 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 183 IF(CMAKE_COMPILER_IS_GNUCC)
 184     SET(CMAKE_C_FLAGS "-fno-gnu89-inline ${CMAKE_C_FLAGS}")
 185
 186     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 187     # Force no inlining for the next test.
 188     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 189
 190     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 191                              int main() {return foo();}" INLINE_IS_C99)
 192     IF(NOT INLINE_IS_C99)
 193         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 194                              Please update your compiler for better C99 compliance.")
 195     ENDIF()
 196
 197     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 198 ENDIF()
 199
 200 # Check if we have a proper timespec declaration
 201 CHECK_STRUCT_HAS_MEMBER("struct timespec" tv_sec time.h HAVE_STRUCT_TIMESPEC)
 202 IF(HAVE_STRUCT_TIMESPEC)
 203     # Define it here so we don't have to include config.h for it
 204     SET(CPP_DEFS ${CPP_DEFS} HAVE_STRUCT_TIMESPEC)
 205 ENDIF()
 206
 207 # Some systems may need libatomic for C11 atomic functions to work
 208 SET(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 209 SET(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 210 CHECK_C_SOURCE_COMPILES("#include <stdatomic.h>
 211 int _Atomic foo = ATOMIC_VAR_INIT(0);
 212 int main()
 213 {
 214     return atomic_fetch_add(&foo, 2);
 215 }"
 216 HAVE_LIBATOMIC)
 217 IF(NOT HAVE_LIBATOMIC)
 218     SET(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 219 ELSE()
 220     SET(EXTRA_LIBS atomic ${EXTRA_LIBS})
 221 ENDIF()
 222 UNSET(OLD_REQUIRED_LIBRARIES)
 223
 224 # Include liblog for Android logging
 225 CHECK_LIBRARY_EXISTS(log __android_log_print "" HAVE_LIBLOG)
 226 IF(HAVE_LIBLOG)
 227     SET(EXTRA_LIBS log ${EXTRA_LIBS})
 228     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 229 ENDIF()
 230
 231 # Check if we have C99 bool
 232 CHECK_C_SOURCE_COMPILES(
 233 "int main(int argc, char *argv[])
 234  {
 235      volatile _Bool ret;
 236      ret = (argc > 1) ? 1 : 0;
 237      return ret ? -1 : 0;
 238  }"
 239 HAVE_C99_BOOL)
 240
 241 # Check if we have C11 static_assert
 242 CHECK_C_SOURCE_COMPILES(
 243 "int main()
 244  {
 245      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 246      return 0;
 247  }"
 248 HAVE_C11_STATIC_ASSERT)
 249
 250 # Check if we have C11 alignas
 251 CHECK_C_SOURCE_COMPILES(
 252 "_Alignas(16) int foo;
 253  int main()
 254  {
 255      return 0;
 256  }"
 257 HAVE_C11_ALIGNAS)
 258
 259 # Check if we have C11 _Atomic
 260 CHECK_C_SOURCE_COMPILES(
 261 "#include <stdatomic.h>
 262  int _Atomic foo = ATOMIC_VAR_INIT(0);
 263  int main()
 264  {
 265      atomic_fetch_add(&foo, 2);
 266      return 0;
 267  }"
 268 HAVE_C11_ATOMIC)
 269
 270 # Add definitions, compiler switches, etc.
 271 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_SOURCE_DIR}/common" "${OpenAL_BINARY_DIR}")
 272
 273 IF(NOT CMAKE_BUILD_TYPE)
 274     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 275         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 276         FORCE)
 277 ENDIF()
 278 IF(NOT CMAKE_DEBUG_POSTFIX)
 279     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 280         "Library postfix for debug builds. Normally left blank."
 281         FORCE)
 282 ENDIF()
 283
 284 IF(MSVC)
 285     SET(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 286     SET(C_FLAGS ${C_FLAGS} /wd4098)
 287
 288     IF(NOT DXSDK_DIR)
 289         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 290     ELSE()
 291         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 292     ENDIF()
 293     IF(DXSDK_DIR)
 294         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 295     ENDIF()
 296
 297     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 298     IF(FORCE_STATIC_VCRT)
 299         FOREACH(flag_var
 300                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 301                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 302             IF(${flag_var} MATCHES "/MD")
 303                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 304             ENDIF()
 305         ENDFOREACH(flag_var)
 306     ENDIF()
 307 ELSE()
 308     SET(C_FLAGS ${C_FLAGS} -Winline -Wall)
 309     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 310     IF(HAVE_W_EXTRA)
 311         SET(C_FLAGS ${C_FLAGS} -Wextra)
 312     ENDIF()
 313
 314     IF(ALSOFT_WERROR)
 315         SET(C_FLAGS ${C_FLAGS} -Werror)
 316     ENDIF()
 317
 318     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 319     # instead of NDEBUG)
 320     FOREACH(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 321         IF(${flag_var} MATCHES "-DNDEBUG")
 322             STRING(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 323         ENDIF()
 324     ENDFOREACH()
 325
 326     CHECK_C_COMPILER_FLAG(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 327     IF(HAVE_FNO_MATH_ERRNO)
 328         SET(C_FLAGS ${C_FLAGS} -fno-math-errno)
 329     ENDIF()
 330
 331     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 332                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 333
 334     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 335     if(ALSOFT_STATIC_LIBGCC)
 336         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 337         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 338         check_c_source_compiles(
 339 "#include <stdlib.h>
 340 int main()
 341 {
 342     return 0;
 343 }"
 344             HAVE_STATIC_LIBGCC_SWITCH
 345         )
 346         if(HAVE_STATIC_LIBGCC_SWITCH)
 347             SET(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 348         endif()
 349         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 350         unset(OLD_REQUIRED_LIBRARIES)
 351     endif()
 352 ENDIF()
 353
 354 # Set visibility/export options if available
 355 IF(WIN32)
 356     SET(EXPORT_DECL "__declspec(dllexport)")
 357     IF(NOT MINGW)
 358         SET(ALIGN_DECL "__declspec(align(x))")
 359     ELSE()
 360         SET(ALIGN_DECL "__declspec(aligned(x))")
 361     ENDIF()
 362 ELSE()
 363     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 364     # Yes GCC, really don't accept visibility modes you don't support
 365     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 366
 367     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 368                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 369     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 370         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 371     ELSE()
 372         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 373                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 374         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 375             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 376         ENDIF()
 377     ENDIF()
 378
 379     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 380         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 381         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 382             SET(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 383         ENDIF()
 384     ENDIF()
 385
 386     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 387                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 388     IF(HAVE_ATTRIBUTE_ALIGNED)
 389         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 390     ENDIF()
 391
 392     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 393 ENDIF()
 394
 395 CHECK_C_SOURCE_COMPILES("
 396 int main()
 397 {
 398     float *ptr;
 399     ptr = __builtin_assume_aligned(ptr, 16);
 400     return 0;
 401 }" HAVE___BUILTIN_ASSUME_ALIGNED)
 402 IF(HAVE___BUILTIN_ASSUME_ALIGNED)
 403     SET(ASSUME_ALIGNED_DECL "__builtin_assume_aligned(x, y)")
 404 ELSE()
 405     SET(ASSUME_ALIGNED_DECL "x")
 406 ENDIF()
 407
 408 SET(SSE_SWITCH "")
 409 SET(SSE2_SWITCH "")
 410 SET(SSE3_SWITCH "")
 411 SET(SSE4_1_SWITCH "")
 412 SET(FPU_NEON_SWITCH "")
 413
 414 CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 415 IF(HAVE_MSSE_SWITCH)
 416     SET(SSE_SWITCH "-msse")
 417 ENDIF()
 418 CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 419 IF(HAVE_MSSE2_SWITCH)
 420     SET(SSE2_SWITCH "-msse2")
 421 ENDIF()
 422 CHECK_C_COMPILER_FLAG(-msse3 HAVE_MSSE3_SWITCH)
 423 IF(HAVE_MSSE3_SWITCH)
 424     SET(SSE3_SWITCH "-msse3")
 425 ENDIF()
 426 CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 427 IF(HAVE_MSSE4_1_SWITCH)
 428     SET(SSE4_1_SWITCH "-msse4.1")
 429 ENDIF()
 430 CHECK_C_COMPILER_FLAG(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 431 IF(HAVE_MFPU_NEON_SWITCH)
 432     SET(FPU_NEON_SWITCH "-mfpu=neon")
 433 ENDIF()
 434
 435 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 436                          int main() {return 0;}" HAVE_GCC_FORMAT)
 437
 438 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 439 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 440 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 441 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
 442 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 443 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 444 CHECK_INCLUDE_FILE(intrin.h HAVE_INTRIN_H)
 445 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 446 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 447 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 448 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 449 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 450 IF(NOT HAVE_GUIDDEF_H)
 451     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 452 ENDIF()
 453
 454 # Some systems need libm for some of the following math functions to work
 455 SET(MATH_LIB )
 456 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 457 IF(HAVE_LIBM)
 458     SET(MATH_LIB ${MATH_LIB} m)
 459     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 460 ENDIF()
 461
 462 # Check for the dlopen API (for dynamicly loading backend libs)
 463 IF(ALSOFT_DLOPEN)
 464     CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 465     IF(HAVE_LIBDL)
 466         SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 467         SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 468     ENDIF()
 469
 470     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 471 ENDIF()
 472
 473 # Check for a cpuid intrinsic
 474 IF(HAVE_CPUID_H)
 475     CHECK_C_SOURCE_COMPILES("#include <cpuid.h>
 476         int main()
 477         {
 478             unsigned int eax, ebx, ecx, edx;
 479             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 480         }" HAVE_GCC_GET_CPUID)
 481 ENDIF()
 482 IF(HAVE_INTRIN_H)
 483     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 484         int main()
 485         {
 486             int regs[4];
 487             __cpuid(regs, 0);
 488             return regs[0];
 489         }" HAVE_CPUID_INTRINSIC)
 490     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 491         int main()
 492         {
 493             unsigned long idx = 0;
 494             _BitScanForward64(&idx, 1);
 495             return idx;
 496         }" HAVE_BITSCANFORWARD64_INTRINSIC)
 497     CHECK_C_SOURCE_COMPILES("#include <intrin.h>
 498         int main()
 499         {
 500             unsigned long idx = 0;
 501             _BitScanForward(&idx, 1);
 502             return idx;
 503         }" HAVE_BITSCANFORWARD_INTRINSIC)
 504 ENDIF()
 505
 506 CHECK_SYMBOL_EXISTS(sysconf          unistd.h HAVE_SYSCONF)
 507 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 508 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 509 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 510 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 511 CHECK_SYMBOL_EXISTS(modff  math.h HAVE_MODFF)
 512 CHECK_SYMBOL_EXISTS(log2f  math.h HAVE_LOG2F)
 513 CHECK_SYMBOL_EXISTS(cbrtf  math.h HAVE_CBRTF)
 514
 515 IF(HAVE_FLOAT_H)
 516     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 517     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 518 ENDIF()
 519
 520 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 521 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 522 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 523 IF(NOT HAVE_STRCASECMP)
 524     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 525     IF(NOT HAVE__STRICMP)
 526         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 527     ENDIF()
 528
 529     SET(CPP_DEFS ${CPP_DEFS} strcasecmp=_stricmp)
 530 ENDIF()
 531
 532 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 533 IF(NOT HAVE_STRNCASECMP)
 534     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 535     IF(NOT HAVE__STRNICMP)
 536         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 537     ENDIF()
 538
 539     SET(CPP_DEFS ${CPP_DEFS} strncasecmp=_strnicmp)
 540 ENDIF()
 541
 542 CHECK_SYMBOL_EXISTS(strnlen string.h HAVE_STRNLEN)
 543 CHECK_SYMBOL_EXISTS(snprintf stdio.h HAVE_SNPRINTF)
 544 IF(NOT HAVE_SNPRINTF)
 545     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 546     IF(NOT HAVE__SNPRINTF)
 547         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 548     ENDIF()
 549
 550     SET(CPP_DEFS ${CPP_DEFS} snprintf=_snprintf)
 551 ENDIF()
 552
 553 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 554 IF(NOT HAVE_ISFINITE)
 555     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 556     IF(NOT HAVE_FINITE)
 557         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 558         IF(NOT HAVE__FINITE)
 559             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 560         ENDIF()
 561         SET(CPP_DEFS ${CPP_DEFS} isfinite=_finite)
 562     ELSE()
 563         SET(CPP_DEFS ${CPP_DEFS} isfinite=finite)
 564     ENDIF()
 565 ENDIF()
 566
 567 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 568 IF(NOT HAVE_ISNAN)
 569     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 570     IF(NOT HAVE__ISNAN)
 571         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 572     ENDIF()
 573
 574     SET(CPP_DEFS ${CPP_DEFS} isnan=_isnan)
 575 ENDIF()
 576
 577
 578 # Check if we have Windows headers
 579 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 580 IF(NOT HAVE_WINDOWS_H)
 581     CHECK_SYMBOL_EXISTS(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 582     IF(NOT HAVE_GETTIMEOFDAY)
 583         MESSAGE(FATAL_ERROR "No timing function found!")
 584     ENDIF()
 585
 586     CHECK_SYMBOL_EXISTS(nanosleep time.h HAVE_NANOSLEEP)
 587     IF(NOT HAVE_NANOSLEEP)
 588         MESSAGE(FATAL_ERROR "No sleep function found!")
 589     ENDIF()
 590
 591     # We need pthreads outside of Windows
 592     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 593     IF(NOT HAVE_PTHREAD_H)
 594         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 595     ENDIF()
 596     # Some systems need pthread_np.h to get recursive mutexes
 597     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 598
 599     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 600     IF(HAVE_PTHREAD)
 601         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 602         SET(C_FLAGS ${C_FLAGS} -pthread)
 603         SET(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 604     ENDIF()
 605
 606     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 607     IF(HAVE_LIBPTHREAD)
 608         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 609     ENDIF()
 610
 611     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 612
 613     IF(HAVE_PTHREAD_NP_H)
 614         CHECK_SYMBOL_EXISTS(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 615         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 616             CHECK_SYMBOL_EXISTS(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 617         ELSE()
 618             CHECK_C_SOURCE_COMPILES("
 619 #include <pthread.h>
 620 #include <pthread_np.h>
 621 int main()
 622 {
 623     pthread_setname_np(\"testname\");
 624     return 0;
 625 }"
 626                 PTHREAD_SETNAME_NP_ONE_PARAM
 627             )
 628             CHECK_C_SOURCE_COMPILES("
 629 #include <pthread.h>
 630 #include <pthread_np.h>
 631 int main()
 632 {
 633     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 634     return 0;
 635 }"
 636                 PTHREAD_SETNAME_NP_THREE_PARAMS
 637             )
 638         ENDIF()
 639         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 640     ELSE()
 641         CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 642         IF(NOT HAVE_PTHREAD_SETNAME_NP)
 643             CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 644         ELSE()
 645             CHECK_C_SOURCE_COMPILES("
 646 #include <pthread.h>
 647 int main()
 648 {
 649     pthread_setname_np(\"testname\");
 650     return 0;
 651 }"
 652                 PTHREAD_SETNAME_NP_ONE_PARAM
 653             )
 654             CHECK_C_SOURCE_COMPILES("
 655 #include <pthread.h>
 656 int main()
 657 {
 658     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 659     return 0;
 660 }"
 661                 PTHREAD_SETNAME_NP_THREE_PARAMS
 662             )
 663         ENDIF()
 664         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np pthread.h HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 665     ENDIF()
 666
 667     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 668
 669     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 670     IF(HAVE_LIBRT)
 671         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 672     ENDIF()
 673 ENDIF()
 674
 675 CHECK_SYMBOL_EXISTS(getopt unistd.h HAVE_GETOPT)
 676
 677 # Check for a 64-bit type
 678 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 679 IF(NOT HAVE_STDINT_H)
 680     IF(HAVE_WINDOWS_H)
 681         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 682                                  #include <windows.h>
 683                                  __int64 foo;
 684                                  int main() {return 0;}" HAVE___INT64)
 685     ENDIF()
 686     IF(NOT HAVE___INT64)
 687         IF(NOT SIZEOF_LONG MATCHES "8")
 688             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 689                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 690             ENDIF()
 691         ENDIF()
 692     ENDIF()
 693 ENDIF()
 694
 695
 696 SET(COMMON_OBJS  common/almalloc.c
 697                  common/atomic.c
 698                  common/rwlock.c
 699                  common/threads.c
 700                  common/uintmap.c
 701 )
 702 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 703                  OpenAL32/alBuffer.c
 704                  OpenAL32/alEffect.c
 705                  OpenAL32/alError.c
 706                  OpenAL32/alExtension.c
 707                  OpenAL32/alFilter.c
 708                  OpenAL32/alListener.c
 709                  OpenAL32/alSource.c
 710                  OpenAL32/alState.c
 711                  OpenAL32/event.c
 712                  OpenAL32/sample_cvt.c
 713 )
 714 SET(ALC_OBJS  Alc/ALc.c
 715               Alc/ALu.c
 716               Alc/alconfig.c
 717               Alc/bs2b.c
 718               Alc/converter.c
 719               Alc/mastering.c
 720               Alc/ringbuffer.c
 721               Alc/effects/chorus.c
 722               Alc/effects/compressor.c
 723               Alc/effects/dedicated.c
 724               Alc/effects/distortion.c
 725               Alc/effects/echo.c
 726               Alc/effects/equalizer.c
 727               Alc/effects/modulator.c
 728               Alc/effects/null.c
 729               Alc/effects/pshifter.c
 730               Alc/effects/reverb.c
 731               Alc/filters/filter.c
 732               Alc/filters/nfc.c
 733               Alc/helpers.c
 734               Alc/hrtf.c
 735               Alc/uhjfilter.c
 736               Alc/ambdec.c
 737               Alc/bformatdec.c
 738               Alc/panning.c
 739               Alc/mixvoice.c
 740               Alc/mixer/mixer_c.c
 741 )
 742
 743
 744 SET(CPU_EXTS "Default")
 745 SET(HAVE_SSE        0)
 746 SET(HAVE_SSE2       0)
 747 SET(HAVE_SSE3       0)
 748 SET(HAVE_SSE4_1     0)
 749 SET(HAVE_NEON       0)
 750
 751 SET(HAVE_ALSA       0)
 752 SET(HAVE_OSS        0)
 753 SET(HAVE_SOLARIS    0)
 754 SET(HAVE_SNDIO      0)
 755 SET(HAVE_QSA        0)
 756 SET(HAVE_DSOUND     0)
 757 SET(HAVE_WASAPI     0)
 758 SET(HAVE_WINMM      0)
 759 SET(HAVE_PORTAUDIO  0)
 760 SET(HAVE_PULSEAUDIO 0)
 761 SET(HAVE_COREAUDIO  0)
 762 SET(HAVE_OPENSL     0)
 763 SET(HAVE_WAVE       0)
 764 SET(HAVE_SDL2       0)
 765
 766 # Check for SSE support
 767 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 768 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 769 IF(HAVE_XMMINTRIN_H)
 770     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 771     IF(ALSOFT_CPUEXT_SSE)
 772         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 773             SET(HAVE_SSE 1)
 774             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse.c)
 775             IF(SSE_SWITCH)
 776                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse.c PROPERTIES
 777                                             COMPILE_FLAGS "${SSE_SWITCH}")
 778             ENDIF()
 779             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 780         ENDIF()
 781     ENDIF()
 782 ENDIF()
 783 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 784     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 785 ENDIF()
 786
 787 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 788 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 789 IF(HAVE_EMMINTRIN_H)
 790     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 791     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 792         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 793             SET(HAVE_SSE2 1)
 794             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse2.c)
 795             IF(SSE2_SWITCH)
 796                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse2.c PROPERTIES
 797                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 798             ENDIF()
 799             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 800         ENDIF()
 801     ENDIF()
 802 ENDIF()
 803 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 804     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 805 ENDIF()
 806
 807 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE3 support" OFF)
 808 CHECK_INCLUDE_FILE(pmmintrin.h HAVE_PMMINTRIN_H "${SSE3_SWITCH}")
 809 IF(HAVE_EMMINTRIN_H)
 810     OPTION(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 811     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 812         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 813             SET(HAVE_SSE3 1)
 814             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse3.c)
 815             IF(SSE2_SWITCH)
 816                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse3.c PROPERTIES
 817                                             COMPILE_FLAGS "${SSE3_SWITCH}")
 818             ENDIF()
 819             SET(CPU_EXTS "${CPU_EXTS}, SSE3")
 820         ENDIF()
 821     ENDIF()
 822 ENDIF()
 823 IF(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 824     MESSAGE(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 825 ENDIF()
 826
 827 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 828 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 829 IF(HAVE_SMMINTRIN_H)
 830     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 831     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 832         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 833             SET(HAVE_SSE4_1 1)
 834             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_sse41.c)
 835             IF(SSE4_1_SWITCH)
 836                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_sse41.c PROPERTIES
 837                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 838             ENDIF()
 839             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 840         ENDIF()
 841     ENDIF()
 842 ENDIF()
 843 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 844     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 845 ENDIF()
 846
 847 # Check for ARM Neon support
 848 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 849 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 850 IF(HAVE_ARM_NEON_H)
 851     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 852     IF(ALSOFT_CPUEXT_NEON)
 853         SET(HAVE_NEON 1)
 854         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer/mixer_neon.c)
 855         IF(FPU_NEON_SWITCH)
 856             SET_SOURCE_FILES_PROPERTIES(Alc/mixer/mixer_neon.c PROPERTIES
 857                                         COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 858         ENDIF()
 859         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 860     ENDIF()
 861 ENDIF()
 862 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 863     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 864 ENDIF()
 865
 866
 867 IF(WIN32 OR HAVE_DLFCN_H)
 868     SET(IS_LINKED "")
 869     MACRO(ADD_BACKEND_LIBS _LIBS)
 870     ENDMACRO()
 871 ELSE()
 872     SET(IS_LINKED " (linked)")
 873     MACRO(ADD_BACKEND_LIBS _LIBS)
 874         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 875     ENDMACRO()
 876 ENDIF()
 877
 878 SET(BACKENDS "")
 879 SET(ALC_OBJS  ${ALC_OBJS}
 880               Alc/backends/base.c
 881               # Default backends, always available
 882               Alc/backends/loopback.c
 883               Alc/backends/null.c
 884 )
 885
 886 # Check ALSA backend
 887 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 888 FIND_PACKAGE(ALSA)
 889 IF(ALSA_FOUND)
 890     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 891     IF(ALSOFT_BACKEND_ALSA)
 892         SET(HAVE_ALSA 1)
 893         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 894         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 895         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 896         SET(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 897     ENDIF()
 898 ENDIF()
 899 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 900     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 901 ENDIF()
 902
 903 # Check OSS backend
 904 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 905 FIND_PACKAGE(OSS)
 906 IF(OSS_FOUND)
 907     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 908     IF(ALSOFT_BACKEND_OSS)
 909         SET(HAVE_OSS 1)
 910         SET(BACKENDS  "${BACKENDS} OSS,")
 911         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 912         IF(OSS_LIBRARIES)
 913             SET(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 914         ENDIF()
 915         SET(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 916     ENDIF()
 917 ENDIF()
 918 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 919     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 920 ENDIF()
 921
 922 # Check Solaris backend
 923 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 924 FIND_PACKAGE(AudioIO)
 925 IF(AUDIOIO_FOUND)
 926     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 927     IF(ALSOFT_BACKEND_SOLARIS)
 928         SET(HAVE_SOLARIS 1)
 929         SET(BACKENDS  "${BACKENDS} Solaris,")
 930         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 931         SET(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 932     ENDIF()
 933 ENDIF()
 934 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 935     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 936 ENDIF()
 937
 938 # Check SndIO backend
 939 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 940 FIND_PACKAGE(SoundIO)
 941 IF(SOUNDIO_FOUND)
 942     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 943     IF(ALSOFT_BACKEND_SNDIO)
 944         SET(HAVE_SNDIO 1)
 945         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 946         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 947         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 948         SET(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 949     ENDIF()
 950 ENDIF()
 951 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 952     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 953 ENDIF()
 954
 955 # Check QSA backend
 956 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 957 FIND_PACKAGE(QSA)
 958 IF(QSA_FOUND)
 959     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 960     IF(ALSOFT_BACKEND_QSA)
 961         SET(HAVE_QSA 1)
 962         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 963         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 964         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 965         SET(INC_PATHS ${INC_PATHS} ${QSA_INCLUDE_DIRS})
 966     ENDIF()
 967 ENDIF()
 968 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 969     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 970 ENDIF()
 971
 972 # Check Windows-only backends
 973 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 974 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 975 OPTION(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 976 IF(HAVE_WINDOWS_H)
 977     # Check MMSystem backend
 978     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 979     IF(HAVE_MMSYSTEM_H)
 980         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 981         IF(HAVE_LIBWINMM)
 982             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 983             IF(ALSOFT_BACKEND_WINMM)
 984                 SET(HAVE_WINMM 1)
 985                 SET(BACKENDS  "${BACKENDS} WinMM,")
 986                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 987                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 988             ENDIF()
 989         ENDIF()
 990     ENDIF()
 991
 992     # Check DSound backend
 993     FIND_PACKAGE(DSound)
 994     IF(DSOUND_FOUND)
 995         OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 996         IF(ALSOFT_BACKEND_DSOUND)
 997             SET(HAVE_DSOUND 1)
 998             SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 999             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
1000             ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
1001             SET(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
1002         ENDIF()
1003     ENDIF()
1004
1005     # Check for WASAPI backend
1006     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1007     IF(HAVE_MMDEVICEAPI_H)
1008         OPTION(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1009         IF(ALSOFT_BACKEND_WASAPI)
1010             SET(HAVE_WASAPI 1)
1011             SET(BACKENDS  "${BACKENDS} WASAPI,")
1012             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wasapi.c)
1013         ENDIF()
1014     ENDIF()
1015 ENDIF()
1016 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1017     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
1018 ENDIF()
1019 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1020     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
1021 ENDIF()
1022 IF(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1023     MESSAGE(FATAL_ERROR "Failed to enabled required WASAPI backend")
1024 ENDIF()
1025
1026 # Check PortAudio backend
1027 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1028 FIND_PACKAGE(PortAudio)
1029 IF(PORTAUDIO_FOUND)
1030     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1031     IF(ALSOFT_BACKEND_PORTAUDIO)
1032         SET(HAVE_PORTAUDIO 1)
1033         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1034         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
1035         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
1036         SET(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1037     ENDIF()
1038 ENDIF()
1039 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1040     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
1041 ENDIF()
1042
1043 # Check PulseAudio backend
1044 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1045 FIND_PACKAGE(PulseAudio)
1046 IF(PULSEAUDIO_FOUND)
1047     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1048     IF(ALSOFT_BACKEND_PULSEAUDIO)
1049         SET(HAVE_PULSEAUDIO 1)
1050         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1051         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
1052         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
1053         SET(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1054     ENDIF()
1055 ENDIF()
1056 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1057     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1058 ENDIF()
1059
1060 # Check JACK backend
1061 OPTION(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1062 FIND_PACKAGE(JACK)
1063 IF(JACK_FOUND)
1064     OPTION(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1065     IF(ALSOFT_BACKEND_JACK)
1066         SET(HAVE_JACK 1)
1067         SET(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1068         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/jack.c)
1069         ADD_BACKEND_LIBS(${JACK_LIBRARIES})
1070         SET(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1071     ENDIF()
1072 ENDIF()
1073 IF(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1074     MESSAGE(FATAL_ERROR "Failed to enabled required JACK backend")
1075 ENDIF()
1076
1077 # Check CoreAudio backend
1078 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1079 FIND_LIBRARY(COREAUDIO_FRAMEWORK
1080              NAMES CoreAudio
1081              PATHS /System/Library/Frameworks
1082 )
1083 IF(COREAUDIO_FRAMEWORK)
1084     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1085     IF(ALSOFT_BACKEND_COREAUDIO)
1086         SET(HAVE_COREAUDIO 1)
1087         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
1088         SET(BACKENDS  "${BACKENDS} CoreAudio,")
1089         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
1090         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
1091         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1092
1093         # Some versions of OSX may need the AudioToolbox framework. Add it if
1094         # it's found.
1095         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
1096                      NAMES AudioToolbox
1097                      PATHS ~/Library/Frameworks
1098                            /Library/Frameworks
1099                            /System/Library/Frameworks
1100                     )
1101         IF(AUDIOTOOLBOX_LIBRARY)
1102             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1103         ENDIF()
1104     ENDIF()
1105 ENDIF()
1106 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1107     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1108 ENDIF()
1109
1110 # Check for OpenSL (Android) backend
1111 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1112 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
1113 IF(HAVE_SLES_OPENSLES_ANDROID_H)
1114     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
1115     IF(HAVE_LIBOPENSLES)
1116         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1117         IF(ALSOFT_BACKEND_OPENSL)
1118             SET(HAVE_OPENSL 1)
1119             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
1120             SET(BACKENDS  "${BACKENDS} OpenSL,")
1121             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
1122         ENDIF()
1123     ENDIF()
1124 ENDIF()
1125 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1126     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
1127 ENDIF()
1128
1129 # Check for SDL2 backend
1130 OPTION(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1131 FIND_PACKAGE(SDL2)
1132 IF(SDL2_FOUND)
1133     # Off by default, since it adds a runtime dependency
1134     OPTION(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1135     IF(ALSOFT_BACKEND_SDL2)
1136         SET(HAVE_SDL2 1)
1137         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sdl2.c)
1138         SET(BACKENDS  "${BACKENDS} SDL2,")
1139         SET(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1140     ENDIF()
1141 ENDIF()
1142 IF(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1143     MESSAGE(FATAL_ERROR "Failed to enabled required SDL2 backend")
1144 ENDIF()
1145
1146 # Optionally enable the Wave Writer backend
1147 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1148 IF(ALSOFT_BACKEND_WAVE)
1149     SET(HAVE_WAVE 1)
1150     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
1151     SET(BACKENDS  "${BACKENDS} WaveFile,")
1152 ENDIF()
1153
1154 # This is always available
1155 SET(BACKENDS  "${BACKENDS} Null")
1156
1157
1158 FIND_PACKAGE(Git)
1159 IF(GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1160     # Get the current working branch and its latest abbreviated commit hash
1161     ADD_CUSTOM_TARGET(build_version
1162         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE}
1163                          -D LIB_VERSION=${LIB_VERSION}
1164                          -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1165                          -D DST=${OpenAL_BINARY_DIR}/version.h
1166                          -P ${OpenAL_SOURCE_DIR}/version.cmake
1167         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1168         VERBATIM
1169     )
1170 ELSE()
1171     SET(GIT_BRANCH "UNKNOWN")
1172     SET(GIT_COMMIT_HASH "unknown")
1173     CONFIGURE_FILE(
1174         "${OpenAL_SOURCE_DIR}/version.h.in"
1175         "${OpenAL_BINARY_DIR}/version.h")
1176 ENDIF()
1177
1178 SET(NATIVE_SRC_DIR  "${OpenAL_SOURCE_DIR}/native-tools/")
1179 SET(NATIVE_BIN_DIR  "${OpenAL_BINARY_DIR}/native-tools/")
1180 FILE(MAKE_DIRECTORY "${NATIVE_BIN_DIR}")
1181
1182 SET(BIN2H_COMMAND  "${NATIVE_BIN_DIR}bin2h")
1183 SET(BSINCGEN_COMMAND  "${NATIVE_BIN_DIR}bsincgen")
1184 ADD_CUSTOM_COMMAND(OUTPUT "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1185     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" "${NATIVE_SRC_DIR}"
1186     COMMAND ${CMAKE_COMMAND} -E remove "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1187     COMMAND ${CMAKE_COMMAND} --build . --config "Release"
1188     WORKING_DIRECTORY "${NATIVE_BIN_DIR}"
1189     DEPENDS "${NATIVE_SRC_DIR}CMakeLists.txt"
1190     IMPLICIT_DEPENDS C "${NATIVE_SRC_DIR}bin2h.c"
1191                      C "${NATIVE_SRC_DIR}bsincgen.c"
1192     VERBATIM
1193 )
1194 ADD_CUSTOM_TARGET(native-tools
1195     DEPENDS "${BIN2H_COMMAND}" "${BSINCGEN_COMMAND}"
1196     VERBATIM
1197 )
1198
1199 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" OFF)
1200 if(ALSOFT_EMBED_HRTF_DATA)
1201     MACRO(make_hrtf_header FILENAME VARNAME)
1202         SET(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1203         SET(outfile  "${OpenAL_BINARY_DIR}/${FILENAME}.h")
1204
1205         ADD_CUSTOM_COMMAND(OUTPUT "${outfile}"
1206             COMMAND "${BIN2H_COMMAND}" "${infile}" "${outfile}" ${VARNAME}
1207             DEPENDS native-tools "${infile}"
1208             VERBATIM
1209         )
1210         SET(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1211     ENDMACRO()
1212
1213     make_hrtf_header(default-44100.mhr "hrtf_default_44100")
1214     make_hrtf_header(default-48000.mhr "hrtf_default_48000")
1215 endif()
1216
1217 ADD_CUSTOM_COMMAND(OUTPUT "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1218     COMMAND "${BSINCGEN_COMMAND}" "${OpenAL_BINARY_DIR}/bsinc_inc.h"
1219     DEPENDS native-tools "${NATIVE_SRC_DIR}bsincgen.c"
1220     VERBATIM
1221 )
1222 SET(ALC_OBJS  ${ALC_OBJS} "${OpenAL_BINARY_DIR}/bsinc_inc.h")
1223
1224
1225 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1226     add_subdirectory(utils/alsoft-config)
1227 ENDIF()
1228 IF(ALSOFT_EXAMPLES)
1229     IF(NOT SDL2_FOUND)
1230         FIND_PACKAGE(SDL2)
1231     ENDIF()
1232     IF(SDL2_FOUND)
1233         FIND_PACKAGE(SDL_sound)
1234         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1235     ENDIF()
1236 ENDIF()
1237
1238 IF(NOT WIN32)
1239     SET(LIBNAME "openal")
1240 ELSE()
1241     SET(LIBNAME "OpenAL32")
1242 ENDIF()
1243
1244 # Needed for openal.pc.in
1245 SET(prefix ${CMAKE_INSTALL_PREFIX})
1246 SET(exec_prefix "\${prefix}")
1247 SET(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1248 SET(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1249 SET(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1250 SET(PACKAGE_VERSION "${LIB_VERSION}")
1251 IF(LIBTYPE STREQUAL "STATIC")
1252     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
1253 ENDIF()
1254
1255 # End configuration
1256 CONFIGURE_FILE(
1257     "${OpenAL_SOURCE_DIR}/config.h.in"
1258     "${OpenAL_BINARY_DIR}/config.h")
1259 CONFIGURE_FILE(
1260     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1261     "${OpenAL_BINARY_DIR}/openal.pc"
1262     @ONLY)
1263
1264
1265 # Add a static library with common functions used by multiple targets
1266 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
1267 TARGET_COMPILE_DEFINITIONS(common PRIVATE ${CPP_DEFS})
1268 TARGET_COMPILE_OPTIONS(common PRIVATE ${C_FLAGS})
1269
1270
1271 UNSET(HAS_ROUTER)
1272 SET(IMPL_TARGET OpenAL)
1273 SET(COMMON_LIB )
1274 SET(SUBSYS_FLAG )
1275
1276 # Build main library
1277 IF(LIBTYPE STREQUAL "STATIC")
1278     SET(CPP_DEFS ${CPP_DEFS} AL_LIBTYPE_STATIC)
1279     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
1280         SET(CPP_DEFS ${CPP_DEFS} AL_NO_UID_DEFS)
1281     ENDIF()
1282     ADD_LIBRARY(OpenAL STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1283 ELSE()
1284     # Make sure to compile the common code with PIC, since it'll be linked into
1285     # shared libs that needs it.
1286     SET_PROPERTY(TARGET common PROPERTY POSITION_INDEPENDENT_CODE TRUE)
1287     SET(COMMON_LIB common)
1288
1289     IF(WIN32)
1290         IF(MSVC)
1291             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "/SUBSYSTEM:WINDOWS")
1292         ELSEIF(CMAKE_COMPILER_IS_GNUCC)
1293             SET(SUBSYS_FLAG ${SUBSYS_FLAG} "-mwindows")
1294         ENDIF()
1295     ENDIF()
1296
1297     IF(WIN32 AND ALSOFT_BUILD_ROUTER)
1298         ADD_LIBRARY(OpenAL SHARED router/router.c router/alc.c router/al.c)
1299         TARGET_COMPILE_DEFINITIONS(OpenAL
1300             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1301         TARGET_COMPILE_OPTIONS(OpenAL PRIVATE ${C_FLAGS})
1302         TARGET_LINK_LIBRARIES(OpenAL PRIVATE ${LINKER_FLAGS} ${COMMON_LIB})
1303         SET_TARGET_PROPERTIES(OpenAL PROPERTIES PREFIX "")
1304         SET_TARGET_PROPERTIES(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1305         IF(TARGET build_version)
1306             ADD_DEPENDENCIES(OpenAL build_version)
1307         ENDIF()
1308         SET(HAS_ROUTER 1)
1309
1310         SET(LIBNAME "soft_oal")
1311         SET(IMPL_TARGET soft_oal)
1312     ENDIF()
1313
1314     ADD_LIBRARY(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS})
1315     IF(WIN32)
1316         SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES PREFIX "")
1317     ENDIF()
1318 ENDIF()
1319 SET_TARGET_PROPERTIES(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1320     VERSION ${LIB_VERSION}
1321     SOVERSION ${LIB_MAJOR_VERSION}
1322 )
1323 TARGET_COMPILE_DEFINITIONS(${IMPL_TARGET}
1324     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1325 TARGET_INCLUDE_DIRECTORIES(${IMPL_TARGET}
1326     PRIVATE "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc" ${INC_PATHS})
1327 TARGET_COMPILE_OPTIONS(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1328 TARGET_LINK_LIBRARIES(${IMPL_TARGET}
1329     PRIVATE ${LINKER_FLAGS} ${COMMON_LIB} ${EXTRA_LIBS} ${MATH_LIB})
1330 IF(TARGET build_version)
1331     ADD_DEPENDENCIES(${IMPL_TARGET} build_version)
1332 ENDIF()
1333
1334 IF(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1335     FIND_PROGRAM(SED_EXECUTABLE NAMES sed DOC "sed executable")
1336     FIND_PROGRAM(DLLTOOL_EXECUTABLE NAMES "${DLLTOOL}" DOC "dlltool executable")
1337     IF(NOT SED_EXECUTABLE OR NOT DLLTOOL_EXECUTABLE)
1338         MESSAGE(STATUS "")
1339         IF(NOT SED_EXECUTABLE)
1340             MESSAGE(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1341         ENDIF()
1342         IF(NOT DLLTOOL_EXECUTABLE)
1343             MESSAGE(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1344         ENDIF()
1345     ELSE()
1346         SET_PROPERTY(TARGET OpenAL APPEND_STRING PROPERTY LINK_FLAGS
1347                         " -Wl,--output-def,OpenAL32.def")
1348         ADD_CUSTOM_COMMAND(TARGET OpenAL POST_BUILD
1349             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1350             COMMAND "${DLLTOOL_EXECUTABLE}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1351             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1352             VERBATIM
1353         )
1354     ENDIF()
1355 ENDIF()
1356
1357 IF(ALSOFT_INSTALL)
1358     INSTALL(TARGETS OpenAL EXPORT OpenAL
1359             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1360             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1361             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1362             INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL
1363     )
1364     EXPORT(TARGETS OpenAL
1365            NAMESPACE OpenAL::
1366            FILE OpenALConfig.cmake)
1367     INSTALL(EXPORT OpenAL
1368             DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1369             NAMESPACE OpenAL::
1370             FILE OpenALConfig.cmake)
1371     INSTALL(FILES include/AL/al.h
1372                   include/AL/alc.h
1373                   include/AL/alext.h
1374                   include/AL/efx.h
1375                   include/AL/efx-creative.h
1376                   include/AL/efx-presets.h
1377             DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/AL
1378     )
1379     INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1380             DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1381     IF(TARGET soft_oal)
1382         INSTALL(TARGETS soft_oal
1383                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1384         )
1385     ENDIF()
1386 ENDIF()
1387
1388
1389 if(HAS_ROUTER)
1390     message(STATUS "")
1391     message(STATUS "Building DLL router")
1392 endif()
1393
1394 MESSAGE(STATUS "")
1395 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1396 MESSAGE(STATUS "    ${BACKENDS}")
1397 MESSAGE(STATUS "")
1398 MESSAGE(STATUS "Building with support for CPU extensions:")
1399 MESSAGE(STATUS "    ${CPU_EXTS}")
1400 MESSAGE(STATUS "")
1401
1402 IF(WIN32)
1403     IF(NOT HAVE_DSOUND)
1404         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1405         MESSAGE(STATUS "         This is probably NOT what you want!")
1406         MESSAGE(STATUS "")
1407     ENDIF()
1408 ENDIF()
1409
1410 if(ALSOFT_EMBED_HRTF_DATA)
1411     message(STATUS "Embedding HRTF datasets")
1412     message(STATUS "")
1413 endif()
1414
1415 # Install alsoft.conf configuration file
1416 IF(ALSOFT_CONFIG)
1417     INSTALL(FILES alsoftrc.sample
1418             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal
1419     )
1420     MESSAGE(STATUS "Installing sample configuration")
1421     MESSAGE(STATUS "")
1422 ENDIF()
1423
1424 # Install HRTF definitions
1425 IF(ALSOFT_HRTF_DEFS)
1426     INSTALL(FILES hrtf/default-44100.mhr
1427                   hrtf/default-48000.mhr
1428             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/hrtf
1429     )
1430     MESSAGE(STATUS "Installing HRTF definitions")
1431     MESSAGE(STATUS "")
1432 ENDIF()
1433
1434 # Install AmbDec presets
1435 IF(ALSOFT_AMBDEC_PRESETS)
1436     INSTALL(FILES presets/3D7.1.ambdec
1437                   presets/hexagon.ambdec
1438                   presets/itu5.1.ambdec
1439                   presets/itu5.1-nocenter.ambdec
1440                   presets/rectangle.ambdec
1441                   presets/square.ambdec
1442                   presets/presets.txt
1443             DESTINATION ${CMAKE_INSTALL_DATADIR}/openal/presets
1444     )
1445     MESSAGE(STATUS "Installing AmbDec presets")
1446     MESSAGE(STATUS "")
1447 ENDIF()
1448
1449 IF(ALSOFT_UTILS)
1450     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1451     TARGET_COMPILE_OPTIONS(openal-info PRIVATE ${C_FLAGS})
1452     TARGET_LINK_LIBRARIES(openal-info PRIVATE ${LINKER_FLAGS} OpenAL)
1453
1454     SET(MAKEHRTF_SRCS  utils/makehrtf.c)
1455     IF(NOT HAVE_GETOPT)
1456         SET(MAKEHRTF_SRCS  ${MAKEHRTF_SRCS} utils/getopt.c)
1457     ENDIF()
1458     ADD_EXECUTABLE(makehrtf ${MAKEHRTF_SRCS})
1459     TARGET_COMPILE_DEFINITIONS(makehrtf PRIVATE ${CPP_DEFS})
1460     TARGET_COMPILE_OPTIONS(makehrtf PRIVATE ${C_FLAGS})
1461     IF(HAVE_LIBM)
1462         TARGET_LINK_LIBRARIES(makehrtf PRIVATE ${LINKER_FLAGS} m)
1463     ENDIF()
1464
1465     IF(ALSOFT_INSTALL)
1466         INSTALL(TARGETS openal-info makehrtf
1467                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1468                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1469                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1470         )
1471     ENDIF()
1472
1473     MESSAGE(STATUS "Building utility programs")
1474     IF(TARGET alsoft-config)
1475         MESSAGE(STATUS "Building configuration program")
1476     ENDIF()
1477     MESSAGE(STATUS "")
1478 ENDIF()
1479
1480 IF(ALSOFT_TESTS)
1481     SET(TEST_COMMON_OBJS  examples/common/alhelpers.c)
1482
1483     ADD_EXECUTABLE(altonegen examples/altonegen.c ${TEST_COMMON_OBJS})
1484     TARGET_COMPILE_DEFINITIONS(altonegen PRIVATE ${CPP_DEFS})
1485     TARGET_COMPILE_OPTIONS(altonegen PRIVATE ${C_FLAGS})
1486     TARGET_LINK_LIBRARIES(altonegen PRIVATE ${LINKER_FLAGS} common OpenAL ${MATH_LIB})
1487
1488     IF(ALSOFT_INSTALL)
1489         INSTALL(TARGETS altonegen
1490                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1491                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1492                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1493         )
1494     ENDIF()
1495
1496     MESSAGE(STATUS "Building test programs")
1497     MESSAGE(STATUS "")
1498 ENDIF()
1499
1500 IF(ALSOFT_EXAMPLES)
1501     ADD_EXECUTABLE(alrecord examples/alrecord.c)
1502     TARGET_COMPILE_DEFINITIONS(alrecord PRIVATE ${CPP_DEFS})
1503     TARGET_COMPILE_OPTIONS(alrecord PRIVATE ${C_FLAGS})
1504     TARGET_LINK_LIBRARIES(alrecord PRIVATE ${LINKER_FLAGS} common OpenAL)
1505
1506     IF(ALSOFT_INSTALL)
1507         INSTALL(TARGETS alrecord
1508                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1509                 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1510                 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1511         )
1512     ENDIF()
1513
1514     MESSAGE(STATUS "Building example programs")
1515
1516     IF(SDL2_FOUND)
1517         IF(SDL_SOUND_FOUND)
1518             # Add a static library with common functions used by multiple targets
1519             ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c)
1520             TARGET_COMPILE_DEFINITIONS(ex-common PRIVATE ${CPP_DEFS})
1521             TARGET_COMPILE_OPTIONS(ex-common PRIVATE ${C_FLAGS})
1522
1523             ADD_EXECUTABLE(alplay examples/alplay.c)
1524             TARGET_COMPILE_DEFINITIONS(alplay PRIVATE ${CPP_DEFS})
1525             TARGET_INCLUDE_DIRECTORIES(alplay
1526                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1527             TARGET_COMPILE_OPTIONS(alplay PRIVATE ${C_FLAGS})
1528             TARGET_LINK_LIBRARIES(alplay
1529                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1530                         OpenAL)
1531
1532             ADD_EXECUTABLE(alstream examples/alstream.c)
1533             TARGET_COMPILE_DEFINITIONS(alstream PRIVATE ${CPP_DEFS})
1534             TARGET_INCLUDE_DIRECTORIES(alstream
1535                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1536             TARGET_COMPILE_OPTIONS(alstream PRIVATE ${C_FLAGS})
1537             TARGET_LINK_LIBRARIES(alstream
1538                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1539                         OpenAL)
1540
1541             ADD_EXECUTABLE(alreverb examples/alreverb.c)
1542             TARGET_COMPILE_DEFINITIONS(alreverb PRIVATE ${CPP_DEFS})
1543             TARGET_INCLUDE_DIRECTORIES(alreverb
1544                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1545             TARGET_COMPILE_OPTIONS(alreverb PRIVATE ${C_FLAGS})
1546             TARGET_LINK_LIBRARIES(alreverb
1547                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1548                         OpenAL)
1549
1550             ADD_EXECUTABLE(almultireverb examples/almultireverb.c)
1551             TARGET_COMPILE_DEFINITIONS(almultireverb PRIVATE ${CPP_DEFS})
1552             TARGET_INCLUDE_DIRECTORIES(almultireverb
1553                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1554             TARGET_COMPILE_OPTIONS(almultireverb PRIVATE ${C_FLAGS})
1555             TARGET_LINK_LIBRARIES(almultireverb
1556                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1557                         OpenAL ${MATH_LIB})
1558
1559             ADD_EXECUTABLE(allatency examples/allatency.c)
1560             TARGET_COMPILE_DEFINITIONS(allatency PRIVATE ${CPP_DEFS})
1561             TARGET_INCLUDE_DIRECTORIES(allatency
1562                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1563             TARGET_COMPILE_OPTIONS(allatency PRIVATE ${C_FLAGS})
1564             TARGET_LINK_LIBRARIES(allatency
1565                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1566                         OpenAL)
1567
1568             ADD_EXECUTABLE(alloopback examples/alloopback.c)
1569             TARGET_COMPILE_DEFINITIONS(alloopback PRIVATE ${CPP_DEFS})
1570             TARGET_INCLUDE_DIRECTORIES(alloopback
1571                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1572             TARGET_COMPILE_OPTIONS(alloopback PRIVATE ${C_FLAGS})
1573             TARGET_LINK_LIBRARIES(alloopback
1574                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1575                         OpenAL ${MATH_LIB})
1576
1577             ADD_EXECUTABLE(alhrtf examples/alhrtf.c)
1578             TARGET_COMPILE_DEFINITIONS(alhrtf PRIVATE ${CPP_DEFS})
1579             TARGET_INCLUDE_DIRECTORIES(alhrtf
1580                 PRIVATE ${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
1581             TARGET_COMPILE_OPTIONS(alhrtf PRIVATE ${C_FLAGS})
1582             TARGET_LINK_LIBRARIES(alhrtf
1583                 PRIVATE ${LINKER_FLAGS} ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ex-common common
1584                         OpenAL ${MATH_LIB})
1585
1586             IF(ALSOFT_INSTALL)
1587                 INSTALL(TARGETS alplay alstream alreverb almultireverb allatency alloopback alhrtf
1588                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1589                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1590                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1591                 )
1592             ENDIF()
1593
1594             MESSAGE(STATUS "Building SDL_sound example programs")
1595         ENDIF()
1596
1597         SET(FFVER_OK FALSE)
1598         IF(FFMPEG_FOUND)
1599             SET(FFVER_OK TRUE)
1600             IF(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1601                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1602                 SET(FFVER_OK FALSE)
1603             ENDIF()
1604             IF(AVCODEC_VERSION VERSION_LESS "57.64.101")
1605                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1606                 SET(FFVER_OK FALSE)
1607             ENDIF()
1608             IF(AVUTIL_VERSION VERSION_LESS "55.34.101")
1609                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1610                 SET(FFVER_OK FALSE)
1611             ENDIF()
1612             IF(SWSCALE_VERSION VERSION_LESS "4.2.100")
1613                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1614                 SET(FFVER_OK FALSE)
1615             ENDIF()
1616             IF(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1617                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1618                 SET(FFVER_OK FALSE)
1619             ENDIF()
1620         ENDIF()
1621         IF(FFVER_OK)
1622             ADD_EXECUTABLE(alffplay examples/alffplay.cpp)
1623             TARGET_COMPILE_DEFINITIONS(alffplay PRIVATE ${CPP_DEFS})
1624             TARGET_INCLUDE_DIRECTORIES(alffplay
1625                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1626             TARGET_COMPILE_OPTIONS(alffplay PRIVATE ${C_FLAGS})
1627             TARGET_LINK_LIBRARIES(alffplay
1628                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} common OpenAL)
1629
1630             IF(ALSOFT_INSTALL)
1631                 INSTALL(TARGETS alffplay
1632                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1633                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1634                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1635                 )
1636             ENDIF()
1637             MESSAGE(STATUS "Building SDL+FFmpeg example programs")
1638         ENDIF()
1639         MESSAGE(STATUS "")
1640     ENDIF()
1641 ENDIF()