lisp/muse-mode.el

   1 ;;; muse-mode.el --- mode for editing Muse files; has font-lock support
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; The Emacs Muse major mode is basically a hyped-up text-mode which
  25 ;; knows a lot more about the apparent structure of the document.
  26
  27 ;;; Contributors:
  28
  29 ;; Andrea Riciputi (ariciputi AT pito DOT com) gave an initial
  30 ;; implementation for tag completion by means of the
  31 ;; `muse-insert-tag' function.
  32
  33 ;;; Code:
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;
  37 ;; Emacs Muse Major Mode
  38 ;;
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (require 'muse)
  42 (require 'muse-regexps)
  43 (require 'muse-project)
  44 (require 'muse-publish)
  45
  46 (autoload 'muse-use-font-lock "muse-colors")
  47
  48 (require 'derived)
  49 (eval-when-compile
  50   (condition-case nil
  51       (require 'pcomplete)              ; load if available
  52     (error nil)))
  53
  54 ;;; Options:
  55
  56 (defgroup muse-mode nil
  57   "Options controlling the behavior of the Muse editing Mode."
  58   :group 'muse)
  59
  60 (defcustom muse-mode-highlight-p t
  61   "If non-nil, highlight the content of Muse buffers."
  62   :type 'boolean
  63   :require 'muse-colors
  64   :group 'muse-mode)
  65
  66 (defcustom muse-mode-auto-p nil
  67   "If non-nil, automagically determine when Muse mode should be activated."
  68   :type 'boolean
  69   :set (function
  70         (lambda (sym value)
  71           (if value
  72               (add-hook 'find-file-hooks 'muse-mode-maybe)
  73             (remove-hook 'find-file-hooks 'muse-mode-maybe))
  74           (set sym value)))
  75   :group 'muse-mode)
  76
  77 (defcustom muse-mode-intangible-links nil
  78   "If non-nil, use the intangible property on links.
  79 This can cause problems with flyspell (and potentially fill-mode),
  80 so only enable this if you don't use either of these."
  81   :type 'boolean
  82   :group 'muse-mode)
  83
  84 (defcustom muse-mode-hook nil
  85   "A hook that is run when Muse mode is entered."
  86   :type 'hook
  87   :options '(flyspell-mode footnote-mode turn-on-auto-fill
  88              highlight-changes-mode)
  89   :set #'(lambda (sym val)
  90            (when (featurep 'muse-wiki)
  91              (add-to-list 'val 'muse-wiki-update-custom-values))
  92            (set sym val))
  93   :group 'muse-mode)
  94
  95 (defvar muse-mode-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map [(control ?c) (control ?a)] 'muse-index)
  98     (define-key map [(control ?c) (control ?b)] 'muse-browse-result)
  99     (define-key map [(control ?c) (control ?c)] 'muse-follow-name-at-point)
 100     (define-key map [(control ?c) (control ?e)] 'muse-edit-link-at-point)
 101     (define-key map [(control ?c) (control ?t)] 'muse-publish-this-file)
 102     (define-key map [(control ?c) (control ?v)] 'muse-follow-name-at-point)
 103
 104     (define-key map [(control ?c) (control ?l)] 'font-lock-mode)
 105
 106     (define-key map [(control ?c) ?=]           'muse-what-changed)
 107
 108     (define-key map [tab] 'muse-next-reference)
 109     (define-key map [(control ?i)] 'muse-next-reference)
 110
 111     (if (featurep 'xemacs)
 112         (progn
 113           (define-key map [(button2)] 'muse-follow-name-at-mouse)
 114           (define-key map [(shift button2)]
 115             'muse-follow-name-at-mouse-other-window))
 116       (define-key map [(shift control ?m)]
 117         'muse-follow-name-at-point-other-window)
 118       (define-key map [mouse-2] 'muse-follow-name-at-mouse)
 119       (define-key map [(shift mouse-2)]
 120         'muse-follow-name-at-mouse-other-window))
 121
 122     (define-key map [(shift tab)] 'muse-previous-reference)
 123     (unless (featurep 'xemacs)
 124       (define-key map [(shift iso-lefttab)] 'muse-previous-reference)
 125       (define-key map [(shift control ?i)] 'muse-previous-reference))
 126
 127     (define-key map [(control ?c) (control ?f)] 'muse-project-find-file)
 128     (define-key map [(control ?c) (control ?p)] 'muse-project-publish)
 129
 130     (define-key map [(control ?c) tab] 'muse-insert-tag)
 131     (define-key map [(control ?c) (control ?i)] 'muse-insert-tag)
 132
 133     (when (featurep 'pcomplete)
 134       (define-key map [(meta tab)] 'pcomplete)
 135       (define-key map [(meta control ?i)] 'pcomplete))
 136
 137     map)
 138   "Keymap used by Emacs Muse mode.")
 139
 140 ;; Code:
 141
 142 ;;;###autoload
 143 (define-derived-mode muse-mode text-mode "Muse"
 144   "Muse is an Emacs mode for authoring and publishing documents.
 145 \\{muse-mode-map}"
 146   ;; Since we're not inheriting from normal-mode, we need to
 147   ;; explicitly run file variables.
 148   (condition-case err
 149       (hack-local-variables)
 150     (error (message "File local-variables error: %s"
 151                     (prin1-to-string err))))
 152   ;; Avoid lock-up caused by use of the 'intangible' text property
 153   ;; with flyspell.
 154   (unless muse-mode-intangible-links
 155     (set (make-local-variable 'inhibit-point-motion-hooks) t))
 156   (setq muse-current-project (muse-project-of-file))
 157   (muse-project-set-variables)
 158   ;; Make sure several variables get updated if the user has changed
 159   ;; them without using the customize interface.
 160   (muse-update-ignored-extensions-regexp 'muse-ignored-extensions
 161                                          muse-ignored-extensions)
 162   (muse-update-url-regexp 'muse-url-protocols muse-url-protocols)
 163   ;; Make fill not split up links
 164   (when (boundp 'fill-nobreak-predicate)
 165     (make-local-variable 'fill-nobreak-predicate)
 166     ;; Work around annoying inconsistency in fill handling between
 167     ;; Emacs 21 and 22.
 168     (if (< emacs-major-version 22)
 169         (setq fill-nobreak-predicate 'muse-mode-fill-nobreak-p)
 170       (add-to-list 'fill-nobreak-predicate
 171                    'muse-mode-fill-nobreak-p)))
 172   ;; Make fill work nicely with item lists
 173   (set (make-local-variable 'adaptive-fill-regexp)
 174        "\\s-+\\(-\\|[0-9]+\\.\\)\\s-+\\|\\[[0-9]+\\]\\s-*\\|\\s-*")
 175   (set (make-local-variable 'paragraph-start)
 176        (concat paragraph-start "\\|\\s-+\\(-\\|[0-9]+\\.\\)\\s-+"
 177                "\\|\\[[0-9]+\\]\\s-*"))
 178   ;; Comment syntax is `; comment'
 179   (set (make-local-variable 'comment-start)
 180        "; ")
 181   ;; If we're using Emacs21, this makes flyspell work like it should
 182   (when (boundp 'flyspell-generic-check-word-p)
 183     (set (make-local-variable 'flyspell-generic-check-word-p)
 184          'muse-mode-flyspell-p))
 185   ;; If pcomplete is available, set it up
 186   (when (featurep 'pcomplete)
 187     (set (make-local-variable 'pcomplete-default-completion-function)
 188          'muse-mode-completions)
 189     (set (make-local-variable 'pcomplete-command-completion-function)
 190          'muse-mode-completions)
 191     (set (make-local-variable 'pcomplete-parse-arguments-function)
 192          'muse-mode-current-word))
 193   (when muse-mode-highlight-p
 194     (muse-use-font-lock)))
 195
 196 (put 'muse-mode
 197      'flyspell-mode-predicate
 198      'muse-mode-flyspell-p)
 199
 200 (defun muse-mode-fill-nobreak-p ()
 201   "Return nil if we should allow a fill to occur at point.
 202 Otherwise return non-nil.
 203
 204 This is used to keep long explicit links from being mangled by
 205 fill mode."
 206   (save-excursion
 207     (save-match-data
 208       (and (re-search-backward "\\[\\[\\|\\]\\]"
 209                                (line-beginning-position) t)
 210            (string= (or (match-string 0) "")
 211                     "[[")))))
 212
 213 (defun muse-mode-flyspell-p ()
 214   "Return non-nil if we should allow spell-checking to occur at point.
 215 Otherwise return nil.
 216
 217 This is used to keep links from being improperly colorized by flyspell."
 218   (save-match-data
 219     (null (muse-link-at-point))))
 220
 221 (defun muse-mode-choose-mode ()
 222   "Turn the proper Emacs Muse related mode on for this file."
 223   (let ((project (muse-project-of-file)))
 224     (funcall (or (and project (muse-get-keyword :major-mode (cadr project) t))
 225                  'muse-mode))))
 226
 227 (defun muse-mode-maybe ()
 228   "Maybe turn Emacs Muse mode on for this file."
 229   (let ((project (muse-project-of-file)))
 230     (and project
 231          (funcall (or (muse-get-keyword :major-mode (cadr project) t)
 232                       'muse-mode)))))
 233
 234 ;;; Support page name completion using pcomplete
 235
 236 (defun muse-completions ()
 237   "Return a list of possible completions names for this buffer."
 238   (let ((project (muse-project-of-file)))
 239     (if project
 240         (while (pcomplete-here
 241                 (mapcar 'car (muse-project-file-alist project)))))))
 242
 243 (defun muse-current-word ()
 244   (let ((end (point)))
 245     (save-restriction
 246       (save-excursion
 247         (skip-chars-backward (concat "^\\["
 248                                      muse-regexp-space))
 249         (narrow-to-region (point) end))
 250       (pcomplete-parse-buffer-arguments))))
 251
 252 ;;; Navigate/visit links or URLs.  Use TAB, S-TAB and RET (or mouse-2).
 253
 254 (defun muse-link-at-point (&optional pos)
 255   "Return link text if a URL or link is at point."
 256   (let ((case-fold-search nil)
 257         (inhibit-point-motion-hooks t)
 258         (here (or pos (point))))
 259     (when (or (null pos)
 260               (and (char-after pos)
 261                    (not (eq (char-syntax (char-after pos)) ?\ ))))
 262       (save-excursion
 263         (goto-char here)
 264         ;; Check for explicit link here or before point
 265         (if (or (looking-at muse-explicit-link-regexp)
 266                 (and
 267                  (re-search-backward "\\[\\[\\|\\]\\]"
 268                                      (muse-line-beginning-position)
 269                                      t)
 270                  (string= (or (match-string 0) "") "[[")
 271                  (looking-at muse-explicit-link-regexp)))
 272             (progn
 273               (goto-char (match-beginning 1))
 274               (muse-handle-explicit-link))
 275           (goto-char here)
 276           ;; Check for bare URL or other link type
 277           (skip-chars-backward (concat "^'\"<>{}(\n"
 278                                        muse-regexp-space))
 279           (and (looking-at muse-implicit-link-regexp)
 280                (muse-handle-implicit-link)))))))
 281
 282 (defun muse-make-link (link &optional name)
 283   "Return a link to LINK with NAME as the text."
 284   (when (string-match muse-explicit-link-regexp link)
 285     (unless name (setq name (match-string 2 link)))
 286     (setq link (match-string 1 link)))
 287   (if (and name
 288            link
 289            (not (string= name ""))
 290            (not (string= link name)))
 291       (concat "[[" (or link "") "][" name "]]")
 292     (concat "[[" (or link "") "]]")))
 293
 294 (defun muse-edit-link-at-point ()
 295   "Edit the current link.
 296 Do not rename the page originally referred to."
 297   (interactive)
 298   (if (muse-link-at-point)
 299       (replace-match
 300        (muse-make-link
 301         (read-string "Link: "
 302                      (muse-match-string-no-properties 1))
 303         (read-string "Text: "
 304                      (muse-match-string-no-properties 2)))
 305        t t)
 306     (error "There is no valid link at point")))
 307
 308 (defun muse-visit-link-default (link &optional other-window anchor)
 309   "Visit the URL or link named by LINK.
 310 If ANCHOR is specified, search for it after opening LINK.
 311
 312 This is the default function to call when visiting links; it is
 313 used by `muse-visit-link' if you have not specified :visit-link
 314 in `muse-project-alist'."
 315   (if (string-match muse-url-regexp link)
 316       (muse-browse-url link)
 317     (let ((base-buffer (get-buffer link)))
 318       (if (and base-buffer (not (buffer-file-name base-buffer)))
 319           ;; If file is temporary (no associated file), just switch to
 320           ;; the buffer
 321           (if other-window
 322               (switch-to-buffer-other-window base-buffer)
 323             (switch-to-buffer base-buffer))
 324         (let ((project (muse-project-of-file)))
 325           (if project
 326               (muse-project-find-file link project
 327                                       (and other-window
 328                                            'find-file-other-window))
 329             (if other-window
 330                 (find-file-other-window link)
 331               (find-file link))))))
 332     (if anchor
 333         (let ((pos (point)))
 334           (goto-char (point-min))
 335           (unless (re-search-forward (concat "^\\W*" (regexp-quote anchor)
 336                                              "\\b")
 337                                      nil t)
 338             (goto-char pos))))))
 339
 340 (defun muse-visit-link (link &optional other-window)
 341   "Visit the URL or link named by LINK."
 342   (let ((visit-link-function
 343          (muse-get-keyword :visit-link (cadr (muse-project-of-file)) t))
 344         anchor)
 345     (if visit-link-function
 346         (funcall visit-link-function link other-window)
 347       (if (string-match "#" link)
 348           (setq anchor (substring link (match-beginning 0))
 349                 link (substring link 0 (match-beginning 0))))
 350       (muse-visit-link-default link other-window anchor))))
 351
 352 (defun muse-browse-result (style &optional other-window)
 353   "Visit the current page's published result."
 354   (interactive (list (muse-publish-get-style) current-prefix-arg))
 355   (setq style (muse-style style))
 356   (let ((result-path
 357          (muse-publish-output-file buffer-file-name
 358                                    (muse-style-element :path style) style)))
 359     (if (not (file-readable-p result-path))
 360         (error "Cannot open output file '%s'" result-path)
 361       (if other-window
 362           (find-file-other-window result-path)
 363         (let ((func (muse-style-element :browser style t)))
 364           (if func
 365               (funcall func result-path)
 366             (message "The %s publishing style does not support browsing."
 367                      style)))))))
 368
 369 (defun muse-follow-name-at-point (&optional other-window)
 370   "Visit the link at point, or insert a newline if none is found."
 371   (interactive "P")
 372   (let ((link (muse-link-at-point)))
 373     (if link
 374         (muse-visit-link link other-window)
 375       (error "There is no valid link at point"))))
 376
 377 (defun muse-follow-name-at-point-other-window ()
 378   "Visit the link at point in other window."
 379   (interactive)
 380   (muse-follow-name-at-point t))
 381
 382 (defun muse-follow-name-at-mouse (event &optional other-window)
 383   "Visit the link at point, or yank text if none is found."
 384   (interactive "eN")
 385   (save-excursion
 386     (cond ((fboundp 'event-window)      ; XEmacs
 387            (set-buffer (window-buffer (event-window event)))
 388            (and (funcall (symbol-function 'event-point) event)
 389                 (goto-char (funcall (symbol-function 'event-point) event))))
 390           ((fboundp 'posn-window)       ; Emacs
 391            (set-buffer (window-buffer (posn-window (event-start event))))
 392            (goto-char (posn-point (event-start event)))))
 393     (let ((link (muse-link-at-point)))
 394       (if link
 395           (muse-visit-link link other-window)
 396         ;; Fall back to normal binding for this event
 397         (call-interactively
 398          (lookup-key (current-global-map) (this-command-keys)))))))
 399
 400 (defun muse-follow-name-at-mouse-other-window (event)
 401   "Visit the link at point"
 402   (interactive "e")
 403   ;; throw away the old window position, since other-window will
 404   ;; change it anyway
 405   (select-window (car (cadr event)))
 406   (muse-follow-name-at-mouse event t))
 407
 408 (defun muse-next-reference ()
 409   "Move forward to next Muse link or URL, cycling if necessary."
 410   (interactive)
 411   (let ((cycled 0) pos)
 412     (save-excursion
 413       (when (memq (get-text-property (point) 'face)
 414                   '(muse-link-face muse-bad-link-face))
 415         (goto-char (or (next-single-property-change (point) 'face)
 416                        (point-max))))
 417       (while (< cycled 2)
 418         (let ((next (point)))
 419           (if (while (and (null pos)
 420                           (setq next
 421                                 (next-single-property-change
 422                                  next 'face)))
 423                 (when (memq (get-text-property next 'face)
 424                             '(muse-link-face muse-bad-link-face))
 425                   (setq pos next)))
 426               (setq cycled 2)
 427             (goto-char (point-min))
 428             (setq cycled (1+ cycled))))))
 429     (if pos
 430         (goto-char pos))))
 431
 432 (defun muse-previous-reference ()
 433   "Move backward to the next Muse link or URL, cycling if necessary.
 434 This function is not entirely accurate, but it's close enough."
 435   (interactive)
 436   (let ((cycled 0) pos)
 437     (save-excursion
 438       (while (< cycled 2)
 439         (let ((prev (point)))
 440           (if (while (and (null pos)
 441                           (setq prev
 442                                 (previous-single-property-change
 443                                  prev 'face)))
 444               (when (memq (get-text-property prev 'face)
 445                           '(muse-link-face muse-bad-link-face))
 446                 (setq pos prev)))
 447               (setq cycled 2)
 448             (goto-char (point-max))
 449             (setq cycled (1+ cycled))))))
 450     (if pos
 451         (goto-char pos))))
 452
 453 (defun muse-what-changed ()
 454   "Show the unsaved changes that have been made to the current file."
 455   (interactive)
 456   (diff-backup buffer-file-name))
 457
 458 ;;; Generate an index of all known Muse pages
 459
 460 (defun muse-generate-index (&optional as-list exclude-private)
 461   "Generate an index of all Muse pages."
 462   (let ((index (muse-index-as-string as-list exclude-private)))
 463     (with-current-buffer (get-buffer-create "*Muse Index*")
 464       (erase-buffer)
 465       (insert index)
 466       (current-buffer))))
 467
 468 (defun muse-index ()
 469   "Display an index of all known Muse pages."
 470   (interactive)
 471   (message "Generating Muse index...")
 472   (let ((project (muse-project)))
 473     (with-current-buffer (muse-generate-index)
 474       (goto-char (point-min))
 475       (muse-mode)
 476       (setq muse-current-project project)
 477       (pop-to-buffer (current-buffer))))
 478   (message "Generating Muse index...done"))
 479
 480 (defun muse-index-as-string (&optional as-list exclude-private exclude-current)
 481   "Generate an index of all Muse pages.
 482 If AS-LIST is non-nil, insert a dash and spaces before each item.
 483 If EXCLUDE-PRIVATE is non-nil, exclude files that have private permissions.
 484 If EXCLUDE-CURRENT is non-nil, exclude the current file from the output."
 485   (let ((files (sort (copy-alist (muse-project-file-alist))
 486                      (function
 487                       (lambda (l r)
 488                         (string-lessp (car l) (car r)))))))
 489     (when (and exclude-current (muse-page-name))
 490       (setq files (delete (assoc (muse-page-name) files) files)))
 491     (muse-with-temp-buffer
 492       (while files
 493         (unless (and exclude-private
 494                      (muse-project-private-p (cdar files)))
 495           (insert (if as-list " - " "") "[[" (caar files) "]]\n"))
 496         (setq files (cdr files)))
 497       (buffer-string))))
 498
 499 ;;; Insert tags interactively on C-c TAB
 500
 501 (defvar muse-tag-history nil
 502   "List of recently-entered tags; used by `muse-insert-tag'.
 503 If you want a tag to start as the default, you may manually set
 504 this variable to a list.")
 505
 506 (defvar muse-custom-tags nil
 507   "Keep track of any new tags entered in `muse-insert-tag'.
 508 If there are (X)HTML tags that you use frequently with that
 509 function, you might want to set this manually.")
 510
 511 (defun muse-insert-tag (tag)
 512   "Insert a tag interactively with a blank line after it."
 513   (interactive
 514    (list
 515     (completing-read
 516      (concat "Tag: "
 517              (when muse-tag-history
 518                (concat "(default: " (car muse-tag-history) ") ")))
 519      (mapcar 'list (nconc (mapcar 'car muse-publish-markup-tags)
 520                           muse-custom-tags))
 521      nil nil nil 'muse-tag-history
 522      (car muse-tag-history))))
 523   (when (equal tag "")
 524     (setq tag (car muse-tag-history)))
 525   (let ((tag-entry (assoc tag muse-publish-markup-tags))
 526         (options ""))
 527     ;; Add to custom list if no entry exists
 528     (unless tag-entry
 529       (add-to-list 'muse-custom-tags tag))
 530     ;; Get option
 531     (when (nth 2 tag-entry)
 532       (setq options (read-string "Option: ")))
 533     (unless (equal options "")
 534       (setq options (concat " " options)))
 535     ;; Insert the tag, closing if necessary
 536     (when tag (insert (concat "<" tag options ">")))
 537     (when (nth 1 tag-entry)
 538       (insert (concat "\n\n</" tag ">\n"))
 539       (forward-line -2))))
 540
 541 (provide 'muse-mode)
 542
 543 ;;; muse-mode.el ends here