configure.ac

   1 dnl Process this file with autoconf 2.63 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.63)
   4 AC_INIT(config/config.h.in)
   5 AC_CONFIG_HEADERS(config/config.h)
   6
   7 AC_PREFIX_PROGRAM(nasm)
   8
   9 dnl Save initial CFLAGS, to see if -g -O2 came from configure or not
  10 pa_init_cflags="$CFLAGS"
  11
  12 dnl This prevents us from running Wine and thinking we are not
  13 dnl cross-compiling when in fact we are; running Wine here is at
  14 dnl the best very slow and doesn't buy us a single thing at all.
  15 WINELOADER=/dev/null
  16 export WINELOADER
  17
  18 dnl Checks for programs and enable necessary CC extensions
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 AC_PROG_CC_STDC
  23 AC_PROG_LN_S
  24 AC_PROG_MAKE_SET
  25 AC_PROG_INSTALL
  26
  27 dnl If the user did not specify a CFLAGS default, change default -O2
  28 dnl to either -O3 (normal) or -O0 (for debugging)
  29 PA_ARG_DISABLED([optimization],
  30  [compile without optimization (-O0) to help debugging],
  31  [pa_optimize=-O0], [pa_optimize=-O3])
  32 AS_IF([test x"$pa_init_cflags" = x],
  33       [CFLAGS=`echo "$CFLAGS" | sed -e "s/-O2/$pa_optimize/"`])
  34
  35 dnl Check for library extension
  36 PA_LIBEXT
  37
  38 dnl Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_CONST
  40 AC_C_INLINE
  41 AC_C_RESTRICT
  42 AC_TYPE_SIZE_T
  43 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN),,)
  44 AH_TEMPLATE(WORDS_BIGENDIAN,
  45 [Define to 1 if your processor stores words with the most significant
  46 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  47 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  48 [Define to 1 if your processor stores words with the least significant
  49 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  50
  51 dnl Force gcc and gcc-compatible compilers treat signed integers
  52 dnl as 2's complement
  53 PA_ADD_CFLAGS([-fwrapv])
  54
  55 dnl Some environments abuse __STRICT_ANSI__ to disable some
  56 dnl function declarations
  57 PA_ADD_CFLAGS([-U__STRICT_ANSI__])
  58
  59 dnl Don't put things in common if we can avoid it.  We don't want to
  60 dnl assume all compilers support common, and this will help find those
  61 dnl problems.  This also works around an OSX linker problem.
  62 PA_ADD_CFLAGS([-fno-common])
  63
  64 dnl Look for programs...
  65 AC_CHECK_PROGS(NROFF,    nroff,    false)
  66 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  67 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  68
  69 dnl Check for progs needed for manpage generation
  70 AS_IF([test $ASCIIDOC = false],
  71   [AC_MSG_WARN([No asciidoc package found])]
  72 )
  73 AS_IF([test $XMLTO = false],
  74   [AC_MSG_WARN([No xmlto package found])]
  75 )
  76
  77 dnl Check for host compiler tools
  78 AC_CHECK_TOOL(AR, ar)
  79 AC_CHECK_TOOL(RANLIB, ranlib, :)
  80 AC_CHECK_TOOL(STRIP, strip)
  81
  82 dnl Checks for header files.
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS(inttypes.h)
  85 AC_CHECK_HEADERS(strings.h)
  86 AC_HEADER_STDBOOL
  87 AC_CHECK_HEADERS(stdnoreturn.h)
  88 AC_CHECK_HEADERS(io.h)
  89 AC_CHECK_HEADERS(fcntl.h)
  90 AC_CHECK_HEADERS(unistd.h)
  91 AC_CHECK_HEADERS(sys/param.h)
  92 AC_CHECK_HEADERS(sys/mman.h)
  93 AC_CHECK_HEADERS(sys/types.h)
  94 AC_CHECK_HEADERS(sys/stat.h)
  95
  96 dnl Checks for library functions.
  97 AC_CHECK_FUNCS(strcasecmp stricmp)
  98 AC_CHECK_FUNCS(strncasecmp strnicmp)
  99 AC_CHECK_FUNCS(strsep)
 100 AC_CHECK_FUNCS(strnlen)
 101
 102 AC_CHECK_FUNCS(getuid)
 103 AC_CHECK_FUNCS(getgid)
 104
 105 AC_CHECK_FUNCS(realpath)
 106 AC_CHECK_FUNCS(canonicalize_file_name)
 107 AC_CHECK_FUNCS(_fullpath)
 108 AC_CHECK_FUNCS(pathconf)
 109
 110 AC_FUNC_FSEEKO
 111 AC_CHECK_FUNCS([_fseeki64])
 112 AC_CHECK_FUNCS([ftruncate _chsize _chsize_s])
 113 AC_CHECK_FUNCS([fileno _fileno])
 114
 115 AC_CHECK_FUNCS(_filelengthi64)
 116 AC_FUNC_MMAP
 117 AC_CHECK_FUNCS(getpagesize)
 118 AC_CHECK_FUNCS(sysconf)
 119
 120 AC_CHECK_FUNCS([access _access faccessat])
 121
 122 PA_HAVE_FUNC(__builtin_clz, (0U))
 123 PA_HAVE_FUNC(__builtin_clzl, (0UL))
 124 PA_HAVE_FUNC(__builtin_clzll, (0ULL))
 125 PA_HAVE_FUNC(__builtin_expect, (1,1))
 126
 127 dnl Functions for which we have replacements available in lib/
 128 AC_CHECK_FUNCS([vsnprintf _vsnprintf])
 129 AC_CHECK_FUNCS([snprintf _snprintf])
 130 AC_CHECK_FUNCS([strlcpy])
 131
 132 dnl These types are POSIX-specific, and Windows does it differently...
 133 AC_CHECK_TYPES([struct _stati64])
 134 AC_CHECK_TYPES([struct stat])
 135 AC_CHECK_FUNCS([stat _stati64])
 136 AC_CHECK_FUNCS([fstat _fstati64])
 137
 138 dnl Check for functions that might not be declared in the headers for
 139 dnl various idiotic reasons (mostly because of library authors
 140 dnl abusing the meaning of __STRICT_ANSI__)
 141 AC_CHECK_DECLS(strcasecmp)
 142 AC_CHECK_DECLS(stricmp)
 143 AC_CHECK_DECLS(strncasecmp)
 144 AC_CHECK_DECLS(strnicmp)
 145 AC_CHECK_DECLS(strsep)
 146 AC_CHECK_DECLS(strlcpy)
 147 AC_CHECK_DECLS(strnlen)
 148
 149 dnl Check for missing types
 150 AC_TYPE_UINTPTR_T
 151
 152 dnl Documentation: should we generate an uncompressed PDF?  It is
 153 dnl about twice as big, but it can be externally compressed (e.g. with xz)
 154 dnl and becomes significantly smaller than the original.
 155 PA_ARG_DISABLED([pdf-compression],
 156   [generate an uncompressed documentation PDF],
 157   [PDFOPT='-nocompress'])
 158 AC_SUBST([PDFOPT])
 159
 160 dnl
 161 dnl Check for supported gcc attributes; some compilers (e.g. Sun CC)
 162 dnl support these, but don't define __GNUC__ as they don't support
 163 dnl some other features of gcc.
 164 dnl
 165 PA_ADD_CFLAGS([-Werror=attributes])
 166 PA_FUNC_ATTRIBUTE(noreturn)
 167 PA_FUNC_ATTRIBUTE(returns_nonnull)
 168 PA_FUNC_ATTRIBUTE(malloc)
 169 PA_FUNC_ATTRIBUTE(alloc_size, (1))
 170 PA_FUNC_ATTRIBUTE(format, [(printf,1,2)], int, [const char *, ...], ["%d",1])
 171 PA_FUNC_ATTRIBUTE(const)
 172 PA_FUNC_ATTRIBUTE(pure)
 173 PA_FUNC_ATTRIBUTE_ERROR
 174
 175 dnl
 176 dnl support function sections
 177 dnl
 178 PA_ARG_ENABLED([sections],
 179  [compile with function/data section support],
 180  [PA_ADD_CLDFLAGS([-ffunction-sections])
 181   PA_ADD_CLDFLAGS([-fdata-sections])
 182   PA_ADD_CLDFLAGS([-Wl,--gc-sections])],
 183  [])
 184 dnl
 185 dnl support LTO
 186 dnl
 187 PA_ARG_ENABLED([lto],
 188  [compile with gcc-style link time optimization],
 189  [PA_ADD_CLDFLAGS([-flto])
 190   dnl Note: we use _PROG rather than _TOOL since we are prepending the full
 191   dnl CC name which ought to already contain the host triplet if needed
 192   ccbase=`echo "$CC" | awk '{ print $1; }'`
 193   AC_CHECK_PROGS(CC_AR, [${ccbase}-ar], [$ac_cv_prog_AR])
 194   AR="$CC_AR"
 195   AC_CHECK_PROGS(CC_RANLIB, [${ccbase}-ranlib], [$ac_cv_prog_RANLIB])
 196   RANLIB="$CC_RANLIB"], [])
 197
 198 dnl If we have gcc, add appropriate code cleanliness options
 199 PA_ADD_CFLAGS([-W])
 200 PA_ADD_CFLAGS([-Wall])
 201 PA_ADD_CFLAGS([-pedantic])
 202 dnl LLVM doesn't error out on invalid -W options unless this option is
 203 dnl specified first.  Enable this so this script can actually discover
 204 dnl which -W options are possible for this compiler.
 205 PA_ADD_CFLAGS([-Werror=unknown-warning-option])
 206 dnl Suppress format warning on Windows targets due to their <inttypes.h>
 207 PA_ADD_CFLAGS([-Wpedantic-ms-format],[-Wno-pedantic-ms-format])
 208 PA_ADD_CFLAGS([-Wc90-c99-compat])
 209 PA_ADD_CFLAGS([-Wlong-long],[-Wno-long-long])
 210 dnl PA_ADD_CFLAGS([-Wwrite-strings])
 211 PA_ARG_ENABLED([werror],
 212  [compile with -Werror to error out on any warning],
 213  [PA_ADD_CFLAGS([-Werror])],
 214  [PA_ADD_CFLAGS([-Werror=implicit])
 215   PA_ADD_CFLAGS([-Werror=missing-braces])
 216   PA_ADD_CFLAGS([-Werror=return-type])
 217   PA_ADD_CFLAGS([-Werror=trigraphs])
 218   PA_ADD_CFLAGS([-Werror=pointer-arith])
 219   PA_ADD_CFLAGS([-Werror=strict-prototypes])
 220   PA_ADD_CFLAGS([-Werror=missing-prototypes])
 221   PA_ADD_CFLAGS([-Werror=missing-declarations])
 222   PA_ADD_CFLAGS([-Werror=comment])
 223   PA_ADD_CFLAGS([-Werror=vla])]
 224 )
 225
 226 dnl
 227 dnl support ccache
 228 dnl
 229 PA_ARG_ENABLED([ccache], [compile with ccache], [CC="ccache $CC"], [])
 230
 231 AC_OUTPUT_COMMANDS([mkdir -p config nasmlib nsis output stdlib x86 asm disasm rdoff macros common])
 232 AC_OUTPUT(Makefile doc/Makefile)