lisp/muse-mode.el

   1 ;;; muse-mode.el --- Mode for editing Muse files; has font-lock support.
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; The Emacs Muse major mode is basically a hyped-up text-mode which
  25 ;; knows a lot more about the apparent structure of the document.
  26
  27 ;;; Contributors:
  28
  29 ;; Andrea Riciputi (ariciputi AT pito DOT com) gave an initial
  30 ;; implementation for tag completion by means of the
  31 ;; `muse-insert-tag' function.
  32
  33 ;;; Code:
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;
  37 ;; Emacs Muse Major Mode
  38 ;;
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (require 'muse)
  42 (require 'muse-regexps)
  43 (require 'muse-project)
  44 (require 'muse-publish)
  45
  46 (autoload 'muse-use-font-lock "muse-colors")
  47
  48 (require 'derived)
  49 (eval-when-compile
  50   (condition-case nil
  51       (require 'pcomplete)              ; load if available
  52     (error nil)))
  53
  54 ;;; Options:
  55
  56 (defgroup muse-mode nil
  57   "Options controlling the behavior of the Muse editing Mode."
  58   :group 'muse)
  59
  60 (defcustom muse-mode-highlight-p t
  61   "If non-nil, highlight the content of Muse buffers."
  62   :type 'boolean
  63   :require 'muse-colors
  64   :group 'muse-mode)
  65
  66 (defcustom muse-mode-auto-p t
  67   "If non-nil, automagically determine when Muse mode should be activated."
  68   :type 'boolean
  69   :set (function
  70         (lambda (sym value)
  71           (if value
  72               (add-hook 'find-file-hooks 'muse-mode-maybe)
  73             (remove-hook 'find-file-hooks 'muse-mode-maybe))
  74           (set sym value)))
  75   :group 'muse-mode)
  76
  77 (defcustom muse-mode-intangible-links nil
  78   "If non-nil, use the intangible property on links.
  79 This can cause problems with flyspell (and potentially fill-mode),
  80 so only enable this if you don't use either of these."
  81   :type 'boolean
  82   :group 'muse-mode)
  83
  84 (defcustom muse-mode-hook nil
  85   "A hook that is run when Muse mode is entered."
  86   :type 'hook
  87   :options '(flyspell-mode footnote-mode turn-on-auto-fill
  88              highlight-changes-mode)
  89   :set #'(lambda (sym val)
  90            (when (featurep 'muse-wiki)
  91              (add-to-list 'val 'muse-wiki-update-custom-values))
  92            (set sym val))
  93   :group 'muse-mode)
  94
  95 (defvar muse-mode-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map [(control ?c) (control ?a)] 'muse-index)
  98     (define-key map [(control ?c) (control ?b)] 'muse-browse-result)
  99     (define-key map [(control ?c) (control ?c)] 'muse-follow-name-at-point)
 100     (define-key map [(control ?c) (control ?e)] 'muse-edit-link-at-point)
 101     (define-key map [(control ?c) (control ?t)] 'muse-publish-this-file)
 102     (define-key map [(control ?c) (control ?v)] 'muse-follow-name-at-point)
 103
 104     (define-key map [(control ?c) (control ?l)] 'font-lock-mode)
 105
 106     (define-key map [(control ?c) ?=]           'muse-what-changed)
 107
 108     (define-key map [tab] 'muse-next-reference)
 109     (define-key map [(control ?i)] 'muse-next-reference)
 110
 111     (if (featurep 'xemacs)
 112         (progn
 113           (define-key map [(button2)] 'muse-follow-name-at-mouse)
 114           (define-key map [(shift button2)]
 115             'muse-follow-name-at-mouse-other-window))
 116       (define-key map [(shift control ?m)]
 117         'muse-follow-name-at-point-other-window)
 118       (define-key map [mouse-2] 'muse-follow-name-at-mouse)
 119       (define-key map [(shift mouse-2)]
 120         'muse-follow-name-at-mouse-other-window))
 121
 122     (define-key map [(shift tab)] 'muse-previous-reference)
 123     (unless (featurep 'xemacs)
 124       (define-key map [(shift iso-lefttab)] 'muse-previous-reference)
 125       (define-key map [(shift control ?i)] 'muse-previous-reference))
 126
 127     (define-key map [(control ?c) (control ?f)] 'muse-project-find-file)
 128     (define-key map [(control ?c) (control ?p)] 'muse-project-publish)
 129
 130     (define-key map [(control ?c) tab] 'muse-insert-tag)
 131     (define-key map [(control ?c) (control ?i)] 'muse-insert-tag)
 132
 133     (when (featurep 'pcomplete)
 134       (define-key map [(meta tab)] 'pcomplete)
 135       (define-key map [(meta control ?i)] 'pcomplete))
 136
 137     map)
 138   "Keymap used by Emacs Muse mode.")
 139
 140 ;; Code:
 141
 142 ;;;###autoload
 143 (define-derived-mode muse-mode text-mode "Muse"
 144   "Muse is an Emacs mode for authoring and publishing documents.
 145 \\{muse-mode-map}"
 146   ;; Since we're not inheriting from normal-mode, we need to
 147   ;; explicitly run file variables.
 148   (condition-case err
 149       (hack-local-variables)
 150     (error (message "File local-variables error: %s"
 151                     (prin1-to-string err))))
 152   ;; Avoid lock-up caused by use of the 'intangible' text property
 153   ;; with flyspell.
 154   (unless muse-mode-intangible-links
 155     (set (make-local-variable 'inhibit-point-motion-hooks) t))
 156   (setq muse-current-project (muse-project-of-file))
 157   (muse-project-set-variables)
 158   ;; Make sure several variables get updated if the user has changed
 159   ;; them without using the customize interface.
 160   (muse-update-ignored-extensions-regexp 'muse-ignored-extensions
 161                                          muse-ignored-extensions)
 162   (muse-update-url-regexp 'muse-url-protocols muse-url-protocols)
 163   ;; Make fill not split up links
 164   (when (boundp 'fill-nobreak-predicate)
 165     (make-local-variable 'fill-nobreak-predicate)
 166     ;; Work around annoying inconsistency in fill handling between
 167     ;; Emacs 21 and 22.
 168     (if (< emacs-major-version 22)
 169         (setq fill-nobreak-predicate 'muse-mode-fill-nobreak-p)
 170       (add-to-list 'fill-nobreak-predicate
 171                    'muse-mode-fill-nobreak-p)))
 172   ;; Make fill work nicely with item lists
 173   (set (make-local-variable 'adaptive-fill-regexp)
 174        "\\s-+\\(-\\|[0-9]+\\.\\)\\s-+\\|\\[[0-9]+\\]\\s-*\\|\\s-*")
 175   (set (make-local-variable 'paragraph-start)
 176        (concat paragraph-start "\\|\\s-+\\(-\\|[0-9]+\\.\\)\\s-+"
 177                "\\|\\[[0-9]+\\]\\s-*"))
 178   (when (featurep 'pcomplete)
 179     ;; If pcomplete is available, set it up
 180     (set (make-local-variable 'pcomplete-default-completion-function)
 181          'muse-mode-completions)
 182     (set (make-local-variable 'pcomplete-command-completion-function)
 183          'muse-mode-completions)
 184     (set (make-local-variable 'pcomplete-parse-arguments-function)
 185          'muse-mode-current-word))
 186   (when muse-mode-highlight-p
 187     (muse-use-font-lock)))
 188
 189 (put 'muse-mode
 190      'flyspell-mode-predicate
 191      'muse-mode-flyspell-p)
 192
 193 (defun muse-mode-fill-nobreak-p ()
 194   "Return nil if we should allow a fill to occur at point.
 195 Otherwise return non-nil.
 196
 197 This is used to keep long explicit links from being mangled by
 198 fill mode."
 199   (save-excursion
 200     (save-match-data
 201       (and (re-search-backward "\\[\\[\\|\\]\\]"
 202                                (line-beginning-position) t)
 203            (string= (or (match-string 0) "")
 204                     "[[")))))
 205
 206 (defun muse-mode-flyspell-p ()
 207   "Return non-nil if we should allow spell-checking to occur at point.
 208 Otherwise return nil.
 209
 210 This is used to keep links from being improperly colorized by flyspell."
 211   (save-match-data
 212     (null (muse-link-at-point))))
 213
 214 (defun muse-mode-choose-mode ()
 215   "Turn the proper Emacs Muse related mode on for this file."
 216   (let ((project (muse-project-of-file)))
 217     (funcall (or (and project (muse-get-keyword :major-mode (cadr project) t))
 218                  'muse-mode))))
 219
 220 (defun muse-mode-maybe ()
 221   "Maybe turn Emacs Muse mode on for this file."
 222   (let ((project (muse-project-of-file)))
 223     (and project
 224          (funcall (or (muse-get-keyword :major-mode (cadr project) t)
 225                       'muse-mode)))))
 226
 227 ;;; Support page name completion using pcomplete
 228
 229 (defun muse-completions ()
 230   "Return a list of possible completions names for this buffer."
 231   (let ((project (muse-project-of-file)))
 232     (if project
 233         (while (pcomplete-here
 234                 (mapcar 'car (muse-project-file-alist project)))))))
 235
 236 (defun muse-current-word ()
 237   (let ((end (point)))
 238     (save-restriction
 239       (save-excursion
 240         (skip-chars-backward (concat "^\\["
 241                                      muse-regexp-space))
 242         (narrow-to-region (point) end))
 243       (pcomplete-parse-buffer-arguments))))
 244
 245 ;;; Navigate/visit links or URLs.  Use TAB, S-TAB and RET (or mouse-2).
 246
 247 (defun muse-link-at-point (&optional pos)
 248   "Return link text if a URL or link is at point."
 249   (let ((case-fold-search nil)
 250         (here (or pos (point))))
 251     (when (or (null pos)
 252               (and (char-after pos)
 253                    (not (eq (char-syntax (char-after pos)) ?\ ))))
 254       (save-excursion
 255         (goto-char here)
 256         ;; Check for explicit link here or before point
 257         (if (or (looking-at muse-explicit-link-regexp)
 258                 (and
 259                  (re-search-backward "\\[\\[\\|\\]\\]"
 260                                      (muse-line-beginning-position)
 261                                      t)
 262                  (string= (or (match-string 0) "") "[[")
 263                  (looking-at muse-explicit-link-regexp)))
 264             (progn
 265               (goto-char (match-beginning 1))
 266               (muse-handle-explicit-link))
 267           (goto-char here)
 268           ;; Check for bare URL or other link type
 269           (skip-chars-backward (concat "^'\"<>{}(\n"
 270                                        muse-regexp-space))
 271           (and (looking-at muse-implicit-link-regexp)
 272                (muse-handle-implicit-link)))))))
 273
 274 (defun muse-make-link (link &optional name)
 275   "Return a link to LINK with NAME as the text."
 276   (if (and name
 277            link
 278            (not (string= name ""))
 279            (not (string= link name)))
 280       (concat "[[" (or link "") "][" name "]]")
 281     (concat "[[" (or link "") "]]")))
 282
 283 (defun muse-edit-link-at-point ()
 284   "Edit the current link.
 285 Do not rename the page originally referred to."
 286   (interactive)
 287   (if (muse-link-at-point)
 288       (replace-match
 289        (muse-make-link
 290         (read-string "Link: "
 291                      (muse-match-string-no-properties 1))
 292         (read-string "Text: "
 293                      (muse-match-string-no-properties 2)))
 294        t t)
 295     (error "There is no valid link at point")))
 296
 297 (defun muse-visit-link-default (link &optional other-window anchor)
 298   "Visit the URL or link named by LINK.
 299 If ANCHOR is specified, search for it after opening LINK.
 300
 301 This is the default function to call when visiting links; it is
 302 used by `muse-visit-link' if you have not specified :visit-link
 303 in `muse-project-alist'."
 304   (if (string-match muse-url-regexp link)
 305       (muse-browse-url link)
 306     (let ((base-buffer (get-buffer link)))
 307       (if (and base-buffer (not (buffer-file-name base-buffer)))
 308           ;; If file is temporary (no associated file), just switch to
 309           ;; the buffer
 310           (if other-window
 311               (switch-to-buffer-other-window base-buffer)
 312             (switch-to-buffer base-buffer))
 313         (let ((project (muse-project-of-file)))
 314           (if project
 315               (muse-project-find-file link project
 316                                       (and other-window
 317                                            'find-file-other-window))
 318             (if other-window
 319                 (find-file-other-window link)
 320               (find-file link))))))
 321     (if anchor
 322         (search-forward (concat anchor "\\b") nil t))))
 323
 324 (defun muse-visit-link (link &optional other-window)
 325   "Visit the URL or link named by LINK."
 326   (let ((visit-link-function
 327          (muse-get-keyword :visit-link (cadr (muse-project-of-file)) t))
 328         anchor)
 329     (if visit-link-function
 330         (funcall visit-link-function link other-window)
 331       (if (string-match "#" link)
 332           (setq anchor (substring link (match-beginning 0))
 333                 link (substring link 0 (match-beginning 0))))
 334       (muse-visit-link-default link other-window anchor))))
 335
 336 (defun muse-browse-result (style &optional other-window)
 337   "Visit the current page's published result."
 338   (interactive (list (muse-publish-get-style) current-prefix-arg))
 339   (setq style (muse-style style))
 340   (let ((result-path
 341          (muse-publish-output-file buffer-file-name
 342                                    (muse-style-element :path style) style)))
 343     (if (not (file-readable-p result-path))
 344         (error "Cannot open output file '%s'" result-path)
 345       (if other-window
 346           (find-file-other-window result-path)
 347         (let ((func (muse-style-element :browser style t)))
 348           (if func
 349               (funcall func result-path)
 350             (message "The %s publishing style does not support browsing."
 351                      style)))))))
 352
 353 (defun muse-follow-name-at-point (&optional other-window)
 354   "Visit the link at point, or insert a newline if none is found."
 355   (interactive "P")
 356   (let ((link (muse-link-at-point)))
 357     (if link
 358         (muse-visit-link link other-window)
 359       (error "There is no valid link at point"))))
 360
 361 (defun muse-follow-name-at-point-other-window ()
 362   "Visit the link at point in other window."
 363   (interactive)
 364   (muse-follow-name-at-point t))
 365
 366 (defun muse-follow-name-at-mouse (event &optional other-window)
 367   "Visit the link at point, or yank text if none is found."
 368   (interactive "eN")
 369   (save-excursion
 370     (cond ((fboundp 'event-window)      ; XEmacs
 371            (set-buffer (window-buffer (event-window event)))
 372            (and (funcall (symbol-function 'event-point) event)
 373                 (goto-char (funcall (symbol-function 'event-point) event))))
 374           ((fboundp 'posn-window)       ; Emacs
 375            (set-buffer (window-buffer (posn-window (event-start event))))
 376            (goto-char (posn-point (event-start event)))))
 377     (let ((link (muse-link-at-point)))
 378       (if link
 379           (muse-visit-link link other-window)
 380         ;; Fall back to normal binding for this event
 381         (call-interactively
 382          (lookup-key (current-global-map) (this-command-keys)))))))
 383
 384 (defun muse-follow-name-at-mouse-other-window (event)
 385   "Visit the link at point"
 386   (interactive "e")
 387   ;; throw away the old window position, since other-window will
 388   ;; change it anyway
 389   (select-window (car (cadr event)))
 390   (muse-follow-name-at-mouse event t))
 391
 392 (defun muse-next-reference ()
 393   "Move forward to next Muse link or URL, cycling if necessary."
 394   (interactive)
 395   (let ((cycled 0) pos)
 396     (save-excursion
 397       (when (memq (get-text-property (point) 'face)
 398                   '(muse-link-face muse-bad-link-face))
 399         (goto-char (or (next-single-property-change (point) 'face)
 400                        (point-max))))
 401       (while (< cycled 2)
 402         (let ((next (point)))
 403           (if (while (and (null pos)
 404                           (setq next
 405                                 (next-single-property-change
 406                                  next 'face)))
 407                 (when (memq (get-text-property next 'face)
 408                             '(muse-link-face muse-bad-link-face))
 409                   (setq pos next)))
 410               (setq cycled 2)
 411             (goto-char (point-min))
 412             (setq cycled (1+ cycled))))))
 413     (if pos
 414         (goto-char pos))))
 415
 416 (defun muse-previous-reference ()
 417   "Move backward to the next Muse link or URL, cycling if necessary.
 418 This function is not entirely accurate, but it's close enough."
 419   (interactive)
 420   (let ((cycled 0) pos)
 421     (save-excursion
 422       (while (< cycled 2)
 423         (let ((prev (point)))
 424           (if (while (and (null pos)
 425                           (setq prev
 426                                 (previous-single-property-change
 427                                  prev 'face)))
 428               (when (memq (get-text-property prev 'face)
 429                           '(muse-link-face muse-bad-link-face))
 430                 (setq pos prev)))
 431               (setq cycled 2)
 432             (goto-char (point-max))
 433             (setq cycled (1+ cycled))))))
 434     (if pos
 435         (goto-char pos))))
 436
 437 (defun muse-what-changed ()
 438   "Show the unsaved changes that have been made to the current file."
 439   (interactive)
 440   (diff-backup buffer-file-name))
 441
 442 ;;; Generate an index of all known Muse pages
 443
 444 (defun muse-generate-index (&optional as-list exclude-private)
 445   "Generate an index of all Muse pages."
 446   (let ((index (muse-index-as-string as-list exclude-private)))
 447     (with-current-buffer (get-buffer-create "*Muse Index*")
 448       (erase-buffer)
 449       (insert index)
 450       (current-buffer))))
 451
 452 (defun muse-index ()
 453   "Display an index of all known Muse pages."
 454   (interactive)
 455   (message "Generating Muse index...")
 456   (let ((project (muse-project)))
 457     (with-current-buffer (muse-generate-index)
 458       (goto-char (point-min))
 459       (muse-mode)
 460       (setq muse-current-project project)
 461       (pop-to-buffer (current-buffer))))
 462   (message "Generating Muse index...done"))
 463
 464 (defun muse-index-as-string (&optional as-list exclude-private exclude-current)
 465   "Generate an index of all Muse pages.
 466 If AS-LIST is non-nil, insert a dash and spaces before each item.
 467 If EXCLUDE-PRIVATE is non-nil, exclude files that have private permissions.
 468 If EXCLUDE-CURRENT is non-nil, exclude the current file from the output."
 469   (let ((files (sort (copy-alist (muse-project-file-alist))
 470                      (function
 471                       (lambda (l r)
 472                         (string-lessp (car l) (car r)))))))
 473     (when (and exclude-current (muse-page-name))
 474       (setq files (delete (assoc (muse-page-name) files) files)))
 475     (muse-with-temp-buffer
 476       (while files
 477         (unless (and exclude-private
 478                      (muse-project-private-p (cdar files)))
 479           (insert (if as-list " - " "") "[[" (caar files) "]]\n"))
 480         (setq files (cdr files)))
 481       (buffer-string))))
 482
 483 ;;; Insert tags interactively on C-c TAB
 484
 485 (defvar muse-tag-history nil
 486   "List of recently-entered tags; used by `muse-insert-tag'.
 487 If you want a tag to start as the default, you may manually set
 488 this variable to a list.")
 489
 490 (defvar muse-custom-tags nil
 491   "Keep track of any new tags entered in `muse-insert-tag'.
 492 If there are (X)HTML tags that you use frequently with that
 493 function, you might want to set this manually.")
 494
 495 (defun muse-insert-tag (tag)
 496   "Insert a tag interactively with a blank line after it."
 497   (interactive
 498    (list
 499     (completing-read
 500      (concat "Tag: "
 501              (when muse-tag-history
 502                (concat "(default: " (car muse-tag-history) ") ")))
 503      (mapcar 'list (nconc (mapcar 'car muse-publish-markup-tags)
 504                           muse-custom-tags))
 505      nil nil nil 'muse-tag-history
 506      (car muse-tag-history))))
 507   (when (equal tag "")
 508     (setq tag (car muse-tag-history)))
 509   (let ((tag-entry (assoc tag muse-publish-markup-tags))
 510         (options ""))
 511     ;; Add to custom list if no entry exists
 512     (unless tag-entry
 513       (add-to-list 'muse-custom-tags tag))
 514     ;; Get option
 515     (when (nth 2 tag-entry)
 516       (setq options (read-string "Option: ")))
 517     (unless (equal options "")
 518       (setq options (concat " " options)))
 519     ;; Insert the tag, closing if necessary
 520     (when tag (insert (concat "<" tag options ">")))
 521     (when (nth 1 tag-entry)
 522       (insert (concat "\n\n</" tag ">\n"))
 523       (forward-line -2))))
 524
 525 (provide 'muse-mode)
 526
 527 ;;; muse-mode.el ends here