gcc/ada/exp_prag.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ P R A G                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Casing;   use Casing;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Exp_Ch11; use Exp_Ch11;
  32 with Exp_Util; use Exp_Util;
  33 with Expander; use Expander;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Restrict; use Restrict;
  39 with Rident;   use Rident;
  40 with Rtsfind;  use Rtsfind;
  41 with Sem;      use Sem;
  42 with Sem_Res;  use Sem_Res;
  43 with Sem_Util; use Sem_Util;
  44 with Sinfo;    use Sinfo;
  45 with Sinput;   use Sinput;
  46 with Snames;   use Snames;
  47 with Stringt;  use Stringt;
  48 with Stand;    use Stand;
  49 with Targparm; use Targparm;
  50 with Tbuild;   use Tbuild;
  51 with Uintp;    use Uintp;
  52
  53 package body Exp_Prag is
  54
  55    -----------------------
  56    -- Local Subprograms --
  57    -----------------------
  58
  59    function Arg1 (N : Node_Id) return Node_Id;
  60    function Arg2 (N : Node_Id) return Node_Id;
  61    function Arg3 (N : Node_Id) return Node_Id;
  62    --  Obtain specified pragma argument expression
  63
  64    procedure Expand_Pragma_Abort_Defer             (N : Node_Id);
  65    procedure Expand_Pragma_Check                   (N : Node_Id);
  66    procedure Expand_Pragma_Common_Object           (N : Node_Id);
  67    procedure Expand_Pragma_Import_Or_Interface     (N : Node_Id);
  68    procedure Expand_Pragma_Import_Export_Exception (N : Node_Id);
  69    procedure Expand_Pragma_Inspection_Point        (N : Node_Id);
  70    procedure Expand_Pragma_Interrupt_Priority      (N : Node_Id);
  71    procedure Expand_Pragma_Psect_Object            (N : Node_Id);
  72    procedure Expand_Pragma_Relative_Deadline       (N : Node_Id);
  73
  74    ----------
  75    -- Arg1 --
  76    ----------
  77
  78    function Arg1 (N : Node_Id) return Node_Id is
  79       Arg : constant Node_Id := First (Pragma_Argument_Associations (N));
  80    begin
  81       if Present (Arg)
  82         and then Nkind (Arg) = N_Pragma_Argument_Association
  83       then
  84          return Expression (Arg);
  85       else
  86          return Arg;
  87       end if;
  88    end Arg1;
  89
  90    ----------
  91    -- Arg2 --
  92    ----------
  93
  94    function Arg2 (N : Node_Id) return Node_Id is
  95       Arg1 : constant Node_Id := First (Pragma_Argument_Associations (N));
  96
  97    begin
  98       if No (Arg1) then
  99          return Empty;
 100
 101       else
 102          declare
 103             Arg : constant Node_Id := Next (Arg1);
 104          begin
 105             if Present (Arg)
 106               and then Nkind (Arg) = N_Pragma_Argument_Association
 107             then
 108                return Expression (Arg);
 109             else
 110                return Arg;
 111             end if;
 112          end;
 113       end if;
 114    end Arg2;
 115
 116    ----------
 117    -- Arg3 --
 118    ----------
 119
 120    function Arg3 (N : Node_Id) return Node_Id is
 121       Arg1 : constant Node_Id := First (Pragma_Argument_Associations (N));
 122
 123    begin
 124       if No (Arg1) then
 125          return Empty;
 126
 127       else
 128          declare
 129             Arg : Node_Id := Next (Arg1);
 130          begin
 131             if No (Arg) then
 132                return Empty;
 133
 134             else
 135                Next (Arg);
 136
 137                if Present (Arg)
 138                  and then Nkind (Arg) = N_Pragma_Argument_Association
 139                then
 140                   return Expression (Arg);
 141                else
 142                   return Arg;
 143                end if;
 144             end if;
 145          end;
 146       end if;
 147    end Arg3;
 148
 149    ---------------------
 150    -- Expand_N_Pragma --
 151    ---------------------
 152
 153    procedure Expand_N_Pragma (N : Node_Id) is
 154       Pname : constant Name_Id := Pragma_Name (N);
 155
 156    begin
 157       --  Note: we may have a pragma whose Pragma_Identifier field is not a
 158       --  recognized pragma, and we must ignore it at this stage.
 159
 160       if Is_Pragma_Name (Pname) then
 161          case Get_Pragma_Id (Pname) is
 162
 163             --  Pragmas requiring special expander action
 164
 165             when Pragma_Abort_Defer =>
 166                Expand_Pragma_Abort_Defer (N);
 167
 168             when Pragma_Check =>
 169                Expand_Pragma_Check (N);
 170
 171             when Pragma_Common_Object =>
 172                Expand_Pragma_Common_Object (N);
 173
 174             when Pragma_Export_Exception =>
 175                Expand_Pragma_Import_Export_Exception (N);
 176
 177             when Pragma_Import =>
 178                Expand_Pragma_Import_Or_Interface (N);
 179
 180             when Pragma_Import_Exception =>
 181                Expand_Pragma_Import_Export_Exception (N);
 182
 183             when Pragma_Inspection_Point =>
 184                Expand_Pragma_Inspection_Point (N);
 185
 186             when Pragma_Interface =>
 187                Expand_Pragma_Import_Or_Interface (N);
 188
 189             when Pragma_Interrupt_Priority =>
 190                Expand_Pragma_Interrupt_Priority (N);
 191
 192             when Pragma_Psect_Object =>
 193                Expand_Pragma_Psect_Object (N);
 194
 195             when Pragma_Relative_Deadline =>
 196                Expand_Pragma_Relative_Deadline (N);
 197
 198             --  All other pragmas need no expander action
 199
 200             when others => null;
 201          end case;
 202       end if;
 203
 204    end Expand_N_Pragma;
 205
 206    -------------------------------
 207    -- Expand_Pragma_Abort_Defer --
 208    -------------------------------
 209
 210    --  An Abort_Defer pragma appears as the first statement in a handled
 211    --  statement sequence (right after the begin). It defers aborts for
 212    --  the entire statement sequence, but not for any declarations or
 213    --  handlers (if any) associated with this statement sequence.
 214
 215    --  The transformation is to transform
 216
 217    --    pragma Abort_Defer;
 218    --    statements;
 219
 220    --  into
 221
 222    --    begin
 223    --       Abort_Defer.all;
 224    --       statements
 225    --    exception
 226    --       when all others =>
 227    --          Abort_Undefer.all;
 228    --          raise;
 229    --    at end
 230    --       Abort_Undefer_Direct;
 231    --    end;
 232
 233    procedure Expand_Pragma_Abort_Defer (N : Node_Id) is
 234       Loc  : constant Source_Ptr := Sloc (N);
 235       Stm  : Node_Id;
 236       Stms : List_Id;
 237       HSS  : Node_Id;
 238       Blk  : constant Entity_Id :=
 239         New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 240
 241    begin
 242       Stms := New_List (Build_Runtime_Call (Loc, RE_Abort_Defer));
 243
 244       loop
 245          Stm := Remove_Next (N);
 246          exit when No (Stm);
 247          Append (Stm, Stms);
 248       end loop;
 249
 250       HSS :=
 251         Make_Handled_Sequence_Of_Statements (Loc,
 252           Statements => Stms,
 253           At_End_Proc =>
 254             New_Occurrence_Of (RTE (RE_Abort_Undefer_Direct), Loc));
 255
 256       Rewrite (N,
 257         Make_Block_Statement (Loc,
 258           Handled_Statement_Sequence => HSS));
 259
 260       Set_Scope (Blk, Current_Scope);
 261       Set_Etype (Blk, Standard_Void_Type);
 262       Set_Identifier (N, New_Occurrence_Of (Blk, Sloc (N)));
 263       Expand_At_End_Handler (HSS, Blk);
 264       Analyze (N);
 265    end Expand_Pragma_Abort_Defer;
 266
 267    --------------------------
 268    -- Expand_Pragma_Check --
 269    --------------------------
 270
 271    procedure Expand_Pragma_Check (N : Node_Id) is
 272       Cond : constant Node_Id    := Arg2 (N);
 273       Loc  : constant Source_Ptr := Sloc (Cond);
 274       Nam  : constant Name_Id    := Chars (Arg1 (N));
 275       Msg  : Node_Id;
 276
 277    begin
 278       --  We already know that this check is enabled, because otherwise the
 279       --  semantic pass dealt with rewriting the assertion (see Sem_Prag)
 280
 281       --  Since this check is enabled, we rewrite the pragma into a
 282       --  corresponding if statement, and then analyze the statement
 283
 284       --  The normal case expansion transforms:
 285
 286       --    pragma Check (name, condition [,message]);
 287
 288       --  into
 289
 290       --    if not condition then
 291       --       System.Assertions.Raise_Assert_Failure (Str);
 292       --    end if;
 293
 294       --  where Str is the message if one is present, or the default of
 295       --  name failed at file:line if no message is given (the "name failed
 296       --  at" is omitted for name = Assertion, since it is redundant, given
 297       --  that the name of the exception is Assert_Failure.)
 298
 299       --  An alternative expansion is used when the No_Exception_Propagation
 300       --  restriction is active and there is a local Assert_Failure handler.
 301       --  This is not a common combination of circumstances, but it occurs in
 302       --  the context of Aunit and the zero footprint profile. In this case we
 303       --  generate:
 304
 305       --    if not condition then
 306       --       raise Assert_Failure;
 307       --    end if;
 308
 309       --  This will then be transformed into a goto, and the local handler will
 310       --  be able to handle the assert error (which would not be the case if a
 311       --  call is made to the Raise_Assert_Failure procedure).
 312
 313       --  We also generate the direct raise if the Suppress_Exception_Locations
 314       --  is active, since we don't want to generate messages in this case.
 315
 316       --  Note that the reason we do not always generate a direct raise is that
 317       --  the form in which the procedure is called allows for more efficient
 318       --  breakpointing of assertion errors.
 319
 320       --  Generate the appropriate if statement. Note that we consider this to
 321       --  be an explicit conditional in the source, not an implicit if, so we
 322       --  do not call Make_Implicit_If_Statement.
 323
 324       --  Case where we generate a direct raise
 325
 326       if ((Debug_Flag_Dot_G
 327            or else Restriction_Active (No_Exception_Propagation))
 328           and then Present (Find_Local_Handler (RTE (RE_Assert_Failure), N)))
 329         or else (Opt.Exception_Locations_Suppressed and then No (Arg3 (N)))
 330       then
 331          Rewrite (N,
 332            Make_If_Statement (Loc,
 333              Condition =>
 334                Make_Op_Not (Loc,
 335                  Right_Opnd => Cond),
 336              Then_Statements => New_List (
 337                Make_Raise_Statement (Loc,
 338                  Name =>
 339                    New_Reference_To (RTE (RE_Assert_Failure), Loc)))));
 340
 341       --  Case where we call the procedure
 342
 343       else
 344          --  If we have a message given, use it
 345
 346          if Present (Arg3 (N)) then
 347             Msg := Get_Pragma_Arg (Arg3 (N));
 348
 349          --  Here we have no string, so prepare one
 350
 351          else
 352             declare
 353                Msg_Loc : constant String := Build_Location_String (Loc);
 354
 355             begin
 356                Name_Len := 0;
 357
 358                --  For Assert, we just use the location
 359
 360                if Nam = Name_Assertion then
 361                   null;
 362
 363                --  For predicate, we generate the string "predicate failed
 364                --  at yyy". We prefer all lower case for predicate.
 365
 366                elsif Nam = Name_Predicate then
 367                   Add_Str_To_Name_Buffer ("predicate failed at ");
 368
 369                --  For special case of Precondition/Postcondition the string is
 370                --  "failed xx from yy" where xx is precondition/postcondition
 371                --  in all lower case. The reason for this different wording is
 372                --  that the failure is not at the point of occurrence of the
 373                --  pragma, unlike the other Check cases.
 374
 375                elsif Nam = Name_Precondition
 376                        or else
 377                      Nam = Name_Postcondition
 378                then
 379                   Get_Name_String (Nam);
 380                   Insert_Str_In_Name_Buffer ("failed ", 1);
 381                   Add_Str_To_Name_Buffer (" from ");
 382
 383                --  For all other checks, the string is "xxx failed at yyy"
 384                --  where xxx is the check name with current source file casing.
 385
 386                else
 387                   Get_Name_String (Nam);
 388                   Set_Casing (Identifier_Casing (Current_Source_File));
 389                   Add_Str_To_Name_Buffer (" failed at ");
 390                end if;
 391
 392                --  In all cases, add location string
 393
 394                Add_Str_To_Name_Buffer (Msg_Loc);
 395
 396                --  Build the message
 397
 398                Msg := Make_String_Literal (Loc, Name_Buffer (1 .. Name_Len));
 399             end;
 400          end if;
 401
 402          --  Now rewrite as an if statement
 403
 404          Rewrite (N,
 405            Make_If_Statement (Loc,
 406              Condition =>
 407                Make_Op_Not (Loc,
 408                  Right_Opnd => Cond),
 409              Then_Statements => New_List (
 410                Make_Procedure_Call_Statement (Loc,
 411                  Name =>
 412                    New_Reference_To (RTE (RE_Raise_Assert_Failure), Loc),
 413                  Parameter_Associations => New_List (Relocate_Node (Msg))))));
 414       end if;
 415
 416       Analyze (N);
 417
 418       --  If new condition is always false, give a warning
 419
 420       if Warn_On_Assertion_Failure
 421         and then Nkind (N) = N_Procedure_Call_Statement
 422         and then Is_RTE (Entity (Name (N)), RE_Raise_Assert_Failure)
 423       then
 424          --  If original condition was a Standard.False, we assume that this is
 425          --  indeed intended to raise assert error and no warning is required.
 426
 427          if Is_Entity_Name (Original_Node (Cond))
 428            and then Entity (Original_Node (Cond)) = Standard_False
 429          then
 430             return;
 431          elsif Nam = Name_Assertion then
 432             Error_Msg_N ("?assertion will fail at run time", N);
 433          else
 434             Error_Msg_N ("?check will fail at run time", N);
 435          end if;
 436       end if;
 437    end Expand_Pragma_Check;
 438
 439    ---------------------------------
 440    -- Expand_Pragma_Common_Object --
 441    ---------------------------------
 442
 443    --  Use a machine attribute to replicate semantic effect in DEC Ada
 444
 445    --    pragma Machine_Attribute (intern_name, "common_object", extern_name);
 446
 447    --  For now we do nothing with the size attribute ???
 448
 449    --  Note: Psect_Object shares this processing
 450
 451    procedure Expand_Pragma_Common_Object (N : Node_Id) is
 452       Loc : constant Source_Ptr := Sloc (N);
 453
 454       Internal : constant Node_Id := Arg1 (N);
 455       External : constant Node_Id := Arg2 (N);
 456
 457       Psect : Node_Id;
 458       --  Psect value upper cased as string literal
 459
 460       Iloc : constant Source_Ptr := Sloc (Internal);
 461       Eloc : constant Source_Ptr := Sloc (External);
 462       Ploc : Source_Ptr;
 463
 464    begin
 465       --  Acquire Psect value and fold to upper case
 466
 467       if Present (External) then
 468          if Nkind (External) = N_String_Literal then
 469             String_To_Name_Buffer (Strval (External));
 470          else
 471             Get_Name_String (Chars (External));
 472          end if;
 473
 474          Set_All_Upper_Case;
 475
 476          Psect :=
 477            Make_String_Literal (Eloc,
 478              Strval => String_From_Name_Buffer);
 479
 480       else
 481          Get_Name_String (Chars (Internal));
 482          Set_All_Upper_Case;
 483          Psect :=
 484            Make_String_Literal (Iloc,
 485              Strval => String_From_Name_Buffer);
 486       end if;
 487
 488       Ploc := Sloc (Psect);
 489
 490       --  Insert the pragma
 491
 492       Insert_After_And_Analyze (N,
 493          Make_Pragma (Loc,
 494            Chars => Name_Machine_Attribute,
 495            Pragma_Argument_Associations => New_List (
 496              Make_Pragma_Argument_Association (Iloc,
 497                Expression => New_Copy_Tree (Internal)),
 498              Make_Pragma_Argument_Association (Eloc,
 499                Expression =>
 500                  Make_String_Literal (Sloc => Ploc,
 501                    Strval => "common_object")),
 502              Make_Pragma_Argument_Association (Ploc,
 503                Expression => New_Copy_Tree (Psect)))));
 504
 505    end Expand_Pragma_Common_Object;
 506
 507    ---------------------------------------
 508    -- Expand_Pragma_Import_Or_Interface --
 509    ---------------------------------------
 510
 511    --  When applied to a variable, the default initialization must not be
 512    --  done. As it is already done when the pragma is found, we just get rid
 513    --  of the call the initialization procedure which followed the object
 514    --  declaration. The call is inserted after the declaration, but validity
 515    --  checks may also have been inserted and the initialization call does
 516    --  not necessarily appear immediately after the object declaration.
 517
 518    --  We can't use the freezing mechanism for this purpose, since we
 519    --  have to elaborate the initialization expression when it is first
 520    --  seen (i.e. this elaboration cannot be deferred to the freeze point).
 521
 522    procedure Expand_Pragma_Import_Or_Interface (N : Node_Id) is
 523       Def_Id    : constant Entity_Id := Entity (Arg2 (N));
 524       Init_Call : Node_Id;
 525
 526    begin
 527       if Ekind (Def_Id) = E_Variable then
 528
 529          --  Find generated initialization call for object, if any
 530
 531          Init_Call := Find_Init_Call (Def_Id, Rep_Clause => N);
 532          if Present (Init_Call) then
 533             Remove (Init_Call);
 534          end if;
 535
 536          --  Any default initialization expression should be removed
 537          --  (e.g., null defaults for access objects, zero initialization
 538          --  of packed bit arrays). Imported objects aren't allowed to
 539          --  have explicit initialization, so the expression must have
 540          --  been generated by the compiler.
 541
 542          if No (Init_Call) and then Present (Expression (Parent (Def_Id))) then
 543             Set_Expression (Parent (Def_Id), Empty);
 544          end if;
 545       end if;
 546    end Expand_Pragma_Import_Or_Interface;
 547
 548    -------------------------------------------
 549    -- Expand_Pragma_Import_Export_Exception --
 550    -------------------------------------------
 551
 552    --  For a VMS exception fix up the language field with "VMS"
 553    --  instead of "Ada" (gigi needs this), create a constant that will be the
 554    --  value of the VMS condition code and stuff the Interface_Name field
 555    --  with the unexpanded name of the exception (if not already set).
 556    --  For a Ada exception, just stuff the Interface_Name field
 557    --  with the unexpanded name of the exception (if not already set).
 558
 559    procedure Expand_Pragma_Import_Export_Exception (N : Node_Id) is
 560    begin
 561       --  This pragma is only effective on OpenVMS systems, it was ignored
 562       --  on non-VMS systems, and we need to ignore it here as well.
 563
 564       if not OpenVMS_On_Target then
 565          return;
 566       end if;
 567
 568       declare
 569          Id     : constant Entity_Id := Entity (Arg1 (N));
 570          Call   : constant Node_Id := Register_Exception_Call (Id);
 571          Loc    : constant Source_Ptr := Sloc (N);
 572
 573       begin
 574          if Present (Call) then
 575             declare
 576                Excep_Internal : constant Node_Id := Make_Temporary (Loc, 'V');
 577                Export_Pragma  : Node_Id;
 578                Excep_Alias    : Node_Id;
 579                Excep_Object   : Node_Id;
 580                Excep_Image    : String_Id;
 581                Exdata         : List_Id;
 582                Lang_Char      : Node_Id;
 583                Code           : Node_Id;
 584
 585             begin
 586                if Present (Interface_Name (Id)) then
 587                   Excep_Image := Strval (Interface_Name (Id));
 588                else
 589                   Get_Name_String (Chars (Id));
 590                   Set_All_Upper_Case;
 591                   Excep_Image := String_From_Name_Buffer;
 592                end if;
 593
 594                Exdata := Component_Associations (Expression (Parent (Id)));
 595
 596                if Is_VMS_Exception (Id) then
 597                   Lang_Char := Next (First (Exdata));
 598
 599                   --  Change the one-character language designator to 'V'
 600
 601                   Rewrite (Expression (Lang_Char),
 602                     Make_Character_Literal (Loc,
 603                       Chars => Name_uV,
 604                       Char_Literal_Value =>
 605                         UI_From_Int (Character'Pos ('V'))));
 606                   Analyze (Expression (Lang_Char));
 607
 608                   if Exception_Code (Id) /= No_Uint then
 609                      Code :=
 610                        Make_Integer_Literal (Loc,
 611                          Intval => Exception_Code (Id));
 612
 613                      Excep_Object :=
 614                        Make_Object_Declaration (Loc,
 615                          Defining_Identifier => Excep_Internal,
 616                          Object_Definition   =>
 617                            New_Reference_To (RTE (RE_Exception_Code), Loc));
 618
 619                      Insert_Action (N, Excep_Object);
 620                      Analyze (Excep_Object);
 621
 622                      Start_String;
 623                      Store_String_Int
 624                        (UI_To_Int (Exception_Code (Id)) / 8 * 8);
 625
 626                      Excep_Alias :=
 627                        Make_Pragma
 628                          (Loc,
 629                           Name_Linker_Alias,
 630                           New_List
 631                             (Make_Pragma_Argument_Association
 632                                (Sloc => Loc,
 633                                 Expression =>
 634                                   New_Reference_To (Excep_Internal, Loc)),
 635
 636                              Make_Pragma_Argument_Association
 637                                (Sloc => Loc,
 638                                 Expression =>
 639                                   Make_String_Literal
 640                                     (Sloc => Loc,
 641                                      Strval => End_String))));
 642
 643                      Insert_Action (N, Excep_Alias);
 644                      Analyze (Excep_Alias);
 645
 646                      Export_Pragma :=
 647                        Make_Pragma
 648                          (Loc,
 649                           Name_Export,
 650                           New_List
 651                             (Make_Pragma_Argument_Association (Loc,
 652                                Expression => Make_Identifier (Loc, Name_C)),
 653
 654                              Make_Pragma_Argument_Association (Loc,
 655                                Expression =>
 656                                  New_Reference_To (Excep_Internal, Loc)),
 657
 658                              Make_Pragma_Argument_Association (Loc,
 659                                Expression =>
 660                                  Make_String_Literal (Loc, Excep_Image)),
 661
 662                              Make_Pragma_Argument_Association (Loc,
 663                                 Expression =>
 664                                   Make_String_Literal (Loc, Excep_Image))));
 665
 666                      Insert_Action (N, Export_Pragma);
 667                      Analyze (Export_Pragma);
 668
 669                   else
 670                      Code :=
 671                         Unchecked_Convert_To (RTE (RE_Exception_Code),
 672                           Make_Function_Call (Loc,
 673                             Name =>
 674                               New_Reference_To (RTE (RE_Import_Value), Loc),
 675                             Parameter_Associations => New_List
 676                               (Make_String_Literal (Loc,
 677                                 Strval => Excep_Image))));
 678                   end if;
 679
 680                   Rewrite (Call,
 681                     Make_Procedure_Call_Statement (Loc,
 682                       Name => New_Reference_To
 683                                 (RTE (RE_Register_VMS_Exception), Loc),
 684                       Parameter_Associations => New_List (
 685                         Code,
 686                         Unchecked_Convert_To (RTE (RE_Exception_Data_Ptr),
 687                           Make_Attribute_Reference (Loc,
 688                             Prefix         => New_Occurrence_Of (Id, Loc),
 689                             Attribute_Name => Name_Unrestricted_Access)))));
 690
 691                   Analyze_And_Resolve (Code, RTE (RE_Exception_Code));
 692                   Analyze (Call);
 693                end if;
 694
 695                if No (Interface_Name (Id)) then
 696                   Set_Interface_Name (Id,
 697                      Make_String_Literal
 698                        (Sloc => Loc,
 699                         Strval => Excep_Image));
 700                end if;
 701             end;
 702          end if;
 703       end;
 704    end Expand_Pragma_Import_Export_Exception;
 705
 706    ------------------------------------
 707    -- Expand_Pragma_Inspection_Point --
 708    ------------------------------------
 709
 710    --  If no argument is given, then we supply a default argument list that
 711    --  includes all objects declared at the source level in all subprograms
 712    --  that enclose the inspection point pragma.
 713
 714    procedure Expand_Pragma_Inspection_Point (N : Node_Id) is
 715       Loc : constant Source_Ptr := Sloc (N);
 716       A     : List_Id;
 717       Assoc : Node_Id;
 718       S     : Entity_Id;
 719       E     : Entity_Id;
 720
 721    begin
 722       if No (Pragma_Argument_Associations (N)) then
 723          A := New_List;
 724          S := Current_Scope;
 725
 726          while S /= Standard_Standard loop
 727             E := First_Entity (S);
 728             while Present (E) loop
 729                if Comes_From_Source (E)
 730                  and then Is_Object (E)
 731                  and then not Is_Entry_Formal (E)
 732                  and then Ekind (E) /= E_Component
 733                  and then Ekind (E) /= E_Discriminant
 734                  and then Ekind (E) /= E_Generic_In_Parameter
 735                  and then Ekind (E) /= E_Generic_In_Out_Parameter
 736                then
 737                   Append_To (A,
 738                     Make_Pragma_Argument_Association (Loc,
 739                       Expression => New_Occurrence_Of (E, Loc)));
 740                end if;
 741
 742                Next_Entity (E);
 743             end loop;
 744
 745             S := Scope (S);
 746          end loop;
 747
 748          Set_Pragma_Argument_Associations (N, A);
 749       end if;
 750
 751       --  Expand the arguments of the pragma. Expanding an entity reference
 752       --  is a noop, except in a protected operation, where a reference may
 753       --  have to be transformed into a reference to the corresponding prival.
 754       --  Are there other pragmas that may require this ???
 755
 756       Assoc := First (Pragma_Argument_Associations (N));
 757
 758       while Present (Assoc) loop
 759          Expand (Expression (Assoc));
 760          Next (Assoc);
 761       end loop;
 762    end Expand_Pragma_Inspection_Point;
 763
 764    --------------------------------------
 765    -- Expand_Pragma_Interrupt_Priority --
 766    --------------------------------------
 767
 768    --  Supply default argument if none exists (System.Interrupt_Priority'Last)
 769
 770    procedure Expand_Pragma_Interrupt_Priority (N : Node_Id) is
 771       Loc : constant Source_Ptr := Sloc (N);
 772
 773    begin
 774       if No (Pragma_Argument_Associations (N)) then
 775          Set_Pragma_Argument_Associations (N, New_List (
 776            Make_Pragma_Argument_Association (Loc,
 777              Expression =>
 778                Make_Attribute_Reference (Loc,
 779                  Prefix =>
 780                    New_Occurrence_Of (RTE (RE_Interrupt_Priority), Loc),
 781                  Attribute_Name => Name_Last))));
 782       end if;
 783    end Expand_Pragma_Interrupt_Priority;
 784
 785    --------------------------------
 786    -- Expand_Pragma_Psect_Object --
 787    --------------------------------
 788
 789    --  Convert to Common_Object, and expand the resulting pragma
 790
 791    procedure Expand_Pragma_Psect_Object (N : Node_Id)
 792      renames Expand_Pragma_Common_Object;
 793
 794    -------------------------------------
 795    -- Expand_Pragma_Relative_Deadline --
 796    -------------------------------------
 797
 798    procedure Expand_Pragma_Relative_Deadline (N : Node_Id) is
 799       P    : constant Node_Id    := Parent (N);
 800       Loc  : constant Source_Ptr := Sloc (N);
 801
 802    begin
 803       --  Expand the pragma only in the case of the main subprogram. For tasks
 804       --  the expansion is done in exp_ch9. Generate a call to Set_Deadline
 805       --  at Clock plus the relative deadline specified in the pragma. Time
 806       --  values are translated into Duration to allow for non-private
 807       --  addition operation.
 808
 809       if Nkind (P) = N_Subprogram_Body then
 810          Rewrite
 811            (N,
 812             Make_Procedure_Call_Statement (Loc,
 813               Name => New_Reference_To (RTE (RE_Set_Deadline), Loc),
 814               Parameter_Associations => New_List (
 815                 Unchecked_Convert_To (RTE (RO_RT_Time),
 816                   Make_Op_Add (Loc,
 817                     Left_Opnd  =>
 818                       Make_Function_Call (Loc,
 819                         New_Reference_To (RTE (RO_RT_To_Duration), Loc),
 820                         New_List (Make_Function_Call (Loc,
 821                           New_Reference_To (RTE (RE_Clock), Loc)))),
 822                     Right_Opnd  =>
 823                       Unchecked_Convert_To (Standard_Duration, Arg1 (N)))))));
 824
 825          Analyze (N);
 826       end if;
 827    end Expand_Pragma_Relative_Deadline;
 828
 829 end Exp_Prag;