configure.in

   1 dnl Process this file with autoconf 2.63 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.63)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 dnl Consider AC_USE_SYSTEM_EXTENSIONS if autoconf 2.61 is OK in the future
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_SYS_LARGEFILE
  53 AC_PROG_CC
  54 AC_PROG_CC_STDC
  55 AC_PROG_LN_S
  56 AC_PROG_MAKE_SET
  57 if test -f nasm.c; then
  58   # we're building in the source dir, so we don't need this check at all
  59   ac_cv_prog_make_vpathok=yes
  60 else
  61   AC_PROG_MAKE_VPATHOK
  62 fi
  63 AC_PROG_INSTALL
  64
  65 dnl Checks for typedefs, structures, and compiler characteristics.
  66 AC_C_CONST
  67 AC_C_INLINE
  68 AC_C_RESTRICT
  69 AC_TYPE_SIZE_T
  70 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN),,)
  71 AH_TEMPLATE(WORDS_BIGENDIAN,
  72 [Define to 1 if your processor stores words with the most significant
  73 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  74 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  75 [Define to 1 if your processor stores words with the least significant
  76 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  77
  78 dnl Force gcc and gcc-compatible compilers treat signed integers
  79 dnl as 2's complement
  80 PA_ADD_CFLAGS([-fwrapv])
  81
  82 dnl Look for programs...
  83 AC_CHECK_PROGS(NROFF,    nroff,    false)
  84 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  85 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  86 AC_CHECK_PROGS(ACRODIST, acrodist, false)
  87 AC_CHECK_PROGS(PS2PDF,   ps2pdf,   false)
  88 AC_CHECK_PROGS(PSTOPDF,  pstopdf,  false)
  89
  90 dnl Check for progs needed for manpage generation
  91 if test $ASCIIDOC = false; then
  92   AC_MSG_WARN([No acsciidoc package found])
  93 fi
  94 if test $XMLTO = false; then
  95   AC_MSG_WARN([No xmlto package found])
  96 fi
  97
  98 dnl Checks for header files.
  99 AC_HEADER_STDC
 100 if test $ac_cv_header_stdc = no; then
 101   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
 102 fi
 103
 104 AC_CHECK_HEADERS(limits.h)
 105 if test $ac_cv_header_limits_h = no; then
 106   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
 107 fi
 108
 109 dnl Check for <inttypes.h> or add a substitute version
 110 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
 111
 112 dnl The standard header for str*casecmp is <strings.h>
 113 AC_CHECK_HEADERS(strings.h)
 114
 115 dnl Look for <stdbool.h>
 116 AC_HEADER_STDBOOL
 117
 118 dnl Look for <io.h>
 119 AC_CHECK_HEADERS(io.h)
 120
 121 dnl Look for <unistd.h>
 122 AC_CHECK_HEADERS(unistd.h)
 123
 124 dnl Look for <sys/param.h>
 125 AC_CHECK_HEADERS(sys/param.h)
 126
 127 dnl Checks for library functions.
 128 AC_CHECK_FUNCS(strcspn, ,
 129   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 130
 131 AC_CHECK_FUNCS(strspn, ,
 132   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 133
 134 AC_CHECK_FUNCS(strcasecmp stricmp)
 135 AC_CHECK_FUNCS(strncasecmp strnicmp)
 136 AC_CHECK_FUNCS(strsep)
 137
 138 AC_CHECK_FUNCS(getuid)
 139 AC_CHECK_FUNCS(getgid)
 140
 141 AC_CHECK_FUNCS(realpath)
 142 AC_CHECK_FUNCS(canonicalize_file_name)
 143 AC_CHECK_FUNCS(_fullpath)
 144 AC_CHECK_FUNCS(pathconf)
 145
 146 AC_FUNC_FSEEKO
 147 AC_CHECK_FUNCS([_fseeki64])
 148 AC_CHECK_FUNCS([ftruncate _chsize _chsize_s])
 149 AC_CHECK_FUNCS([fileno])
 150
 151 PA_HAVE_FUNC(__builtin_ctz, (0U))
 152 PA_HAVE_FUNC(__builtin_ctzl, (0UL))
 153 PA_HAVE_FUNC(__builtin_ctzll, (0ULL))
 154
 155 dnl Functions for which we have replacements available in lib/
 156 AC_CONFIG_LIBOBJ_DIR([lib])
 157 AC_SUBST([LIBOBJDIR], [lib/])
 158 PA_REPLACE_FUNC([vsnprintf _vsnprintf])
 159 PA_REPLACE_FUNC([snprintf _snprintf])
 160 PA_REPLACE_FUNC([strlcpy])
 161
 162 dnl Check for functions that might not be declared in the headers for
 163 dnl various idiotic reasons (mostly because of library authors
 164 dnl abusing the meaning of __STRICT_ANSI__)
 165 AC_CHECK_DECLS(strcasecmp)
 166 AC_CHECK_DECLS(stricmp)
 167 AC_CHECK_DECLS(strncasecmp)
 168 AC_CHECK_DECLS(strnicmp)
 169 AC_CHECK_DECLS(strsep)
 170 AC_CHECK_DECLS(strlcpy)
 171
 172 if test $ac_cv_prog_make_vpathok = no; then
 173   echo Copying generated srcs into build directory to compensate for VPATH breakage
 174   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 175     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 176   done
 177 fi
 178
 179 dnl
 180 dnl support cchace
 181 dnl
 182 AC_ARG_ENABLE([ccache],
 183 [AC_HELP_STRING([--with-ccache], [compile with ccache])],
 184 [CC="ccache $CC"],
 185 [])
 186
 187 dnl If we have gcc, add appropriate code cleanliness options
 188 PA_ADD_CFLAGS([-W])
 189 PA_ADD_CFLAGS([-Wall])
 190 PA_ADD_CFLAGS([-std=c99])
 191 PA_ADD_CFLAGS([-pedantic])
 192 AC_ARG_ENABLE([werror],
 193 [AC_HELP_STRING([--enable-werror],
 194 [compile with -Werror to error out on any warning])],
 195 [PA_ADD_CFLAGS([-Werror])],
 196 [PA_ADD_CFLAGS([-Werror=implicit])
 197 PA_ADD_CFLAGS([-Werror=missing-braces])
 198 PA_ADD_CFLAGS([-Werror=return-type])
 199 PA_ADD_CFLAGS([-Werror=trigraphs])
 200 PA_ADD_CFLAGS([-Werror=pointer-arith])
 201 PA_ADD_CFLAGS([-Werror=strict-prototypes])
 202 PA_ADD_CFLAGS([-Werror=missing-prototypes])
 203 PA_ADD_CFLAGS([-Werror=missing-declarations])
 204 PA_ADD_CFLAGS([-Werror=comment])
 205 PA_ADD_CFLAGS([-Werror=vla])])
 206
 207 AC_OUTPUT_COMMANDS([mkdir -p output])
 208 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)