lib/NonameTV/Augmenter/Tvdb.pm

   1 package NonameTV::Augmenter::Tvdb;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Encode;
   8 use TVDB::API;
   9
  10 use NonameTV qw/norm/;
  11 use NonameTV::Augmenter::Base;
  12 use NonameTV::Config qw/ReadConfig/;
  13 use NonameTV::Log qw/w/;
  14
  15 use base 'NonameTV::Augmenter::Base';
  16
  17
  18 sub new {
  19     my $proto = shift;
  20     my $class = ref($proto) || $proto;
  21     my $self  = $class->SUPER::new( @_ );
  22     bless ($self, $class);
  23
  24     defined( $self->{ApiKey} )   or die "You must specify ApiKey";
  25     defined( $self->{Language} ) or die "You must specify Language";
  26
  27     # need config for main content cache path
  28     my $conf = ReadConfig( );
  29
  30     my $cachefile = $conf->{ContentCachePath} . '/' . $self->{Type} . '/tvdb.db';
  31     my $bannerdir = $conf->{ContentCachePath} . '/' . $self->{Type} . '/banner';
  32
  33     $self->{tvdb} = TVDB::API::new({ apikey    => $self->{ApiKey},
  34                                      lang      => $self->{Language},
  35                                      cache     => $cachefile,
  36                                      banner    => $bannerdir,
  37                                   });
  38     $self->{tvdb}->getUpdates( 'guess' );
  39
  40     my $opt = { quiet => 1 };
  41     Debug::Simple::debuglevels($opt);
  42
  43     return $self;
  44 }
  45
  46
  47 sub FillHash( $$$$ ) {
  48   my( $self, $resultref, $series, $episode )=@_;
  49
  50   return if( !defined $episode );
  51
  52   my $episodeid = $series->{Seasons}[$episode->{SeasonNumber}][$episode->{EpisodeNumber}];
  53
  54   $resultref->{title} = $series->{SeriesName};
  55
  56   $resultref->{episode} = ($episode->{SeasonNumber} - 1) . ' . ' . ($episode->{EpisodeNumber} - 1) . ' .';
  57
  58   $resultref->{subtitle} = decode( 'utf-8', $episode->{EpisodeName} );
  59
  60   if( defined( $episode->{Overview} ) ) {
  61     $resultref->{description} = decode( 'utf-8', $episode->{Overview} ) . "\nQuelle: Tvdb";
  62   }
  63
  64   $resultref->{production_date} = $episode->{FirstAired};
  65
  66   # FIXME link to the correct language instead of hardcoding german (14)
  67   $resultref->{url} = sprintf(
  68     'http://thetvdb.com/?tab=episode&seriesid=%d&seasonid=%d&id=%d&lid=%d',
  69     $episode->{seriesid}, $episode->{seasonid}, $episodeid, 14
  70   );
  71
  72   my @actors = split( '\|', decode( 'utf-8', $series->{Actors} ) );
  73   foreach( @actors ){
  74     $_ = norm( $_ );
  75     if( $_ eq '' ){
  76       $_ = undef;
  77     }
  78   }
  79   @actors = grep{ defined } @actors;
  80   if( @actors ) {
  81     # replace programme's actors
  82     $resultref->{actors} = join( ', ', @actors );
  83   } else {
  84     # remove existing actors from programme
  85     $resultref->{actors} = undef;
  86   }
  87
  88   $resultref->{program_type} = 'series';
  89 }
  90
  91
  92 sub AugmentProgram( $$$ ){
  93   my( $self, $ceref, $ruleref ) = @_;
  94
  95   # empty hash to get all attributes to change
  96   my $resultref = {};
  97   # result string, empty/false for success, message/true for failure
  98   my $result = '';
  99
 100   if( $ruleref->{matchby} eq 'episodeabs' ) {
 101     # match by absolute episode number from program hash
 102
 103     if( defined $ceref->{episode} ){
 104       my( $episodeabs )=( $ceref->{episode} =~ m|^\s*\.\s*(\d+)\s*/?\s*\d*\s*\.\s*$| );
 105       if( defined $episodeabs ){
 106         $episodeabs += 1;
 107
 108         my $series;
 109         if( defined( $ruleref->{remoteref} ) ) {
 110           my $seriesname = $self->{tvdb}->getSeriesName( $ruleref->{remoteref} );
 111           $series = $self->{tvdb}->getSeries( $seriesname );
 112         } else {
 113           $series = $self->{tvdb}->getSeries( $ceref->{title} );
 114         }
 115         if( defined $series ){
 116           my $episode = $self->{tvdb}->getEpisodeAbs( $series->{SeriesName}, $episodeabs );
 117
 118           if( defined( $episode ) ) {
 119             $self->FillHash( $resultref, $series, $episode );
 120           } else {
 121             w( "no absolute episode " . $episodeabs . " found for '" . $ceref->{title} . "'" );
 122             $resultref = undef;
 123           }
 124         }
 125       } else {
 126         $resultref = undef;
 127       }
 128     } else {
 129       $resultref = undef;
 130     }
 131   }elsif( $ruleref->{matchby} eq 'episodetitle' ) {
 132     # match by episode title from program hash
 133
 134     if( defined( $ceref->{subtitle} ) ) {
 135       my $series;
 136       if( defined( $ruleref->{remoteref} ) ) {
 137         my $seriesname = $self->{tvdb}->getSeriesName( $ruleref->{remoteref} );
 138         $series = $self->{tvdb}->getSeries( $seriesname );
 139       } else {
 140         $series = $self->{tvdb}->getSeries( $ceref->{title} );
 141       }
 142
 143       my $episodetitle = $ceref->{subtitle};
 144       $episodetitle =~ s|,\s+Teil\s+(\d+)$| ($1)|;
 145       $episodetitle =~ s|\s+-\s+Teil\s+(\d+)$| ($1)|;
 146       $episodetitle =~ s|\s+\(Teil\s+(\d+)\)$| ($1)|;
 147       $episodetitle =~ s|\s+-\s+(\d+)\.\s+Teil$| ($1)|;
 148
 149       my $episode = $self->{tvdb}->getEpisodeByName( $series->{SeriesName}, $episodetitle );
 150       if( defined( $episode ) ) {
 151         $self->FillHash( $resultref, $series, $episode );
 152       } else {
 153         $resultref = undef;
 154       }
 155     } else {
 156       $resultref = undef;
 157     }
 158
 159   }else{
 160     $result = "don't know how to match by '" . $ruleref->{matchby} . "'";
 161   }
 162
 163   return( $resultref, $result );
 164 }
 165
 166
 167 1;