lisp/muse-publish.el

   1 ;;; muse-publish.el --- base publishing implementation
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;; Yann Hodique (yann DOT hodique AT gmail DOT com) fixed an
  27 ;; unnecessary URL description transform in `muse-publish-url'.
  28 ;;
  29 ;; Peter K. Lee (saint AT corenova DOT com) provided the
  30 ;; `muse-style-elements-list' function.
  31 ;;
  32 ;; Jim Ottaway (j DOT ottaway AT lse DOT ac DOT uk) provided an
  33 ;; implementation for nested lists.
  34
  35 ;;; Code:
  36
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38 ;;
  39 ;; Muse Publishing
  40 ;;
  41 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  42
  43 (require 'muse)
  44 (require 'muse-regexps)
  45
  46 (defgroup muse-publish nil
  47   "Options controlling the general behavior of Muse publishing."
  48   :group 'muse)
  49
  50 (defcustom muse-before-publish-hook nil
  51   "A hook run in the buffer to be published, before it is done."
  52   :type 'hook
  53   :group 'muse-publish)
  54
  55 (defcustom muse-after-publish-hook nil
  56   "A hook run in the buffer to be published, after it is done."
  57   :type 'hook
  58   :group 'muse-publish)
  59
  60 (defcustom muse-publish-url-transforms
  61   '(muse-resolve-url)
  62   "A list of functions used to prepare URLs for publication.
  63 Each is passed the URL.  The transformed URL should be returned."
  64   :type 'hook
  65   :options '(muse-resolve-url)
  66   :group 'muse-publish)
  67
  68 (defcustom muse-publish-desc-transforms nil
  69   "A list of functions used to prepare URL desciptions for publication.
  70 Each is passed the description.  The modified description should
  71 be returned."
  72   :type 'hook
  73   :group 'muse-publish)
  74
  75 (defcustom muse-publish-comments-p nil
  76   "If nil, remove comments before publishing.
  77 If non-nil, publish comments using the markup of the current style."
  78   :type 'boolean
  79   :group 'muse-publish)
  80
  81 (defcustom muse-publish-report-threshhold 100000
  82   "If a file is this size or larger, report publishing progress."
  83   :type 'integer
  84   :group 'muse-publish)
  85
  86 (defcustom muse-publish-markup-regexps
  87   `(;; Remove leading and trailing whitespace from the file
  88     (1000 "\\(\\`\n+\\|\n+\\'\\)" 0 "")
  89
  90     ;; Remove trailing whitespace from all lines
  91     (1100 ,(concat "[" muse-regexp-blank "]+$") 0 "")
  92
  93     ;; Handle any leading #directives
  94     (1200 "\\`#\\([a-zA-Z-]+\\)\\s-+\\(.+\\)\n+" 0 directive)
  95
  96     ;; markup tags
  97     (1300 muse-tag-regexp 0 tag)
  98
  99     ;; commented lines
 100     (1350 "^;\\s-+\\(.+\\)" 0 comment)
 101
 102     ;; prevent emphasis characters in explicit links from being marked
 103     (1400 muse-explicit-link-regexp 0 muse-publish-mark-noemphasis)
 104
 105     ;; define anchor points
 106     (1500 "^\\(\\W*\\)#\\(\\S-+\\)\\s-*" 0 anchor)
 107
 108     ;; emphasized or literal text
 109     (1600 ,(concat "\\(^\\|[-[" muse-regexp-blank
 110                    "<('`\"\n]\\)\\(=[^=" muse-regexp-blank
 111                    "\n]\\|_[^_" muse-regexp-blank
 112                    "\n]\\|\\*+[^*" muse-regexp-blank
 113                    "\n]\\)")
 114           2 word)
 115
 116     ;; headings, outline-mode style
 117     (1700 "^\\(\\*+\\)\\s-+" 0 heading)
 118
 119     ;; ellipses
 120     (1800 "\\.\\.\\.\\." 0 enddots)
 121     (1850 "\\.\\.\\." 0 dots)
 122
 123     ;; horizontal rule, or section separator
 124     (1900 "^----+" 0 rule)
 125
 126     ;; non-breaking space
 127     (1950 "~~" 0 no-break-space)
 128
 129     ;; beginning of footnotes section
 130     (2000 "^Footnotes:?\\s-*" 0 fn-sep)
 131     ;; footnote definition/reference (def if at beginning of line)
 132     (2100 "\\[\\([1-9][0-9]*\\)\\]" 0 footnote)
 133
 134     ;; unnumbered List items begin with a -.  numbered list items
 135     ;; begin with number and a period.  definition lists have a
 136     ;; leading term separated from the body with ::.  centered
 137     ;; paragraphs begin with at least six columns of whitespace; any
 138     ;; other whitespace at the beginning indicates a blockquote.  The
 139     ;; reason all of these rules are handled here, is so that
 140     ;; blockquote detection doesn't interfere with indented list
 141     ;; members.
 142
 143     (2200 ,(format muse-list-item-regexp (concat "[" muse-regexp-blank "]+"))
 144           1 list)
 145
 146     (2300 ,(concat "^\\(\\(?:.+?\\)[" muse-regexp-blank "]+::\n?\\)")
 147           0 list)
 148
 149     (2400 ,(concat "^\\([" muse-regexp-blank "]+\\)") 0 quote)
 150
 151     (2500 ,(concat "\\(^\\|[" muse-regexp-blank "]+\\)--\\($\\|["
 152                    muse-regexp-blank "]+\\)")
 153           0 emdash)
 154
 155     ;; "verse" text is indicated the same way as a quoted e-mail
 156     ;; response: "> text", where text may contain initial whitespace
 157     ;; (see below).
 158     (2600 ,(concat "^[" muse-regexp-blank "]*> ") 0 verse)
 159
 160     ;; simple table markup is supported, nothing fancy.  use | to
 161     ;; separate cells, || to separate header cells, and ||| for footer
 162     ;; cells
 163     (2700 ,(concat "\\(" muse-table-line-regexp "\n"
 164                    "\\(" muse-regexp-blank "*\n\\)?\\)+")
 165           0 table)
 166
 167     ;; replace links in the buffer (links to other pages)
 168     (2900 muse-explicit-link-regexp 0 link)
 169
 170     ;; bare URLs
 171     (3000 muse-url-regexp  0 url)
 172
 173     ;; bare email addresses
 174     (3500
 175      "\\([^[]\\)[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+" 0 email)
 176     )
 177   "List of markup rules for publishing a page with Muse.
 178 The rules given in this variable are invoked first, followed by
 179 whatever rules are specified by the current style.
 180
 181 Each member of the list is either a function, or a list of the form:
 182
 183   (REGEXP/SYMBOL TEXT-BEGIN-GROUP REPLACEMENT-TEXT/FUNCTION/SYMBOL)
 184
 185 REGEXP is a regular expression, or symbol whose value is a regular
 186 expression, which is searched for using `re-search-forward'.
 187 TEXT-BEGIN-GROUP is the matching group within that regexp which
 188 denotes the beginning of the actual text to be marked up.
 189 REPLACEMENT-TEXT is a string that will be passed to `replace-match'.
 190 If it is not a string, but a function, it will be called to determine
 191 what the replacement text should be (it must return a string).  If it
 192 is a symbol, the value of that symbol should be a string.
 193
 194 The replacements are done in order, one rule at a time.  Writing
 195 the regular expressions can be a tricky business.  Note that case
 196 is never ignored.  `case-fold-search' is always bound to nil
 197 while processing the markup rules."
 198   :type '(repeat (choice
 199                   (list :tag "Markup rule"
 200                         integer
 201                         (choice regexp symbol)
 202                         integer
 203                         (choice string function symbol))
 204                   function))
 205   :group 'muse-publish)
 206
 207 (defcustom muse-publish-markup-functions
 208   '((directive . muse-publish-markup-directive)
 209     (comment   . muse-publish-markup-comment)
 210     (anchor    . muse-publish-markup-anchor)
 211     (tag       . muse-publish-markup-tag)
 212     (word      . muse-publish-markup-word)
 213     (emdash    . muse-publish-markup-emdash)
 214     (enddots   . muse-publish-markup-enddots)
 215     (dots      . muse-publish-markup-dots)
 216     (rule      . muse-publish-markup-rule)
 217     (no-break-space . muse-publish-markup-no-break-space)
 218     (heading   . muse-publish-markup-heading)
 219     (footnote  . muse-publish-markup-footnote)
 220     (fn-sep    . muse-publish-markup-fn-sep)
 221     (list      . muse-publish-markup-list)
 222     (quote     . muse-publish-markup-quote)
 223     (verse     . muse-publish-markup-verse)
 224     (table     . muse-publish-markup-table)
 225     (email     . muse-publish-markup-email)
 226     (link      . muse-publish-markup-link)
 227     (url       . muse-publish-markup-url))
 228   "An alist of style types to custom functions for that kind of text.
 229
 230 Each member of the list is of the form:
 231
 232   (SYMBOL FUNCTION)
 233
 234 SYMBOL describes the type of text to associate with this rule.
 235 `muse-publish-markup-regexps' maps regexps to these symbols.
 236
 237 FUNCTION is the function to use to mark up this kind of rule if
 238 no suitable function is found through the :functions tag of the
 239 current style."
 240   :type '(alist :key-type symbol :value-type function)
 241   :group 'muse-publish)
 242
 243 (defcustom muse-publish-markup-tags
 244   '(("contents" nil t   muse-publish-contents-tag)
 245     ("verse"    t   nil muse-publish-verse-tag)
 246     ("example"  t   nil muse-publish-example-tag)
 247     ("code"     t   nil muse-publish-code-tag)
 248     ("quote"    t   nil muse-publish-quote-tag)
 249     ("literal"  t   nil muse-publish-mark-read-only)
 250     ("verbatim" t   nil muse-publish-verbatim-tag)
 251     ("lisp"     t   nil muse-publish-lisp-tag)
 252     ("class"    t   t   muse-publish-class-tag)
 253     ("command"  t   t   muse-publish-command-tag)
 254     ("comment"  t   nil muse-publish-comment-tag))
 255   "A list of tag specifications, for specially marking up text.
 256 XML-style tags are the best way to add custom markup to Muse.
 257 This is easily accomplished by customizing this list of markup tags.
 258
 259 For each entry, the name of the tag is given, whether it expects
 260 a closing tag and/or an optional set of attributes, and a
 261 function that performs whatever action is desired within the
 262 delimited region.
 263
 264 The tags themselves are deleted during publishing, before the
 265 function is called.  The function is called with three arguments,
 266 the beginning and end of the region surrounded by the tags.  If
 267 properties are allowed, they are passed as a third argument in
 268 the form of an alist.  The `end' argument to the function is
 269 always a marker.
 270
 271 Point is always at the beginning of the region within the tags, when
 272 the function is called.  Wherever point is when the function finishes
 273 is where tag markup will resume.
 274
 275 These tag rules are processed once at the beginning of markup, and
 276 once at the end, to catch any tags which may have been inserted
 277 in-between."
 278   :type '(repeat (list (string :tag "Markup tag")
 279                        (boolean :tag "Expect closing tag" :value t)
 280                        (boolean :tag "Parse attributes" :value nil)
 281                        function))
 282   :group 'muse-publish)
 283
 284 (defcustom muse-publish-markup-specials nil
 285   "A table of characters which must be represented specially."
 286   :type '(alist :key-type character :value-type string)
 287   :group 'muse-publish)
 288
 289 (defvar muse-publishing-p nil
 290   "Set to t while a page is being published.")
 291 (defvar muse-batch-publishing-p nil
 292   "Set to t while a page is being batch published.")
 293 (defvar muse-publishing-styles nil
 294   "The publishing styles that Muse recognizes.
 295 This is automatically generated when loading publishing styles.")
 296 (defvar muse-publishing-current-file nil
 297   "The file that is currently being published.")
 298 (defvar muse-publishing-current-output-path nil
 299   "The path where the current file will be published to.")
 300 (defvar muse-publishing-current-style nil
 301   "The style of the file that is currently being published.")
 302 (defvar muse-publishing-directives nil
 303   "An alist of publishing directives from the top of a file.")
 304 (defvar muse-publish-generate-contents nil
 305   "Non-nil if a table of contents should be generated.
 306 If non-nil, it is a cons cell specifying (MARKER . DEPTH), to
 307 tell where the <contents> was seen, and to what depth the
 308 contents were requested.")
 309 (defvar muse-publishing-last-position nil
 310   "Last position of the point when publishing.
 311 This is used to make sure that publishing doesn't get stalled.")
 312
 313 ;; Functions for handling style information
 314
 315 (defsubst muse-style (&optional style)
 316   "Resolve the given STYLE into a Muse style, if it is a string."
 317   (if (null style)
 318       muse-publishing-current-style
 319     (if (stringp style)
 320         (assoc style muse-publishing-styles)
 321       (muse-assert (consp style))
 322       style)))
 323
 324 (defun muse-define-style (name &rest elements)
 325   (let ((entry (assoc name muse-publishing-styles)))
 326     (if entry
 327         (error "There is already a style named %s." name)
 328       (setq muse-publishing-styles
 329             (cons (append (list name) elements)
 330                   muse-publishing-styles)))))
 331
 332 (defun muse-derive-style (new-name base-name &rest elements)
 333   (let ((entry (assoc new-name muse-publishing-styles)))
 334     (if entry
 335         (error "There is already a style named %s." new-name)
 336       (apply 'muse-define-style new-name
 337              (append elements (list :base base-name))))))
 338
 339 (defsubst muse-get-keyword (keyword list &optional direct)
 340   (let ((value (cadr (memq keyword list))))
 341     (if (and (not direct) (symbolp value))
 342         (symbol-value value)
 343       value)))
 344
 345 (defun muse-style-elements-list (elem &optional style)
 346   "Return a list all references to ELEM in STYLE, including base styles.
 347 If STYLE is not specified, use current style."
 348   (let (base elements)
 349     (while style
 350       (setq style (muse-style style))
 351       (setq elements (append elements
 352                              (muse-get-keyword elem style)))
 353       (setq style (muse-get-keyword :base style)))
 354     elements))
 355
 356 (defsubst muse-style-element (elem &optional style direct)
 357   "Search for ELEM in STYLE, including base styles.
 358 If STYLE is not specified, use current style."
 359   (setq style (muse-style style))
 360   (let ((value (muse-get-keyword elem style direct)))
 361     (if value
 362         value
 363       (let ((base (muse-get-keyword :base style)))
 364         (if base
 365             (muse-style-element elem base direct))))))
 366
 367 (defun muse-find-markup-element (keyword ident style)
 368   (let ((def (assq ident (muse-style-element keyword style))))
 369     (if def
 370         (cdr def)
 371       (let ((base (muse-style-element :base style)))
 372         (if base
 373             (muse-find-markup-element keyword ident base))))))
 374
 375 (defun muse-markup-text (ident &rest args)
 376   "Insert ARGS into the text markup associated with IDENT.
 377 If the markup text has sections like %N%, this will be replaced
 378 with the N-1th argument in ARGS.  After that, `format' is applied
 379 to the text with ARGS as parameters."
 380   (let ((text (muse-find-markup-element :strings ident (muse-style))))
 381     (if (and text args)
 382         (progn
 383           (let (start repl-text)
 384             (while (setq start (string-match "%\\([1-9][0-9]*\\)%" text start))
 385               ;; escape '%' in the argument text, since we will be
 386               ;; using format on it
 387               (setq repl-text (muse-replace-regexp-in-string
 388                                "%" "%%"
 389                                (nth (1- (string-to-number
 390                                          (match-string 1 text))) args)
 391                                t t)
 392                     start (+ start (length repl-text))
 393                     text (replace-match repl-text t t text))))
 394           (apply 'format text args))
 395       (or text ""))))
 396
 397 (defun muse-insert-markup (&rest args)
 398   (let ((beg (point)))
 399     (apply 'insert args)
 400     (muse-publish-mark-read-only beg (point))))
 401
 402 (defun muse-find-markup-tag (keyword tagname style)
 403   (let ((def (assoc tagname (muse-style-element keyword style))))
 404     (or def
 405         (let ((base (muse-style-element :base style)))
 406           (if base
 407               (muse-find-markup-tag keyword tagname base))))))
 408
 409 (defsubst muse-markup-tag-info (tagname &rest args)
 410   (let ((tag-info (muse-find-markup-tag :tags tagname (muse-style))))
 411     (or tag-info
 412         (assoc (match-string 1) muse-publish-markup-tags))))
 413
 414 (defsubst muse-markup-function (category)
 415   (let ((func (muse-find-markup-element :functions category (muse-style))))
 416     (or func
 417         (cdr (assq category muse-publish-markup-functions)))))
 418
 419 ;; Publishing routines
 420
 421 (defun muse-publish-markup (name rules)
 422   (let* ((case-fold-search nil)
 423          (inhibit-read-only t)
 424          (limit (* (length rules) (point-max)))
 425          (verbose (and muse-publish-report-threshhold
 426                        (> (point-max) muse-publish-report-threshhold)))
 427          (base 0))
 428     (while rules
 429       (goto-char (point-min))
 430       (let ((regexp (nth 1 (car rules)))
 431             (group (nth 2 (car rules)))
 432             (repl (nth 3 (car rules)))
 433             pos)
 434         (setq muse-publishing-last-position nil)
 435         (if (symbolp regexp)
 436             (setq regexp (symbol-value regexp)))
 437         (if (and verbose (not muse-batch-publishing-p))
 438             (message "Publishing %s...%d%%" name
 439                      (* (/ (float (+ (point) base)) limit) 100)))
 440         (while (and regexp (setq pos (re-search-forward regexp nil t)))
 441           (if (and verbose (not muse-batch-publishing-p))
 442               (message "Publishing %s...%d%%" name
 443                        (* (/ (float (+ (point) base)) limit) 100)))
 444           (unless (and (> (- (match-end 0) (match-beginning 0)) 0)
 445                        (get-text-property (match-beginning group) 'read-only))
 446             (let* (func
 447                    (text (cond
 448                           ((and (symbolp repl)
 449                                 (setq func (muse-markup-function repl)))
 450                            (funcall func))
 451                           ((functionp repl)
 452                            (funcall repl))
 453                           ((symbolp repl)
 454                            (symbol-value repl))
 455                           (t repl))))
 456               (if text
 457                   (replace-match text t))))
 458           (if (and muse-publishing-last-position
 459                    (= pos muse-publishing-last-position))
 460               (if (eobp)
 461                   (setq regexp nil)
 462                 (forward-char 1)))
 463           (setq muse-publishing-last-position pos)))
 464       (setq rules (cdr rules)
 465             base (+ base (point-max))))
 466     (if (and verbose (not muse-batch-publishing-p))
 467         (message "Publishing %s...done" name))))
 468
 469 (defun muse-insert-file-or-string (file-or-string &optional title)
 470   (let ((beg (point)) end)
 471     (if (and (not (string-equal file-or-string ""))
 472              (file-readable-p file-or-string))
 473         (setq end (+ beg (cadr (insert-file-contents file-or-string))))
 474       (insert file-or-string)
 475       (setq end (point)))
 476     (save-restriction
 477       (narrow-to-region beg end)
 478       (muse-publish-markup (or title "")
 479                            '((100 "<\\(lisp\\)>" 0
 480                               muse-publish-markup-tag))))))
 481
 482 (defun muse-style-run-hooks (keyword style &rest args)
 483   (let (handled)
 484     (while (and style (not handled))
 485       (setq style (muse-style style))
 486       (let ((func (muse-get-keyword keyword style t)))
 487         (if func
 488             (if (apply func args)
 489                 (setq handled t))))
 490       (unless handled
 491         (setq style (muse-style-element :base style))))
 492     handled))
 493
 494 (defun muse-publish-markup-region (beg end title style)
 495   "Apply the given STYLE's markup rules to the given region."
 496   (save-restriction
 497     (narrow-to-region beg end)
 498     (muse-style-run-hooks :before style)
 499     (muse-publish-markup
 500      title
 501      (sort (copy-alist (append muse-publish-markup-regexps
 502                                (muse-style-elements-list :regexps style)))
 503            (function
 504             (lambda (l r)
 505               (< (car l) (car r))))))
 506     (muse-style-run-hooks :before-end style)
 507     (muse-publish-escape-specials (point-min) (point-max) nil 'document)))
 508
 509 (defun muse-publish-markup-buffer (title style)
 510   "Apply the given STYLE's markup rules to the current buffer."
 511   (setq style (muse-style style))
 512   (let ((style-header (muse-style-element :header style))
 513         (style-footer (muse-style-element :footer style))
 514         (muse-publishing-current-style style)
 515         (muse-publishing-directives
 516          (list (cons "title" title)
 517                (cons "author" (user-full-name))
 518                (cons "date" (format-time-string
 519                              "%B %e, %Y"
 520                              (nth 5 (file-attributes
 521                                      muse-publishing-current-file))))))
 522         (muse-publishing-p t)
 523         (inhibit-read-only t))
 524     (run-hooks 'muse-before-publish-hook)
 525     (muse-publish-markup-region (point-min) (point-max) title style)
 526     (goto-char (point-min))
 527     (when style-header
 528       (muse-insert-file-or-string style-header title))
 529     (goto-char (point-max))
 530     (when style-footer
 531       (muse-insert-file-or-string style-footer title))
 532     (muse-style-run-hooks :after style)
 533     (run-hooks 'muse-after-publish-hook)))
 534
 535 (defun muse-publish-markup-string (string &optional style)
 536   "Markup STRING using the given STYLE's markup rules."
 537   (setq style (muse-style style))
 538   (muse-with-temp-buffer
 539     (insert string)
 540     (let ((muse-publishing-current-style style)
 541           (muse-publishing-p t))
 542       (muse-publish-markup "*string*" (muse-style-element :rules style)))
 543     (buffer-string)))
 544
 545 ;; Commands for publishing files
 546
 547 (defsubst muse-publish-get-style ()
 548   (if (= 1 (length muse-publishing-styles))
 549       (car muse-publishing-styles)
 550     (assoc (completing-read "Publish with style: "
 551                             muse-publishing-styles nil t)
 552            muse-publishing-styles)))
 553
 554 (defsubst muse-publish-get-output-dir (style)
 555   (let ((default-directory (or (muse-style-element :path style)
 556                                default-directory)))
 557     (muse-read-directory-name "Publish to directory: " nil default-directory)))
 558
 559 (defsubst muse-publish-get-info ()
 560   (let ((style (muse-publish-get-style)))
 561     (list style (muse-publish-get-output-dir style)
 562           current-prefix-arg)))
 563
 564 (defsubst muse-publish-output-name (&optional file style)
 565   (setq style (muse-style style))
 566   (concat (muse-style-element :prefix style)
 567           (muse-page-name file)
 568           (muse-style-element :suffix style)))
 569
 570 (defsubst muse-publish-output-file (file &optional output-dir style)
 571   (setq style (muse-style style))
 572   (if output-dir
 573       (expand-file-name (muse-publish-output-name file style) output-dir)
 574     (concat (file-name-directory file)
 575             (muse-publish-output-name file style))))
 576
 577 (defsubst muse-publish-link-name (&optional file style)
 578   (setq style (muse-style style))
 579   (concat (muse-style-element :prefix style)
 580           (muse-page-name file)
 581           (or (muse-style-element :link-suffix style)
 582               (muse-style-element :suffix style))))
 583
 584 (defsubst muse-publish-link-file (file &optional output-dir style)
 585   (setq style (muse-style style))
 586   (if output-dir
 587       (expand-file-name (muse-publish-link-name file style) output-dir)
 588     (concat (file-name-directory file)
 589             (muse-publish-link-name file style))))
 590
 591 ;;;###autoload
 592 (defun muse-publish-file (file style &optional output-dir force)
 593   "Publish the given FILE in a particular STYLE to OUTPUT-DIR.
 594 If the argument FORCE is nil, each file is only published if it is
 595 newer than the published version.  If the argument FORCE is non-nil,
 596 the file is published no matter what."
 597   (interactive (cons (read-file-name "Publish file: ")
 598                      (muse-publish-get-info)))
 599   (setq style (muse-style style))
 600   (let* ((output-path (muse-publish-output-file file output-dir style))
 601          (output-suffix (muse-style-element :osuffix style))
 602          (muse-publishing-current-file file)
 603          (muse-publishing-current-output-path output-path)
 604          (target (if output-suffix
 605                      (concat (file-name-sans-extension output-path)
 606                              output-suffix)
 607                    output-path)))
 608     (when (or force (file-newer-than-file-p file target))
 609       (if (and muse-publish-report-threshhold
 610                (> (nth 7 (file-attributes file))
 611                   muse-publish-report-threshhold))
 612           (message "Publishing %s ..." file))
 613       (muse-with-temp-buffer
 614         (insert-file-contents file)
 615         (muse-publish-markup-buffer (muse-page-name file) style)
 616         (let ((backup-inhibited t))
 617           (write-file output-path))
 618         (muse-style-run-hooks :final style file output-path target))
 619       t)))
 620
 621 ;;;###autoload
 622 (defun muse-publish-this-file (style output-dir &optional force)
 623   "Publish the page in the current file."
 624   (interactive (muse-publish-get-info))
 625   (unless (muse-publish-file buffer-file-name style output-dir force)
 626     (message (concat "The published version is up-to-date; use"
 627                      " C-u C-c C-t to force an update."))))
 628
 629 (defun muse-batch-publish-files ()
 630   "Publish Muse files in batch mode."
 631   (let ((muse-batch-publishing-p t)
 632         style-name style output-dir)
 633     (setq style-name (car command-line-args-left)
 634           style (muse-style style-name)
 635           command-line-args-left (cdr command-line-args-left)
 636           output-dir (car command-line-args-left)
 637           output-dir
 638           (if (string-match "\\`--output-dir=" output-dir)
 639               (prog1
 640                   (substring output-dir (match-end 0))
 641                 (setq command-line-args-left (cdr command-line-args-left)))))
 642     (unless style
 643       (error "There is no style '%s' defined." style-name))
 644     (dolist (file command-line-args-left)
 645       (muse-publish-file file style output-dir t))))
 646
 647 ;; Default publishing rules
 648
 649 (defun muse-publish-section-close (depth)
 650   "Seach forward for the closing tag of given DEPTH."
 651   (let (not-end)
 652     (save-excursion
 653       (while (and (setq not-end (re-search-forward
 654                                  (concat "^\\*\\{1," (number-to-string depth)
 655                                          "\\}\\s-+")
 656                                  nil t))
 657                   (get-text-property (match-beginning 0) 'read-only)))
 658       (if not-end
 659           (forward-line 0)
 660         (goto-char (point-max)))
 661       (cond ((not (eq (char-before) ?\n))
 662              (insert "\n\n"))
 663             ((not (eq (char-before (1- (point))) ?\n))
 664              (insert "\n")))
 665       (muse-insert-markup (muse-markup-text 'section-close depth))
 666       (insert "\n"))))
 667
 668 (defun muse-publish-markup-directive (&optional name value)
 669   (unless name (setq name (match-string 1)))
 670   (unless value (setq value (match-string 2)))
 671   (let ((elem (assoc name muse-publishing-directives)))
 672     (if elem
 673         (setcdr elem value)
 674       (setq muse-publishing-directives
 675             (cons (cons name value)
 676                   muse-publishing-directives))))
 677   ;; Make sure we don't ever try to move the point forward (past the
 678   ;; beginning of buffer) while we're still searching for directives.
 679   (setq muse-publishing-last-position nil)
 680   (delete-region (match-beginning 0) (match-end 0)))
 681
 682 (defun muse-publish-markup-anchor ()
 683   (unless (get-text-property (match-end 1) 'noemphasis)
 684     (let ((text (muse-markup-text 'anchor (match-string 2))))
 685       (unless (string= text "")
 686         (save-match-data
 687           (skip-chars-forward (concat muse-regexp-blank "\n"))
 688           (muse-insert-markup text)))
 689       (match-string 1))))
 690
 691 (defun muse-publish-markup-comment ()
 692   (if (null muse-publish-comments-p)
 693       ""
 694     (goto-char (match-end 0))
 695     (muse-insert-markup (muse-markup-text 'comment-end))
 696     (muse-publish-mark-read-only (match-beginning 1) (match-end 1))
 697     (goto-char (match-beginning 1))
 698     (muse-insert-markup (muse-markup-text 'comment-begin))
 699     (delete-region (match-beginning 0) (1- (match-beginning 1)))))
 700
 701 (defun muse-publish-markup-tag ()
 702   (let ((tag-info (muse-markup-tag-info (match-string 1))))
 703     (when (and tag-info
 704                (not (get-text-property (match-beginning 0) 'read-only)))
 705       (let ((closed-tag (match-string 3))
 706             (start (match-beginning 0))
 707             (beg (point)) end attrs)
 708         (when (nth 2 tag-info)
 709           (let ((attrstr (match-string 2)))
 710             (while (and attrstr
 711                         (string-match (concat "\\([^"
 712                                               muse-regexp-blank
 713                                               "=\n]+\\)\\(=\"\\"
 714                                               "([^\"]+\\)\"\\)?")
 715                                       attrstr))
 716               (let ((attr (cons (downcase
 717                                  (muse-match-string-no-properties 1 attrstr))
 718                                 (muse-match-string-no-properties 3 attrstr))))
 719                 (setq attrstr (replace-match "" t t attrstr))
 720                 (if attrs
 721                     (nconc attrs (list attr))
 722                   (setq attrs (list attr)))))))
 723         (if (and (cadr tag-info) (not closed-tag))
 724             (if (search-forward (concat "</" (car tag-info) ">") nil t)
 725                 (delete-region (match-beginning 0) (point))
 726               (setq tag-info nil)))
 727         (when tag-info
 728           (setq end (point-marker))
 729           (delete-region start beg)
 730           (goto-char start)
 731           (let ((args (list start end)))
 732             (if (nth 2 tag-info)
 733                 (nconc args (list attrs)))
 734             (apply (nth 3 tag-info) args))))))
 735   nil)
 736
 737 (defun muse-publish-escape-specials (beg end &optional ignore-read-only context)
 738   "Escape specials from BEG to END using style-specific :specials.
 739 If IGNORE-READ-ONLY is non-nil, ignore the read-only property.
 740 CONTEXT is used to figure out what kind of specials to escape.
 741
 742 The following contexts exist in Muse.
 743 'underline  _underlined text_
 744 'literal    =monospaced text= or <code>region</code> (monospaced, escaped)
 745 'emphasis   *emphasized text*
 746 'email      email@example.com
 747 'url        http://example.com
 748 'url-desc   [[...][description of an extended link]]
 749 'example    <example>region</example> (monospaced, block context, escaped)
 750 'verbatim   <verbatim>region</verbatim> (escaped)
 751 'document   normal text"
 752   (let ((specials (muse-style-element :specials nil t)))
 753     (cond ((functionp specials)
 754            (setq specials (funcall specials context)))
 755           ((symbolp specials)
 756            (setq specials (symbol-value specials))))
 757     (save-excursion
 758       (goto-char beg)
 759       (while (< (point) end)
 760         (if (and (not ignore-read-only) (get-text-property (point) 'read-only))
 761             (goto-char (next-single-property-change (point) 'read-only))
 762           (let (repl)
 763             (setq repl (or (assoc (char-after) specials)
 764                            (assoc (char-after) muse-publish-markup-specials)))
 765             (if (null repl)
 766                 (forward-char 1)
 767               (delete-char 1)
 768               (insert-before-markers (cdr repl)))))))))
 769
 770 (defun muse-publish-markup-word ()
 771   (let* ((beg (match-beginning 2))
 772          (end (1- (match-end 2)))
 773          (leader (buffer-substring-no-properties beg end))
 774          open-tag close-tag mark-read-only loc context)
 775     (cond
 776      ((string= leader "_")
 777       (setq context 'underline
 778             open-tag (muse-markup-text 'begin-underline)
 779             close-tag (muse-markup-text 'end-underline)))
 780      ((string= leader "=")
 781       (setq context 'literal
 782             open-tag (muse-markup-text 'begin-literal)
 783             close-tag (muse-markup-text 'end-literal))
 784       (setq mark-read-only t))
 785      (t
 786       (let ((l (length leader)))
 787         (setq context 'emphasis)
 788         (cond
 789          ((= l 1) (setq open-tag (muse-markup-text 'begin-emph)
 790                         close-tag (muse-markup-text 'end-emph)))
 791          ((= l 2) (setq open-tag (muse-markup-text 'begin-more-emph)
 792                         close-tag (muse-markup-text 'end-more-emph)))
 793          ((= l 3) (setq open-tag (muse-markup-text 'begin-most-emph)
 794                         close-tag (muse-markup-text 'end-most-emph)))
 795          (t (setq context nil))))))
 796     (if (and context
 797              (not (get-text-property beg 'noemphasis))
 798              (setq loc (search-forward leader nil t))
 799              (or (eobp) (not (eq (char-syntax (char-after loc)) ?w)))
 800              (not (eq (char-syntax (char-before (point))) ?\ ))
 801              (not (get-text-property (point) 'noemphasis)))
 802         (progn
 803           (replace-match "")
 804           (delete-region beg end)
 805           (setq end (point-marker))
 806           (muse-insert-markup close-tag)
 807           (save-excursion
 808             (goto-char beg)
 809             (muse-insert-markup open-tag)
 810             (setq beg (point)))
 811           (when mark-read-only
 812             (muse-publish-escape-specials beg end t context)
 813             (muse-publish-mark-read-only beg end)))
 814       (backward-char))
 815     nil))
 816
 817 (defun muse-publish-markup-emdash ()
 818   (delete-region (match-beginning 0) (match-end 0))
 819   (muse-insert-markup (muse-markup-text 'emdash))
 820   (if (eq (char-after) ?\<)
 821       (insert ?\n)))
 822
 823 (defun muse-publish-markup-enddots ()
 824   (unless (get-text-property (match-beginning 0) 'noemphasis)
 825     (delete-region (match-beginning 0) (match-end 0))
 826     (muse-insert-markup (muse-markup-text 'enddots))))
 827
 828 (defun muse-publish-markup-dots ()
 829   (unless (get-text-property (match-beginning 0) 'noemphasis)
 830     (delete-region (match-beginning 0) (match-end 0))
 831     (muse-insert-markup (muse-markup-text 'dots))))
 832
 833 (defun muse-publish-markup-rule ()
 834   (unless (get-text-property (match-beginning 0) 'noemphasis)
 835     (delete-region (match-beginning 0) (match-end 0))
 836     (muse-insert-markup (muse-markup-text 'rule))))
 837
 838 (defun muse-publish-markup-no-break-space ()
 839   (unless (get-text-property (match-beginning 0) 'noemphasis)
 840     (delete-region (match-beginning 0) (match-end 0))
 841     (muse-insert-markup (muse-markup-text 'no-break-space))))
 842
 843 (defun muse-publish-markup-heading ()
 844   (let* ((len (length (match-string 1)))
 845          (start (muse-markup-text
 846                  (cond ((= len 1) 'section)
 847                        ((= len 2) 'subsection)
 848                        ((= len 3) 'subsubsection)
 849                        (t 'section-other))
 850                  len))
 851          (end   (muse-markup-text
 852                  (cond ((= len 1) 'section-end)
 853                        ((= len 2) 'subsection-end)
 854                        ((= len 3) 'subsubsection-end)
 855                        (t 'section-other-end))
 856                  len)))
 857     (delete-region (match-beginning 0) (match-end 0))
 858     (muse-insert-markup start)
 859     (end-of-line)
 860     (when end
 861       (muse-insert-markup end))
 862     (muse-publish-section-close len)))
 863
 864 (defvar muse-publish-footnotes nil)
 865
 866 (defun muse-publish-markup-footnote ()
 867   "Scan ahead and snarf up the footnote body"
 868   (cond
 869    ((get-text-property (match-beginning 0) 'noemphasis)
 870     nil)
 871    ((= (muse-line-beginning-position) (match-beginning 0))
 872     "")
 873    (t
 874     (let ((footnote (save-match-data
 875                       (string-to-number (match-string 1))))
 876           footnotemark)
 877       (delete-region (match-beginning 0) (match-end 0))
 878       (save-excursion
 879         (when (re-search-forward (format "^\\[%d\\]\\s-+" footnote) nil t)
 880           (let* ((start (match-beginning 0))
 881                  (beg (goto-char (match-end 0)))
 882                  (end (save-excursion
 883                         (if (search-forward "\n\n" nil t)
 884                             (copy-marker (match-beginning 0))
 885                           (goto-char (point-max))
 886                           (skip-chars-backward "\n")
 887                           (point-marker)))))
 888             (while (re-search-forward
 889                     (concat "^[" muse-regexp-blank "]+\\([^\n]\\)")
 890                     end t)
 891               (replace-match "\\1" t))
 892             (let ((footnotemark-cmd (muse-markup-text 'footnotemark))
 893                   (footnotemark-end-cmd (muse-markup-text 'footnotemark-end)))
 894               (if (string= "" footnotemark-cmd)
 895                   (setq footnotemark
 896                         (concat (muse-markup-text 'footnote)
 897                                 (buffer-substring-no-properties beg end)
 898                                 (muse-markup-text 'footnote-end)))
 899                 (setq footnotemark (format footnotemark-cmd footnote
 900                                            footnotemark-end-cmd))
 901                 (unless muse-publish-footnotes
 902                   (set (make-local-variable 'muse-publish-footnotes)
 903                        (make-vector 256 nil)))
 904                 (unless (aref muse-publish-footnotes footnote)
 905                   (setq footnotemark
 906                         (concat
 907                          footnotemark
 908                          (concat (format (muse-markup-text 'footnotetext)
 909                                          footnote)
 910                                  (buffer-substring-no-properties beg end)
 911                                  (muse-markup-text 'footnotetext-end))))
 912                   (aset muse-publish-footnotes footnote footnotemark))))
 913             (goto-char end)
 914             (skip-chars-forward "\n")
 915             (delete-region start (point)))))
 916       (muse-insert-markup (or footnotemark footnote))))))
 917
 918 (defun muse-publish-markup-fn-sep ()
 919   (delete-region (match-beginning 0) (match-end 0))
 920   (muse-insert-markup (muse-markup-text 'fn-sep)))
 921
 922 (defun muse-publish-surround-text (beg-tag end-tag move-func &optional indent)
 923   (unless indent
 924     (setq indent (concat "[" muse-regexp-blank "]+")))
 925   (let ((beg (point))
 926         (continue t)
 927         end)
 928     (while continue
 929       (muse-insert-markup beg-tag)
 930       (setq continue (funcall move-func)
 931             end (point-marker))
 932       (goto-char beg)
 933       (while (< (point) end)
 934         (when (looking-at indent)
 935           (replace-match ""))
 936         (forward-line 1))
 937       (goto-char end)
 938       (skip-chars-backward (concat muse-regexp-blank "\n"))
 939       (muse-insert-markup end-tag)
 940       (goto-char end))))
 941
 942 (defun muse-list-item-type (str)
 943 "Determine the type of list given STR.
 944 Returns either 'ul, 'ol, or 'dl."
 945   (cond ((= (aref str 0) ?-) 'ul)
 946         ((and (>= (aref str 0) ?0)
 947               (<= (aref str 0) ?9)) 'ol)
 948         (t 'dl)))
 949
 950 (defsubst muse-forward-paragraph (&optional pattern)
 951   (if (re-search-forward (if pattern
 952                              (concat "^\\(" pattern "\\|$\\|\\'\\)")
 953                            "^\\s-*\\($\\|\\'\\)") nil t)
 954       (goto-char (match-beginning 0))
 955     (goto-char (point-max))))
 956
 957 (defun muse-forward-list-item (type indent post-indent)
 958   "Move forward to the next item of TYPE.
 959 Return non-nil if successful, nil otherwise.
 960 The beginning indentation is given by INDENT.
 961 The maximum number of spaces to permit after that is given by POST-INDENT."
 962   (let ((list-item (format muse-list-item-regexp
 963                            (concat indent " \\{0," post-indent "\\}")))
 964         (empty-line (concat "^[" muse-regexp-blank "]*\n")))
 965     (muse-forward-paragraph (concat "\\(?:" empty-line "\\)?"
 966                                     "\\(" list-item "\\)\\|"
 967                                     empty-line))
 968     (if (null (match-string 3))
 969         (if (eq type (muse-list-item-type (match-string 3)))
 970             (goto-char (match-beginning 2))
 971           (goto-char (match-beginning 0))
 972           nil)
 973       (goto-char (match-beginning 0))
 974       nil)))
 975
 976 (defun muse-publish-markup-list ()
 977   "Markup a list entry or quoted paragraph.
 978 The reason this function is so funky, is to prevent text properties
 979 like read-only from being inadvertently deleted."
 980   (let* ((str (match-string 1))
 981          (type (muse-list-item-type str))
 982          (indent (buffer-substring (muse-line-beginning-position)
 983                                    (match-beginning 1)))
 984          (post-indent (length (save-match-data
 985                                 (when (string-match str "\\s-+\\'")
 986                                   (match-string 0 str)))))
 987          (last (match-beginning 0)))
 988     (cond
 989      ((eq type 'ul)
 990       (delete-region (match-beginning 0) (match-end 0))
 991       (muse-insert-markup (muse-markup-text 'begin-uli))
 992       (muse-publish-surround-text
 993        (muse-markup-text 'begin-uli-item)
 994        (muse-markup-text 'end-uli-item)
 995        (function
 996         (lambda ()
 997           (muse-forward-list-item type indent post-indent)))
 998        indent)
 999       (muse-insert-markup (muse-markup-text 'end-uli)))
1000      ((eq type 'ol)
1001       (delete-region (match-beginning 0) (match-end 0))
1002       (muse-insert-markup (muse-markup-text 'begin-oli))
1003       (muse-publish-surround-text
1004        (muse-markup-text 'begin-oli-item)
1005        (muse-markup-text 'end-oli-item)
1006        (function
1007         (lambda ()
1008           (muse-forward-list-item type indent post-indent)))
1009        indent)
1010       (muse-insert-markup (muse-markup-text 'end-oli)))
1011      (t
1012       (goto-char (match-beginning 1))
1013       (muse-insert-markup (muse-markup-text 'begin-ddt))
1014       (save-match-data
1015         (save-excursion
1016           (forward-line 1)
1017           (while (looking-at (concat "^\\([" muse-regexp-blank
1018                                      "]*\\)[^" muse-regexp-blank "\n]"))
1019             (delete-region (match-beginning 1) (match-end 1))
1020             (forward-line 1))))
1021       (save-match-data
1022         (when (re-search-forward (concat "[" muse-regexp-blank "\n]+::["
1023                                          muse-regexp-blank "\n]+")
1024                                  nil t)
1025           (replace-match "")
1026           (muse-insert-markup (muse-markup-text 'start-dde))))
1027       (muse-forward-paragraph)
1028       (muse-insert-markup (muse-markup-text 'end-ddt) ?\n)))))
1029
1030 (defun muse-publish-markup-quote ()
1031   "Markup a list entry or quoted paragraph.
1032 The reason this function is so funky, is to prevent text properties
1033 like read-only from being inadvertently deleted."
1034   (let* ((ws (match-string 0))
1035          (centered (>= (string-width ws) 6))
1036          (begin-elem (if centered 'begin-center 'begin-quote))
1037          (end-elem (if centered 'end-center 'end-quote)))
1038     (muse-publish-surround-text (muse-markup-text begin-elem)
1039                                 (muse-markup-text end-elem)
1040                                 'muse-forward-paragraph)))
1041
1042 (defun muse-publish-markup-leading-space (markup-space multiple)
1043   (let (count)
1044     (when (and markup-space
1045                (>= (setq count (skip-chars-forward " ")) 0))
1046       (delete-region (muse-line-beginning-position) (point))
1047       (while (> count 0)
1048         (muse-insert-markup markup-space)
1049         (setq count (- count multiple))))))
1050
1051 (defun muse-publish-markup-verse ()
1052   (let ((leader (match-string 0)))
1053     (goto-char (match-beginning 0))
1054     (muse-insert-markup (muse-markup-text 'begin-verse))
1055     (while (looking-at leader)
1056       (replace-match "")
1057       (muse-publish-markup-leading-space (muse-markup-text 'verse-space) 2)
1058       (let ((beg (point)))
1059         (end-of-line)
1060         (cond
1061          ((bolp)
1062           (let ((text (muse-markup-text 'empty-verse-line)))
1063             (when text (muse-insert-markup text))))
1064          ((save-excursion
1065             (save-match-data
1066               (forward-line 1)
1067               (or (looking-at (concat leader "["
1068                                       muse-regexp-blank
1069                                       "]*$"))
1070                   (not (looking-at leader)))))
1071           (let ((begin-text (muse-markup-text 'begin-last-stanza-line))
1072                 (end-text (muse-markup-text 'end-last-stanza-line)))
1073             (when end-text (muse-insert-markup end-text))
1074             (goto-char beg)
1075             (when begin-text (muse-insert-markup begin-text))
1076             (end-of-line)))
1077          (t
1078           (let ((begin-text (muse-markup-text 'begin-verse-line))
1079                 (end-text (muse-markup-text 'end-verse-line)))
1080             (when end-text (muse-insert-markup end-text))
1081             (goto-char beg)
1082             (when begin-text (muse-insert-markup begin-text))
1083             (end-of-line))))
1084         (forward-line 1))))
1085   (muse-insert-markup (muse-markup-text 'end-verse) ?\n))
1086
1087 (defun muse-publish-table-fields (beg end)
1088   "Parse given region as a table, returning a cons cell.
1089 The car is the length of the longest row.
1090
1091 The cdr is a list of the fields of the table, with the first
1092 element indicating the type of the row:
1093   1: body, 2: header, 3: footer.
1094
1095 The existing region will be removed."
1096   (let ((longest 0)
1097         (left 0)
1098         fields field-list)
1099     (save-restriction
1100       (narrow-to-region beg end)
1101       (goto-char (point-min))
1102       (while (= left 0)
1103         (when (looking-at muse-table-line-regexp)
1104           (setq fields (cons (length (match-string 1))
1105                              (split-string (match-string 0)
1106                                            muse-table-field-regexp))
1107                 field-list (cons fields field-list)
1108                 longest (max (length fields) longest)))
1109         (setq left (forward-line 1))))
1110     (delete-region beg end)
1111     (if (= longest 0)
1112         (cons 0 nil)
1113       (cons (1- longest) (nreverse field-list)))))
1114
1115 (defun muse-publish-markup-table ()
1116   "Style does not support tables.")
1117
1118 (defun muse-publish-escape-specials-in-string (string &optional context)
1119   "Escape specials in STRING using style-specific :specials.
1120 CONTEXT is used to figure out what kind of specials to escape.
1121
1122 See the documentation of the `muse-publish-escape-specials'
1123 function for the list of available contexts."
1124   (unless string
1125     (setq string ""))
1126   (let ((specials (muse-style-element :specials nil t)))
1127     (cond ((functionp specials)
1128            (setq specials (funcall specials context)))
1129           ((symbolp specials)
1130            (setq specials (symbol-value specials))))
1131     (if (functionp specials)
1132         (funcall specials string)
1133       (apply (function concat)
1134              (mapcar
1135               (lambda (ch)
1136                 (let (repl)
1137                   (setq repl (or (assoc ch specials)
1138                                  (assoc ch muse-publish-markup-specials)))
1139                   (if (null repl)
1140                       (char-to-string ch)
1141                     (cdr repl))))
1142               (append string nil))))))
1143
1144 (defun muse-publish-markup-email ()
1145   (let* ((beg (match-end 1))
1146          (addr (buffer-substring-no-properties beg (match-end 0))))
1147     (setq addr (muse-publish-escape-specials-in-string addr 'email))
1148     (goto-char beg)
1149     (delete-region beg (match-end 0))
1150     (if (or (eq (char-before (match-beginning 0)) ?\")
1151             (eq (char-after (match-end 0)) ?\"))
1152         (insert addr)
1153       (insert (format (muse-markup-text 'email-addr) addr addr)))
1154     (muse-publish-mark-read-only beg (point))))
1155
1156 (defun muse-publish-classify-url (target)
1157   "Transform anchors and get published name, if TARGET is a page.
1158 The return value is a cons cell.  The car is the type of link,
1159 the cadr is the page name, and the cddr is the anchor."
1160   (save-match-data
1161     (cond ((or (null target) (string= target ""))
1162            nil)
1163           ((string-match muse-url-regexp target)
1164            (cons 'url (cons target nil)))
1165           ((string-match muse-image-regexp target)
1166            (cons 'image (cons target nil)))
1167           ((string-match muse-file-regexp target)
1168            (cons 'file (cons target nil)))
1169           ((string-match "#" target)
1170            (if (eq (aref target 0) ?\#)
1171               (cons 'anchor-ref (cons nil (substring target 1)))
1172              (cons 'link-and-anchor
1173                    (cons (muse-publish-link-name
1174                           (substring target 0 (match-beginning 0)))
1175                          (substring target (match-end 0))))))
1176           (t
1177            (cons 'link (cons (muse-publish-link-name target) nil))))))
1178
1179 (defun muse-publish-url (url &optional desc explicit)
1180   "Resolve a URL into its final <a href> form."
1181   (let ((orig-url url)
1182         type anchor)
1183     (dolist (transform muse-publish-url-transforms)
1184       (setq url (save-match-data (when url (funcall transform url explicit)))))
1185     (dolist (transform muse-publish-desc-transforms)
1186       (setq desc (save-match-data
1187                    (when desc (funcall transform desc explicit)))))
1188     (when desc
1189       (setq desc (muse-publish-escape-specials-in-string desc 'url-desc)))
1190     (setq orig-url
1191           (muse-publish-escape-specials-in-string orig-url 'url-desc))
1192     (let ((target (muse-publish-classify-url url)))
1193       (setq type (car target)
1194             url (muse-publish-escape-specials-in-string (cadr target) 'url)
1195             anchor (muse-publish-escape-specials-in-string
1196                     (cddr target) 'url)))
1197     (cond ((eq type 'anchor-ref)
1198            (muse-markup-text 'anchor-ref anchor (or desc orig-url)))
1199           ((string= url "")
1200            desc)
1201           ((eq type 'image)
1202            (if desc
1203                (muse-markup-text 'image-with-desc url desc)
1204              (muse-markup-text 'image-link url)))
1205           ((eq type 'link-and-anchor)
1206            (muse-markup-text 'link-and-anchor url anchor
1207                              (or desc orig-url)))
1208           ((and desc (string-match muse-image-regexp desc))
1209            (muse-markup-text 'url-with-image url desc))
1210           ((eq type 'link)
1211            (muse-markup-text 'link url (or desc orig-url)))
1212           (t
1213            (muse-markup-text 'url url (or desc orig-url))))))
1214
1215 (defun muse-publish-insert-url (url &optional desc explicit)
1216   "Resolve a URL into its final <a href> form."
1217   (delete-region (match-beginning 0) (match-end 0))
1218   (let ((text (muse-publish-url url desc explicit)))
1219     (when text
1220       (muse-insert-markup text))))
1221
1222 (defun muse-publish-markup-link ()
1223   (let (desc explicit link)
1224     (setq explicit (save-match-data
1225                      (if (string-match muse-explicit-link-regexp
1226                                        (match-string 0))
1227                          t nil)))
1228     (setq desc (if explicit (match-string 2) (match-string 0)))
1229     (setq link (if explicit
1230                    (muse-handle-explicit-link (match-string 1))
1231                  (muse-handle-implicit-link (match-string 0))))
1232     (when (and link
1233                (or explicit
1234                    (not (or (eq (char-before (match-beginning 0)) ?\")
1235                             (eq (char-after (match-end 0)) ?\")))))
1236       (muse-publish-insert-url link desc explicit))))
1237
1238 (defun muse-publish-markup-url ()
1239   (unless (or (eq (char-before (match-beginning 0)) ?\")
1240               (eq (char-after (match-end 0)) ?\"))
1241     (muse-publish-insert-url (match-string 0))))
1242
1243 ;; Default publishing tags
1244
1245 (defun muse-publish-contents-tag (beg end attrs)
1246   (set (make-local-variable 'muse-publish-generate-contents)
1247        (cons (copy-marker (point) t)
1248              (let ((depth (cdr (assoc "depth" attrs))))
1249                (or (and depth (string-to-number depth)) 2)))))
1250
1251 (defun muse-publish-verse-tag (beg end)
1252   (save-excursion
1253     (goto-char beg)
1254     (while (eq ?\  (char-syntax (char-after)))
1255       (delete-char 1))
1256     (while (< (point) end)
1257       (insert "> ")
1258       (forward-line))
1259     (if (eq ?\  (char-syntax (char-before)))
1260       (delete-char -1))))
1261
1262 (defun muse-publish-mark-read-only (beg end)
1263   (add-text-properties beg end '(rear-nonsticky (read-only) read-only t))
1264   nil)
1265
1266 (defun muse-publish-mark-noemphasis (&optional beg end)
1267   (unless beg (setq beg (match-beginning 0)))
1268   (unless end (setq end (match-end 0)))
1269   (add-text-properties beg end '(noemphasis t))
1270   nil)
1271
1272 (defun muse-publish-quote-tag (beg end)
1273   (goto-char end)
1274   (muse-insert-markup (muse-markup-text 'end-quote))
1275   (goto-char beg)
1276   (muse-insert-markup (muse-markup-text 'begin-quote)))
1277
1278 (defun muse-publish-code-tag (beg end)
1279   (muse-publish-escape-specials beg end nil 'literal)
1280   (goto-char beg)
1281   (insert (muse-markup-text 'begin-literal))
1282   (goto-char end)
1283   (insert (muse-markup-text 'end-literal))
1284   (muse-publish-mark-read-only beg (point)))
1285
1286 (defun muse-publish-example-tag (beg end)
1287   (muse-publish-escape-specials beg end nil 'example)
1288   (goto-char beg)
1289   (insert (muse-markup-text 'begin-example))
1290   (goto-char end)
1291   (insert (muse-markup-text 'end-example))
1292   (muse-publish-mark-read-only beg (point)))
1293
1294 (defun muse-publish-verbatim-tag (beg end)
1295   (muse-publish-escape-specials beg end nil 'verbatim)
1296   (muse-publish-mark-read-only beg end))
1297
1298 (defalias 'muse-publish-class-tag 'ignore)
1299
1300 (defun muse-publish-lisp-tag (beg end)
1301   (save-excursion
1302     (let ((str (muse-eval-lisp
1303                 (prog1
1304                     (buffer-substring-no-properties beg end)
1305                   (delete-region beg end)))))
1306       (set-text-properties 0 (length str) nil str)
1307       (insert str))))
1308
1309 (defun muse-publish-command-tag (beg end attrs)
1310   (while (looking-at "\\s-*$")
1311     (forward-line))
1312   (let ((interp (cdr (assoc "interp" attrs))))
1313     (if (null interp)
1314         (shell-command
1315          (prog1
1316              (buffer-substring-no-properties (point) end)
1317            (delete-region beg end)) t)
1318       (shell-command-on-region beg end interp t t))
1319     (muse-publish-mark-read-only beg (point))))
1320
1321 (defun muse-publish-comment-tag (beg end)
1322   (if (null muse-publish-comments-p)
1323       (delete-region beg end)
1324     (goto-char end)
1325     (muse-insert-markup (muse-markup-text 'comment-end))
1326     (goto-char beg)
1327     (muse-insert-markup (muse-markup-text 'comment-begin))))
1328
1329 ;; Miscellaneous helper functions
1330
1331 (defsubst muse-publishing-directive (name)
1332   (cdr (assoc name muse-publishing-directives)))
1333
1334 (defun muse-publish-strip-tags (string)
1335   "Remove all tags from the string."
1336   (while (string-match "<.*?>" string)
1337     (setq string (replace-match "" nil t string)))
1338   string)
1339
1340 (defun muse-publish-markup-type (category default-func)
1341   (let ((rule (muse-find-markup-element :overrides category (muse-style))))
1342     (funcall (or rule default-func))))
1343
1344 (defun muse-published-buffer-contents (buffer)
1345   (with-current-buffer buffer
1346     (goto-char (point-min))
1347     (let ((beg (and (search-forward "Emacs Muse begins here")
1348                     (muse-line-end-position)))
1349           (end (and (search-forward "Emacs Muse ends here")
1350                     (muse-line-beginning-position))))
1351       (buffer-substring-no-properties beg end))))
1352
1353 (defun muse-published-contents (file)
1354   (when (file-readable-p file)
1355     (muse-with-temp-buffer
1356       (insert-file-contents file)
1357       (muse-published-buffer-contents (current-buffer)))))
1358
1359 (defun muse-publish-transform-output
1360   (file temp-file output-path name gen-func &rest cleanup-exts)
1361   "Transform the given TEMP-FILE into the OUTPUT-PATH, using GEN-FUNC."
1362   (setq file (muse-page-name file))
1363   (message "Generating %s output for %s..." name file)
1364   (if (not (funcall gen-func temp-file output-path))
1365       (message "Generating %s from %s...failed" name file)
1366     (message "Generating %s output for %s...done" name file)
1367     (muse-delete-file-if-exists temp-file)
1368     (dolist (ext cleanup-exts)
1369       (muse-delete-file-if-exists
1370        (expand-file-name (concat file ext)
1371                          (file-name-directory output-path))))
1372     (message "Wrote %s" output-path)))
1373
1374 (defun muse-publish-read-only (string)
1375   (let ((end (1- (length string))))
1376     (add-text-properties 0 end
1377                          '(rear-nonsticky (read-only) read-only t)
1378                          string)
1379     string))
1380
1381 (provide 'muse-publish)
1382
1383 ;;; muse-publish.el ends here