www-client/netsurf/netsurf-9999.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 NETSURF_COMPONENT_TYPE=binary
   6 NETSURF_BUILDSYSTEM="buildsystem-9999"
   7
   8 inherit netsurf git-r3
   9
  10 DESCRIPTION="a free, open source web browser"
  11 HOMEPAGE="http://www.netsurf-browser.org/"
  12 SRC_URI="http://xmw.de/mirror/netsurf-fb.modes-example.gz"
  13 EGIT_REPO_URI="http://git.netsurf-browser.org/netsurf.git"
  14
  15 LICENSE="GPL-2 MIT"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="+bmp fbcon truetype +gif gstreamer gtk javascript +jpeg +mng +png
  19         +rosprite +svg +svgtiny fbcon_frontend_able fbcon_frontend_linux
  20         fbcon_frontend_sdl fbcon_frontend_vnc fbcon_frontend_x"
  21
  22 REQUIRED_USE="|| ( fbcon gtk )
  23         amd64? ( abi_x86_32? (
  24                 !gstreamer !javascript svg? ( svgtiny ) !truetype ) )
  25         fbcon? ( ^^ ( fbcon_frontend_able fbcon_frontend_linux fbcon_frontend_sdl
  26                 fbcon_frontend_vnc fbcon_frontend_x ) )"
  27
  28 RDEPEND="dev-libs/libxml2
  29         net-misc/curl
  30         >=dev-libs/libcss-9999[${MULTILIB_USEDEP}]
  31         >=net-libs/libhubbub-9999[${MULTILIB_USEDEP}]
  32         >=net-libs/libdom-9999[xml,${MULTILIB_USEDEP}]
  33         >=dev-libs/libutf8proc-9999
  34         >=dev-libs/libnsutils-9999
  35         bmp? ( >=media-libs/libnsbmp-9999[${MULTILIB_USEDEP}] )
  36         fbcon? ( >=dev-libs/libnsfb-9999[${MULTILIB_USEDEP}]
  37                 truetype? ( media-fonts/dejavu
  38                         >=media-libs/freetype-2.5.0.1[${MULTILIB_USEDEP}] )
  39         )
  40         gif? ( >=media-libs/libnsgif-9999[${MULTILIB_USEDEP}] )
  41         gtk? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  42                 gnome-base/libglade:2.0
  43                 >=x11-libs/gtk+-2.24.23:2[${MULTILIB_USEDEP}] )
  44         gstreamer? ( media-libs/gstreamer:0.10 )
  45         javascript? ( >=dev-libs/nsgenbind-9999 )
  46         jpeg? ( >=virtual/jpeg-0-r2[${MULTILIB_USEDEP}] )
  47         mng? ( >=media-libs/libmng-1.0.10-r2[${MULTILIB_USEDEP}] )
  48         png? ( >=media-libs/libpng-1.2.51[${MULTILIB_USEDEP}] )
  49         svg? ( svgtiny? ( >=media-libs/libsvgtiny-9999[${MULTILIB_USEDEP}] )
  50                 !svgtiny? ( gnome-base/librsvg:2 ) )"
  51 DEPEND="${RDEPEND}
  52         javascript? ( >=dev-libs/nsgenbind-0.1.1 )
  53         rosprite? ( >=media-libs/librosprite-0.1.1[${MULTILIB_USEDEP}] )
  54         >=dev-util/netsurf-buildsystem-9999"
  55
  56 PATCHES=(
  57         "${FILESDIR}"/${P}-reenable-glib-deprecated.patch
  58 )
  59 DOCS=( fb.modes README docs/using-framebuffer.md
  60         docs/ideas/{cache,css-engine,render-library}.txt )
  61
  62 src_unpack() {
  63         git-r3_src_unpack
  64         unpack "netsurf-fb.modes-example.gz"
  65         cp -r /usr/share/netsurf-buildsystem "${WORKDIR}/${NETSURF_BUILDSYSTEM}"
  66 }
  67
  68 src_prepare() {
  69         rm -rf amiga atari beos cocoa monkey riscos windows  || die
  70
  71         mv "${WORKDIR}"/netsurf-fb.modes-example fb.modes
  72
  73         netsurf_src_prepare
  74 }
  75
  76 src_configure() {
  77         netsurf_src_configure
  78
  79         netsurf_makeconf+=(
  80                 NETSURF_USE_BMP=$(usex bmp YES NO)
  81                 NETSURF_USE_GIF=$(usex gif YES NO)
  82                 NETSURF_USE_JPEG=$(usex jpeg YES NO)
  83                 NETSURF_USE_PNG=$(usex png YES NO)
  84                 NETSURF_USE_PNG=$(usex png YES NO)
  85                 NETSURF_USE_MNG=$(usex mng YES NO)
  86                 NETSURF_USE_VIDEO=$(usex gstreamer YES NO)
  87                 NETSURF_USE_JS=NO
  88                 NETSURF_USE_MOZJS=NO
  89                 NETSURF_USE_DUKTAPE=$(usex javascript YES NO)
  90                 NETSURF_USE_HARU_PDF=NO
  91                 NETSURF_USE_NSSVG=$(usex svg $(usex svgtiny YES NO) NO)
  92                 NETSURF_USE_RSVG=$(usex svg $(usex svgtiny NO YES) NO)
  93                 NETSURF_USE_ROSPRITE=$(usex rosprite YES NO)
  94                 PKG_CONFIG=$(tc-getPKG_CONFIG)
  95                 $(usex fbcon_frontend_able  NETSURF_FB_FRONTEND=able  "")
  96                 $(usex fbcon_frontend_linux NETSURF_FB_FRONTEND=linux "")
  97                 $(usex fbcon_frontend_sdl   NETSURF_FB_FRONTEND=sdl   "")
  98                 $(usex fbcon_frontend_vnc   NETSURF_FB_FRONTEND=vnc   "")
  99                 $(usex fbcon_frontend_x     NETSURF_FB_FRONTEND=x     "")
 100                 NETSURF_FB_FONTLIB=$(usex truetype freetype internal)
 101                 NETSURF_FB_FONTPATH=${EROOT}usr/share/fonts/dejavu
 102                 TARGET=dummy
 103         )
 104 }
 105
 106 src_compile() {
 107         if use fbcon ; then
 108                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=framebuffer}" )
 109                 netsurf_src_compile
 110         fi
 111         if use gtk ; then
 112                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=gtk}" )
 113                 netsurf_src_compile
 114         fi
 115 }
 116
 117 src_install() {
 118         sed -e '1iexit;' \
 119                 -i "${WORKDIR}"/*/utils/git-testament.pl || die
 120
 121         if use fbcon ; then
 122                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=framebuffer}" )
 123                 netsurf_src_install
 124                 elog "framebuffer binary has been installed as netsurf-fb"
 125                 make_desktop_entry "${EROOT}"usr/bin/netsurf-fb NetSurf-framebuffer netsurf "Network;WebBrowser"
 126
 127                 elog "In order to setup the framebuffer console, netsurf needs an /etc/fb.modes"
 128                 elog "You can use an example from /usr/share/doc/${PF}/fb.modes.* (bug 427092)."
 129                 elog "Please make /etc/input/mice readable to the account using netsurf-fb."
 130                 elog "Either use chmod a+r /etc/input/mice (security!!!) or use an group."
 131         fi
 132         if use gtk ; then
 133                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=gtk}" )
 134                 netsurf_src_install
 135                 elog "netsurf gtk version has been installed as netsurf-gtk"
 136                 make_desktop_entry "${EROOT}"usr/bin/netsurf-gtk NetSurf-gtk netsurf "Network;WebBrowser"
 137         fi
 138
 139         insinto /usr/share/pixmaps
 140         doins frontends/gtk/res/netsurf.xpm
 141 }