configure.in

   1 dnl Process this file with autoconf 2.61 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.61)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 dnl Consider AC_USE_SYSTEM_EXTENSIONS if autoconf 2.61 is OK in the future
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_PROG_CC
  53 AC_PROG_LN_S
  54 AC_PROG_MAKE_SET
  55 if test -f nasm.c; then
  56   # we're building in the source dir, so we don't need this check at all
  57   ac_cv_prog_make_vpathok=yes
  58 else
  59   AC_PROG_MAKE_VPATHOK
  60 fi
  61 AC_PROG_INSTALL
  62
  63 dnl Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_RESTRICT
  66 AC_TYPE_SIZE_T
  67 PA_WORKING_BOOL
  68 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN))
  69 AH_TEMPLATE(WORDS_BIGENDIAN,
  70 [Define to 1 if your processor stores words with the most significant
  71 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  72 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  73 [Define to 1 if your processor stores words with the least significant
  74 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  75
  76 dnl If we have gcc, add appropriate options
  77 PA_ADD_CFLAGS([-W])
  78 PA_ADD_CFLAGS([-Wall])
  79 PA_ADD_CFLAGS([-std=c99])
  80 PA_ADD_CFLAGS([-pedantic])
  81 PA_ADD_CFLAGS([-Werror=implicit])
  82 PA_ADD_CFLAGS([-Werror=missing-braces])
  83 PA_ADD_CFLAGS([-Werror=return-type])
  84 PA_ADD_CFLAGS([-Werror=trigraphs])
  85 PA_ADD_CFLAGS([-Werror=pointer-arith])
  86 PA_ADD_CFLAGS([-Werror=strict-prototypes])
  87 PA_ADD_CFLAGS([-Werror=missing-prototypes])
  88 PA_ADD_CFLAGS([-Werror=missing-declarations])
  89 PA_ADD_CFLAGS([-Werror=comment])
  90 PA_ADD_CFLAGS([-Werror=vla])
  91
  92 dnl Look for programs...
  93 AC_CHECK_PROGS(NROFF,    nroff,    false)
  94 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  95 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  96 AC_CHECK_PROGS(ACRODIST, acrodist, false)
  97 AC_CHECK_PROGS(PS2PDF,   ps2pdf,   false)
  98 AC_CHECK_PROGS(PSTOPDF,  pstopdf,  false)
  99
 100 dnl Check for progs needed for manpage generation
 101 if test $ASCIIDOC = false; then
 102   AC_MSG_WARN([No acsciidoc package found])
 103 fi
 104 if test $XMLTO = false; then
 105   AC_MSG_WARN([No xmlto package found])
 106 fi
 107
 108 dnl Checks for header files.
 109 AC_HEADER_STDC
 110 if test $ac_cv_header_stdc = no; then
 111   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
 112 fi
 113
 114 AC_CHECK_HEADERS(limits.h)
 115 if test $ac_cv_header_limits_h = no; then
 116   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
 117 fi
 118
 119 dnl Check for <inttypes.h> or add a substitute version
 120 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
 121
 122 dnl The standard header for str*casecmp is <strings.h>
 123 AC_CHECK_HEADERS(strings.h)
 124
 125 dnl Look for <stdbool.h>
 126 AC_CHECK_HEADERS(stdbool.h)
 127
 128 dnl Checks for library functions.
 129 AC_SUBST(XOBJS)
 130
 131 AC_CHECK_FUNCS(strcspn, ,
 132   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 133
 134 AC_CHECK_FUNCS(strspn, ,
 135   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 136
 137 missing=true
 138 AC_CHECK_FUNCS([vsnprintf _vsnprintf], missing=false)
 139 if $missing; then
 140    XOBJS="$XOBJS lib/vsnprintf.o"
 141 fi
 142
 143 missing=true
 144 AC_CHECK_FUNCS([snprintf _snprintf], missing=false)
 145 if $missing; then
 146    XOBJS="$XOBJS lib/snprintf.o"
 147 fi
 148
 149 AC_CHECK_FUNCS(strcasecmp stricmp)
 150 AC_CHECK_FUNCS(strncasecmp strnicmp)
 151 AC_CHECK_FUNCS(strsep)
 152 AC_CHECK_FUNCS(strlcpy)
 153
 154 AC_CHECK_FUNCS(getuid)
 155 AC_CHECK_FUNCS(getgid)
 156
 157 dnl Check for functions that might not be declared in the headers for
 158 dnl various idiotic reasons (mostly because of library authors
 159 dnl abusing the meaning of __STRICT_ANSI__)
 160 AC_CHECK_DECLS(strcasecmp)
 161 AC_CHECK_DECLS(stricmp)
 162 AC_CHECK_DECLS(strncasecmp)
 163 AC_CHECK_DECLS(strnicmp)
 164 AC_CHECK_DECLS(strsep)
 165 AC_CHECK_DECLS(strlcpy)
 166
 167 if test $ac_cv_prog_make_vpathok = no; then
 168   echo Copying generated srcs into build directory to compensate for VPATH breakage
 169   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 170     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 171   done
 172 fi
 173
 174 dnl
 175 dnl support cchace
 176 dnl
 177 AC_ARG_WITH([ccache],
 178             [AC_HELP_STRING([--with-ccache],
 179                             [Compile with ccache])],
 180           [CC="ccache $CC"],
 181           [])
 182
 183 AC_OUTPUT_COMMANDS([mkdir -p output])
 184 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)