configure.ac

   1 dnl Process this file with autoconf 2.69 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.69)
   4 AC_INIT(config/config.h.in)
   5 AC_CONFIG_HEADERS(config/config.h)
   6
   7 AC_PREFIX_PROGRAM(nasm)
   8
   9 dnl Save initial CFLAGS, to see if -g -O2 came from configure or not
  10 pa_init_cflags="$CFLAGS"
  11
  12 dnl This prevents us from running Wine and thinking we are not
  13 dnl cross-compiling when in fact we are; running Wine here is at
  14 dnl the best very slow and doesn't buy us a single thing at all.
  15 WINELOADER=/dev/null
  16 export WINELOADER
  17
  18 dnl Checks for programs and enable necessary CC extensions
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 AC_PROG_CC_STDC
  23 AC_PROG_LN_S
  24 AC_PROG_MAKE_SET
  25 AC_PROG_INSTALL
  26
  27 dnl If the user did not specify a CFLAGS default, change default -O2
  28 dnl to either -O3 (normal) or -O0 (for debugging)
  29 PA_ARG_DISABLED([optimization],
  30  [compile without optimization (-O0) to help debugging],
  31  [pa_optimize=-O0], [pa_optimize=-O3])
  32
  33 dnl Compile and link with dwarf debug
  34 PA_ARG_ENABLED([gdb],
  35  [disable optimization and compile with extra debug information for GDB debugger],
  36  [pa_optimize='-O0'
  37   PA_ADD_CFLAGS([-ggdb3])
  38  ])
  39
  40 AS_IF([test x"$pa_init_cflags" = x],
  41       [CFLAGS=`echo "$CFLAGS" | sed -e "s/-O2/$pa_optimize/"`])
  42
  43 AS_IF([test x"$pa_optimize" = "x-O0"],
  44       [PA_ADD_CFLAGS([-fno-omit-frame-pointer])])
  45
  46 dnl Abort on panic
  47 PA_ARG_ENABLED([panic-abort],
  48  [call abort() on panic to trap in the debugger],
  49  [AC_DEFINE(ABORT_ON_PANIC)])
  50 AH_TEMPLATE(ABORT_ON_PANIC,
  51 [Define to 1 to call abort() on panics (internal errors), for debugging.])
  52
  53 dnl Check for library extension
  54 PA_LIBEXT
  55
  56 dnl Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_C_RESTRICT
  60 AC_TYPE_SIZE_T
  61 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN),,)
  62 AH_TEMPLATE(WORDS_BIGENDIAN,
  63 [Define to 1 if your processor stores words with the most significant
  64 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  65 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  66 [Define to 1 if your processor stores words with the least significant
  67 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  68
  69 dnl Force gcc and gcc-compatible compilers treat signed integers
  70 dnl as 2's complement
  71 PA_ADD_CFLAGS([-fwrapv])
  72
  73 dnl Some environments abuse __STRICT_ANSI__ to disable some
  74 dnl function declarations
  75 PA_ADD_CFLAGS([-U__STRICT_ANSI__])
  76
  77 dnl Don't put things in common if we can avoid it.  We don't want to
  78 dnl assume all compilers support common, and this will help find those
  79 dnl problems.  This also works around an OSX linker problem.
  80 PA_ADD_CFLAGS([-fno-common])
  81
  82 dnl Look for programs...
  83 AC_CHECK_PROGS(NROFF,    nroff,    false)
  84 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  85 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  86
  87 dnl Check for progs needed for manpage generation
  88 AS_IF([test $ASCIIDOC = false],
  89   [AC_MSG_WARN([No asciidoc package found])]
  90 )
  91 AS_IF([test $XMLTO = false],
  92   [AC_MSG_WARN([No xmlto package found])]
  93 )
  94
  95 dnl Check for host compiler tools
  96 AC_CHECK_TOOL(AR, ar)
  97 AC_CHECK_TOOL(RANLIB, ranlib, :)
  98 AC_CHECK_TOOL(STRIP, strip)
  99
 100 dnl Checks for header files.
 101 AC_HEADER_STDC
 102 AC_CHECK_HEADERS(inttypes.h)
 103 AC_CHECK_HEADERS(strings.h)
 104 AC_HEADER_STDBOOL
 105 AC_CHECK_HEADERS(stdnoreturn.h)
 106 AC_CHECK_HEADERS(io.h)
 107 AC_CHECK_HEADERS(fcntl.h)
 108 AC_CHECK_HEADERS(unistd.h)
 109 AC_CHECK_HEADERS(sys/mman.h)
 110 AC_CHECK_HEADERS(sys/types.h)
 111 AC_CHECK_HEADERS(sys/stat.h)
 112
 113 dnl Checks for library functions.
 114 AC_CHECK_FUNCS(strcasecmp stricmp)
 115 AC_CHECK_FUNCS(strncasecmp strnicmp)
 116 AC_CHECK_FUNCS(strsep)
 117 AC_CHECK_FUNCS(strnlen)
 118 AC_CHECK_FUNCS(strrchrnul)
 119
 120 AC_CHECK_FUNCS(getuid)
 121 AC_CHECK_FUNCS(getgid)
 122
 123 AC_CHECK_FUNCS(realpath)
 124 AC_CHECK_FUNCS(canonicalize_file_name)
 125 AC_CHECK_FUNCS(_fullpath)
 126 AC_CHECK_FUNCS(pathconf)
 127
 128 AC_FUNC_FSEEKO
 129 AC_CHECK_FUNCS([_fseeki64])
 130 AC_CHECK_FUNCS([ftruncate _chsize _chsize_s])
 131 AC_CHECK_FUNCS([fileno _fileno])
 132
 133 AC_CHECK_FUNCS(_filelengthi64)
 134 AC_FUNC_MMAP
 135 AC_CHECK_FUNCS(getpagesize)
 136 AC_CHECK_FUNCS(sysconf)
 137
 138 AC_CHECK_FUNCS([access _access faccessat])
 139
 140 PA_HAVE_FUNC(__builtin_expect, (1,1))
 141
 142 dnl ilog2() building blocks
 143 PA_ADD_HEADERS(intrin.h)
 144 PA_HAVE_FUNC(__builtin_clz, (0U))
 145 PA_HAVE_FUNC(__builtin_clzl, (0UL))
 146 PA_HAVE_FUNC(__builtin_clzll, (0ULL))
 147 PA_HAVE_FUNC(_BitScanReverse, (0))
 148 PA_HAVE_FUNC(_BitScanReverse64, (0))
 149
 150 dnl Functions for which we have replacements available in stdlib/
 151 AC_CHECK_FUNCS([vsnprintf _vsnprintf])
 152 AC_CHECK_FUNCS([snprintf _snprintf])
 153 AC_CHECK_FUNCS([strlcpy])
 154 AC_CHECK_FUNCS([strrchrnul])
 155
 156 dnl These types are POSIX-specific, and Windows does it differently...
 157 AC_CHECK_TYPES([struct _stati64])
 158 AC_CHECK_TYPES([struct stat])
 159 AC_CHECK_FUNCS([stat _stati64])
 160 AC_CHECK_FUNCS([fstat _fstati64])
 161
 162 dnl Check for functions that might not be declared in the headers for
 163 dnl various idiotic reasons (mostly because of library authors
 164 dnl abusing the meaning of __STRICT_ANSI__)
 165 AC_CHECK_DECLS(strcasecmp)
 166 AC_CHECK_DECLS(stricmp)
 167 AC_CHECK_DECLS(strncasecmp)
 168 AC_CHECK_DECLS(strnicmp)
 169 AC_CHECK_DECLS(strsep)
 170 AC_CHECK_DECLS(strlcpy)
 171 AC_CHECK_DECLS(strnlen)
 172 AC_CHECK_DECLS(strrchrnul)
 173
 174 dnl Check for missing types
 175 AC_TYPE_UINTPTR_T
 176
 177 dnl Documentation: should we generate an uncompressed PDF?  It is
 178 dnl about twice as big, but it can be externally compressed (e.g. with xz)
 179 dnl and becomes significantly smaller than the original.
 180 PA_ARG_DISABLED([pdf-compression],
 181   [generate an uncompressed documentation PDF],
 182   [PDFOPT='-nocompress'])
 183 AC_SUBST([PDFOPT])
 184
 185 dnl
 186 dnl Look for byte-swapping support...
 187 dnl
 188 PA_ADD_HEADERS(endian.h sys/endian.h machine/endian.h)
 189 PA_HAVE_FUNC(cpu_to_le16, (0))
 190 PA_HAVE_FUNC(cpu_to_le32, (0))
 191 PA_HAVE_FUNC(cpu_to_le64, (0))
 192 PA_HAVE_FUNC(__cpu_to_le16, (0))
 193 PA_HAVE_FUNC(__cpu_to_le32, (0))
 194 PA_HAVE_FUNC(__cpu_to_le64, (0))
 195 PA_HAVE_FUNC(htole16, (0))
 196 PA_HAVE_FUNC(htole32, (0))
 197 PA_HAVE_FUNC(htole64, (0))
 198 PA_HAVE_FUNC(__bswap_16, (0))
 199 PA_HAVE_FUNC(__bswap_32, (0))
 200 PA_HAVE_FUNC(__bswap_64, (0))
 201 PA_HAVE_FUNC(__builtin_bswap16, (0))
 202 PA_HAVE_FUNC(__builtin_bswap32, (0))
 203 PA_HAVE_FUNC(__builtin_bswap64, (0))
 204 PA_HAVE_FUNC(_byteswap_ushort, (0))
 205 PA_HAVE_FUNC(_byteswap_ulong, (0))
 206 PA_HAVE_FUNC(_byteswap_uint64, (0))
 207
 208 dnl
 209 dnl Check for __builtin_constant_p()
 210 dnl
 211 PA_HAVE_FUNC(__builtin_constant_p, (0))
 212
 213 dnl
 214 dnl Check for supported gcc attributes; some compilers (e.g. Sun CC)
 215 dnl support these, but don't define __GNUC__ as they don't support
 216 dnl some other features of gcc.
 217 dnl
 218 PA_ADD_CFLAGS([-Werror=attributes])
 219 PA_FUNC_ATTRIBUTE(noreturn)
 220 PA_FUNC_ATTRIBUTE(returns_nonnull)
 221 PA_FUNC_ATTRIBUTE(malloc)
 222 PA_FUNC_ATTRIBUTE(alloc_size, (1))
 223 PA_FUNC_ATTRIBUTE(format, [(printf,1,2)], int, [const char *, ...], ["%d",1])
 224 PA_FUNC_ATTRIBUTE(const)
 225 PA_FUNC_ATTRIBUTE(pure)
 226 PA_FUNC_ATTRIBUTE(cold)
 227 PA_FUNC_ATTRIBUTE_ERROR
 228
 229 dnl
 230 dnl support function sections (if available)
 231 dnl
 232 PA_ARG_ENABLED([sections],
 233  [compile with function/data section support],
 234  [PA_ADD_CLDFLAGS([-ffunction-sections])
 235   PA_ADD_CLDFLAGS([-fdata-sections])
 236   PA_ADD_CLDFLAGS([-Wl,--gc-sections])],
 237  [])
 238
 239 dnl
 240 dnl support LTO
 241 dnl
 242 PA_ARG_ENABLED([lto],
 243  [compile with gcc-style link time optimization],
 244  [PA_ADD_CLDFLAGS([-flto])
 245   dnl Note: we use _PROG rather than _TOOL since we are prepending the full
 246   dnl CC name which ought to already contain the host triplet if needed
 247   ccbase=`echo "$CC" | awk '{ print $1; }'`
 248   AC_CHECK_PROGS(CC_AR, [${ccbase}-ar], [$ac_cv_prog_AR])
 249   AR="$CC_AR"
 250   AC_CHECK_PROGS(CC_RANLIB, [${ccbase}-ranlib], [$ac_cv_prog_RANLIB])
 251   RANLIB="$CC_RANLIB"], [])
 252
 253 dnl
 254 dnl support sanitizers (if available)
 255 dnl
 256 PA_ARG_ENABLED([sanitizer],
 257  [compile with sanitizers enabled],
 258  [PA_ADD_CFLAGS([-fno-omit-frame-pointer])
 259   PA_ADD_CLDFLAGS([-fsanitize=address])
 260   PA_ADD_CLDFLAGS([-fsanitize=undefined])])
 261
 262 dnl If we have gcc, add appropriate code cleanliness options
 263 PA_ADD_CFLAGS([-W])
 264 PA_ADD_CFLAGS([-Wall])
 265 PA_ADD_CFLAGS([-pedantic])
 266 dnl LLVM doesn't error out on invalid -W options unless this option is
 267 dnl specified first.  Enable this so this script can actually discover
 268 dnl which -W options are possible for this compiler.
 269 PA_ADD_CFLAGS([-Werror=unknown-warning-option])
 270 dnl Suppress format warning on Windows targets due to their <inttypes.h>
 271 PA_ADD_CFLAGS([-Wpedantic-ms-format],[-Wno-pedantic-ms-format])
 272 PA_ADD_CFLAGS([-Wc90-c99-compat])
 273 PA_ADD_CFLAGS([-Wlong-long],[-Wno-long-long])
 274 dnl PA_ADD_CFLAGS([-Wwrite-strings])
 275 PA_ARG_ENABLED([werror],
 276  [compile with -Werror to error out on any warning],
 277  [PA_ADD_CFLAGS([-Werror])],
 278  [PA_ADD_CFLAGS([-Werror=implicit])
 279   PA_ADD_CFLAGS([-Werror=missing-braces])
 280   PA_ADD_CFLAGS([-Werror=return-type])
 281   PA_ADD_CFLAGS([-Werror=trigraphs])
 282   PA_ADD_CFLAGS([-Werror=pointer-arith])
 283   PA_ADD_CFLAGS([-Werror=strict-prototypes])
 284   PA_ADD_CFLAGS([-Werror=missing-prototypes])
 285   PA_ADD_CFLAGS([-Werror=missing-declarations])
 286   PA_ADD_CFLAGS([-Werror=comment])
 287   PA_ADD_CFLAGS([-Werror=vla])]
 288 )
 289
 290 dnl
 291 dnl On some versions of gcc, -Werror=missing-prototypes causes problems
 292 dnl with C99-style external inlines.  Test this *after* adding the -Werror
 293 dnl options.
 294 dnl
 295 PA_CHECK_BAD_STDC_INLINE
 296
 297 dnl
 298 dnl support ccache
 299 dnl
 300 PA_ARG_ENABLED([ccache], [compile with ccache], [CC="ccache $CC"], [])
 301
 302 AC_OUTPUT_COMMANDS([mkdir -p config nasmlib nsis output stdlib x86 asm disasm rdoff macros common])
 303 AC_OUTPUT(Makefile doc/Makefile)