kernel/2.6.29.6-aldebaran-rt/arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         INIT_TEXT
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_load = .;
  68                 __per_cpu_start = .;
  69                         *(.data.percpu.page_aligned)
  70                         *(.data.percpu)
  71                         *(.data.percpu.shared_aligned)
  72                 __per_cpu_end = .;
  73 #ifndef CONFIG_XIP_KERNEL
  74                 __init_begin = _stext;
  75                 INIT_DATA
  76                 . = ALIGN(4096);
  77                 __init_end = .;
  78 #endif
  79         }
  80
  81         /DISCARD/ : {                   /* Exit code and data           */
  82                 EXIT_TEXT
  83                 EXIT_DATA
  84                 *(.exitcall.exit)
  85 #ifndef CONFIG_MMU
  86                 *(.fixup)
  87                 *(__ex_table)
  88 #endif
  89         }
  90
  91         .text : {                       /* Real text segment            */
  92                 _text = .;              /* Text and read-only data      */
  93                         __exception_text_start = .;
  94                         *(.exception.text)
  95                         __exception_text_end = .;
  96                         TEXT_TEXT
  97                         SCHED_TEXT
  98                         LOCK_TEXT
  99                         KPROBES_TEXT
 100 #ifdef CONFIG_MMU
 101                         *(.fixup)
 102 #endif
 103                         *(.gnu.warning)
 104                         *(.rodata)
 105                         *(.rodata.*)
 106                         *(.glue_7)
 107                         *(.glue_7t)
 108                 *(.got)                 /* Global offset table          */
 109         }
 110
 111         RODATA
 112
 113         _etext = .;                     /* End of text and rodata section */
 114
 115 #ifdef CONFIG_XIP_KERNEL
 116         __data_loc = ALIGN(4);          /* location in binary */
 117         . = PAGE_OFFSET + TEXT_OFFSET;
 118 #else
 119         . = ALIGN(THREAD_SIZE);
 120         __data_loc = .;
 121 #endif
 122
 123         .data : AT(__data_loc) {
 124                 _data = .;              /* address in memory */
 125
 126                 /*
 127                  * first, the init task union, aligned
 128                  * to an 8192 byte boundary.
 129                  */
 130                 *(.data.init_task)
 131
 132 #ifdef CONFIG_XIP_KERNEL
 133                 . = ALIGN(4096);
 134                 __init_begin = .;
 135                 INIT_DATA
 136                 . = ALIGN(4096);
 137                 __init_end = .;
 138 #endif
 139
 140                 . = ALIGN(4096);
 141                 __nosave_begin = .;
 142                 *(.data.nosave)
 143                 . = ALIGN(4096);
 144                 __nosave_end = .;
 145
 146                 /*
 147                  * then the cacheline aligned data
 148                  */
 149                 . = ALIGN(32);
 150                 *(.data.cacheline_aligned)
 151
 152                 /*
 153                  * The exception fixup table (might need resorting at runtime)
 154                  */
 155                 . = ALIGN(32);
 156                 __start___ex_table = .;
 157 #ifdef CONFIG_MMU
 158                 *(__ex_table)
 159 #endif
 160                 __stop___ex_table = .;
 161
 162                 /*
 163                  * and the usual data section
 164                  */
 165                 DATA_DATA
 166                 CONSTRUCTORS
 167
 168                 _edata = .;
 169         }
 170         _edata_loc = __data_loc + SIZEOF(.data);
 171
 172         .bss : {
 173                 __bss_start = .;        /* BSS                          */
 174                 *(.bss)
 175                 *(COMMON)
 176                 _end = .;
 177         }
 178                                         /* Stabs debugging sections.    */
 179         .stab 0 : { *(.stab) }
 180         .stabstr 0 : { *(.stabstr) }
 181         .stab.excl 0 : { *(.stab.excl) }
 182         .stab.exclstr 0 : { *(.stab.exclstr) }
 183         .stab.index 0 : { *(.stab.index) }
 184         .stab.indexstr 0 : { *(.stab.indexstr) }
 185         .comment 0 : { *(.comment) }
 186 }
 187
 188 /*
 189  * These must never be empty
 190  * If you have to comment these two assert statements out, your
 191  * binutils is too old (for other reasons as well)
 192  */
 193 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 194 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")