lisp/muse-html.el

   1 ;;; muse-html.el --- publish to HTML and XHTML
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;; Zhiqiang Ye (yezq AT mail DOT cbi DOT pku DOT edu DOT cn) suggested
  27 ;; appending an 'encoding="..."' fragment to the first line of the
  28 ;; sample publishing header so that when editing the resulting XHTML
  29 ;; file, Emacs would use the proper encoding.
  30
  31 ;; Sun Jiyang (sunyijiang AT gmail DOT com) came up with the idea for
  32 ;; the <src> tag and provided an implementation for emacs-wiki.
  33
  34 ;; Charles Wang (wcy123 AT gmail DOT com) provided an initial
  35 ;; implementation of the <src> tag for Muse.
  36
  37 ;; Clinton Ebadi (clinton AT unknownlamer DOT org) provided further
  38 ;; ideas for the implementation of the <src> tag.
  39
  40 ;;; Code:
  41
  42 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43 ;;
  44 ;; Muse HTML Publishing
  45 ;;
  46 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  47
  48 (require 'muse-publish)
  49 (require 'muse-regexps)
  50 (require 'muse-xml-common)
  51
  52 (defgroup muse-html nil
  53   "Options controlling the behavior of Muse HTML publishing."
  54   :group 'muse-publish)
  55
  56 (defcustom muse-html-extension ".html"
  57   "Default file extension for publishing HTML files."
  58   :type 'string
  59   :group 'muse-html)
  60
  61 (defcustom muse-xhtml-extension ".html"
  62   "Default file extension for publishing XHTML files."
  63   :type 'string
  64   :group 'muse-html)
  65
  66 (defcustom muse-html-style-sheet
  67   "<style type=\"text/css\">
  68 body {
  69   background: white; color: black;
  70   margin-left: 3%; margin-right: 7%;
  71 }
  72
  73 p { margin-top: 1% }
  74 p.verse { margin-left: 3% }
  75
  76 .example { margin-left: 3% }
  77
  78 h2 {
  79   margin-top: 25px;
  80   margin-bottom: 0px;
  81 }
  82 h3 { margin-bottom: 0px; }
  83     </style>"
  84   "Store your stylesheet definitions here.
  85 This is used in `muse-html-header'.
  86 You can put raw CSS in here or a <link> tag to an external stylesheet.
  87 This text may contain <lisp> markup tags.
  88
  89 An example of using <link> is as follows.
  90
  91 <link rel=\"stylesheet\" type=\"text/css\" charset=\"utf-8\" media=\"all\" href=\"/default.css\">"
  92   :type 'string
  93   :group 'muse-html)
  94
  95 (defcustom muse-xhtml-style-sheet
  96   "<style type=\"text/css\">
  97 body {
  98   background: white; color: black;
  99   margin-left: 3%; margin-right: 7%;
 100 }
 101
 102 p { margin-top: 1% }
 103 p.verse { margin-left: 3% }
 104
 105 .example { margin-left: 3% }
 106
 107 h2 {
 108   margin-top: 25px;
 109   margin-bottom: 0px;
 110 }
 111 h3 { margin-bottom: 0px; }
 112     </style>"
 113   "Store your stylesheet definitions here.
 114 This is used in `muse-xhtml-header'.
 115 You can put raw CSS in here or a <link> tag to an external stylesheet.
 116 This text may contain <lisp> markup tags.
 117
 118 An example of using <link> is as follows.
 119
 120 <link rel=\"stylesheet\" type=\"text/css\" charset=\"utf-8\" media=\"all\" href=\"/default.css\" />"
 121   :type 'string
 122   :group 'muse-html)
 123
 124 (defcustom muse-html-header
 125   "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.0 Transitional//EN\">
 126 <html>
 127   <head>
 128     <title><lisp>
 129   (concat (muse-publishing-directive \"title\")
 130           (let ((author (muse-publishing-directive \"author\")))
 131             (if (not (string= author (user-full-name)))
 132                 (concat \" (by \" author \")\"))))</lisp></title>
 133     <meta name=\"generator\" content=\"muse.el\">
 134     <meta http-equiv=\"<lisp>muse-html-meta-http-equiv</lisp>\"
 135           content=\"<lisp>muse-html-meta-content-type</lisp>\">
 136     <lisp>
 137       (let ((maintainer (muse-style-element :maintainer)))
 138         (when maintainer
 139           (concat \"<link rev=\\\"made\\\" href=\\\"\" maintainer \"\\\">\")))
 140     </lisp><lisp>
 141       (muse-style-element :style-sheet muse-publishing-current-style)
 142     </lisp>
 143   </head>
 144   <body>
 145     <h1><lisp>
 146   (concat (muse-publishing-directive \"title\")
 147           (let ((author (muse-publishing-directive \"author\")))
 148             (if (not (string= author (user-full-name)))
 149                 (concat \" (by \" author \")\"))))</lisp></h1>
 150     <!-- Page published by Emacs Muse begins here -->\n"
 151   "Header used for publishing HTML files.  This may be text or a filename."
 152   :type 'string
 153   :group 'muse-html)
 154
 155 (defcustom muse-html-footer "
 156 <!-- Page published by Emacs Muse ends here -->
 157   </body>
 158 </html>\n"
 159   "Footer used for publishing HTML files.  This may be text or a filename."
 160   :type 'string
 161   :group 'muse-html)
 162
 163 (defcustom muse-xhtml-header
 164   "<?xml version=\"1.0\" encoding=\"<lisp>
 165   (muse-html-encoding)</lisp>\"?>
 166 <!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\"
 167     \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">
 168 <html xmlns=\"http://www.w3.org/1999/xhtml\">
 169   <head>
 170     <title><lisp>
 171   (concat (muse-publishing-directive \"title\")
 172           (let ((author (muse-publishing-directive \"author\")))
 173             (if (not (string= author (user-full-name)))
 174                 (concat \" (by \" author \")\"))))</lisp></title>
 175     <meta name=\"generator\" content=\"muse.el\" />
 176     <meta http-equiv=\"<lisp>muse-html-meta-http-equiv</lisp>\"
 177           content=\"<lisp>muse-html-meta-content-type</lisp>\" />
 178     <lisp>
 179       (let ((maintainer (muse-style-element :maintainer)))
 180         (when maintainer
 181           (concat \"<link rev=\\\"made\\\" href=\\\"\" maintainer \"\\\" />\")))
 182     </lisp><lisp>
 183       (muse-style-element :style-sheet muse-publishing-current-style)
 184     </lisp>
 185   </head>
 186   <body>
 187     <h1><lisp>
 188   (concat (muse-publishing-directive \"title\")
 189           (let ((author (muse-publishing-directive \"author\")))
 190             (if (not (string= author (user-full-name)))
 191                 (concat \" (by \" author \")\"))))</lisp></h1>
 192     <!-- Page published by Emacs Muse begins here -->\n"
 193   "Header used for publishing XHTML files.  This may be text or a filename."
 194   :type 'string
 195   :group 'muse-html)
 196
 197 (defcustom muse-xhtml-footer "
 198 <!-- Page published by Emacs Muse ends here -->
 199   </body>
 200 </html>\n"
 201   "Footer used for publishing XHTML files.  This may be text or a filename."
 202   :type 'string
 203   :group 'muse-html)
 204
 205 (defcustom muse-html-anchor-on-word nil
 206   "When true, anchors surround the closest word. This allows you
 207 to select them in a browser (i.e. for pasting), but has the
 208 side-effect of marking up headers in multiple colors if your
 209 header style is different from your link style."
 210   :type 'boolean
 211   :group 'muse-html)
 212
 213 (defcustom muse-html-table-attributes
 214   " class=\"muse-table\" border=\"2\" cellpadding=\"5\""
 215   "The attribute to be used with HTML <table> tags.
 216 Note that since Muse supports insertion of raw HTML tags, as long
 217 as you wrap the region in <literal></literal>."
 218   :type 'string
 219   :group 'muse-html)
 220
 221 (defcustom muse-html-markup-regexps
 222   `(;; Beginning of doc, end of doc, or plain paragraph separator
 223     (10000 ,(concat "\\(\\(\n\\(?:[" muse-regexp-blank "]*\n\\)*"
 224                     "\\([" muse-regexp-blank "]*\n\\)\\)"
 225                     "\\|\\`\\s-*\\|\\s-*\\'\\)")
 226            ;; this is somewhat repetitive because we only require the
 227            ;; line just before the paragraph beginning to be not
 228            ;; read-only
 229            3 muse-html-markup-paragraph))
 230   "List of markup rules for publishing a Muse page to HTML.
 231 For more on the structure of this list, see `muse-publish-markup-regexps'."
 232   :type '(repeat (choice
 233                   (list :tag "Markup rule"
 234                         integer
 235                         (choice regexp symbol)
 236                         integer
 237                         (choice string function symbol))
 238                   function))
 239   :group 'muse-html)
 240
 241 (defcustom muse-html-markup-functions
 242   '((anchor   . muse-html-markup-anchor)
 243     (table    . muse-html-markup-table)
 244     (footnote . muse-html-markup-footnote))
 245   "An alist of style types to custom functions for that kind of text.
 246 For more on the structure of this list, see
 247 `muse-publish-markup-functions'."
 248   :type '(alist :key-type symbol :value-type function)
 249   :group 'muse-html)
 250
 251 (defcustom muse-html-markup-strings
 252   '((image-with-desc . "<table class=\"image\" width=\"100%%\">
 253   <tr><td align=\"center\"><img src=\"%1%.%2%\" alt=\"%3%\"></td></tr>
 254   <tr><td align=\"center\" class=\"image-caption\">%3%</td></tr>
 255 </table>")
 256     (image           . "<img src=\"%s.%s\" alt=\"\">")
 257     (image-link      . "<a class=\"image-link\" href=\"%s\">
 258 <img src=\"%s.%s\"></a>")
 259     (anchor-ref      . "<a href=\"#%s\">%s</a>")
 260     (url             . "<a href=\"%s\">%s</a>")
 261     (link            . "<a href=\"%s\">%s</a>")
 262     (link-and-anchor . "<a href=\"%s#%s\">%s</a>")
 263     (email-addr      . "<a href=\"mailto:%s\">%s</a>")
 264     (emdash          . "%s&mdash;%s")
 265     (comment-begin   . "<!-- ")
 266     (comment-end     . " -->")
 267     (rule            . "<hr>")
 268     (fn-sep          . "<hr>\n")
 269     (no-break-space  . "&nbsp;")
 270     (enddots         . "....")
 271     (dots            . "...")
 272     (section         . "<h2>")
 273     (section-end     . "</h2>")
 274     (subsection      . "<h3>")
 275     (subsection-end  . "</h3>")
 276     (subsubsection   . "<h4>")
 277     (subsubsection-end . "</h4>")
 278     (section-other   . "<h5>")
 279     (section-other-end . "</h5>")
 280     (begin-underline . "<u>")
 281     (end-underline   . "</u>")
 282     (begin-literal   . "<code>")
 283     (end-literal     . "</code>")
 284     (begin-emph      . "<em>")
 285     (end-emph        . "</em>")
 286     (begin-more-emph . "<strong>")
 287     (end-more-emph   . "</strong>")
 288     (begin-most-emph . "<strong><em>")
 289     (end-most-emph   . "</em></strong>")
 290     (begin-verse     . "<p class=\"verse\">\n")
 291     (verse-space     . "&nbsp;&nbsp;")
 292     (end-verse-line  . "<br>")
 293     (end-last-stanza-line . "<br>")
 294     (empty-verse-line . "<br>")
 295     (end-verse       . "</p>")
 296     (begin-example   . "<pre class=\"example\">")
 297     (end-example     . "</pre>")
 298     (begin-center    . "<center>\n<p>")
 299     (end-center      . "</p>\n</center>")
 300     (begin-quote     . "<blockquote>\n")
 301     (end-quote       . "\n</blockquote>")
 302     (begin-quote-item . "<p class=\"quoted\">")
 303     (end-quote-item  . "</p>")
 304     (begin-uli       . "<ul>\n")
 305     (end-uli         . "\n</ul>")
 306     (begin-uli-item  . "<li>")
 307     (end-uli-item    . "</li>")
 308     (begin-oli       . "<ol>\n")
 309     (end-oli         . "\n</ol>")
 310     (begin-oli-item  . "<li>")
 311     (end-oli-item    . "</li>")
 312     (begin-dl        . "<dl>\n")
 313     (end-dl          . "\n</dl>")
 314     (begin-ddt       . "<dt><strong>")
 315     (end-ddt         . "</strong></dt>")
 316     (begin-dde       . "<dd>")
 317     (end-dde         . "</dd>")
 318     (begin-table     . "<table%s>\n")
 319     (end-table       . "</table>")
 320     (begin-table-row . "    <tr>\n")
 321     (end-table-row   . "    </tr>\n")
 322     (begin-table-entry . "      <%s>")
 323     (end-table-entry . "</%s>\n"))
 324   "Strings used for marking up text as HTML.
 325 These cover the most basic kinds of markup, the handling of which
 326 differs little between the various styles."
 327   :type '(alist :key-type symbol :value-type string)
 328   :group 'muse-html)
 329
 330 (defcustom muse-xhtml-markup-strings
 331   '((image-with-desc . "<table class=\"image\" width=\"100%%\">
 332   <tr><td align=\"center\"><img src=\"%1%.%2%\" alt=\"%3%\" /></td></tr>
 333   <tr><td align=\"center\" class=\"image-caption\">%3%</td></tr>
 334 </table>")
 335     (image           . "<img src=\"%s.%s\" alt=\"\" />")
 336     (image-link      . "<a class=\"image-link\" href=\"%s\">
 337 <img src=\"%s.%s\" alt=\"\" /></a>")
 338     (rule            . "<hr />")
 339     (fn-sep          . "<hr />\n")
 340     (begin-underline . "<span style=\"text-decoration: underline;\">")
 341     (end-underline   . "</span>")
 342     (begin-center    . "<p style=\"text-align: center;\">\n")
 343     (end-center      . "\n</p>")
 344     (end-verse-line  . "<br />")
 345     (end-last-stanza-line . "<br />")
 346     (empty-verse-line . "<br />"))
 347   "Strings used for marking up text as XHTML.
 348 These cover the most basic kinds of markup, the handling of which
 349 differs little between the various styles.
 350
 351 If a markup rule is not found here, `muse-html-markup-strings' is
 352 searched."
 353   :type '(alist :key-type symbol :value-type string)
 354   :group 'muse-html)
 355
 356 (defcustom muse-html-markup-tags
 357   '(("class" t t   t muse-html-class-tag)
 358     ("src"   t t nil muse-html-src-tag))
 359  "A list of tag specifications, for specially marking up HTML."
 360   :type '(repeat (list (string :tag "Markup tag")
 361                        (boolean :tag "Expect closing tag" :value t)
 362                        (boolean :tag "Parse attributes" :value nil)
 363                        (boolean :tag "Nestable" :value nil)
 364                        function))
 365   :group 'muse-html)
 366
 367 (defcustom muse-html-meta-http-equiv "Content-Type"
 368   "The http-equiv attribute used for the HTML <meta> tag."
 369   :type 'string
 370   :group 'muse-html)
 371
 372 (defcustom muse-html-meta-content-type "text/html"
 373   "The content type used for the HTML <meta> tag.
 374 If you are striving for XHTML 1.1 compliance, you may want to
 375 change this to \"application/xhtml+xml\"."
 376   :type 'string
 377   :group 'muse-html)
 378
 379 (defcustom muse-html-meta-content-encoding (if (featurep 'mule)
 380                                               'detect
 381                                             "iso-8859-1")
 382   "The charset to append to the HTML <meta> tag.
 383 If set to the symbol 'detect, use `muse-html-encoding-map' to try
 384 and determine the HTML charset from emacs's coding.  If set to a
 385 string, this string will be used to force a particular charset"
 386   :type '(choice string symbol)
 387   :group 'muse-html)
 388
 389 (defcustom muse-html-encoding-default 'iso-8859-1
 390   "The default Emacs buffer encoding to use in published files.
 391 This will be used if no special characters are found."
 392   :type 'symbol
 393   :group 'muse-html)
 394
 395 (defcustom muse-html-charset-default "iso-8859-1"
 396   "The default HTML meta charset to use if no translation is found in
 397 `muse-html-encoding-map'."
 398   :type 'string
 399   :group 'muse-html)
 400
 401 (defun muse-html-insert-anchor (anchor)
 402   "Insert an anchor, either around the word at point, or within a tag."
 403   (skip-chars-forward (concat muse-regexp-blank "\n"))
 404   (if (looking-at (concat "<\\([^" muse-regexp-blank "/>\n]+\\)>"))
 405       (let ((tag (match-string 1)))
 406         (goto-char (match-end 0))
 407         (muse-insert-markup "<a name=\"" anchor "\" id=\"" anchor "\">")
 408         (when muse-html-anchor-on-word
 409           (or (and (search-forward (format "</%s>" tag)
 410                                    (muse-line-end-position) t)
 411                    (goto-char (match-beginning 0)))
 412               (forward-word 1)))
 413         (muse-insert-markup "</a>"))
 414     (muse-insert-markup "<a name=\"" anchor "\" id=\"" anchor "\">")
 415     (when muse-html-anchor-on-word
 416       (forward-word 1))
 417     (muse-insert-markup "</a>\n")))
 418
 419 (defun muse-html-markup-anchor ()
 420   (unless (get-text-property (match-end 1) 'muse-link)
 421     (save-match-data
 422       (muse-html-insert-anchor (match-string 2)))
 423     (match-string 1)))
 424
 425 (defun muse-html-markup-paragraph ()
 426   (let ((end (copy-marker (match-end 0) t)))
 427     (goto-char (match-beginning 0))
 428     (when (save-excursion
 429             (save-match-data
 430               (and (re-search-backward "<\\(/?\\)p[ >]" nil t)
 431                    (not (string-equal (match-string 1) "/")))))
 432       (when (get-text-property (1- (point)) 'end-list)
 433         (goto-char (previous-single-property-change (1- (point)) 'end-list)))
 434       (muse-insert-markup "</p>"))
 435     (goto-char end))
 436   (cond
 437    ((eobp)
 438     (unless (bolp)
 439       (insert "\n")))
 440    ((eq (char-after) ?\<)
 441     (cond
 442      ((looking-at "<\\(em\\|strong\\|code\\|span\\)[ >]")
 443       (muse-insert-markup "<p>"))
 444      ((looking-at "<a ")
 445       (if (looking-at "<a[^>\n]+><img")
 446           (muse-insert-markup "<p class=\"image-link\">")
 447         (muse-insert-markup "<p>")))
 448      ((looking-at "<img[ >]")
 449       (muse-insert-markup "<p class=\"image\">"))
 450      (t
 451       (forward-char 1)
 452       nil)))
 453    ((muse-looking-back "\\(</h[1-4]>\\|<hr>\\)\n\n")
 454     (muse-insert-markup "<p class=\"first\">"))
 455    (t
 456     (muse-insert-markup "<p>"))))
 457
 458 (defun muse-html-markup-footnote ()
 459   (cond
 460    ((get-text-property (match-beginning 0) 'muse-link)
 461     nil)
 462    ((= (muse-line-beginning-position) (match-beginning 0))
 463     (prog1
 464         (let ((text (match-string 1)))
 465           (muse-insert-markup
 466            (concat "<p class=\"footnote\">"
 467                    "<a name=\"fn." text "\" href=\"#fnr." text "\">"
 468                    text ".</a>")))
 469       (save-excursion
 470         (save-match-data
 471           (let* ((beg (goto-char (match-end 0)))
 472                  (end (and (search-forward "\n\n" nil t)
 473                            (prog1
 474                                (copy-marker (match-beginning 0))
 475                              (goto-char beg)))))
 476             (while (re-search-forward (concat "^["
 477                                               muse-regexp-blank
 478                                               "]+\\([^\n]\\)")
 479                                       end t)
 480               (replace-match "\\1" t)))))
 481       (replace-match "")))
 482    (t (let ((text (match-string 1)))
 483         (muse-insert-markup
 484          (concat "<sup><a name=\"fnr." text "\" href=\"#fn." text "\">"
 485                  text "</a></sup>")))
 486       (replace-match ""))))
 487
 488 (defun muse-html-markup-table ()
 489   (muse-xml-markup-table muse-html-table-attributes))
 490
 491 ;; Handling of tags for HTML
 492
 493 (defun muse-html-insert-contents (depth)
 494   (let ((max-depth (or depth 2))
 495         (index 1)
 496         base contents l)
 497     (save-excursion
 498       (goto-char (point-min))
 499       (search-forward "Page published by Emacs Muse begins here" nil t)
 500       (catch 'done
 501         (while (re-search-forward "<h\\([0-9]+\\)>\\(.+?\\)</h\\1>$" nil t)
 502           (unless (get-text-property (point) 'read-only)
 503             (setq l (1- (string-to-number (match-string 1))))
 504             (if (null base)
 505                 (setq base l)
 506               (if (< l base)
 507                   (throw 'done t)))
 508             (when (<= l max-depth)
 509               (setq contents (cons (cons l (muse-match-string-no-properties 2))
 510                                    contents))
 511               (goto-char (match-beginning 2))
 512               (muse-html-insert-anchor (concat "sec" (int-to-string index)))
 513               (setq index (1+ index)))))))
 514     (setq index 1 contents (nreverse contents))
 515     (let ((depth 1) (sub-open 0) (p (point)))
 516       (muse-insert-markup "<div class=\"contents\">\n<dl>\n")
 517       (while contents
 518         (muse-insert-markup "<dt>\n"
 519                             "<a href=\"#sec" (int-to-string index) "\">"
 520                             (muse-publish-strip-tags (cdar contents))
 521                             "</a>\n"
 522                             "</dt>\n")
 523         (setq index (1+ index)
 524               depth (caar contents)
 525               contents (cdr contents))
 526         (when contents
 527           (cond
 528            ((< (caar contents) depth)
 529             (let ((idx (caar contents)))
 530               (while (< idx depth)
 531                 (muse-insert-markup "</dl>\n</dd>\n")
 532                 (setq sub-open (1- sub-open)
 533                       idx (1+ idx)))))
 534            ((> (caar contents) depth) ; can't jump more than one ahead
 535             (muse-insert-markup "<dd>\n<dl>\n")
 536             (setq sub-open (1+ sub-open))))))
 537       (while (> sub-open 0)
 538         (muse-insert-markup "</dl>\n</dd>\n")
 539         (setq sub-open (1- sub-open)))
 540       (muse-insert-markup "</dl>\n</div>\n")
 541       (muse-publish-mark-read-only p (point)))))
 542
 543 (defun muse-html-class-tag (beg end attrs)
 544   (goto-char beg)
 545   (muse-insert-markup "<span class=\"" (cdr (assoc "name" attrs)) "\">")
 546   (goto-char end)
 547   (muse-insert-markup "</span>"))
 548
 549 (defun muse-html-src-tag (beg end attrs)
 550   "Publish the region using htmlize.
 551 The language to use may be specified by the \"lang\" attribute.
 552
 553 Muse will look for a function named LANG-mode, where LANG is the
 554 value of the \"lang\" attribute.
 555
 556 This tag requires htmlize 1.34 or later in order to work."
 557   (if (condition-case nil
 558           (progn
 559             (require 'htmlize)
 560             (if (fboundp 'htmlize-region-for-paste)
 561                 nil
 562               (muse-display-warning
 563                (concat "The `htmlize-region-for-paste' function was not"
 564                        " found.\nThis is available in htmlize.el 1.34"
 565                        " or later."))
 566               t))
 567         (error nil t))
 568       ;; if htmlize.el was not found, treat this like an example tag
 569       (muse-publish-example-tag beg end)
 570     (let* ((mode (and (assoc "lang" attrs)
 571                       (intern (concat (cdr (assoc "lang" attrs))
 572                                       "-mode"))))
 573            (text (delete-and-extract-region beg end))
 574            (htmltext
 575             (with-temp-buffer
 576               (insert text)
 577               (if (functionp mode)
 578                   (funcall mode)
 579                 (fundamental-mode))
 580               (font-lock-fontify-buffer)
 581               ;; silence the byte-compiler
 582               (when (fboundp 'htmlize-region-for-paste)
 583                 ;; transform the region to HTML
 584                 (htmlize-region-for-paste (point-min) (point-max))))))
 585       (save-restriction
 586         (narrow-to-region (point) (point))
 587         (insert htmltext)
 588         (goto-char (point-min))
 589         (re-search-forward "<pre\\([^>]*\\)>" nil t)
 590         (replace-match " class=\"src\"" t t nil 1)
 591         (goto-char (point-max))
 592         (muse-publish-mark-read-only (point-min) (point-max))))))
 593
 594 ;; Register the Muse HTML Publisher
 595
 596 (defun muse-html-browse-file (file)
 597   (browse-url (concat "file:" file)))
 598
 599 (defun muse-html-encoding ()
 600   (if (stringp muse-html-meta-content-encoding)
 601       muse-html-meta-content-encoding
 602     (muse-xml-transform-content-type
 603      (or (and (boundp 'buffer-file-coding-system)
 604               buffer-file-coding-system)
 605          muse-html-encoding-default)
 606      muse-html-charset-default)))
 607
 608 (defun muse-html-prepare-buffer ()
 609   (make-local-variable 'muse-html-meta-http-equiv)
 610   (set (make-local-variable 'muse-html-meta-content-type)
 611        (if (save-match-data
 612              (string-match "charset=" muse-html-meta-content-type))
 613            muse-html-meta-content-type
 614          (concat muse-html-meta-content-type "; charset="
 615                  (muse-html-encoding)))))
 616
 617 (defun muse-html-munge-buffer ()
 618   (when muse-publish-generate-contents
 619     (goto-char (car muse-publish-generate-contents))
 620     (muse-html-insert-contents (cdr muse-publish-generate-contents))
 621     (setq muse-publish-generate-contents nil)))
 622
 623 (defun muse-html-finalize-buffer ()
 624   (when (and (boundp 'buffer-file-coding-system)
 625              (memq buffer-file-coding-system '(no-conversion undecided-unix)))
 626     ;; make it agree with the default charset
 627     (setq buffer-file-coding-system muse-html-encoding-default)))
 628
 629 ;;; Register the Muse HTML and XHTML Publishers
 630
 631 (muse-define-style "html"
 632                    :suffix    'muse-html-extension
 633                    :regexps   'muse-html-markup-regexps
 634                    :functions 'muse-html-markup-functions
 635                    :strings   'muse-html-markup-strings
 636                    :tags      'muse-html-markup-tags
 637                    :specials  'muse-xml-decide-specials
 638                    :before    'muse-html-prepare-buffer
 639                    :before-end 'muse-html-munge-buffer
 640                    :after     'muse-html-finalize-buffer
 641                    :header    'muse-html-header
 642                    :footer    'muse-html-footer
 643                    :style-sheet 'muse-html-style-sheet
 644                    :browser   'muse-html-browse-file)
 645
 646 (muse-derive-style "xhtml" "html"
 647                    :suffix    'muse-xhtml-extension
 648                    :strings   'muse-xhtml-markup-strings
 649                    :header    'muse-xhtml-header
 650                    :footer    'muse-xhtml-footer
 651                    :style-sheet 'muse-xhtml-style-sheet)
 652
 653 (provide 'muse-html)
 654
 655 ;;; muse-html.el ends here