configure.in

   1 dnl Process this file with autoconf 2.63 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.63)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 dnl Consider AC_USE_SYSTEM_EXTENSIONS if autoconf 2.61 is OK in the future
  51 AC_PROG_CC
  52 AC_PROG_CC_STDC
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_PROG_LN_S
  55 AC_PROG_MAKE_SET
  56 if test -f nasm.c; then
  57   # we're building in the source dir, so we don't need this check at all
  58   ac_cv_prog_make_vpathok=yes
  59 else
  60   AC_PROG_MAKE_VPATHOK
  61 fi
  62 AC_PROG_INSTALL
  63
  64 dnl Checks for typedefs, structures, and compiler characteristics.
  65 AC_C_CONST
  66 AC_C_INLINE
  67 AC_C_RESTRICT
  68 AC_TYPE_SIZE_T
  69 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN))
  70 AH_TEMPLATE(WORDS_BIGENDIAN,
  71 [Define to 1 if your processor stores words with the most significant
  72 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  73 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  74 [Define to 1 if your processor stores words with the least significant
  75 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  76
  77 dnl Look for programs...
  78 AC_CHECK_PROGS(NROFF,    nroff,    false)
  79 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  80 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  81 AC_CHECK_PROGS(ACRODIST, acrodist, false)
  82 AC_CHECK_PROGS(PS2PDF,   ps2pdf,   false)
  83 AC_CHECK_PROGS(PSTOPDF,  pstopdf,  false)
  84
  85 dnl Check for progs needed for manpage generation
  86 if test $ASCIIDOC = false; then
  87   AC_MSG_WARN([No acsciidoc package found])
  88 fi
  89 if test $XMLTO = false; then
  90   AC_MSG_WARN([No xmlto package found])
  91 fi
  92
  93 dnl Checks for header files.
  94 AC_HEADER_STDC
  95 if test $ac_cv_header_stdc = no; then
  96   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  97 fi
  98
  99 AC_CHECK_HEADERS(limits.h)
 100 if test $ac_cv_header_limits_h = no; then
 101   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
 102 fi
 103
 104 dnl Check for <inttypes.h> or add a substitute version
 105 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
 106
 107 dnl The standard header for str*casecmp is <strings.h>
 108 AC_CHECK_HEADERS(strings.h)
 109
 110 dnl Look for <stdbool.h>
 111 AC_HEADER_STDBOOL
 112
 113 dnl Look for <unistd.h>
 114 AC_CHECK_HEADERS(unistd.h)
 115
 116 dnl Look for <sys/param.h>
 117 AC_CHECK_HEADERS(sys/param.h)
 118
 119 dnl Checks for library functions.
 120 AC_CHECK_FUNCS(strcspn, ,
 121   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 122
 123 AC_CHECK_FUNCS(strspn, ,
 124   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 125
 126 AC_CHECK_FUNCS(strcasecmp stricmp)
 127 AC_CHECK_FUNCS(strncasecmp strnicmp)
 128
 129 AC_CHECK_FUNCS(getuid)
 130 AC_CHECK_FUNCS(getgid)
 131
 132 AC_CHECK_FUNCS(realpath)
 133 AC_CHECK_FUNCS(canonicalize_file_name)
 134 AC_CHECK_FUNCS(_fullpath)
 135 AC_CHECK_FUNCS(pathconf)
 136
 137 PA_HAVE_FUNC(__builtin_ctz, (0U))
 138 PA_HAVE_FUNC(__builtin_ctzl, (0UL))
 139 PA_HAVE_FUNC(__builtin_ctzll, (0ULL))
 140
 141 dnl Functions for which we have replacements available in lib/
 142 AC_CONFIG_LIBOBJ_DIR([lib])
 143 AC_SUBST([LIBOBJDIR], [lib/])
 144 PA_REPLACE_FUNC([vsnprintf _vsnprintf])
 145 PA_REPLACE_FUNC([snprintf _snprintf])
 146 PA_REPLACE_FUNC([strlcpy])
 147 PA_REPLACE_FUNC([strsep])
 148
 149 dnl Check for functions that might not be declared in the headers for
 150 dnl various idiotic reasons (mostly because of library authors
 151 dnl abusing the meaning of __STRICT_ANSI__)
 152 AC_CHECK_DECLS(strcasecmp)
 153 AC_CHECK_DECLS(stricmp)
 154 AC_CHECK_DECLS(strncasecmp)
 155 AC_CHECK_DECLS(strnicmp)
 156 AC_CHECK_DECLS(strsep)
 157 AC_CHECK_DECLS(strlcpy)
 158
 159 if test $ac_cv_prog_make_vpathok = no; then
 160   echo Copying generated srcs into build directory to compensate for VPATH breakage
 161   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 162     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 163   done
 164 fi
 165
 166 dnl
 167 dnl support cchace
 168 dnl
 169 AC_ARG_WITH([ccache],
 170             [AC_HELP_STRING([--with-ccache],
 171                             [Compile with ccache])],
 172           [CC="ccache $CC"],
 173           [])
 174
 175 dnl If we have gcc, add appropriate options
 176 PA_ADD_CFLAGS([-W])
 177 PA_ADD_CFLAGS([-Wall])
 178 PA_ADD_CFLAGS([-pedantic])
 179 PA_ADD_CFLAGS([-Werror=implicit])
 180 PA_ADD_CFLAGS([-Werror=missing-braces])
 181 PA_ADD_CFLAGS([-Werror=return-type])
 182 PA_ADD_CFLAGS([-Werror=trigraphs])
 183 PA_ADD_CFLAGS([-Werror=pointer-arith])
 184 PA_ADD_CFLAGS([-Werror=strict-prototypes])
 185 PA_ADD_CFLAGS([-Werror=missing-prototypes])
 186 PA_ADD_CFLAGS([-Werror=missing-declarations])
 187 PA_ADD_CFLAGS([-Werror=comment])
 188 PA_ADD_CFLAGS([-Werror=vla])
 189
 190 AC_OUTPUT_COMMANDS([mkdir -p output])
 191 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)