configure.ac

   1 dnl Process this file with autoconf 2.63 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.63)
   4 AC_INIT(config/config.h.in)
   5 AC_CONFIG_HEADERS(config/config.h)
   6
   7 AC_PREFIX_PROGRAM(nasm)
   8
   9 dnl Save initial CFLAGS, to see if -g -O2 came from configure or not
  10 pa_init_cflags="$CFLAGS"
  11
  12 dnl This prevents us from running Wine and thinking we are not
  13 dnl cross-compiling when in fact we are; running Wine here is at
  14 dnl the best very slow and doesn't buy us a single thing at all.
  15 WINELOADER=/dev/null
  16 export WINELOADER
  17
  18 dnl Checks for programs and enable necessary CC extensions
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 AC_PROG_CC_STDC
  23 AC_PROG_LN_S
  24 AC_PROG_MAKE_SET
  25 AC_PROG_INSTALL
  26
  27 dnl If the user did not specify a CFLAGS default, change default -O2
  28 dnl to either -O3 (normal) or -O0 (for debugging)
  29 PA_ARG_DISABLED([optimization],
  30  [compile without optimization (-O0) to help debugging],
  31  [pa_optimize=-O0], [pa_optimize=-O3])
  32 AS_IF([test x"$pa_init_cflags" = x],
  33       [CFLAGS=`echo "$CFLAGS" | sed -e "s/-O2/$pa_optimize/"`])
  34
  35 dnl Check for library extension
  36 PA_LIBEXT
  37
  38 dnl Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_CONST
  40 AC_C_INLINE
  41 AC_C_RESTRICT
  42 AC_TYPE_SIZE_T
  43 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN),,)
  44 AH_TEMPLATE(WORDS_BIGENDIAN,
  45 [Define to 1 if your processor stores words with the most significant
  46 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  47 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  48 [Define to 1 if your processor stores words with the least significant
  49 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  50
  51 dnl Force gcc and gcc-compatible compilers treat signed integers
  52 dnl as 2's complement
  53 PA_ADD_CFLAGS([-fwrapv])
  54
  55 dnl Some environments abuse __STRICT_ANSI__ to disable some
  56 dnl function declarations
  57 PA_ADD_CFLAGS([-U__STRICT_ANSI__])
  58
  59 dnl Don't put things in common if we can avoid it.  We don't want to
  60 dnl assume all compilers support common, and this will help find those
  61 dnl problems.  This also works around an OSX linker problem.
  62 PA_ADD_CFLAGS([-fno-common])
  63
  64 dnl Look for programs...
  65 AC_CHECK_PROGS(NROFF,    nroff,    false)
  66 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  67 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  68 AC_CHECK_PROGS(ACRODIST, acrodist, false)
  69 AC_CHECK_PROGS(PS2PDF,   ps2pdf,   false)
  70 AC_CHECK_PROGS(PSTOPDF,  pstopdf,  false)
  71
  72 dnl Check for progs needed for manpage generation
  73 AS_IF([test $ASCIIDOC = false],
  74   [AC_MSG_WARN([No asciidoc package found])]
  75 )
  76 AS_IF([test $XMLTO = false],
  77   [AC_MSG_WARN([No xmlto package found])]
  78 )
  79
  80 dnl Check for host compiler tools
  81 AC_CHECK_TOOL(AR, ar)
  82 AC_CHECK_TOOL(RANLIB, ranlib, :)
  83 AC_CHECK_TOOL(STRIP, strip)
  84
  85 dnl Checks for header files.
  86 AC_HEADER_STDC
  87 AC_CHECK_HEADERS(inttypes.h)
  88 AC_CHECK_HEADERS(strings.h)
  89 AC_HEADER_STDBOOL
  90 AC_CHECK_HEADERS(stdnoreturn.h)
  91 AC_CHECK_HEADERS(io.h)
  92 AC_CHECK_HEADERS(fcntl.h)
  93 AC_CHECK_HEADERS(unistd.h)
  94 AC_CHECK_HEADERS(sys/param.h)
  95 AC_CHECK_HEADERS(sys/mman.h)
  96 AC_CHECK_HEADERS(sys/types.h)
  97 AC_CHECK_HEADERS(sys/stat.h)
  98
  99 dnl Checks for library functions.
 100 AC_CHECK_FUNCS(strcasecmp stricmp)
 101 AC_CHECK_FUNCS(strncasecmp strnicmp)
 102 AC_CHECK_FUNCS(strsep)
 103 AC_CHECK_FUNCS(strnlen)
 104
 105 AC_CHECK_FUNCS(getuid)
 106 AC_CHECK_FUNCS(getgid)
 107
 108 AC_CHECK_FUNCS(realpath)
 109 AC_CHECK_FUNCS(canonicalize_file_name)
 110 AC_CHECK_FUNCS(_fullpath)
 111 AC_CHECK_FUNCS(pathconf)
 112
 113 AC_FUNC_FSEEKO
 114 AC_CHECK_FUNCS([_fseeki64])
 115 AC_CHECK_FUNCS([ftruncate _chsize _chsize_s])
 116 AC_CHECK_FUNCS([fileno _fileno])
 117
 118 AC_CHECK_FUNCS(_filelengthi64)
 119 AC_FUNC_MMAP
 120 AC_CHECK_FUNCS(getpagesize)
 121 AC_CHECK_FUNCS(sysconf)
 122
 123 AC_CHECK_FUNCS([access _access faccessat])
 124
 125 PA_HAVE_FUNC(__builtin_clz, (0U))
 126 PA_HAVE_FUNC(__builtin_clzl, (0UL))
 127 PA_HAVE_FUNC(__builtin_clzll, (0ULL))
 128 PA_HAVE_FUNC(__builtin_expect, (1,1))
 129
 130 dnl Functions for which we have replacements available in lib/
 131 AC_CHECK_FUNCS([vsnprintf _vsnprintf])
 132 AC_CHECK_FUNCS([snprintf _snprintf])
 133 AC_CHECK_FUNCS([strlcpy])
 134
 135 dnl These types are POSIX-specific, and Windows does it differently...
 136 AC_CHECK_TYPES([struct _stati64])
 137 AC_CHECK_TYPES([struct stat])
 138 AC_CHECK_FUNCS([stat _stati64])
 139 AC_CHECK_FUNCS([fstat _fstati64])
 140
 141 dnl Check for functions that might not be declared in the headers for
 142 dnl various idiotic reasons (mostly because of library authors
 143 dnl abusing the meaning of __STRICT_ANSI__)
 144 AC_CHECK_DECLS(strcasecmp)
 145 AC_CHECK_DECLS(stricmp)
 146 AC_CHECK_DECLS(strncasecmp)
 147 AC_CHECK_DECLS(strnicmp)
 148 AC_CHECK_DECLS(strsep)
 149 AC_CHECK_DECLS(strlcpy)
 150 AC_CHECK_DECLS(strnlen)
 151
 152 dnl Check for missing types
 153 AC_TYPE_UINTPTR_T
 154
 155 dnl
 156 dnl Check for supported gcc attributes; some compilers (e.g. Sun CC)
 157 dnl support these, but don't define __GNUC__ as they don't support
 158 dnl some other features of gcc.
 159 dnl
 160 PA_ADD_CFLAGS([-Werror=attributes])
 161 PA_FUNC_ATTRIBUTE(noreturn)
 162 PA_FUNC_ATTRIBUTE(returns_nonnull)
 163 PA_FUNC_ATTRIBUTE(malloc)
 164 PA_FUNC_ATTRIBUTE(alloc_size, (1))
 165 PA_FUNC_ATTRIBUTE(format, [(printf,1,2)], int, [const char *, ...], ["%d",1])
 166 PA_FUNC_ATTRIBUTE(const)
 167 PA_FUNC_ATTRIBUTE(pure)
 168 PA_FUNC_ATTRIBUTE_ERROR
 169
 170 dnl
 171 dnl support function sections
 172 dnl
 173 PA_ARG_ENABLED([sections],
 174  [compile with function/data section support],
 175  [PA_ADD_CFLAGS([-ffunction-sections]),
 176   PA_ADD_CFLAGS([-fdata-sections])],
 177  [])
 178 dnl
 179 dnl support LTO
 180 dnl
 181 PA_ARG_ENABLED([lto],
 182  [compile with gcc-style link time optimization],
 183  [PA_ADD_CLDFLAGS([-flto])
 184   dnl Note: we use _PROG rather than _TOOL since we are prepending the full
 185   dnl CC name which ought to already contain the host triplet if needed
 186   ccbase=`echo "$CC" | awk '{ print $1; }'`
 187   AC_CHECK_PROGS(CC_AR, [${ccbase}-ar], [$ac_cv_prog_AR])
 188   AR="$CC_AR"
 189   AC_CHECK_PROGS(CC_RANLIB, [${ccbase}-ranlib], [$ac_cv_prog_RANLIB])
 190   RANLIB="$CC_RANLIB"], [])
 191
 192 dnl If we have gcc, add appropriate code cleanliness options
 193 PA_ADD_CFLAGS([-W])
 194 PA_ADD_CFLAGS([-Wall])
 195 PA_ADD_CFLAGS([-pedantic])
 196 dnl LLVM doesn't error out on invalid -W options unless this option is
 197 dnl specified first.  Enable this so this script can actually discover
 198 dnl which -W options are possible for this compiler.
 199 PA_ADD_CFLAGS([-Werror=unknown-warning-option])
 200 dnl Suppress format warning on Windows targets due to their <inttypes.h>
 201 PA_ADD_CFLAGS([-Wpedantic-ms-format],[-Wno-pedantic-ms-format])
 202 PA_ADD_CFLAGS([-Wc90-c99-compat])
 203 PA_ADD_CFLAGS([-Wlong-long],[-Wno-long-long])
 204 dnl PA_ADD_CFLAGS([-Wwrite-strings])
 205 PA_ARG_ENABLED([werror],
 206  [compile with -Werror to error out on any warning],
 207  [PA_ADD_CFLAGS([-Werror])],
 208  [PA_ADD_CFLAGS([-Werror=implicit])
 209   PA_ADD_CFLAGS([-Werror=missing-braces])
 210   PA_ADD_CFLAGS([-Werror=return-type])
 211   PA_ADD_CFLAGS([-Werror=trigraphs])
 212   PA_ADD_CFLAGS([-Werror=pointer-arith])
 213   PA_ADD_CFLAGS([-Werror=strict-prototypes])
 214   PA_ADD_CFLAGS([-Werror=missing-prototypes])
 215   PA_ADD_CFLAGS([-Werror=missing-declarations])
 216   PA_ADD_CFLAGS([-Werror=comment])
 217   PA_ADD_CFLAGS([-Werror=vla])]
 218 )
 219
 220 dnl
 221 dnl support ccache
 222 dnl
 223 PA_ARG_ENABLED([ccache], [compile with ccache], [CC="ccache $CC"], [])
 224
 225 AC_OUTPUT_COMMANDS([mkdir -p config nasmlib nsis output stdlib x86 asm disasm])
 226 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)