lisp/muse-texinfo.el

   1 ;;; muse-texinfo.el --- publish entries to Texinfo format or PDF
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;;; Code:
  27
  28 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  29 ;;
  30 ;; Muse Texinfo Publishing
  31 ;;
  32 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  33
  34 (require 'muse-publish)
  35 (require 'muse-latex)
  36 (require 'texnfo-upd)
  37
  38 (defgroup muse-texinfo nil
  39   "Rules for marking up a Muse file as a Texinfo article."
  40   :group 'muse-publish)
  41
  42 (defcustom muse-texinfo-process-natively t
  43   "If non-nil, use the Emacs `texinfmt' module to make Info files."
  44   :type 'boolean
  45   :require 'texinfmt
  46   :group 'muse-texinfo)
  47
  48 (defcustom muse-texinfo-extension ".texi"
  49   "Default file extension for publishing Texinfo files."
  50   :type 'string
  51   :group 'muse-texinfo)
  52
  53 (defcustom muse-texinfo-info-extension ".info"
  54   "Default file extension for publishing Info files."
  55   :type 'string
  56   :group 'muse-texinfo)
  57
  58 (defcustom muse-texinfo-pdf-extension ".pdf"
  59   "Default file extension for publishing PDF files."
  60   :type 'string
  61   :group 'muse-texinfo)
  62
  63 (defcustom muse-texinfo-header
  64   "\\input texinfo  @c -*-texinfo-*-
  65
  66 @setfilename <lisp>(concat (muse-page-name) \".info\")</lisp>
  67 @settitle <lisp>(muse-publishing-directive \"title\")</lisp>
  68
  69 @documentencoding iso-8859-1
  70
  71 @iftex
  72 @finalout
  73 @end iftex
  74
  75 @titlepage
  76 @title <lisp>(muse-publishing-directive \"title\")</lisp>
  77 @author <lisp>(muse-publishing-directive \"author\")</lisp>
  78 @end titlepage
  79
  80 <lisp>(and muse-publish-generate-contents \"@contents\")</lisp>
  81
  82 @node Top, Overview, , (dir)
  83 @top Overview
  84 @c Page published by Emacs Muse begins here\n\n"
  85   "Text to prepend to a Muse page being published as Texinfo.
  86 This may be text or a filename.
  87 It may contain <lisp> markup tags."
  88   :type 'string
  89   :group 'muse-texinfo)
  90
  91 (defcustom muse-texinfo-footer
  92   "\n@c Page published by Emacs Muse ends here
  93 @bye\n"
  94   "Text to append to a Muse page being published as Texinfo.
  95 This may be text or a filename.
  96 It may contain <lisp> markup tags."
  97   :type 'string
  98   :group 'muse-texinfo)
  99
 100 (defcustom muse-texinfo-markup-regexps nil
 101   "List of markup rules for publishing a Muse page to Texinfo.
 102 For more on the structure of this list, see `muse-publish-markup-regexps'."
 103   :type '(repeat (choice
 104                   (list :tag "Markup rule"
 105                         integer
 106                         (choice regexp symbol)
 107                         integer
 108                         (choice string function symbol))
 109                   function))
 110   :group 'muse-texinfo)
 111
 112 (defcustom muse-texinfo-markup-functions
 113   '((table . muse-texinfo-markup-table)
 114     (heading . muse-texinfo-markup-heading))
 115   "An alist of style types to custom functions for that kind of text.
 116 For more on the structure of this list, see
 117 `muse-publish-markup-functions'."
 118   :type '(alist :key-type symbol :value-type function)
 119   :group 'muse-texinfo)
 120
 121 (defcustom muse-texinfo-markup-strings
 122   '((image-with-desc . "@center @image{%1%, , , %3%, %2%}@*\n@center %3%")
 123     (image           . "@noindent @image{%s, , , , %s}")
 124     (image-link      . "@uref{%s, %s.%s}")
 125     (anchor-ref      . "@ref{%s, %s}")
 126     (url             . "@uref{%s}")
 127     (link            . "@ref{Top, , Overview, %s, %s}")
 128     (link-and-anchor . "@ref{%2%, , %2%, %1%, %3%}")
 129     (email-addr      . "@email{%s}")
 130     (anchor          . "@anchor{%s} ")
 131     (emdash          . "---")
 132     (comment-begin   . "@ignore\n")
 133     (comment-end     . "\n@end ignore\n")
 134     (rule            . "@sp 1")
 135     (no-break-space  . "@w{ }")
 136     (enddots         . "@enddots{}")
 137     (dots            . "@dots{}")
 138     (section         . "@chapter ")
 139     (subsection      . "@section ")
 140     (subsubsection   . "@subsection ")
 141     (section-other   . "@subsubheading ")
 142     (footnote        . "@footnote{")
 143     (footnote-end    . "}")
 144     (begin-underline . "_")
 145     (end-underline   . "_")
 146     (begin-literal   . "@samp{")
 147     (end-literal     . "}")
 148     (begin-emph      . "@emph{")
 149     (end-emph        . "}")
 150     (begin-more-emph . "@strong{")
 151     (end-more-emph   . "}")
 152     (begin-most-emph . "@strong{@emph{")
 153     (end-most-emph   . "}}")
 154     (begin-verse     . "@display\n")
 155     (end-verse-line  . "")
 156     (verse-space     . "@ @ ")
 157     (end-verse       . "\n@end display")
 158     (begin-example   . "@example")
 159     (end-example     . "@end example")
 160     (begin-center    . "@quotation\n")
 161     (end-center      . "\n@end quotation")
 162     (begin-quote     . "@quotation\n")
 163     (end-quote       . "\n@end quotation")
 164     (begin-uli       . "@itemize @bullet\n")
 165     (end-uli         . "\n@end itemize")
 166     (begin-uli-item  . "@item\n")
 167     (begin-oli       . "@enumerate\n")
 168     (end-oli         . "\n@end enumerate")
 169     (begin-oli-item  . "@item\n")
 170     (begin-dl        . "@table @strong\n")
 171     (end-dl          . "\n@end table")
 172     (begin-ddt       . "@item "))
 173   "Strings used for marking up text.
 174 These cover the most basic kinds of markup, the handling of which
 175 differs little between the various styles."
 176   :type '(alist :key-type symbol :value-type string)
 177   :group 'muse-texinfo)
 178
 179 (defcustom muse-texinfo-markup-specials
 180   '((?@ . "@@")
 181     (?{ . "@{")
 182     (?} . "@}"))
 183   "A table of characters which must be represented specially."
 184   :type '(alist :key-type character :value-type string)
 185   :group 'muse-texinfo)
 186
 187 (defcustom muse-texinfo-markup-specials-url
 188   '((?@ . "@@")
 189     (?{ . "@{")
 190     (?} . "@}")
 191     (?, . "@comma{}"))
 192   "A table of characters which must be represented specially.
 193 These are applied to URLs."
 194   :type '(alist :key-type character :value-type string)
 195   :group 'muse-texinfo)
 196
 197 (defun muse-texinfo-decide-specials (context)
 198   "Determine the specials to escape, depending on CONTEXT."
 199   (cond ((memq context '(url image))
 200          muse-texinfo-markup-specials-url)
 201         (t muse-texinfo-markup-specials)))
 202
 203 (defun muse-texinfo-markup-table ()
 204   (let* ((table-info (muse-publish-table-fields (match-beginning 0)
 205                                                 (match-end 0)))
 206          (row-len (car table-info))
 207          (field-list (cdr table-info)))
 208     (when table-info
 209       (muse-insert-markup "@multitable @columnfractions")
 210       (dotimes (field row-len)
 211         (muse-insert-markup " " (number-to-string (/ 1.0 row-len))))
 212       (dolist (fields field-list)
 213         (let ((type (car fields)))
 214           (unless (eq type 'hline)
 215             (setq fields (cdr fields))
 216             (if (= type 2)
 217                 (muse-insert-markup "\n@headitem ")
 218               (muse-insert-markup "\n@item "))
 219             (insert (car fields))
 220             (setq fields (cdr fields))
 221             (dolist (field fields)
 222               (muse-insert-markup " @tab ")
 223               (insert field)))))
 224       (muse-insert-markup "\n@end multitable")
 225       (insert ?\n))))
 226
 227 (defun muse-texinfo-remove-links (string)
 228   "Remove explicit links from STRING, replacing them with the link
 229 description.
 230
 231 If no description exists for the link, use the link itself."
 232   (let ((start nil))
 233     (while (setq start (string-match muse-explicit-link-regexp string
 234                                      start))
 235       (setq string
 236             (replace-match (or (match-string 2 string)
 237                                (match-string 1 string))
 238                            t t string)))
 239     string))
 240
 241 (defun muse-texinfo-protect-wikiwords (start end)
 242   "Protect all wikiwords from START to END from further processing."
 243   (and (boundp 'muse-wiki-wikiword-regexp)
 244        (featurep 'muse-wiki)
 245        (save-excursion
 246          (goto-char start)
 247          (while (re-search-forward muse-wiki-wikiword-regexp end t)
 248            (muse-publish-mark-read-only (match-beginning 0)
 249                                         (match-end 0))))))
 250
 251 (defun muse-texinfo-markup-heading ()
 252   (save-excursion
 253     (muse-publish-markup-heading))
 254   (let* ((eol (muse-line-end-position))
 255          (orig-heading (buffer-substring (point) eol))
 256          (beg (point)))
 257     (delete-region (point) eol)
 258     ;; don't allow links to be published in headings
 259     (insert (muse-texinfo-remove-links orig-heading))
 260     (muse-texinfo-protect-wikiwords beg (point))))
 261
 262 (defun muse-texinfo-munge-buffer ()
 263   (muse-latex-fixup-dquotes)
 264   (texinfo-insert-node-lines (point-min) (point-max) t)
 265   (texinfo-all-menus-update t))
 266
 267 (defun muse-texinfo-pdf-browse-file (file)
 268   (shell-command (concat "open " file)))
 269
 270 (defun muse-texinfo-info-generate (file output-path final-target)
 271   ;; The version of `texinfmt.el' that comes with Emacs 21 doesn't
 272   ;; support @documentencoding, so hack it in.
 273   (when (and (not (featurep 'xemacs))
 274              (eq emacs-major-version 21))
 275     (put 'documentencoding 'texinfo-format
 276          'texinfo-discard-line-with-args))
 277   (muse-publish-transform-output
 278    file output-path final-target "Info"
 279    (function
 280     (lambda (file output-path)
 281       (if muse-texinfo-process-natively
 282           (save-window-excursion
 283             (save-excursion
 284               (find-file file)
 285               (let ((inhibit-read-only t))
 286                 (texinfo-format-buffer))
 287               (save-buffer)
 288               (kill-buffer (current-buffer))
 289               (let ((buf (get-file-buffer file)))
 290                 (with-current-buffer buf
 291                   (set-buffer-modified-p nil)
 292                   (kill-buffer (current-buffer))))
 293               t))
 294         (= 0 (shell-command
 295               (concat "makeinfo --enable-encoding --output="
 296                       output-path " " file))))))))
 297
 298 (defun muse-texinfo-pdf-generate (file output-path final-target)
 299   (let ((muse-latex-pdf-program "pdftex")
 300         (muse-latex-pdf-cruft '(".aux" ".cp" ".fn" ".ky" ".log" ".pg" ".toc"
 301                                 ".tp" ".vr")))
 302     (muse-latex-pdf-generate file output-path final-target)))
 303
 304 ;;; Register the Muse TEXINFO Publishers
 305
 306 (muse-define-style "texi"
 307                    :suffix    'muse-texinfo-extension
 308                    :regexps   'muse-texinfo-markup-regexps
 309                    :functions 'muse-texinfo-markup-functions
 310                    :strings   'muse-texinfo-markup-strings
 311                    :specials  'muse-texinfo-decide-specials
 312                    :after     'muse-texinfo-munge-buffer
 313                    :header    'muse-texinfo-header
 314                    :footer    'muse-texinfo-footer
 315                    :browser   'find-file)
 316
 317 (muse-derive-style "info" "texi"
 318                    :final   'muse-texinfo-info-generate
 319                    :link-suffix 'muse-texinfo-info-extension
 320                    :osuffix 'muse-texinfo-info-extension
 321                    :browser 'info)
 322
 323 (muse-derive-style "info-pdf" "texi"
 324                    :final   'muse-texinfo-pdf-generate
 325                    :link-suffix 'muse-texinfo-pdf-extension
 326                    :osuffix 'muse-texinfo-pdf-extension
 327                    :browser 'muse-texinfo-pdf-browse-file)
 328
 329 (provide 'muse-texinfo)
 330
 331 ;;; muse-texinfo.el ends here