src/bpf_lexer.l

   1 /*
   2  * netsniff-ng - the packet sniffing beast
   3  * By Daniel Borkmann <daniel@netsniff-ng.org>
   4  * Copyright 2012 Daniel Borkmann <dborkma@tik.ee.ethz.ch>,
   5  * Swiss federal institute of technology (ETH Zurich)
   6  * Subject to the GPL, version 2.
   7  */
   8
   9 /* lex-func-prefix: yy */
  10
  11 %{
  12
  13 #include <stdio.h>
  14 #include <stdlib.h>
  15 #include <string.h>
  16 #include <ctype.h>
  17
  18 #include "bpf_parser.tab.h"
  19 #include "xmalloc.h"
  20
  21 extern void yyerror(const char *);
  22
  23 %}
  24
  25 %option align
  26 %option nounput
  27 %option noyywrap
  28 %option noreject
  29 %option 8bit
  30 %option caseless
  31 %option noinput
  32 %option nodefault
  33
  34 digit           [0-9]
  35 digit_s         [1-9]
  36 digit_n         [0]
  37 bindigit        [0-1]
  38 bindigit_b      [b]
  39 hex             [a-fA-F0-9]
  40 hex_x           [x]
  41
  42 number_dec      {digit_n}|{digit_s}{digit}*
  43 number_oct      {digit_n}{digit}+
  44 number_hex      {digit_n}{hex_x}{hex}+
  45 number_bin      {digit_n}{bindigit_b}{bindigit}+
  46
  47 label_s         [a-zA-Z_]
  48 label_me        [a-zA-Z0-9_]
  49 label           {label_s}{label_me}+
  50
  51 %%
  52
  53 "ldb"           { return OP_LDB; }
  54 "ldh"           { return OP_LDH; }
  55 "ld"            { return OP_LD; }
  56 "ldx"           { return OP_LDX; }
  57 "ldxb"          { return OP_LDXB; }
  58 "st"            { return OP_ST; }
  59 "stx"           { return OP_STX; }
  60 "jmp"|"ja"      { return OP_JMP; }
  61 "jeq"           { return OP_JEQ; }
  62 "jgt"           { return OP_JGT; }
  63 "jge"           { return OP_JGE; }
  64 "jset"          { return OP_JSET; }
  65 "add"           { return OP_ADD; }
  66 "sub"           { return OP_SUB; }
  67 "mul"           { return OP_MUL; }
  68 "div"           { return OP_DIV; }
  69 "mod"           { return OP_MOD; }
  70 "neg"           { return OP_NEG; }
  71 "and"           { return OP_AND; }
  72 "xor"           { return OP_XOR; }
  73 "or"            { return OP_OR; }
  74 "lsh"           { return OP_LSH; }
  75 "rsh"           { return OP_RSH; }
  76 "ret"           { return OP_RET; }
  77 "tax"           { return OP_TAX; }
  78 "txa"           { return OP_TXA; }
  79 "len"|"pktlen"  { return K_PKT_LEN; }
  80 "pto"|"proto"   { return K_PROTO; }
  81 "type"          { return K_TYPE; }
  82 "ifx"|"ifidx"   { return K_IFIDX; }
  83 "nla"           { return K_NLATTR; }
  84 "nlan"          { return K_NLATTR_NEST; }
  85 "mark"          { return K_MARK; }
  86 "que"|"queue"   { return K_QUEUE; }
  87 "hat"|"hatype"  { return K_HATYPE; }
  88 "rxh"|"rxhash"  { return K_RXHASH; }
  89 "cpu"           { return K_CPU; }
  90
  91 ":"             { return ':'; }
  92 ","             { return ','; }
  93 "#"             { return '#'; }
  94 "["             { return '['; }
  95 "]"             { return ']'; }
  96 "("             { return '('; }
  97 ")"             { return ')'; }
  98 "x"             { return 'x'; }
  99 "a"             { return 'a'; }
 100 "+"             { return '+'; }
 101 "M"             { return 'M'; }
 102 "*"             { return '*'; }
 103 "&"             { return '&'; }
 104
 105 {number_hex}    { yylval.number = strtoul(yytext, NULL, 16);
 106                   return number_hex; }
 107
 108 {number_dec}    { yylval.number = strtol(yytext, NULL, 10);
 109                   return number_dec; }
 110
 111 {number_oct}    { yylval.number = strtol(yytext, NULL, 8);
 112                   return number_oct; }
 113
 114 {number_bin}    { yylval.number = strtol(yytext + 2, NULL, 2);
 115                   return number_bin; }
 116
 117 {label}         { yylval.label = xstrdup(yytext);
 118                   return label; }
 119
 120 "/*"([^\*]|\*[^/])*"*/" { /* NOP */ }
 121 ";"[^\n]*       {/* NOP */}
 122 "\n"            { yylineno++; }
 123 [ \t]+          {/* NOP */ }
 124 .               { printf("Unknown character '%s'", yytext);
 125                   yyerror("lex Unknown character"); }
 126
 127 %%