CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   4
   5 PROJECT(OpenAL)
   6
   7 IF(COMMAND CMAKE_POLICY)
   8   CMAKE_POLICY(SET CMP0003 NEW)
   9   CMAKE_POLICY(SET CMP0005 NEW)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 SET(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  13
  14 INCLUDE(CheckFunctionExists)
  15 INCLUDE(CheckLibraryExists)
  16 INCLUDE(CheckSharedFunctionExists)
  17 INCLUDE(CheckIncludeFile)
  18 INCLUDE(CheckIncludeFiles)
  19 INCLUDE(CheckSymbolExists)
  20 INCLUDE(CheckCCompilerFlag)
  21 INCLUDE(CheckCSourceCompiles)
  22 INCLUDE(CheckTypeSize)
  23
  24
  25 SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
  26
  27
  28 IF(WIN32)
  29     # This option is mainly for static linking OpenAL Soft into another project
  30     # that already defines the IDs. It is up to that project to ensure all
  31     # required IDs are defined.
  32     OPTION(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
  33 ELSE()
  34     # These are needed on non-Windows systems for extra features
  35     ADD_DEFINITIONS(-D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700)
  36     SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_GNU_SOURCE=1 -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700")
  37 ENDIF()
  38
  39
  40 OPTION(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  41
  42 OPTION(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  43
  44 OPTION(ALSOFT_UTILS          "Build and install utility programs"         ON)
  45 OPTION(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  46
  47 OPTION(ALSOFT_EXAMPLES  "Build and install example programs"  ON)
  48
  49 OPTION(ALSOFT_CONFIG "Install alsoft.conf sample configuration file" ON)
  50 OPTION(ALSOFT_HRTF_DEFS "Install HRTF definition files" ON)
  51
  52
  53 IF(WIN32)
  54     SET(LIBNAME OpenAL32)
  55     ADD_DEFINITIONS("-D_WIN32 -D_WIN32_WINNT=0x0502")
  56 ELSE()
  57     SET(LIBNAME openal)
  58 ENDIF()
  59
  60 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
  61 IF ("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
  62     ADD_DEFINITIONS("-I/usr/include")
  63     SET(EXTRA_LIBS ${EXTRA_LIBS} -L/usr/lib)
  64 ENDIF()
  65
  66 IF(NOT LIBTYPE)
  67     SET(LIBTYPE SHARED)
  68 ENDIF()
  69
  70 SET(LIB_MAJOR_VERSION "1")
  71 SET(LIB_MINOR_VERSION "15")
  72 SET(LIB_REVISION "1")
  73 SET(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
  74
  75 SET(EXPORT_DECL "")
  76 SET(ALIGN_DECL "")
  77
  78
  79 CHECK_TYPE_SIZE("long" SIZEOF_LONG)
  80 CHECK_TYPE_SIZE("long long" SIZEOF_LONG_LONG)
  81
  82
  83 CHECK_C_COMPILER_FLAG(-std=c99 HAVE_STD_C99)
  84 IF(HAVE_STD_C99)
  85     SET(CMAKE_C_FLAGS "-std=c99 ${CMAKE_C_FLAGS}")
  86 ENDIF()
  87
  88 # MSVC may need workarounds for C99 restrict and inline
  89 IF(MSVC)
  90     # TODO: Once we truly require C99, these restrict and inline checks should go
  91     # away.
  92     CHECK_C_SOURCE_COMPILES("int *restrict foo;
  93                              int main() {return 0;}" HAVE_RESTRICT)
  94     IF(NOT HAVE_RESTRICT)
  95         ADD_DEFINITIONS("-Drestrict=")
  96         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Drestrict=")
  97     ENDIF()
  98
  99     CHECK_C_SOURCE_COMPILES("inline void foo(void) { }
 100                              int main() {return 0;}" HAVE_INLINE)
 101     IF(NOT HAVE_INLINE)
 102         CHECK_C_SOURCE_COMPILES("__inline void foo(void) { }
 103                                  int main() {return 0;}" HAVE___INLINE)
 104         IF(NOT HAVE___INLINE)
 105             MESSAGE(FATAL_ERROR "No inline keyword found, please report!")
 106         ENDIF()
 107
 108         ADD_DEFINITIONS(-Dinline=__inline)
 109         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Dinline=__inline")
 110     ENDIF()
 111 ENDIF()
 112
 113 # Make sure we have C99-style inline semantics with GCC (4.3 or newer).
 114 IF(CMAKE_COMPILER_IS_GNUCC)
 115     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 116     # Force no inlining for the next test.
 117     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -fno-inline")
 118
 119     CHECK_C_SOURCE_COMPILES("extern inline int foo() { return 0; }
 120                              int main() {return foo();}" INLINE_IS_C99)
 121     IF(NOT INLINE_IS_C99)
 122         MESSAGE(FATAL_ERROR "Your compiler does not seem to have C99 inline semantics!
 123                              Please update your compiler for better C99 compliance.")
 124     ENDIF()
 125
 126     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 127 ENDIF()
 128
 129 # Check if we have C99 variable length arrays
 130 CHECK_C_SOURCE_COMPILES(
 131 "int main(int argc, char *argv[])
 132  {
 133      volatile int tmp[argc];
 134      tmp[0] = argv[0][0];
 135      return tmp[0];
 136  }"
 137 HAVE_C99_VLA)
 138
 139 # Check if we have C99 bool
 140 CHECK_C_SOURCE_COMPILES(
 141 "int main(int argc, char *argv[])
 142  {
 143      volatile _Bool ret;
 144      ret = (argc > 1) ? 1 : 0;
 145      return ret ? -1 : 0;
 146  }"
 147 HAVE_C99_BOOL)
 148
 149 # Check if we have C11 static_assert
 150 CHECK_C_SOURCE_COMPILES(
 151 "int main()
 152  {
 153      _Static_assert(sizeof(int) == sizeof(int), \"What\");
 154      return 0;
 155  }"
 156 HAVE_C11_STATIC_ASSERT)
 157
 158 # Check if we have C11 alignas
 159 CHECK_C_SOURCE_COMPILES(
 160 "_Alignas(16) int foo;
 161  int main()
 162  {
 163      return 0;
 164  }"
 165 HAVE_C11_ALIGNAS)
 166
 167 # Check if we have C11 _Atomic
 168 CHECK_C_SOURCE_COMPILES(
 169 "#include <stdatomic.h>
 170  int _Atomic foo;
 171  int main()
 172  {
 173      return atomic_load(&foo);
 174  }"
 175 HAVE_C11_ATOMIC)
 176
 177 # Add definitions, compiler switches, etc.
 178 INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/include" "${OpenAL_BINARY_DIR}")
 179 IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 180     INCLUDE_DIRECTORIES("${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
 181     IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 182         ADD_DEFINITIONS("-DAL_NO_UID_DEFS")
 183     ENDIF()
 184 ENDIF()
 185
 186 IF(NOT CMAKE_BUILD_TYPE)
 187     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 188         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
 189         FORCE)
 190 ENDIF()
 191 IF(NOT CMAKE_DEBUG_POSTFIX)
 192     SET(CMAKE_DEBUG_POSTFIX "" CACHE STRING
 193         "Library postfix for debug builds. Normally left blank."
 194         FORCE)
 195 ENDIF()
 196
 197 IF(MSVC)
 198     # ???
 199     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -D_DEBUG")
 200     SET(CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} -DNDEBUG")
 201     SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -DNDEBUG")
 202     SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -D_DEBUG")
 203     ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
 204     ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
 205     ADD_DEFINITIONS("/wd4098")
 206
 207     IF(NOT DXSDK_DIR)
 208         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 209     ELSE()
 210         STRING(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 211     ENDIF()
 212     IF(DXSDK_DIR)
 213         MESSAGE(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 214         SET(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} "${DXSDK_DIR}/Include")
 215         INCLUDE_DIRECTORIES("${DXSDK_DIR}/Include")
 216         LINK_DIRECTORIES("${DXSDK_DIR}/Lib")
 217     ENDIF()
 218
 219     OPTION(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 220     IF(FORCE_STATIC_VCRT)
 221         FOREACH(flag_var
 222                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 223                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 224             IF(${flag_var} MATCHES "/MD")
 225                 STRING(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 226             ENDIF()
 227         ENDFOREACH(flag_var)
 228     ENDIF()
 229 ELSE()
 230     ADD_DEFINITIONS(-Winline -Wall)
 231     CHECK_C_COMPILER_FLAG(-Wextra HAVE_W_EXTRA)
 232     IF(HAVE_W_EXTRA)
 233         ADD_DEFINITIONS(-Wextra)
 234     ENDIF()
 235
 236     IF(ALSOFT_WERROR)
 237         ADD_DEFINITIONS(-Werror)
 238     ENDIF()
 239
 240     # Force enable PIC if available. The static common library will be linked
 241     # into the dynamic openal library, which requires all its code to be
 242     # position-independent, and CMake doesn't automatically enable PIC for
 243     # static library targets (Windows code is always position-independent).
 244     CHECK_C_COMPILER_FLAG(-fPIC HAVE_FPIC_SWITCH)
 245     IF(HAVE_FPIC_SWITCH AND NOT WIN32)
 246         ADD_DEFINITIONS(-fPIC)
 247     ENDIF()
 248
 249     SET(CMAKE_C_FLAGS_RELWITHDEBINFO "-g -O2 -D_DEBUG" CACHE STRING
 250         "Flags used by the compiler during Release with Debug Info builds."
 251         FORCE)
 252     SET(CMAKE_C_FLAGS_MINSIZEREL "-Os -DNDEBUG" CACHE STRING
 253         "Flags used by the compiler during release minsize builds."
 254         FORCE)
 255     SET(CMAKE_C_FLAGS_RELEASE "-O2 -fomit-frame-pointer -DNDEBUG" CACHE STRING
 256         "Flags used by the compiler during release builds"
 257         FORCE)
 258     SET(CMAKE_C_FLAGS_DEBUG "-g3 -D_DEBUG" CACHE STRING
 259         "Flags used by the compiler during debug builds."
 260         FORCE)
 261
 262     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((destructor));
 263                              int main() {return 0;}" HAVE_GCC_DESTRUCTOR)
 264 ENDIF()
 265
 266 # Set visibility/export options if available
 267 IF(WIN32)
 268     SET(EXPORT_DECL "__declspec(dllexport)")
 269     IF(NOT MINGW)
 270         SET(ALIGN_DECL "__declspec(align(x))")
 271     ELSE()
 272         SET(ALIGN_DECL "__declspec(aligned(x))")
 273     ENDIF()
 274 ELSE()
 275     SET(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 276     # Yes GCC, really don't accept visibility modes you don't support
 277     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 278
 279     CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"protected\")));
 280                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 281     IF(HAVE_GCC_PROTECTED_VISIBILITY)
 282         SET(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 283     ELSE()
 284         CHECK_C_SOURCE_COMPILES("int foo() __attribute__((visibility(\"default\")));
 285                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 286         IF(HAVE_GCC_DEFAULT_VISIBILITY)
 287             SET(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 288         ENDIF()
 289     ENDIF()
 290
 291     IF(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 292         CHECK_C_COMPILER_FLAG(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 293         IF(HAVE_VISIBILITY_HIDDEN_SWITCH)
 294             ADD_DEFINITIONS(-fvisibility=hidden)
 295         ENDIF()
 296     ENDIF()
 297
 298     CHECK_C_SOURCE_COMPILES("int foo __attribute__((aligned(16)));
 299                              int main() {return 0;}" HAVE_ATTRIBUTE_ALIGNED)
 300     IF(HAVE_ATTRIBUTE_ALIGNED)
 301         SET(ALIGN_DECL "__attribute__((aligned(x)))")
 302     ENDIF()
 303
 304     SET(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 305 ENDIF()
 306
 307 SET(SSE_SWITCH "")
 308 SET(SSE2_SWITCH "")
 309 SET(SSE4_1_SWITCH "")
 310 IF(NOT MSVC)
 311     CHECK_C_COMPILER_FLAG(-msse HAVE_MSSE_SWITCH)
 312     IF(HAVE_MSSE_SWITCH)
 313         SET(SSE_SWITCH "-msse")
 314     ENDIF()
 315     CHECK_C_COMPILER_FLAG(-msse2 HAVE_MSSE2_SWITCH)
 316     IF(HAVE_MSSE2_SWITCH)
 317         SET(SSE2_SWITCH "-msse2")
 318     ENDIF()
 319     CHECK_C_COMPILER_FLAG(-msse4.1 HAVE_MSSE4_1_SWITCH)
 320     IF(HAVE_MSSE4_1_SWITCH)
 321         SET(SSE4_1_SWITCH "-msse4.1")
 322     ENDIF()
 323 ENDIF()
 324
 325 CHECK_C_SOURCE_COMPILES("int foo(const char *str, ...) __attribute__((format(printf, 1, 2)));
 326                          int main() {return 0;}" HAVE_GCC_FORMAT)
 327
 328 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 329 CHECK_INCLUDE_FILE(stdalign.h HAVE_STDALIGN_H)
 330 CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 331 CHECK_INCLUDE_FILE(ftw.h HAVE_FTW_H)
 332 CHECK_INCLUDE_FILE(io.h HAVE_IO_H)
 333 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 334 CHECK_INCLUDE_FILE(cpuid.h HAVE_CPUID_H)
 335 CHECK_INCLUDE_FILE(sys/sysconf.h HAVE_SYS_SYSCONF_H)
 336 CHECK_INCLUDE_FILE(fenv.h HAVE_FENV_H)
 337 CHECK_INCLUDE_FILE(float.h HAVE_FLOAT_H)
 338 CHECK_INCLUDE_FILE(ieeefp.h HAVE_IEEEFP_H)
 339 CHECK_INCLUDE_FILE(guiddef.h HAVE_GUIDDEF_H)
 340 IF(NOT HAVE_GUIDDEF_H)
 341     CHECK_INCLUDE_FILE(initguid.h HAVE_INITGUID_H)
 342 ENDIF()
 343
 344 # Some systems need libm for some of the following math functions to work
 345 CHECK_LIBRARY_EXISTS(m pow "" HAVE_LIBM)
 346 IF(HAVE_LIBM)
 347     SET(EXTRA_LIBS m ${EXTRA_LIBS})
 348     SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 349 ENDIF()
 350
 351
 352 CHECK_SYMBOL_EXISTS(aligned_alloc    stdlib.h HAVE_ALIGNED_ALLOC)
 353 CHECK_SYMBOL_EXISTS(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 354 CHECK_SYMBOL_EXISTS(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 355 CHECK_SYMBOL_EXISTS(lrintf math.h HAVE_LRINTF)
 356 IF(NOT HAVE_C99_VLA)
 357     CHECK_SYMBOL_EXISTS(alloca malloc.h HAVE_ALLOCA)
 358     IF(NOT HAVE_ALLOCA)
 359         MESSAGE(FATAL_ERROR "No alloca function found, please report!")
 360     ENDIF()
 361 ENDIF()
 362
 363 IF(HAVE_FLOAT_H)
 364     CHECK_SYMBOL_EXISTS(_controlfp float.h HAVE__CONTROLFP)
 365     CHECK_SYMBOL_EXISTS(__control87_2 float.h HAVE___CONTROL87_2)
 366 ENDIF()
 367 IF(HAVE_FTW_H)
 368     CHECK_SYMBOL_EXISTS(ftw ftw.h HAVE_FTW)
 369 ENDIF()
 370 IF(HAVE_IO_H)
 371     CHECK_SYMBOL_EXISTS(_wfindfirst io.h HAVE__WFINDFIRST)
 372 ENDIF()
 373
 374 CHECK_FUNCTION_EXISTS(strtof HAVE_STRTOF)
 375 CHECK_FUNCTION_EXISTS(stat HAVE_STAT)
 376 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 377 IF(NOT HAVE_STRCASECMP)
 378     CHECK_FUNCTION_EXISTS(_stricmp HAVE__STRICMP)
 379     IF(NOT HAVE__STRICMP)
 380         MESSAGE(FATAL_ERROR "No case-insensitive compare function found, please report!")
 381     ENDIF()
 382
 383     ADD_DEFINITIONS(-Dstrcasecmp=_stricmp)
 384 ENDIF()
 385
 386 CHECK_FUNCTION_EXISTS(strncasecmp HAVE_STRNCASECMP)
 387 IF(NOT HAVE_STRNCASECMP)
 388     CHECK_FUNCTION_EXISTS(_strnicmp HAVE__STRNICMP)
 389     IF(NOT HAVE__STRNICMP)
 390         MESSAGE(FATAL_ERROR "No case-insensitive size-limitted compare function found, please report!")
 391     ENDIF()
 392
 393     ADD_DEFINITIONS(-Dstrncasecmp=_strnicmp)
 394 ENDIF()
 395
 396 CHECK_FUNCTION_EXISTS(snprintf HAVE_SNPRINTF)
 397 IF(NOT HAVE_SNPRINTF)
 398     CHECK_FUNCTION_EXISTS(_snprintf HAVE__SNPRINTF)
 399     IF(NOT HAVE__SNPRINTF)
 400         MESSAGE(FATAL_ERROR "No snprintf function found, please report!")
 401     ENDIF()
 402
 403     ADD_DEFINITIONS(-Dsnprintf=_snprintf)
 404 ENDIF()
 405
 406 CHECK_SYMBOL_EXISTS(isfinite math.h HAVE_ISFINITE)
 407 IF(NOT HAVE_ISFINITE)
 408     CHECK_FUNCTION_EXISTS(finite HAVE_FINITE)
 409     IF(NOT HAVE_FINITE)
 410         CHECK_FUNCTION_EXISTS(_finite HAVE__FINITE)
 411         IF(NOT HAVE__FINITE)
 412             MESSAGE(FATAL_ERROR "No isfinite function found, please report!")
 413         ENDIF()
 414         ADD_DEFINITIONS(-Disfinite=_finite)
 415     ELSE()
 416         ADD_DEFINITIONS(-Disfinite=finite)
 417     ENDIF()
 418 ENDIF()
 419
 420 CHECK_SYMBOL_EXISTS(isnan math.h HAVE_ISNAN)
 421 IF(NOT HAVE_ISNAN)
 422     CHECK_FUNCTION_EXISTS(_isnan HAVE__ISNAN)
 423     IF(NOT HAVE__ISNAN)
 424         MESSAGE(FATAL_ERROR "No isnan function found, please report!")
 425     ENDIF()
 426
 427     ADD_DEFINITIONS(-Disnan=_isnan)
 428 ENDIF()
 429
 430
 431 # Check for the dlopen API (for dynamicly loading backend libs)
 432 IF(ALSOFT_DLOPEN)
 433     CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 434     IF(HAVE_DLFCN_H)
 435         CHECK_LIBRARY_EXISTS(dl dlopen "" HAVE_LIBDL)
 436         IF(HAVE_LIBDL)
 437             SET(EXTRA_LIBS dl ${EXTRA_LIBS})
 438         ENDIF()
 439     ENDIF()
 440 ENDIF()
 441
 442 # Check if we have Windows headers
 443 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H -D_WIN32_WINNT=0x0502)
 444 IF(NOT HAVE_WINDOWS_H)
 445     CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 446     IF(NOT HAVE_GETTIMEOFDAY)
 447         MESSAGE(FATAL_ERROR "No timing function found!")
 448     ENDIF()
 449
 450     CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 451     IF(NOT HAVE_NANOSLEEP)
 452         MESSAGE(FATAL_ERROR "No sleep function found!")
 453     ENDIF()
 454
 455     # We need pthreads outside of Windows
 456     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD_H)
 457     IF(NOT HAVE_PTHREAD_H)
 458         MESSAGE(FATAL_ERROR "PThreads is required for non-Windows builds!")
 459     ENDIF()
 460     # Some systems need pthread_np.h to get recursive mutexes
 461     CHECK_INCLUDE_FILES("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 462
 463     CHECK_C_COMPILER_FLAG(-pthread HAVE_PTHREAD)
 464     IF(HAVE_PTHREAD)
 465         ADD_DEFINITIONS(-pthread)
 466         SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 467         SET(EXTRA_LIBS ${EXTRA_LIBS} -pthread)
 468     ENDIF()
 469
 470     CHECK_LIBRARY_EXISTS(pthread pthread_create "" HAVE_LIBPTHREAD)
 471     IF(HAVE_LIBPTHREAD)
 472         SET(EXTRA_LIBS pthread ${EXTRA_LIBS})
 473     ENDIF()
 474
 475     CHECK_SYMBOL_EXISTS(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 476
 477     CHECK_SYMBOL_EXISTS(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 478     IF(NOT HAVE_PTHREAD_SETNAME_NP)
 479         CHECK_SYMBOL_EXISTS(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 480     ENDIF()
 481     IF(HAVE_PTHREAD_NP_H)
 482         CHECK_SYMBOL_EXISTS(pthread_mutexattr_setkind_np "pthread.h;pthread_np.h" HAVE_PTHREAD_MUTEXATTR_SETKIND_NP)
 483     ENDIF()
 484
 485     CHECK_SYMBOL_EXISTS(pthread_mutex_timedlock pthread.h HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 486
 487     CHECK_LIBRARY_EXISTS(rt clock_gettime "" HAVE_LIBRT)
 488     IF(HAVE_LIBRT)
 489         SET(EXTRA_LIBS rt ${EXTRA_LIBS})
 490     ENDIF()
 491 ENDIF()
 492
 493 # Check for a 64-bit type
 494 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 495 IF(NOT HAVE_STDINT_H)
 496     IF(HAVE_WINDOWS_H)
 497         CHECK_C_SOURCE_COMPILES("#define _WIN32_WINNT 0x0502
 498                                  #include <windows.h>
 499                                  __int64 foo;
 500                                  int main() {return 0;}" HAVE___INT64)
 501     ENDIF()
 502     IF(NOT HAVE___INT64)
 503         IF(NOT SIZEOF_LONG MATCHES "8")
 504             IF(NOT SIZEOF_LONG_LONG MATCHES "8")
 505                 MESSAGE(FATAL_ERROR "No 64-bit types found, please report!")
 506             ENDIF()
 507         ENDIF()
 508     ENDIF()
 509 ENDIF()
 510
 511
 512 SET(COMMON_OBJS  common/atomic.c
 513                  common/rwlock.c
 514                  common/threads.c
 515                  common/uintmap.c
 516 )
 517 SET(OPENAL_OBJS  OpenAL32/alAuxEffectSlot.c
 518                  OpenAL32/alBuffer.c
 519                  OpenAL32/alEffect.c
 520                  OpenAL32/alError.c
 521                  OpenAL32/alExtension.c
 522                  OpenAL32/alFilter.c
 523                  OpenAL32/alFontsound.c
 524                  OpenAL32/alListener.c
 525                  OpenAL32/alMidi.c
 526                  OpenAL32/alPreset.c
 527                  OpenAL32/alSoundfont.c
 528                  OpenAL32/alSource.c
 529                  OpenAL32/alState.c
 530                  OpenAL32/alThunk.c
 531                  OpenAL32/sample_cvt.c
 532 )
 533 SET(ALC_OBJS  Alc/ALc.c
 534               Alc/ALu.c
 535               Alc/alcConfig.c
 536               Alc/alcRing.c
 537               Alc/bs2b.c
 538               Alc/effects/autowah.c
 539               Alc/effects/chorus.c
 540               Alc/effects/compressor.c
 541               Alc/effects/dedicated.c
 542               Alc/effects/distortion.c
 543               Alc/effects/echo.c
 544               Alc/effects/equalizer.c
 545               Alc/effects/flanger.c
 546               Alc/effects/modulator.c
 547               Alc/effects/null.c
 548               Alc/effects/reverb.c
 549               Alc/helpers.c
 550               Alc/hrtf.c
 551               Alc/panning.c
 552               Alc/mixer.c
 553               Alc/mixer_c.c
 554 )
 555
 556
 557 SET(CPU_EXTS "Default")
 558 SET(HAVE_SSE 0)
 559 SET(HAVE_SSE2 0)
 560 SET(HAVE_SSE4_1 0)
 561 SET(HAVE_NEON 0)
 562
 563 # Check for SSE support
 564 OPTION(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 565 CHECK_INCLUDE_FILE(xmmintrin.h HAVE_XMMINTRIN_H "${SSE_SWITCH}")
 566 IF(HAVE_XMMINTRIN_H)
 567     OPTION(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 568     IF(ALSOFT_CPUEXT_SSE)
 569         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 570             SET(HAVE_SSE 1)
 571             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse.c)
 572             IF(SSE_SWITCH)
 573                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse.c PROPERTIES
 574                                             COMPILE_FLAGS "${SSE_SWITCH}")
 575             ENDIF()
 576             SET(CPU_EXTS "${CPU_EXTS}, SSE")
 577         ENDIF()
 578     ENDIF()
 579 ENDIF()
 580 IF(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 581     MESSAGE(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 582 ENDIF()
 583
 584 OPTION(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 585 CHECK_INCLUDE_FILE(emmintrin.h HAVE_EMMINTRIN_H "${SSE2_SWITCH}")
 586 IF(HAVE_EMMINTRIN_H)
 587     OPTION(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 588     IF(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 589         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 590             SET(HAVE_SSE2 1)
 591             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse2.c)
 592             IF(SSE2_SWITCH)
 593                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse2.c PROPERTIES
 594                                             COMPILE_FLAGS "${SSE2_SWITCH}")
 595             ENDIF()
 596             SET(CPU_EXTS "${CPU_EXTS}, SSE2")
 597         ENDIF()
 598     ENDIF()
 599 ENDIF()
 600 IF(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 601     MESSAGE(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 602 ENDIF()
 603
 604 OPTION(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 605 CHECK_INCLUDE_FILE(smmintrin.h HAVE_SMMINTRIN_H "${SSE4_1_SWITCH}")
 606 IF(HAVE_SMMINTRIN_H)
 607     OPTION(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 608     IF(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE4_1)
 609         IF(ALIGN_DECL OR HAVE_C11_ALIGNAS)
 610             SET(HAVE_SSE4_1 1)
 611             SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_sse41.c)
 612             IF(SSE4_1_SWITCH)
 613                 SET_SOURCE_FILES_PROPERTIES(Alc/mixer_sse41.c PROPERTIES
 614                                             COMPILE_FLAGS "${SSE4_1_SWITCH}")
 615             ENDIF()
 616             SET(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 617         ENDIF()
 618     ENDIF()
 619 ENDIF()
 620 IF(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 621     MESSAGE(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 622 ENDIF()
 623
 624 # Check for ARM Neon support
 625 OPTION(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 626 CHECK_INCLUDE_FILE(arm_neon.h HAVE_ARM_NEON_H)
 627 IF(HAVE_ARM_NEON_H)
 628     OPTION(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 629     IF(ALSOFT_CPUEXT_NEON)
 630         SET(HAVE_NEON 1)
 631         SET(ALC_OBJS  ${ALC_OBJS} Alc/mixer_neon.c)
 632         SET(CPU_EXTS "${CPU_EXTS}, Neon")
 633     ENDIF()
 634 ENDIF()
 635 IF(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 636     MESSAGE(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 637 ENDIF()
 638
 639
 640 SET(ALC_OBJS  ${ALC_OBJS}
 641               Alc/midi/base.c
 642               Alc/midi/sf2load.c
 643               Alc/midi/dummy.c
 644               Alc/midi/fluidsynth.c
 645               Alc/midi/soft.c
 646 )
 647
 648 SET(HAVE_FLUIDSYNTH  0)
 649
 650 # Check for FluidSynth support
 651 OPTION(ALSOFT_REQUIRE_FLUIDSYNTH "Require FluidSynth MIDI" OFF)
 652 FIND_PACKAGE(FluidSynth)
 653 IF(FLUIDSYNTH_FOUND)
 654     OPTION(ALSOFT_MIDI_FLUIDSYNTH "Enable FluidSynth MIDI" ON)
 655     IF(ALSOFT_MIDI_FLUIDSYNTH)
 656         SET(HAVE_FLUIDSYNTH 1)
 657         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 658             INCLUDE_DIRECTORIES(${FLUIDSYNTH_INCLUDE_DIR})
 659         ENDIF()
 660         SET(EXTRA_LIBS ${FLUIDSYNTH_LIBRARIES} ${EXTRA_LIBS})
 661     ENDIF()
 662 ENDIF()
 663 IF(ALSOFT_REQUIRE_FLUIDSYNTH AND NOT HAVE_FLUIDSYNTH)
 664     MESSAGE(FATAL_ERROR "Failed to enabled required FluidSynth support")
 665 ENDIF()
 666
 667
 668 SET(ALC_OBJS  ${ALC_OBJS}
 669               Alc/backends/base.c
 670               # Default backends, always available
 671               Alc/backends/loopback.c
 672               Alc/backends/null.c
 673 )
 674
 675 SET(BACKENDS "")
 676 SET(HAVE_ALSA       0)
 677 SET(HAVE_OSS        0)
 678 SET(HAVE_SOLARIS    0)
 679 SET(HAVE_SNDIO      0)
 680 SET(HAVE_QSA        0)
 681 SET(HAVE_DSOUND     0)
 682 SET(HAVE_MMDEVAPI   0)
 683 SET(HAVE_WINMM      0)
 684 SET(HAVE_PORTAUDIO  0)
 685 SET(HAVE_PULSEAUDIO 0)
 686 SET(HAVE_COREAUDIO  0)
 687 SET(HAVE_OPENSL     0)
 688 SET(HAVE_WAVE       0)
 689 IF(WIN32 OR HAVE_DLFCN_H)
 690     SET(IS_LINKED "")
 691     MACRO(ADD_BACKEND_LIBS _LIBS)
 692     ENDMACRO()
 693 ELSE()
 694     SET(IS_LINKED " (linked)")
 695     MACRO(ADD_BACKEND_LIBS _LIBS)
 696         SET(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 697     ENDMACRO()
 698 ENDIF()
 699
 700 # Check ALSA backend
 701 OPTION(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 702 FIND_PACKAGE(ALSA)
 703 IF(ALSA_FOUND)
 704     OPTION(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 705     IF(ALSOFT_BACKEND_ALSA)
 706         SET(HAVE_ALSA 1)
 707         SET(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 708         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/alsa.c)
 709         ADD_BACKEND_LIBS(${ALSA_LIBRARIES})
 710         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 711             INCLUDE_DIRECTORIES(${ALSA_INCLUDE_DIRS})
 712         ENDIF()
 713     ENDIF()
 714 ENDIF()
 715 IF(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 716     MESSAGE(FATAL_ERROR "Failed to enabled required ALSA backend")
 717 ENDIF()
 718
 719 # Check OSS backend
 720 OPTION(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 721 FIND_PACKAGE(OSS)
 722 IF(OSS_FOUND)
 723     OPTION(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 724     IF(ALSOFT_BACKEND_OSS)
 725         SET(HAVE_OSS 1)
 726         SET(BACKENDS  "${BACKENDS} OSS,")
 727         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/oss.c)
 728         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 729             INCLUDE_DIRECTORIES(${OSS_INCLUDE_DIRS})
 730         ENDIF()
 731     ENDIF()
 732 ENDIF()
 733 IF(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 734     MESSAGE(FATAL_ERROR "Failed to enabled required OSS backend")
 735 ENDIF()
 736
 737 # Check Solaris backend
 738 OPTION(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 739 FIND_PACKAGE(AudioIO)
 740 IF(AUDIOIO_FOUND)
 741     OPTION(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 742     IF(ALSOFT_BACKEND_SOLARIS)
 743         SET(HAVE_SOLARIS 1)
 744         SET(BACKENDS  "${BACKENDS} Solaris,")
 745         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/solaris.c)
 746         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 747             INCLUDE_DIRECTORIES(${AUDIOIO_INCLUDE_DIRS})
 748         ENDIF()
 749     ENDIF()
 750 ENDIF()
 751 IF(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 752     MESSAGE(FATAL_ERROR "Failed to enabled required Solaris backend")
 753 ENDIF()
 754
 755 # Check SndIO backend
 756 OPTION(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 757 FIND_PACKAGE(SoundIO)
 758 IF(SOUNDIO_FOUND)
 759     OPTION(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 760     IF(ALSOFT_BACKEND_SNDIO)
 761         SET(HAVE_SNDIO 1)
 762         SET(BACKENDS  "${BACKENDS} SndIO (linked),")
 763         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/sndio.c)
 764         SET(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 765         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 766             INCLUDE_DIRECTORIES(${SOUNDIO_INCLUDE_DIRS})
 767         ENDIF()
 768     ENDIF()
 769 ENDIF()
 770 IF(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 771     MESSAGE(FATAL_ERROR "Failed to enabled required SndIO backend")
 772 ENDIF()
 773
 774 # Check QSA backend
 775 OPTION(ALSOFT_REQUIRE_QSA "Require QSA backend" OFF)
 776 FIND_PACKAGE(QSA)
 777 IF(QSA_FOUND)
 778     OPTION(ALSOFT_BACKEND_QSA "Enable QSA backend" ON)
 779     IF(ALSOFT_BACKEND_QSA)
 780         SET(HAVE_QSA 1)
 781         SET(BACKENDS  "${BACKENDS} QSA (linked),")
 782         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/qsa.c)
 783         SET(EXTRA_LIBS ${QSA_LIBRARIES} ${EXTRA_LIBS})
 784         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 785             INCLUDE_DIRECTORIES(${QSA_INCLUDE_DIRS})
 786         ENDIF()
 787     ENDIF()
 788 ENDIF()
 789 IF(ALSOFT_REQUIRE_QSA AND NOT HAVE_QSA)
 790     MESSAGE(FATAL_ERROR "Failed to enabled required QSA backend")
 791 ENDIF()
 792
 793 # Check DSound backend
 794 OPTION(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 795 FIND_PACKAGE(DSound)
 796 IF(DSOUND_FOUND)
 797     OPTION(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 798     IF(ALSOFT_BACKEND_DSOUND)
 799         SET(HAVE_DSOUND 1)
 800         SET(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 801         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/dsound.c)
 802         ADD_BACKEND_LIBS(${DSOUND_LIBRARIES})
 803         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 804             INCLUDE_DIRECTORIES(${DSOUND_INCLUDE_DIRS})
 805         ENDIF()
 806     ENDIF()
 807 ENDIF()
 808 IF(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 809     MESSAGE(FATAL_ERROR "Failed to enabled required DSound backend")
 810 ENDIF()
 811
 812 # Check for MMDevApi backend
 813 OPTION(ALSOFT_REQUIRE_MMDEVAPI "Require MMDevApi backend" OFF)
 814 IF(HAVE_WINDOWS_H)
 815     CHECK_INCLUDE_FILE(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 816     IF(HAVE_MMDEVICEAPI_H)
 817         OPTION(ALSOFT_BACKEND_MMDEVAPI "Enable MMDevApi backend" ON)
 818         IF(ALSOFT_BACKEND_MMDEVAPI)
 819             SET(HAVE_MMDEVAPI 1)
 820             SET(BACKENDS  "${BACKENDS} MMDevApi,")
 821             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/mmdevapi.c)
 822         ENDIF()
 823     ENDIF()
 824 ENDIF()
 825 IF(ALSOFT_REQUIRE_MMDEVAPI AND NOT HAVE_MMDEVAPI)
 826     MESSAGE(FATAL_ERROR "Failed to enabled required MMDevApi backend")
 827 ENDIF()
 828
 829 # Check MMSystem backend
 830 OPTION(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 831 IF(HAVE_WINDOWS_H)
 832     CHECK_INCLUDE_FILES("windows.h;mmsystem.h" HAVE_MMSYSTEM_H -D_WIN32_WINNT=0x0502)
 833     IF(HAVE_MMSYSTEM_H)
 834         CHECK_SHARED_FUNCTION_EXISTS(waveOutOpen "windows.h;mmsystem.h" winmm "" HAVE_LIBWINMM)
 835         IF(HAVE_LIBWINMM)
 836             OPTION(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 837             IF(ALSOFT_BACKEND_WINMM)
 838                 SET(HAVE_WINMM 1)
 839                 SET(BACKENDS  "${BACKENDS} WinMM,")
 840                 SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/winmm.c)
 841                 SET(EXTRA_LIBS winmm ${EXTRA_LIBS})
 842             ENDIF()
 843         ENDIF()
 844     ENDIF()
 845 ENDIF()
 846 IF(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 847     MESSAGE(FATAL_ERROR "Failed to enabled required WinMM backend")
 848 ENDIF()
 849
 850 # Check PortAudio backend
 851 OPTION(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 852 FIND_PACKAGE(PortAudio)
 853 IF(PORTAUDIO_FOUND)
 854     OPTION(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 855     IF(ALSOFT_BACKEND_PORTAUDIO)
 856         SET(HAVE_PORTAUDIO 1)
 857         SET(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 858         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/portaudio.c)
 859         ADD_BACKEND_LIBS(${PORTAUDIO_LIBRARIES})
 860         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 861             INCLUDE_DIRECTORIES(${PORTAUDIO_INCLUDE_DIRS})
 862         ENDIF()
 863     ENDIF()
 864 ENDIF()
 865 IF(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 866     MESSAGE(FATAL_ERROR "Failed to enabled required PortAudio backend")
 867 ENDIF()
 868
 869 # Check PulseAudio backend
 870 OPTION(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 871 FIND_PACKAGE(PulseAudio)
 872 IF(PULSEAUDIO_FOUND)
 873     OPTION(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 874     IF(ALSOFT_BACKEND_PULSEAUDIO)
 875         SET(HAVE_PULSEAUDIO 1)
 876         SET(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 877         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/pulseaudio.c)
 878         ADD_BACKEND_LIBS(${PULSEAUDIO_LIBRARIES})
 879         IF(CMAKE_VERSION VERSION_LESS "2.8.8")
 880             INCLUDE_DIRECTORIES(${PULSEAUDIO_INCLUDE_DIRS})
 881         ENDIF()
 882     ENDIF()
 883 ENDIF()
 884 IF(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 885     MESSAGE(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 886 ENDIF()
 887
 888 # Check CoreAudio backend
 889 OPTION(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 890 FIND_LIBRARY(COREAUDIO_FRAMEWORK
 891              NAMES CoreAudio
 892              PATHS /System/Library/Frameworks
 893 )
 894 IF(COREAUDIO_FRAMEWORK)
 895     OPTION(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 896     IF(ALSOFT_BACKEND_COREAUDIO)
 897         SET(HAVE_COREAUDIO 1)
 898         SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/coreaudio.c)
 899         SET(BACKENDS  "${BACKENDS} CoreAudio,")
 900         SET(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${EXTRA_LIBS})
 901         SET(EXTRA_LIBS /System/Library/Frameworks/AudioUnit.framework ${EXTRA_LIBS})
 902         SET(EXTRA_LIBS /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 903
 904         # Some versions of OSX may need the AudioToolbox framework. Add it if
 905         # it's found.
 906         FIND_LIBRARY(AUDIOTOOLBOX_LIBRARY
 907                      NAMES AudioToolbox
 908                      PATHS ~/Library/Frameworks
 909                            /Library/Frameworks
 910                            /System/Library/Frameworks
 911                     )
 912         IF(AUDIOTOOLBOX_LIBRARY)
 913             SET(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
 914         ENDIF()
 915     ENDIF()
 916 ENDIF()
 917 IF(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
 918     MESSAGE(FATAL_ERROR "Failed to enabled required CoreAudio backend")
 919 ENDIF()
 920
 921 # Check for OpenSL (Android) backend
 922 OPTION(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
 923 CHECK_INCLUDE_FILES("SLES/OpenSLES.h;SLES/OpenSLES_Android.h" HAVE_SLES_OPENSLES_ANDROID_H)
 924 IF(HAVE_SLES_OPENSLES_ANDROID_H)
 925     CHECK_SHARED_FUNCTION_EXISTS(slCreateEngine "SLES/OpenSLES.h" OpenSLES "" HAVE_LIBOPENSLES)
 926     IF(HAVE_LIBOPENSLES)
 927         OPTION(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
 928         IF(ALSOFT_BACKEND_OPENSL)
 929             SET(HAVE_OPENSL 1)
 930             SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/opensl.c)
 931             SET(BACKENDS  "${BACKENDS} OpenSL,")
 932             SET(EXTRA_LIBS OpenSLES ${EXTRA_LIBS})
 933         ENDIF()
 934     ENDIF()
 935 ENDIF()
 936 IF(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
 937     MESSAGE(FATAL_ERROR "Failed to enabled required OpenSL backend")
 938 ENDIF()
 939
 940 # Optionally enable the Wave Writer backend
 941 OPTION(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
 942 IF(ALSOFT_BACKEND_WAVE)
 943     SET(HAVE_WAVE 1)
 944     SET(ALC_OBJS  ${ALC_OBJS} Alc/backends/wave.c)
 945     SET(BACKENDS  "${BACKENDS} WaveFile,")
 946 ENDIF()
 947
 948 # This is always available
 949 SET(BACKENDS  "${BACKENDS} Null")
 950
 951 IF(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
 952     add_subdirectory(utils/alsoft-config)
 953 ENDIF()
 954 IF(ALSOFT_EXAMPLES)
 955     FIND_PACKAGE(SDL2)
 956     IF(SDL2_FOUND)
 957         FIND_PACKAGE(SDL_sound)
 958         IF(SDL_SOUND_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 959             INCLUDE_DIRECTORIES(${SDL2_INCLUDE_DIR} ${SDL_SOUND_INCLUDE_DIR})
 960         ENDIF()
 961         FIND_PACKAGE(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
 962         IF(FFMPEG_FOUND AND CMAKE_VERSION VERSION_LESS "2.8.8")
 963             INCLUDE_DIRECTORIES(${FFMPEG_INCLUDE_DIRS})
 964         ENDIF()
 965     ENDIF()
 966 ENDIF()
 967
 968 IF(LIBTYPE STREQUAL "STATIC")
 969     ADD_DEFINITIONS(-DAL_LIBTYPE_STATIC)
 970     SET(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC ${PKG_CONFIG_CFLAGS})
 971 ENDIF()
 972
 973 # Needed for openal.pc.in
 974 SET(prefix ${CMAKE_INSTALL_PREFIX})
 975 SET(exec_prefix "\${prefix}")
 976 SET(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
 977 SET(bindir "\${exec_prefix}/bin")
 978 SET(includedir "\${prefix}/include")
 979 SET(PACKAGE_VERSION "${LIB_VERSION}")
 980
 981 # End configuration
 982 CONFIGURE_FILE(
 983     "${OpenAL_SOURCE_DIR}/config.h.in"
 984     "${OpenAL_BINARY_DIR}/config.h")
 985 CONFIGURE_FILE(
 986     "${OpenAL_SOURCE_DIR}/openal.pc.in"
 987     "${OpenAL_BINARY_DIR}/openal.pc"
 988     @ONLY)
 989
 990 # Build a common library with reusable helpers
 991 ADD_LIBRARY(common STATIC ${COMMON_OBJS})
 992
 993 # Build main library
 994 ADD_LIBRARY(${LIBNAME} ${LIBTYPE} ${OPENAL_OBJS} ${ALC_OBJS})
 995 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES)
 996 IF(WIN32 AND ALSOFT_NO_UID_DEFS)
 997     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY COMPILE_DEFINITIONS AL_NO_UID_DEFS)
 998 ENDIF()
 999 SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES "${OpenAL_SOURCE_DIR}/OpenAL32/Include" "${OpenAL_SOURCE_DIR}/Alc")
1000 IF(FLUIDSYNTH_FOUND)
1001     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${FLUIDSYNTH_INCLUDE_DIR})
1002 ENDIF()
1003 IF(HAVE_ALSA)
1004     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
1005 ENDIF()
1006 IF(HAVE_OSS)
1007     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${OSS_INCLUDE_DIRS})
1008 ENDIF()
1009 IF(HAVE_SOLARIS)
1010     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${AUDIOIO_INCLUDE_DIRS})
1011 ENDIF()
1012 IF(HAVE_SNDIO)
1013     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${SOUNDIO_INCLUDE_DIRS})
1014 ENDIF()
1015 IF(HAVE_QSA)
1016     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${QSA_INCLUDE_DIRS})
1017 ENDIF()
1018 IF(HAVE_DSOUND)
1019     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${DSOUND_INCLUDE_DIRS})
1020 ENDIF()
1021 IF(HAVE_PORTAUDIO)
1022     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PORTAUDIO_INCLUDE_DIRS})
1023 ENDIF()
1024 IF(HAVE_PULSEAUDIO)
1025     SET_PROPERTY(TARGET ${LIBNAME} APPEND PROPERTY INCLUDE_DIRECTORIES ${PULSEAUDIO_INCLUDE_DIRS})
1026 ENDIF()
1027 SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES VERSION ${LIB_VERSION}
1028                                             SOVERSION ${LIB_MAJOR_VERSION})
1029 IF(WIN32 AND NOT LIBTYPE STREQUAL "STATIC")
1030     SET_TARGET_PROPERTIES(${LIBNAME} PROPERTIES PREFIX "")
1031 ENDIF()
1032
1033 TARGET_LINK_LIBRARIES(${LIBNAME} common ${EXTRA_LIBS})
1034
1035 # Add an install target here
1036 INSTALL(TARGETS ${LIBNAME}
1037         RUNTIME DESTINATION bin
1038         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1039         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1040 )
1041 INSTALL(FILES include/AL/al.h
1042               include/AL/alc.h
1043               include/AL/alext.h
1044               include/AL/efx.h
1045               include/AL/efx-creative.h
1046               include/AL/efx-presets.h
1047         DESTINATION include/AL
1048 )
1049 INSTALL(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1050         DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
1051
1052
1053 MESSAGE(STATUS "")
1054 MESSAGE(STATUS "Building OpenAL with support for the following backends:")
1055 MESSAGE(STATUS "    ${BACKENDS}")
1056 MESSAGE(STATUS "")
1057 MESSAGE(STATUS "Building with support for CPU extensions:")
1058 MESSAGE(STATUS "    ${CPU_EXTS}")
1059 MESSAGE(STATUS "")
1060 IF(HAVE_FLUIDSYNTH)
1061     MESSAGE(STATUS "FluidSynth support for ALC_SOFT_midi_interface enabled")
1062     MESSAGE(STATUS "")
1063 ENDIF()
1064
1065 IF(WIN32)
1066     IF(NOT HAVE_DSOUND)
1067         MESSAGE(STATUS "WARNING: Building the Windows version without DirectSound output")
1068         MESSAGE(STATUS "         This is probably NOT what you want!")
1069         MESSAGE(STATUS "")
1070     ENDIF()
1071 ENDIF()
1072
1073 # Install alsoft.conf configuration file
1074 IF(ALSOFT_CONFIG)
1075     INSTALL(FILES alsoftrc.sample
1076             DESTINATION share/openal
1077     )
1078     MESSAGE(STATUS "Installing sample configuration")
1079     MESSAGE(STATUS "")
1080 ENDIF()
1081
1082 # Install HRTF definitions
1083 IF(ALSOFT_HRTF_DEFS)
1084     INSTALL(FILES hrtf/default-44100.mhr
1085             DESTINATION share/openal/hrtf
1086     )
1087     MESSAGE(STATUS "Installing HRTF definitions")
1088     MESSAGE(STATUS "")
1089 ENDIF()
1090
1091 IF(ALSOFT_UTILS)
1092     ADD_EXECUTABLE(openal-info utils/openal-info.c)
1093     TARGET_LINK_LIBRARIES(openal-info ${LIBNAME})
1094
1095     ADD_EXECUTABLE(makehrtf utils/makehrtf.c)
1096     IF(HAVE_LIBM)
1097         TARGET_LINK_LIBRARIES(makehrtf m)
1098     ENDIF()
1099
1100     INSTALL(TARGETS openal-info makehrtf
1101             RUNTIME DESTINATION bin
1102             LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1103             ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1104     )
1105
1106     MESSAGE(STATUS "Building utility programs")
1107     IF(TARGET alsoft-config)
1108         MESSAGE(STATUS "Building configuration program")
1109     ENDIF()
1110     MESSAGE(STATUS "")
1111 ENDIF()
1112
1113 IF(ALSOFT_EXAMPLES)
1114     IF(SDL2_FOUND AND SDL_SOUND_FOUND)
1115         ADD_LIBRARY(ex-common STATIC examples/common/alhelpers.c
1116                                      examples/common/sdl_sound.c)
1117         SET_PROPERTY(TARGET ex-common APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1118                                                                           ${SDL_SOUND_INCLUDE_DIR})
1119
1120         ADD_EXECUTABLE(alstream examples/alstream.c)
1121         TARGET_LINK_LIBRARIES(alstream ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1122         SET_PROPERTY(TARGET alstream APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1123                                                                          ${SDL_SOUND_INCLUDE_DIR})
1124
1125         ADD_EXECUTABLE(alreverb examples/alreverb.c)
1126         TARGET_LINK_LIBRARIES(alreverb ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1127         SET_PROPERTY(TARGET alreverb APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1128                                                                          ${SDL_SOUND_INCLUDE_DIR})
1129
1130         ADD_EXECUTABLE(allatency examples/allatency.c)
1131         TARGET_LINK_LIBRARIES(allatency ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1132         SET_PROPERTY(TARGET allatency APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1133                                                                           ${SDL_SOUND_INCLUDE_DIR})
1134
1135         ADD_EXECUTABLE(alloopback examples/alloopback.c)
1136         TARGET_LINK_LIBRARIES(alloopback ex-common ${SDL_SOUND_LIBRARIES} ${SDL2_LIBRARY} ${LIBNAME})
1137         SET_PROPERTY(TARGET alloopback APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1138                                                                            ${SDL_SOUND_INCLUDE_DIR})
1139
1140         INSTALL(TARGETS alstream alreverb allatency alloopback
1141                 RUNTIME DESTINATION bin
1142                 LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1143                 ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1144         )
1145
1146         SET(FFVER_OK FALSE)
1147         IF(FFMPEG_FOUND)
1148             SET(FFVER_OK TRUE)
1149             IF(AVFORMAT_VERSION VERSION_LESS "55.33.100")
1150                 MESSAGE(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 55.33.100)")
1151                 SET(FFVER_OK FALSE)
1152             ENDIF()
1153             IF(AVCODEC_VERSION VERSION_LESS "55.52.102")
1154                 MESSAGE(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 55.52.102)")
1155                 SET(FFVER_OK FALSE)
1156             ENDIF()
1157             IF(AVUTIL_VERSION VERSION_LESS "52.66.100")
1158                 MESSAGE(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 52.66.100)")
1159                 SET(FFVER_OK FALSE)
1160             ENDIF()
1161             IF(SWSCALE_VERSION VERSION_LESS "2.5.102")
1162                 MESSAGE(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 2.5.102)")
1163                 SET(FFVER_OK FALSE)
1164             ENDIF()
1165             IF(SWRESAMPLE_VERSION VERSION_LESS "0.18.100")
1166                 MESSAGE(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 0.18.100)")
1167                 SET(FFVER_OK FALSE)
1168             ENDIF()
1169         ENDIF()
1170         IF(FFVER_OK AND NOT MSVC)
1171             ADD_EXECUTABLE(alffplay examples/alffplay.c)
1172             TARGET_LINK_LIBRARIES(alffplay common ex-common ${SDL2_LIBRARY} ${LIBNAME} ${FFMPEG_LIBRARIES})
1173             SET_PROPERTY(TARGET alffplay APPEND PROPERTY INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR}
1174                                                                              ${FFMPEG_INCLUDE_DIRS})
1175
1176             INSTALL(TARGETS alffplay
1177                     RUNTIME DESTINATION bin
1178                     LIBRARY DESTINATION "lib${LIB_SUFFIX}"
1179                     ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
1180             )
1181             MESSAGE(STATUS "Building SDL and FFmpeg example programs")
1182         ELSE()
1183             MESSAGE(STATUS "Building SDL example programs")
1184         ENDIF()
1185         MESSAGE(STATUS "")
1186     ENDIF()
1187 ENDIF()