lisp/muse-mode.el

   1 ;;; muse-mode.el --- mode for editing Muse files; has font-lock support
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; The Emacs Muse major mode is basically a hyped-up text-mode which
  25 ;; knows a lot more about the apparent structure of the document.
  26
  27 ;;; Contributors:
  28
  29 ;; Andrea Riciputi (ariciputi AT pito DOT com) gave an initial
  30 ;; implementation for tag completion by means of the
  31 ;; `muse-insert-tag' function.
  32
  33 ;;; Code:
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;
  37 ;; Emacs Muse Major Mode
  38 ;;
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (require 'muse)
  42 (require 'muse-regexps)
  43 (require 'muse-project)
  44 (require 'muse-publish)
  45
  46 (autoload 'muse-use-font-lock "muse-colors")
  47
  48 (require 'derived)
  49 (eval-when-compile
  50   (condition-case nil
  51       (require 'pcomplete)              ; load if available
  52     (error nil)))
  53
  54 ;;; Options:
  55
  56 (defgroup muse-mode nil
  57   "Options controlling the behavior of the Muse editing Mode."
  58   :group 'muse)
  59
  60 (defcustom muse-mode-highlight-p t
  61   "If non-nil, highlight the content of Muse buffers."
  62   :type 'boolean
  63   :require 'muse-colors
  64   :group 'muse-mode)
  65
  66 (defcustom muse-mode-auto-p nil
  67   "If non-nil, automagically determine when Muse mode should be activated."
  68   :type 'boolean
  69   :set (function
  70         (lambda (sym value)
  71           (if value
  72               (add-hook 'find-file-hooks 'muse-mode-maybe)
  73             (remove-hook 'find-file-hooks 'muse-mode-maybe))
  74           (set sym value)))
  75   :group 'muse-mode)
  76
  77 (defcustom muse-mode-intangible-links nil
  78   "If non-nil, use the intangible property on links.
  79 This can cause problems with flyspell (and potentially fill-mode),
  80 so only enable this if you don't use either of these."
  81   :type 'boolean
  82   :group 'muse-mode)
  83
  84 (defcustom muse-mode-hook nil
  85   "A hook that is run when Muse mode is entered."
  86   :type 'hook
  87   :options '(flyspell-mode footnote-mode turn-on-auto-fill
  88              highlight-changes-mode)
  89   :set #'(lambda (sym val)
  90            (when (featurep 'muse-wiki)
  91              (add-to-list 'val 'muse-wiki-update-custom-values))
  92            (set sym val))
  93   :group 'muse-mode)
  94
  95 (defvar muse-mode-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map [(control ?c) (control ?a)] 'muse-index)
  98     (define-key map [(control ?c) (control ?b)] 'muse-browse-result)
  99     (define-key map [(control ?c) (control ?c)] 'muse-follow-name-at-point)
 100     (define-key map [(control ?c) (control ?e)] 'muse-edit-link-at-point)
 101     (define-key map [(control ?c) (control ?t)] 'muse-publish-this-file)
 102     (define-key map [(control ?c) (control ?v)] 'muse-follow-name-at-point)
 103
 104     (define-key map [(control ?c) (control ?l)] 'font-lock-mode)
 105
 106     (define-key map [(control ?c) ?=]           'muse-what-changed)
 107
 108     (define-key map [tab] 'muse-next-reference)
 109     (define-key map [(control ?i)] 'muse-next-reference)
 110
 111     (if (featurep 'xemacs)
 112         (progn
 113           (define-key map [(button2)] 'muse-follow-name-at-mouse)
 114           (define-key map [(shift button2)]
 115             'muse-follow-name-at-mouse-other-window))
 116       (define-key map [(shift control ?m)]
 117         'muse-follow-name-at-point-other-window)
 118       (define-key map [mouse-2] 'muse-follow-name-at-mouse)
 119       (define-key map [(shift mouse-2)]
 120         'muse-follow-name-at-mouse-other-window))
 121
 122     (define-key map [(shift tab)] 'muse-previous-reference)
 123     (unless (featurep 'xemacs)
 124       (define-key map [(shift iso-lefttab)] 'muse-previous-reference)
 125       (define-key map [(shift control ?i)] 'muse-previous-reference))
 126
 127     (define-key map [(control ?c) (control ?f)] 'muse-project-find-file)
 128     (define-key map [(control ?c) (control ?p)] 'muse-project-publish)
 129
 130     (define-key map [(control ?c) tab] 'muse-insert-tag)
 131     (define-key map [(control ?c) (control ?i)] 'muse-insert-tag)
 132
 133     (when (featurep 'pcomplete)
 134       (define-key map [(meta tab)] 'pcomplete)
 135       (define-key map [(meta control ?i)] 'pcomplete))
 136
 137     map)
 138   "Keymap used by Emacs Muse mode.")
 139
 140 ;; Code:
 141
 142 ;;;###autoload
 143 (define-derived-mode muse-mode text-mode "Muse"
 144   "Muse is an Emacs mode for authoring and publishing documents.
 145 \\{muse-mode-map}"
 146   ;; Since we're not inheriting from normal-mode, we need to
 147   ;; explicitly run file variables.
 148   (condition-case err
 149       (hack-local-variables)
 150     (error (message "File local-variables error: %s"
 151                     (prin1-to-string err))))
 152   ;; Avoid lock-up caused by use of the 'intangible' text property
 153   ;; with flyspell.
 154   (unless muse-mode-intangible-links
 155     (set (make-local-variable 'inhibit-point-motion-hooks) t))
 156   (setq muse-current-project (muse-project-of-file))
 157   (muse-project-set-variables)
 158   ;; Make sure several variables get updated if the user has changed
 159   ;; them without using the customize interface.
 160   (muse-update-ignored-extensions-regexp 'muse-ignored-extensions
 161                                          muse-ignored-extensions)
 162   (muse-update-url-regexp 'muse-url-protocols muse-url-protocols)
 163   ;; Make fill not split up links
 164   (when (boundp 'fill-nobreak-predicate)
 165     (make-local-variable 'fill-nobreak-predicate)
 166     ;; Work around annoying inconsistency in fill handling between
 167     ;; Emacs 21 and 22.
 168     (if (< emacs-major-version 22)
 169         (setq fill-nobreak-predicate 'muse-mode-fill-nobreak-p)
 170       (add-to-list 'fill-nobreak-predicate
 171                    'muse-mode-fill-nobreak-p)))
 172   ;; Make fill work nicely with item lists
 173   (set (make-local-variable 'adaptive-fill-regexp)
 174        "\\s-+\\(-\\|[0-9]+\\.\\)\\s-+\\|\\[[0-9]+\\]\\s-*\\|\\s-*")
 175   (set (make-local-variable 'paragraph-start)
 176        (concat paragraph-start "\\|\\s-+\\(-\\|[0-9]+\\.\\)\\s-+"
 177                "\\|\\[[0-9]+\\]\\s-*"))
 178   ;; Comment syntax is `; comment'
 179   (set (make-local-variable 'comment-start)
 180        "; ")
 181   ;; If we're using Emacs21, this makes flyspell work like it should
 182   (when (boundp 'flyspell-generic-check-word-p)
 183     (set (make-local-variable 'flyspell-generic-check-word-p)
 184          'muse-mode-flyspell-p))
 185   ;; If pcomplete is available, set it up
 186   (when (featurep 'pcomplete)
 187     (set (make-local-variable 'pcomplete-default-completion-function)
 188          'muse-mode-completions)
 189     (set (make-local-variable 'pcomplete-command-completion-function)
 190          'muse-mode-completions)
 191     (set (make-local-variable 'pcomplete-parse-arguments-function)
 192          'muse-mode-current-word))
 193   (when muse-mode-highlight-p
 194     (muse-use-font-lock)))
 195
 196 (put 'muse-mode
 197      'flyspell-mode-predicate
 198      'muse-mode-flyspell-p)
 199
 200 (defun muse-mode-fill-nobreak-p ()
 201   "Return nil if we should allow a fill to occur at point.
 202 Otherwise return non-nil.
 203
 204 This is used to keep long explicit links from being mangled by
 205 fill mode."
 206   (save-excursion
 207     (save-match-data
 208       (and (re-search-backward "\\[\\[\\|\\]\\]"
 209                                (line-beginning-position) t)
 210            (string= (or (match-string 0) "")
 211                     "[[")))))
 212
 213 (defun muse-mode-flyspell-p ()
 214   "Return non-nil if we should allow spell-checking to occur at point.
 215 Otherwise return nil.
 216
 217 This is used to keep links from being improperly colorized by flyspell."
 218   (save-match-data
 219     (null (muse-link-at-point))))
 220
 221 (defun muse-mode-choose-mode ()
 222   "Turn the proper Emacs Muse related mode on for this file."
 223   (let ((project (muse-project-of-file)))
 224     (funcall (or (and project (muse-get-keyword :major-mode (cadr project) t))
 225                  'muse-mode))))
 226
 227 (defun muse-mode-maybe ()
 228   "Maybe turn Emacs Muse mode on for this file."
 229   (let ((project (muse-project-of-file)))
 230     (and project
 231          (funcall (or (muse-get-keyword :major-mode (cadr project) t)
 232                       'muse-mode)))))
 233
 234 ;;; Support page name completion using pcomplete
 235
 236 (defun muse-completions ()
 237   "Return a list of possible completions names for this buffer."
 238   (let ((project (muse-project-of-file)))
 239     (if project
 240         (while (pcomplete-here
 241                 (mapcar 'car (muse-project-file-alist project)))))))
 242
 243 (defun muse-current-word ()
 244   (let ((end (point)))
 245     (save-restriction
 246       (save-excursion
 247         (skip-chars-backward (concat "^\\["
 248                                      muse-regexp-space))
 249         (narrow-to-region (point) end))
 250       (pcomplete-parse-buffer-arguments))))
 251
 252 ;;; Navigate/visit links or URLs.  Use TAB, S-TAB and RET (or mouse-2).
 253
 254 (defun muse-link-at-point (&optional pos)
 255   "Return link text if a URL or link is at point."
 256   (let ((case-fold-search nil)
 257         (inhibit-point-motion-hooks t)
 258         (here (or pos (point))))
 259     (when (or (null pos)
 260               (and (char-after pos)
 261                    (not (eq (char-syntax (char-after pos)) ?\ ))))
 262       (save-excursion
 263         (goto-char here)
 264         ;; Check for explicit link here or before point
 265         (if (or (looking-at muse-explicit-link-regexp)
 266                 (and
 267                  (re-search-backward "\\[\\[\\|\\]\\]"
 268                                      (muse-line-beginning-position)
 269                                      t)
 270                  (string= (or (match-string 0) "") "[[")
 271                  (looking-at muse-explicit-link-regexp)))
 272             (progn
 273               (goto-char (match-beginning 1))
 274               (muse-handle-explicit-link))
 275           (goto-char here)
 276           ;; Check for bare URL or other link type
 277           (skip-chars-backward (concat "^'\"<>{}(\n"
 278                                        muse-regexp-space))
 279           (and (looking-at muse-implicit-link-regexp)
 280                (muse-handle-implicit-link)))))))
 281
 282 (defun muse-make-link (link &optional name)
 283   "Return a link to LINK with NAME as the text."
 284   (if (and name
 285            link
 286            (not (string= name ""))
 287            (not (string= link name)))
 288       (concat "[[" (or link "") "][" name "]]")
 289     (concat "[[" (or link "") "]]")))
 290
 291 (defun muse-edit-link-at-point ()
 292   "Edit the current link.
 293 Do not rename the page originally referred to."
 294   (interactive)
 295   (if (muse-link-at-point)
 296       (replace-match
 297        (muse-make-link
 298         (read-string "Link: "
 299                      (muse-match-string-no-properties 1))
 300         (read-string "Text: "
 301                      (muse-match-string-no-properties 2)))
 302        t t)
 303     (error "There is no valid link at point")))
 304
 305 (defun muse-visit-link-default (link &optional other-window anchor)
 306   "Visit the URL or link named by LINK.
 307 If ANCHOR is specified, search for it after opening LINK.
 308
 309 This is the default function to call when visiting links; it is
 310 used by `muse-visit-link' if you have not specified :visit-link
 311 in `muse-project-alist'."
 312   (if (string-match muse-url-regexp link)
 313       (muse-browse-url link)
 314     (let ((base-buffer (get-buffer link)))
 315       (if (and base-buffer (not (buffer-file-name base-buffer)))
 316           ;; If file is temporary (no associated file), just switch to
 317           ;; the buffer
 318           (if other-window
 319               (switch-to-buffer-other-window base-buffer)
 320             (switch-to-buffer base-buffer))
 321         (let ((project (muse-project-of-file)))
 322           (if project
 323               (muse-project-find-file link project
 324                                       (and other-window
 325                                            'find-file-other-window))
 326             (if other-window
 327                 (find-file-other-window link)
 328               (find-file link))))))
 329     (if anchor
 330         (let ((pos (point)))
 331           (goto-char (point-min))
 332           (unless (re-search-forward (concat "^\\W*" (regexp-quote anchor)
 333                                              "\\b")
 334                                      nil t)
 335             (goto-char pos))))))
 336
 337 (defun muse-visit-link (link &optional other-window)
 338   "Visit the URL or link named by LINK."
 339   (let ((visit-link-function
 340          (muse-get-keyword :visit-link (cadr (muse-project-of-file)) t))
 341         anchor)
 342     (if visit-link-function
 343         (funcall visit-link-function link other-window)
 344       (if (string-match "#" link)
 345           (setq anchor (substring link (match-beginning 0))
 346                 link (substring link 0 (match-beginning 0))))
 347       (muse-visit-link-default link other-window anchor))))
 348
 349 (defun muse-browse-result (style &optional other-window)
 350   "Visit the current page's published result."
 351   (interactive (list (muse-publish-get-style) current-prefix-arg))
 352   (setq style (muse-style style))
 353   (let ((result-path
 354          (muse-publish-output-file buffer-file-name
 355                                    (muse-style-element :path style) style)))
 356     (if (not (file-readable-p result-path))
 357         (error "Cannot open output file '%s'" result-path)
 358       (if other-window
 359           (find-file-other-window result-path)
 360         (let ((func (muse-style-element :browser style t)))
 361           (if func
 362               (funcall func result-path)
 363             (message "The %s publishing style does not support browsing."
 364                      style)))))))
 365
 366 (defun muse-follow-name-at-point (&optional other-window)
 367   "Visit the link at point, or insert a newline if none is found."
 368   (interactive "P")
 369   (let ((link (muse-link-at-point)))
 370     (if link
 371         (muse-visit-link link other-window)
 372       (error "There is no valid link at point"))))
 373
 374 (defun muse-follow-name-at-point-other-window ()
 375   "Visit the link at point in other window."
 376   (interactive)
 377   (muse-follow-name-at-point t))
 378
 379 (defun muse-follow-name-at-mouse (event &optional other-window)
 380   "Visit the link at point, or yank text if none is found."
 381   (interactive "eN")
 382   (save-excursion
 383     (cond ((fboundp 'event-window)      ; XEmacs
 384            (set-buffer (window-buffer (event-window event)))
 385            (and (funcall (symbol-function 'event-point) event)
 386                 (goto-char (funcall (symbol-function 'event-point) event))))
 387           ((fboundp 'posn-window)       ; Emacs
 388            (set-buffer (window-buffer (posn-window (event-start event))))
 389            (goto-char (posn-point (event-start event)))))
 390     (let ((link (muse-link-at-point)))
 391       (if link
 392           (muse-visit-link link other-window)
 393         ;; Fall back to normal binding for this event
 394         (call-interactively
 395          (lookup-key (current-global-map) (this-command-keys)))))))
 396
 397 (defun muse-follow-name-at-mouse-other-window (event)
 398   "Visit the link at point"
 399   (interactive "e")
 400   ;; throw away the old window position, since other-window will
 401   ;; change it anyway
 402   (select-window (car (cadr event)))
 403   (muse-follow-name-at-mouse event t))
 404
 405 (defun muse-next-reference ()
 406   "Move forward to next Muse link or URL, cycling if necessary."
 407   (interactive)
 408   (let ((cycled 0) pos)
 409     (save-excursion
 410       (when (memq (get-text-property (point) 'face)
 411                   '(muse-link-face muse-bad-link-face))
 412         (goto-char (or (next-single-property-change (point) 'face)
 413                        (point-max))))
 414       (while (< cycled 2)
 415         (let ((next (point)))
 416           (if (while (and (null pos)
 417                           (setq next
 418                                 (next-single-property-change
 419                                  next 'face)))
 420                 (when (memq (get-text-property next 'face)
 421                             '(muse-link-face muse-bad-link-face))
 422                   (setq pos next)))
 423               (setq cycled 2)
 424             (goto-char (point-min))
 425             (setq cycled (1+ cycled))))))
 426     (if pos
 427         (goto-char pos))))
 428
 429 (defun muse-previous-reference ()
 430   "Move backward to the next Muse link or URL, cycling if necessary.
 431 This function is not entirely accurate, but it's close enough."
 432   (interactive)
 433   (let ((cycled 0) pos)
 434     (save-excursion
 435       (while (< cycled 2)
 436         (let ((prev (point)))
 437           (if (while (and (null pos)
 438                           (setq prev
 439                                 (previous-single-property-change
 440                                  prev 'face)))
 441               (when (memq (get-text-property prev 'face)
 442                           '(muse-link-face muse-bad-link-face))
 443                 (setq pos prev)))
 444               (setq cycled 2)
 445             (goto-char (point-max))
 446             (setq cycled (1+ cycled))))))
 447     (if pos
 448         (goto-char pos))))
 449
 450 (defun muse-what-changed ()
 451   "Show the unsaved changes that have been made to the current file."
 452   (interactive)
 453   (diff-backup buffer-file-name))
 454
 455 ;;; Generate an index of all known Muse pages
 456
 457 (defun muse-generate-index (&optional as-list exclude-private)
 458   "Generate an index of all Muse pages."
 459   (let ((index (muse-index-as-string as-list exclude-private)))
 460     (with-current-buffer (get-buffer-create "*Muse Index*")
 461       (erase-buffer)
 462       (insert index)
 463       (current-buffer))))
 464
 465 (defun muse-index ()
 466   "Display an index of all known Muse pages."
 467   (interactive)
 468   (message "Generating Muse index...")
 469   (let ((project (muse-project)))
 470     (with-current-buffer (muse-generate-index)
 471       (goto-char (point-min))
 472       (muse-mode)
 473       (setq muse-current-project project)
 474       (pop-to-buffer (current-buffer))))
 475   (message "Generating Muse index...done"))
 476
 477 (defun muse-index-as-string (&optional as-list exclude-private exclude-current)
 478   "Generate an index of all Muse pages.
 479 If AS-LIST is non-nil, insert a dash and spaces before each item.
 480 If EXCLUDE-PRIVATE is non-nil, exclude files that have private permissions.
 481 If EXCLUDE-CURRENT is non-nil, exclude the current file from the output."
 482   (let ((files (sort (copy-alist (muse-project-file-alist))
 483                      (function
 484                       (lambda (l r)
 485                         (string-lessp (car l) (car r)))))))
 486     (when (and exclude-current (muse-page-name))
 487       (setq files (delete (assoc (muse-page-name) files) files)))
 488     (muse-with-temp-buffer
 489       (while files
 490         (unless (and exclude-private
 491                      (muse-project-private-p (cdar files)))
 492           (insert (if as-list " - " "") "[[" (caar files) "]]\n"))
 493         (setq files (cdr files)))
 494       (buffer-string))))
 495
 496 ;;; Insert tags interactively on C-c TAB
 497
 498 (defvar muse-tag-history nil
 499   "List of recently-entered tags; used by `muse-insert-tag'.
 500 If you want a tag to start as the default, you may manually set
 501 this variable to a list.")
 502
 503 (defvar muse-custom-tags nil
 504   "Keep track of any new tags entered in `muse-insert-tag'.
 505 If there are (X)HTML tags that you use frequently with that
 506 function, you might want to set this manually.")
 507
 508 (defun muse-insert-tag (tag)
 509   "Insert a tag interactively with a blank line after it."
 510   (interactive
 511    (list
 512     (completing-read
 513      (concat "Tag: "
 514              (when muse-tag-history
 515                (concat "(default: " (car muse-tag-history) ") ")))
 516      (mapcar 'list (nconc (mapcar 'car muse-publish-markup-tags)
 517                           muse-custom-tags))
 518      nil nil nil 'muse-tag-history
 519      (car muse-tag-history))))
 520   (when (equal tag "")
 521     (setq tag (car muse-tag-history)))
 522   (let ((tag-entry (assoc tag muse-publish-markup-tags))
 523         (options ""))
 524     ;; Add to custom list if no entry exists
 525     (unless tag-entry
 526       (add-to-list 'muse-custom-tags tag))
 527     ;; Get option
 528     (when (nth 2 tag-entry)
 529       (setq options (read-string "Option: ")))
 530     (unless (equal options "")
 531       (setq options (concat " " options)))
 532     ;; Insert the tag, closing if necessary
 533     (when tag (insert (concat "<" tag options ">")))
 534     (when (nth 1 tag-entry)
 535       (insert (concat "\n\n</" tag ">\n"))
 536       (forward-line -2))))
 537
 538 (provide 'muse-mode)
 539
 540 ;;; muse-mode.el ends here