lisp/muse-texinfo.el

   1 ;;; muse-texinfo.el --- publish entries to Texinfo format or PDF
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 3, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;;; Code:
  27
  28 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  29 ;;
  30 ;; Muse Texinfo Publishing
  31 ;;
  32 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  33
  34 (require 'muse-publish)
  35 (require 'muse-latex)
  36 (require 'texnfo-upd)
  37
  38 (defgroup muse-texinfo nil
  39   "Rules for marking up a Muse file as a Texinfo article."
  40   :group 'muse-publish)
  41
  42 (defcustom muse-texinfo-process-natively nil
  43   "If non-nil, use the Emacs `texinfmt' module to make Info files."
  44   :type 'boolean
  45   :require 'texinfmt
  46   :group 'muse-texinfo)
  47
  48 (defcustom muse-texinfo-extension ".texi"
  49   "Default file extension for publishing Texinfo files."
  50   :type 'string
  51   :group 'muse-texinfo)
  52
  53 (defcustom muse-texinfo-info-extension ".info"
  54   "Default file extension for publishing Info files."
  55   :type 'string
  56   :group 'muse-texinfo)
  57
  58 (defcustom muse-texinfo-pdf-extension ".pdf"
  59   "Default file extension for publishing PDF files."
  60   :type 'string
  61   :group 'muse-texinfo)
  62
  63 (defcustom muse-texinfo-header
  64   "\\input texinfo  @c -*-texinfo-*-
  65
  66 @setfilename <lisp>(concat (muse-page-name) \".info\")</lisp>
  67 @settitle <lisp>(muse-publishing-directive \"title\")</lisp>
  68
  69 @documentencoding iso-8859-1
  70
  71 @iftex
  72 @finalout
  73 @end iftex
  74
  75 @titlepage
  76 @title <lisp>(muse-publishing-directive \"title\")</lisp>
  77 @author <lisp>(muse-publishing-directive \"author\")</lisp>
  78 @end titlepage
  79
  80 <lisp>(and muse-publish-generate-contents \"@contents\")</lisp>
  81
  82 @node Top, Overview, , (dir)
  83 @top Overview
  84 @c Page published by Emacs Muse begins here\n\n"
  85   "Text to prepend to a Muse page being published as Texinfo.
  86 This may be text or a filename.
  87 It may contain <lisp> markup tags."
  88   :type 'string
  89   :group 'muse-texinfo)
  90
  91 (defcustom muse-texinfo-footer
  92   "\n@c Page published by Emacs Muse ends here
  93 @bye\n"
  94   "Text to append to a Muse page being published as Texinfo.
  95 This may be text or a filename.
  96 It may contain <lisp> markup tags."
  97   :type 'string
  98   :group 'muse-texinfo)
  99
 100 (defcustom muse-texinfo-markup-regexps nil
 101   "List of markup rules for publishing a Muse page to Texinfo.
 102 For more on the structure of this list, see `muse-publish-markup-regexps'."
 103   :type '(repeat (choice
 104                   (list :tag "Markup rule"
 105                         integer
 106                         (choice regexp symbol)
 107                         integer
 108                         (choice string function symbol))
 109                   function))
 110   :group 'muse-texinfo)
 111
 112 (defcustom muse-texinfo-markup-functions
 113   '((table . muse-texinfo-markup-table)
 114     (heading . muse-texinfo-markup-heading))
 115   "An alist of style types to custom functions for that kind of text.
 116 For more on the structure of this list, see
 117 `muse-publish-markup-functions'."
 118   :type '(alist :key-type symbol :value-type function)
 119   :group 'muse-texinfo)
 120
 121 (defcustom muse-texinfo-markup-strings
 122   '((image-with-desc . "@center @image{%1%, , , %3%, %2%}@*\n@center %3%")
 123     (image           . "@noindent @image{%s, , , , %s}")
 124     (image-link      . "@uref{%s, %s.%s}")
 125     (anchor-ref      . "@ref{%s, %s}")
 126     (url             . "@uref{%s, %s}")
 127     (link            . "@ref{Top, %2%, , %1%, }")
 128     (link-and-anchor . "@ref{%3%, %2%, , %1%, %3%}")
 129     (email-addr      . "@email{%s}")
 130     (anchor          . "@anchor{%s} ")
 131     (emdash          . "---")
 132     (comment-begin   . "@ignore\n")
 133     (comment-end     . "\n@end ignore\n")
 134     (rule            . "@sp 1")
 135     (no-break-space  . "@w{ }")
 136     (enddots         . "@enddots{}")
 137     (dots            . "@dots{}")
 138     (section         . "@chapter ")
 139     (subsection      . "@section ")
 140     (subsubsection   . "@subsection ")
 141     (section-other   . "@subsubheading ")
 142     (footnote        . "@footnote{")
 143     (footnote-end    . "}")
 144     (begin-underline . "_")
 145     (end-underline   . "_")
 146     (begin-literal   . "@samp{")
 147     (end-literal     . "}")
 148     (begin-emph      . "@emph{")
 149     (end-emph        . "}")
 150     (begin-more-emph . "@strong{")
 151     (end-more-emph   . "}")
 152     (begin-most-emph . "@strong{@emph{")
 153     (end-most-emph   . "}}")
 154     (begin-verse     . "@display\n")
 155     (end-verse-line  . "")
 156     (verse-space     . "@ @ ")
 157     (end-verse       . "\n@end display")
 158     (begin-example   . "@example\n")
 159     (end-example     . "\n@end example")
 160     (begin-center    . "@quotation\n")
 161     (end-center      . "\n@end quotation")
 162     (begin-quote     . "@quotation\n")
 163     (end-quote       . "\n@end quotation")
 164     (begin-cite     . "")
 165     (begin-cite-author . "")
 166     (begin-cite-year . "")
 167     (end-cite        . "")
 168     (begin-uli       . "@itemize @bullet\n")
 169     (end-uli         . "\n@end itemize")
 170     (begin-uli-item  . "@item\n")
 171     (begin-oli       . "@enumerate\n")
 172     (end-oli         . "\n@end enumerate")
 173     (begin-oli-item  . "@item\n")
 174     (begin-dl        . "@table @strong\n")
 175     (end-dl          . "\n@end table")
 176     (begin-ddt       . "@item "))
 177   "Strings used for marking up text.
 178 These cover the most basic kinds of markup, the handling of which
 179 differs little between the various styles."
 180   :type '(alist :key-type symbol :value-type string)
 181   :group 'muse-texinfo)
 182
 183 (defcustom muse-texinfo-markup-specials
 184   '((?@ . "@@")
 185     (?{ . "@{")
 186     (?} . "@}"))
 187   "A table of characters which must be represented specially."
 188   :type '(alist :key-type character :value-type string)
 189   :group 'muse-texinfo)
 190
 191 (defcustom muse-texinfo-markup-specials-url
 192   '((?@ . "@@")
 193     (?{ . "@{")
 194     (?} . "@}")
 195     (?, . "@comma{}"))
 196   "A table of characters which must be represented specially.
 197 These are applied to URLs."
 198   :type '(alist :key-type character :value-type string)
 199   :group 'muse-texinfo)
 200
 201 (defun muse-texinfo-decide-specials (context)
 202   "Determine the specials to escape, depending on CONTEXT."
 203   (cond ((memq context '(underline literal emphasis email url url-desc image))
 204          muse-texinfo-markup-specials-url)
 205         (t muse-texinfo-markup-specials)))
 206
 207 (defun muse-texinfo-markup-table ()
 208   (let* ((table-info (muse-publish-table-fields (match-beginning 0)
 209                                                 (match-end 0)))
 210          (row-len (car table-info))
 211          (field-list (cdr table-info)))
 212     (when table-info
 213       (muse-insert-markup "@multitable @columnfractions")
 214       (dotimes (field row-len)
 215         (muse-insert-markup " " (number-to-string (/ 1.0 row-len))))
 216       (dolist (fields field-list)
 217         (let ((type (car fields)))
 218           (unless (eq type 'hline)
 219             (setq fields (cdr fields))
 220             (if (= type 2)
 221                 (muse-insert-markup "\n@headitem ")
 222               (muse-insert-markup "\n@item "))
 223             (insert (car fields))
 224             (setq fields (cdr fields))
 225             (dolist (field fields)
 226               (muse-insert-markup " @tab ")
 227               (insert field)))))
 228       (muse-insert-markup "\n@end multitable")
 229       (insert ?\n))))
 230
 231 (defun muse-texinfo-remove-links (string)
 232   "Remove explicit links from STRING, replacing them with the link
 233 description.
 234
 235 If no description exists for the link, use the link itself."
 236   (let ((start nil))
 237     (while (setq start (string-match muse-explicit-link-regexp string
 238                                      start))
 239       (setq string
 240             (replace-match (or (match-string 2 string)
 241                                (match-string 1 string))
 242                            t t string)))
 243     string))
 244
 245 (defun muse-texinfo-protect-wikiwords (start end)
 246   "Protect all wikiwords from START to END from further processing."
 247   (and (boundp 'muse-wiki-wikiword-regexp)
 248        (featurep 'muse-wiki)
 249        (save-excursion
 250          (goto-char start)
 251          (while (re-search-forward muse-wiki-wikiword-regexp end t)
 252            (muse-publish-mark-read-only (match-beginning 0)
 253                                         (match-end 0))))))
 254
 255 (defun muse-texinfo-markup-heading ()
 256   (save-excursion
 257     (muse-publish-markup-heading))
 258   (let* ((eol (muse-line-end-position))
 259          (orig-heading (buffer-substring (point) eol))
 260          (beg (point)))
 261     (delete-region (point) eol)
 262     ;; don't allow links to be published in headings
 263     (insert (muse-texinfo-remove-links orig-heading))
 264     (muse-texinfo-protect-wikiwords beg (point))))
 265
 266 (defun muse-texinfo-munge-buffer ()
 267   (muse-latex-fixup-dquotes)
 268   (texinfo-insert-node-lines (point-min) (point-max) t)
 269   (texinfo-all-menus-update t))
 270
 271 (defun muse-texinfo-pdf-browse-file (file)
 272   (shell-command (concat "open " file)))
 273
 274 (defun muse-texinfo-info-generate (file output-path final-target)
 275   ;; The version of `texinfmt.el' that comes with Emacs 21 doesn't
 276   ;; support @documentencoding, so hack it in.
 277   (when (and (not (featurep 'xemacs))
 278              (eq emacs-major-version 21))
 279     (put 'documentencoding 'texinfo-format
 280          'texinfo-discard-line-with-args))
 281   ;; Most versions of `texinfmt.el' do not support @headitem, so hack
 282   ;; it in.
 283   (unless (get 'headitem 'texinfo-format)
 284     (put 'headitem 'texinfo-format 'texinfo-multitable-item))
 285   (muse-publish-transform-output
 286    file output-path final-target "Info"
 287    (function
 288     (lambda (file output-path)
 289       (if muse-texinfo-process-natively
 290           (save-window-excursion
 291             (save-excursion
 292               (find-file file)
 293               (let ((inhibit-read-only t))
 294                 (texinfo-format-buffer))
 295               (save-buffer)
 296               (kill-buffer (current-buffer))
 297               (let ((buf (get-file-buffer file)))
 298                 (with-current-buffer buf
 299                   (set-buffer-modified-p nil)
 300                   (kill-buffer (current-buffer))))
 301               t))
 302         (let ((result (shell-command
 303                        (concat "makeinfo --enable-encoding --output="
 304                                output-path " " file))))
 305           (if (or (not (numberp result))
 306                   (eq result 0))
 307               t
 308             nil)))))))
 309
 310 (defun muse-texinfo-pdf-generate (file output-path final-target)
 311   (let ((muse-latex-pdf-program "pdftex")
 312         (muse-latex-pdf-cruft '(".aux" ".cp" ".fn" ".ky" ".log" ".pg" ".toc"
 313                                 ".tp" ".vr")))
 314     (muse-latex-pdf-generate file output-path final-target)))
 315
 316 ;;; Register the Muse TEXINFO Publishers
 317
 318 (muse-define-style "texi"
 319                    :suffix    'muse-texinfo-extension
 320                    :regexps   'muse-texinfo-markup-regexps
 321                    :functions 'muse-texinfo-markup-functions
 322                    :strings   'muse-texinfo-markup-strings
 323                    :specials  'muse-texinfo-decide-specials
 324                    :after     'muse-texinfo-munge-buffer
 325                    :header    'muse-texinfo-header
 326                    :footer    'muse-texinfo-footer
 327                    :browser   'find-file)
 328
 329 (muse-derive-style "info" "texi"
 330                    :final   'muse-texinfo-info-generate
 331                    :link-suffix 'muse-texinfo-info-extension
 332                    :osuffix 'muse-texinfo-info-extension
 333                    :browser 'info)
 334
 335 (muse-derive-style "info-pdf" "texi"
 336                    :final   'muse-texinfo-pdf-generate
 337                    :link-suffix 'muse-texinfo-pdf-extension
 338                    :osuffix 'muse-texinfo-pdf-extension
 339                    :browser 'muse-texinfo-pdf-browse-file)
 340
 341 (provide 'muse-texinfo)
 342
 343 ;;; muse-texinfo.el ends here