lisp/muse-publish.el

   1 ;;; muse-publish.el --- base publishing implementation
   2
   3 ;; Copyright (C) 2004, 2005, 2006  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;; Yann Hodique (yann DOT hodique AT gmail DOT com) fixed an
  27 ;; unnecessary URL description transform in `muse-publish-url'.
  28 ;;
  29 ;; Peter K. Lee (saint AT corenova DOT com) provided the
  30 ;; `muse-style-elements-list' function.
  31 ;;
  32 ;; Jim Ottaway (j DOT ottaway AT lse DOT ac DOT uk) provided an
  33 ;; implementation for nested lists.
  34
  35 ;;; Code:
  36
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38 ;;
  39 ;; Muse Publishing
  40 ;;
  41 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  42
  43 (require 'muse)
  44 (require 'muse-regexps)
  45
  46 (defgroup muse-publish nil
  47   "Options controlling the general behavior of Muse publishing."
  48   :group 'muse)
  49
  50 (defcustom muse-before-publish-hook nil
  51   "A hook run in the buffer to be published, before it is done."
  52   :type 'hook
  53   :group 'muse-publish)
  54
  55 (defcustom muse-after-publish-hook nil
  56   "A hook run in the buffer to be published, after it is done."
  57   :type 'hook
  58   :group 'muse-publish)
  59
  60 (defcustom muse-publish-url-transforms
  61   '(muse-resolve-url)
  62   "A list of functions used to prepare URLs for publication.
  63 Each is passed the URL.  The transformed URL should be returned."
  64   :type 'hook
  65   :options '(muse-resolve-url)
  66   :group 'muse-publish)
  67
  68 (defcustom muse-publish-desc-transforms nil
  69   "A list of functions used to prepare URL desciptions for publication.
  70 Each is passed the description.  The modified description should
  71 be returned."
  72   :type 'hook
  73   :group 'muse-publish)
  74
  75 (defcustom muse-publish-comments-p nil
  76   "If nil, remove comments before publishing.
  77 If non-nil, publish comments using the markup of the current style."
  78   :type 'boolean
  79   :group 'muse-publish)
  80
  81 (defcustom muse-publish-report-threshhold 100000
  82   "If a file is this size or larger, report publishing progress."
  83   :type 'integer
  84   :group 'muse-publish)
  85
  86 (defcustom muse-publish-markup-regexps
  87   `(;; Remove leading and trailing whitespace from the file
  88     (1000 "\\(\\`\n+\\|\n+\\'\\)" 0 "")
  89
  90     ;; Remove trailing whitespace from all lines
  91     (1100 ,(concat "[" muse-regexp-blank "]+$") 0 "")
  92
  93     ;; Handle any leading #directives
  94     (1200 "\\`#\\([a-zA-Z-]+\\)\\s-+\\(.+\\)\n+" 0 directive)
  95
  96     ;; markup tags
  97     (1300 muse-tag-regexp 0 tag)
  98
  99     ;; commented lines
 100     (1350 "^;\\s-+\\(.+\\)" 0 comment)
 101
 102     ;; prevent emphasis characters in explicit links from being marked
 103     (1400 muse-explicit-link-regexp 0 muse-publish-mark-noemphasis)
 104
 105     ;; define anchor points
 106     (1500 "^\\(\\W*\\)#\\(\\S-+\\)\\s-*" 0 anchor)
 107
 108     ;; emphasized or literal text
 109     (1600 ,(concat "\\(^\\|[-[" muse-regexp-blank
 110                    "<('`\"\n]\\)\\(=[^=" muse-regexp-blank
 111                    "\n]\\|_[^_" muse-regexp-blank
 112                    "\n]\\|\\*+[^*" muse-regexp-blank
 113                    "\n]\\)")
 114           2 word)
 115
 116     ;; headings, outline-mode style
 117     (1700 "^\\(\\*+\\)\\s-+" 0 heading)
 118
 119     ;; ellipses
 120     (1800 "\\.\\.\\.\\." 0 enddots)
 121     (1850 "\\.\\.\\." 0 dots)
 122
 123     ;; horizontal rule, or section separator
 124     (1900 "^----+" 0 rule)
 125
 126     ;; non-breaking space
 127     (1950 "~~" 0 no-break-space)
 128
 129     ;; beginning of footnotes section
 130     (2000 "^Footnotes:?\\s-*" 0 fn-sep)
 131     ;; footnote definition/reference (def if at beginning of line)
 132     (2100 "\\[\\([1-9][0-9]*\\)\\]" 0 footnote)
 133
 134     ;; unnumbered List items begin with a -.  numbered list items
 135     ;; begin with number and a period.  definition lists have a
 136     ;; leading term separated from the body with ::.  centered
 137     ;; paragraphs begin with at least six columns of whitespace; any
 138     ;; other whitespace at the beginning indicates a blockquote.  The
 139     ;; reason all of these rules are handled here, is so that
 140     ;; blockquote detection doesn't interfere with indented list
 141     ;; members.
 142
 143     (2200 ,(format muse-list-item-regexp (concat "[" muse-regexp-blank "]*"))
 144           0 list)
 145
 146     (2400 ,(concat "^\\([" muse-regexp-blank "]+\\).+") 0 quote)
 147
 148     (2500 ,(concat "\\(^\\|[" muse-regexp-blank "]+\\)--\\($\\|["
 149                    muse-regexp-blank "]+\\)")
 150           0 emdash)
 151
 152     ;; "verse" text is indicated the same way as a quoted e-mail
 153     ;; response: "> text", where text may contain initial whitespace
 154     ;; (see below).
 155     (2600 ,(concat "^[" muse-regexp-blank "]*> ") 0 verse)
 156
 157     ;; simple table markup is supported, nothing fancy.  use | to
 158     ;; separate cells, || to separate header cells, and ||| for footer
 159     ;; cells
 160     (2700 ,(concat "\\(\\([" muse-regexp-blank "]*\n\\)?"
 161                    "\\(" muse-table-line-regexp "\\(?:\n\\|\\'\\)\\)\\)+")
 162           0 table)
 163
 164     ;; replace links in the buffer (links to other pages)
 165     (2900 muse-explicit-link-regexp 0 link)
 166
 167     ;; bare URLs
 168     (3000 muse-url-regexp 0 url)
 169
 170     ;; bare email addresses
 171     (3500
 172      "\\([^[]\\)[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+" 0 email)
 173     )
 174   "List of markup rules for publishing a page with Muse.
 175 The rules given in this variable are invoked first, followed by
 176 whatever rules are specified by the current style.
 177
 178 Each member of the list is either a function, or a list of the form:
 179
 180   (REGEXP/SYMBOL TEXT-BEGIN-GROUP REPLACEMENT-TEXT/FUNCTION/SYMBOL)
 181
 182 REGEXP is a regular expression, or symbol whose value is a regular
 183 expression, which is searched for using `re-search-forward'.
 184 TEXT-BEGIN-GROUP is the matching group within that regexp which
 185 denotes the beginning of the actual text to be marked up.
 186 REPLACEMENT-TEXT is a string that will be passed to `replace-match'.
 187 If it is not a string, but a function, it will be called to determine
 188 what the replacement text should be (it must return a string).  If it
 189 is a symbol, the value of that symbol should be a string.
 190
 191 The replacements are done in order, one rule at a time.  Writing
 192 the regular expressions can be a tricky business.  Note that case
 193 is never ignored.  `case-fold-search' is always bound to nil
 194 while processing the markup rules."
 195   :type '(repeat (choice
 196                   (list :tag "Markup rule"
 197                         integer
 198                         (choice regexp symbol)
 199                         integer
 200                         (choice string function symbol))
 201                   function))
 202   :group 'muse-publish)
 203
 204 (defcustom muse-publish-markup-functions
 205   '((directive . muse-publish-markup-directive)
 206     (comment   . muse-publish-markup-comment)
 207     (anchor    . muse-publish-markup-anchor)
 208     (tag       . muse-publish-markup-tag)
 209     (word      . muse-publish-markup-word)
 210     (emdash    . muse-publish-markup-emdash)
 211     (enddots   . muse-publish-markup-enddots)
 212     (dots      . muse-publish-markup-dots)
 213     (rule      . muse-publish-markup-rule)
 214     (no-break-space . muse-publish-markup-no-break-space)
 215     (heading   . muse-publish-markup-heading)
 216     (footnote  . muse-publish-markup-footnote)
 217     (fn-sep    . muse-publish-markup-fn-sep)
 218     (list      . muse-publish-markup-list)
 219     (quote     . muse-publish-markup-quote)
 220     (verse     . muse-publish-markup-verse)
 221     (table     . muse-publish-markup-table)
 222     (email     . muse-publish-markup-email)
 223     (link      . muse-publish-markup-link)
 224     (url       . muse-publish-markup-url))
 225   "An alist of style types to custom functions for that kind of text.
 226
 227 Each member of the list is of the form:
 228
 229   (SYMBOL FUNCTION)
 230
 231 SYMBOL describes the type of text to associate with this rule.
 232 `muse-publish-markup-regexps' maps regexps to these symbols.
 233
 234 FUNCTION is the function to use to mark up this kind of rule if
 235 no suitable function is found through the :functions tag of the
 236 current style."
 237   :type '(alist :key-type symbol :value-type function)
 238   :group 'muse-publish)
 239
 240 (defcustom muse-publish-markup-tags
 241   '(("contents" nil t   muse-publish-contents-tag)
 242     ("verse"    t   nil muse-publish-verse-tag)
 243     ("example"  t   nil muse-publish-example-tag)
 244     ("code"     t   nil muse-publish-code-tag)
 245     ("quote"    t   nil muse-publish-quote-tag)
 246     ("literal"  t   nil muse-publish-mark-read-only)
 247     ("verbatim" t   nil muse-publish-verbatim-tag)
 248     ("lisp"     t   nil muse-publish-lisp-tag)
 249     ("class"    t   t   muse-publish-class-tag)
 250     ("command"  t   t   muse-publish-command-tag)
 251     ("comment"  t   nil muse-publish-comment-tag))
 252   "A list of tag specifications, for specially marking up text.
 253 XML-style tags are the best way to add custom markup to Muse.
 254 This is easily accomplished by customizing this list of markup tags.
 255
 256 For each entry, the name of the tag is given, whether it expects
 257 a closing tag and/or an optional set of attributes, and a
 258 function that performs whatever action is desired within the
 259 delimited region.
 260
 261 The tags themselves are deleted during publishing, before the
 262 function is called.  The function is called with three arguments,
 263 the beginning and end of the region surrounded by the tags.  If
 264 properties are allowed, they are passed as a third argument in
 265 the form of an alist.  The `end' argument to the function is
 266 always a marker.
 267
 268 Point is always at the beginning of the region within the tags, when
 269 the function is called.  Wherever point is when the function finishes
 270 is where tag markup will resume.
 271
 272 These tag rules are processed once at the beginning of markup, and
 273 once at the end, to catch any tags which may have been inserted
 274 in-between."
 275   :type '(repeat (list (string :tag "Markup tag")
 276                        (boolean :tag "Expect closing tag" :value t)
 277                        (boolean :tag "Parse attributes" :value nil)
 278                        function))
 279   :group 'muse-publish)
 280
 281 (defcustom muse-publish-markup-specials nil
 282   "A table of characters which must be represented specially."
 283   :type '(alist :key-type character :value-type string)
 284   :group 'muse-publish)
 285
 286 (defvar muse-publishing-p nil
 287   "Set to t while a page is being published.")
 288 (defvar muse-batch-publishing-p nil
 289   "Set to t while a page is being batch published.")
 290 (defvar muse-publishing-styles nil
 291   "The publishing styles that Muse recognizes.
 292 This is automatically generated when loading publishing styles.")
 293 (defvar muse-publishing-current-file nil
 294   "The file that is currently being published.")
 295 (defvar muse-publishing-current-output-path nil
 296   "The path where the current file will be published to.")
 297 (defvar muse-publishing-current-style nil
 298   "The style of the file that is currently being published.")
 299 (defvar muse-publishing-directives nil
 300   "An alist of publishing directives from the top of a file.")
 301 (defvar muse-publish-generate-contents nil
 302   "Non-nil if a table of contents should be generated.
 303 If non-nil, it is a cons cell specifying (MARKER . DEPTH), to
 304 tell where the <contents> was seen, and to what depth the
 305 contents were requested.")
 306 (defvar muse-publishing-last-position nil
 307   "Last position of the point when publishing.
 308 This is used to make sure that publishing doesn't get stalled.")
 309
 310 ;; Functions for handling style information
 311
 312 (defsubst muse-style (&optional style)
 313   "Resolve the given STYLE into a Muse style, if it is a string."
 314   (if (null style)
 315       muse-publishing-current-style
 316     (if (stringp style)
 317         (assoc style muse-publishing-styles)
 318       (muse-assert (consp style))
 319       style)))
 320
 321 (defun muse-define-style (name &rest elements)
 322   (let ((entry (assoc name muse-publishing-styles)))
 323     (if entry
 324         (error "There is already a style named %s." name)
 325       (setq muse-publishing-styles
 326             (cons (append (list name) elements)
 327                   muse-publishing-styles)))))
 328
 329 (defun muse-derive-style (new-name base-name &rest elements)
 330   (let ((entry (assoc new-name muse-publishing-styles)))
 331     (if entry
 332         (error "There is already a style named %s." new-name)
 333       (apply 'muse-define-style new-name
 334              (append elements (list :base base-name))))))
 335
 336 (defsubst muse-get-keyword (keyword list &optional direct)
 337   (let ((value (cadr (memq keyword list))))
 338     (if (and (not direct) (symbolp value))
 339         (symbol-value value)
 340       value)))
 341
 342 (defun muse-style-elements-list (elem &optional style)
 343   "Return a list all references to ELEM in STYLE, including base styles.
 344 If STYLE is not specified, use current style."
 345   (let (base elements)
 346     (while style
 347       (setq style (muse-style style))
 348       (setq elements (append elements
 349                              (muse-get-keyword elem style)))
 350       (setq style (muse-get-keyword :base style)))
 351     elements))
 352
 353 (defsubst muse-style-element (elem &optional style direct)
 354   "Search for ELEM in STYLE, including base styles.
 355 If STYLE is not specified, use current style."
 356   (setq style (muse-style style))
 357   (let ((value (muse-get-keyword elem style direct)))
 358     (if value
 359         value
 360       (let ((base (muse-get-keyword :base style)))
 361         (if base
 362             (muse-style-element elem base direct))))))
 363
 364 (defun muse-find-markup-element (keyword ident style)
 365   (let ((def (assq ident (muse-style-element keyword style))))
 366     (if def
 367         (cdr def)
 368       (let ((base (muse-style-element :base style)))
 369         (if base
 370             (muse-find-markup-element keyword ident base))))))
 371
 372 (defun muse-markup-text (ident &rest args)
 373   "Insert ARGS into the text markup associated with IDENT.
 374 If the markup text has sections like %N%, this will be replaced
 375 with the N-1th argument in ARGS.  After that, `format' is applied
 376 to the text with ARGS as parameters."
 377   (let ((text (muse-find-markup-element :strings ident (muse-style))))
 378     (if (and text args)
 379         (progn
 380           (let (start repl-text)
 381             (while (setq start (string-match "%\\([1-9][0-9]*\\)%" text start))
 382               ;; escape '%' in the argument text, since we will be
 383               ;; using format on it
 384               (setq repl-text (muse-replace-regexp-in-string
 385                                "%" "%%"
 386                                (nth (1- (string-to-number
 387                                          (match-string 1 text))) args)
 388                                t t)
 389                     start (+ start (length repl-text))
 390                     text (replace-match repl-text t t text))))
 391           (apply 'format text args))
 392       (or text ""))))
 393
 394 (defun muse-insert-markup (&rest args)
 395   (let ((beg (point)))
 396     (apply 'insert args)
 397     (muse-publish-mark-read-only beg (point))))
 398
 399 (defun muse-find-markup-tag (keyword tagname style)
 400   (let ((def (assoc tagname (muse-style-element keyword style))))
 401     (or def
 402         (let ((base (muse-style-element :base style)))
 403           (if base
 404               (muse-find-markup-tag keyword tagname base))))))
 405
 406 (defsubst muse-markup-tag-info (tagname &rest args)
 407   (let ((tag-info (muse-find-markup-tag :tags tagname (muse-style))))
 408     (or tag-info
 409         (assoc (match-string 1) muse-publish-markup-tags))))
 410
 411 (defsubst muse-markup-function (category)
 412   (let ((func (muse-find-markup-element :functions category (muse-style))))
 413     (or func
 414         (cdr (assq category muse-publish-markup-functions)))))
 415
 416 ;; Publishing routines
 417
 418 (defun muse-publish-markup (name rules)
 419   (let* ((case-fold-search nil)
 420          (inhibit-read-only t)
 421          (limit (* (length rules) (point-max)))
 422          (verbose (and muse-publish-report-threshhold
 423                        (> (point-max) muse-publish-report-threshhold)))
 424          (base 0))
 425     (while rules
 426       (goto-char (point-min))
 427       (let ((regexp (nth 1 (car rules)))
 428             (group (nth 2 (car rules)))
 429             (repl (nth 3 (car rules)))
 430             pos)
 431         (setq muse-publishing-last-position nil)
 432         (if (symbolp regexp)
 433             (setq regexp (symbol-value regexp)))
 434         (if (and verbose (not muse-batch-publishing-p))
 435             (message "Publishing %s...%d%%" name
 436                      (* (/ (float (+ (point) base)) limit) 100)))
 437         (while (and regexp (setq pos (re-search-forward regexp nil t)))
 438           (if (and verbose (not muse-batch-publishing-p))
 439               (message "Publishing %s...%d%%" name
 440                        (* (/ (float (+ (point) base)) limit) 100)))
 441           (unless (and (> (- (match-end 0) (match-beginning 0)) 0)
 442                        (get-text-property (match-beginning group) 'read-only))
 443             (let* (func
 444                    (text (cond
 445                           ((and (symbolp repl)
 446                                 (setq func (muse-markup-function repl)))
 447                            (funcall func))
 448                           ((functionp repl)
 449                            (funcall repl))
 450                           ((symbolp repl)
 451                            (symbol-value repl))
 452                           (t repl))))
 453               (if (stringp text)
 454                   (replace-match text t))))
 455           (if (and muse-publishing-last-position
 456                    (= pos muse-publishing-last-position))
 457               (if (eobp)
 458                   (setq regexp nil)
 459                 (forward-char 1)))
 460           (setq muse-publishing-last-position pos)))
 461       (setq rules (cdr rules)
 462             base (+ base (point-max))))
 463     (if (and verbose (not muse-batch-publishing-p))
 464         (message "Publishing %s...done" name))))
 465
 466 (defun muse-insert-file-or-string (file-or-string &optional title)
 467   (let ((beg (point)) end)
 468     (if (and (not (string-equal file-or-string ""))
 469              (file-readable-p file-or-string))
 470         (setq end (+ beg (cadr (insert-file-contents file-or-string))))
 471       (insert file-or-string)
 472       (setq end (point)))
 473     (save-restriction
 474       (narrow-to-region beg end)
 475       (remove-text-properties (point-min) (point-max)
 476                               '(read-only nil rear-nonsticky nil))
 477       (goto-char (point-min))
 478       (muse-publish-markup (or title "")
 479                            '((100 "<\\(lisp\\)>" 0
 480                               muse-publish-markup-tag))))))
 481
 482 (defun muse-style-run-hooks (keyword style &rest args)
 483   (let (handled)
 484     (while (and style (not handled))
 485       (setq style (muse-style style))
 486       (let ((func (muse-get-keyword keyword style t)))
 487         (if func
 488             (if (apply func args)
 489                 (setq handled t))))
 490       (unless handled
 491         (setq style (muse-style-element :base style))))
 492     handled))
 493
 494 (defun muse-publish-markup-region (beg end title style)
 495   "Apply the given STYLE's markup rules to the given region."
 496   (save-restriction
 497     (narrow-to-region beg end)
 498     (muse-style-run-hooks :before style)
 499     (muse-publish-markup
 500      title
 501      (sort (copy-alist (append muse-publish-markup-regexps
 502                                (muse-style-elements-list :regexps style)))
 503            (function
 504             (lambda (l r)
 505               (< (car l) (car r))))))
 506     (muse-style-run-hooks :before-end style)
 507     (muse-publish-escape-specials (point-min) (point-max) nil 'document)))
 508
 509 (defun muse-publish-markup-buffer (title style)
 510   "Apply the given STYLE's markup rules to the current buffer."
 511   (setq style (muse-style style))
 512   (let ((style-header (muse-style-element :header style))
 513         (style-footer (muse-style-element :footer style))
 514         (muse-publishing-current-style style)
 515         (muse-publishing-directives
 516          (list (cons "title" title)
 517                (cons "author" (user-full-name))
 518                (cons "date" (format-time-string
 519                              "%B %e, %Y"
 520                              (nth 5 (file-attributes
 521                                      muse-publishing-current-file))))))
 522         (muse-publishing-p t)
 523         (inhibit-read-only t))
 524     (run-hooks 'muse-before-publish-hook)
 525     (muse-publish-markup-region (point-min) (point-max) title style)
 526     (goto-char (point-min))
 527     (when style-header
 528       (muse-insert-file-or-string style-header title))
 529     (goto-char (point-max))
 530     (when style-footer
 531       (muse-insert-file-or-string style-footer title))
 532     (muse-style-run-hooks :after style)
 533     (run-hooks 'muse-after-publish-hook)))
 534
 535 (defun muse-publish-markup-string (string &optional style)
 536   "Markup STRING using the given STYLE's markup rules."
 537   (setq style (muse-style style))
 538   (muse-with-temp-buffer
 539     (insert string)
 540     (let ((muse-publishing-current-style style)
 541           (muse-publishing-p t))
 542       (muse-publish-markup "*string*" (muse-style-element :rules style)))
 543     (buffer-string)))
 544
 545 ;; Commands for publishing files
 546
 547 (defsubst muse-publish-get-style ()
 548   (if (= 1 (length muse-publishing-styles))
 549       (car muse-publishing-styles)
 550     (assoc (completing-read "Publish with style: "
 551                             muse-publishing-styles nil t)
 552            muse-publishing-styles)))
 553
 554 (defsubst muse-publish-get-output-dir (style)
 555   (let ((default-directory (or (muse-style-element :path style)
 556                                default-directory)))
 557     (muse-read-directory-name "Publish to directory: " nil default-directory)))
 558
 559 (defsubst muse-publish-get-info ()
 560   (let ((style (muse-publish-get-style)))
 561     (list style (muse-publish-get-output-dir style)
 562           current-prefix-arg)))
 563
 564 (defsubst muse-publish-output-name (&optional file style)
 565   (setq style (muse-style style))
 566   (concat (muse-style-element :prefix style)
 567           (muse-page-name file)
 568           (muse-style-element :suffix style)))
 569
 570 (defsubst muse-publish-output-file (file &optional output-dir style)
 571   (setq style (muse-style style))
 572   (if output-dir
 573       (expand-file-name (muse-publish-output-name file style) output-dir)
 574     (concat (file-name-directory file)
 575             (muse-publish-output-name file style))))
 576
 577 (defsubst muse-publish-link-name (&optional file style)
 578   (setq style (muse-style style))
 579   (concat (muse-style-element :prefix style)
 580           (muse-page-name file)
 581           (or (muse-style-element :link-suffix style)
 582               (muse-style-element :suffix style))))
 583
 584 (defsubst muse-publish-link-file (file &optional output-dir style)
 585   (setq style (muse-style style))
 586   (if output-dir
 587       (expand-file-name (muse-publish-link-name file style) output-dir)
 588     (concat (file-name-directory file)
 589             (muse-publish-link-name file style))))
 590
 591 ;;;###autoload
 592 (defun muse-publish-file (file style &optional output-dir force)
 593   "Publish the given FILE in a particular STYLE to OUTPUT-DIR.
 594 If the argument FORCE is nil, each file is only published if it is
 595 newer than the published version.  If the argument FORCE is non-nil,
 596 the file is published no matter what."
 597   (interactive (cons (read-file-name "Publish file: ")
 598                      (muse-publish-get-info)))
 599   (setq style (muse-style style))
 600   (let* ((output-path (muse-publish-output-file file output-dir style))
 601          (output-suffix (muse-style-element :osuffix style))
 602          (muse-publishing-current-file file)
 603          (muse-publishing-current-output-path output-path)
 604          (target (if output-suffix
 605                      (concat (file-name-sans-extension output-path)
 606                              output-suffix)
 607                    output-path))
 608          (threshhold (nth 7 (file-attributes file))))
 609     (if (not threshhold)
 610         (message "Please save %s before publishing" file)
 611       (when (or force (file-newer-than-file-p file target))
 612         (if (and muse-publish-report-threshhold
 613                  (> threshhold
 614                     muse-publish-report-threshhold))
 615             (message "Publishing %s ..." file))
 616         (muse-with-temp-buffer
 617           (insert-file-contents file)
 618           (muse-publish-markup-buffer (muse-page-name file) style)
 619           (let ((backup-inhibited t))
 620             (write-file output-path))
 621           (muse-style-run-hooks :final style file output-path target))
 622         t))))
 623
 624 ;;;###autoload
 625 (defun muse-publish-this-file (style output-dir &optional force)
 626   "Publish the page in the current file."
 627   (interactive (muse-publish-get-info))
 628   (unless (muse-publish-file buffer-file-name style output-dir force)
 629     (message (concat "The published version is up-to-date; use"
 630                      " C-u C-c C-t to force an update."))))
 631
 632 (defun muse-batch-publish-files ()
 633   "Publish Muse files in batch mode."
 634   (let ((muse-batch-publishing-p t)
 635         style-name style output-dir)
 636     (setq style-name (car command-line-args-left)
 637           style (muse-style style-name)
 638           command-line-args-left (cdr command-line-args-left)
 639           output-dir (car command-line-args-left)
 640           output-dir
 641           (if (string-match "\\`--output-dir=" output-dir)
 642               (prog1
 643                   (substring output-dir (match-end 0))
 644                 (setq command-line-args-left (cdr command-line-args-left)))))
 645     (unless style
 646       (error "There is no style '%s' defined." style-name))
 647     (dolist (file command-line-args-left)
 648       (muse-publish-file file style output-dir t))))
 649
 650 ;; Default publishing rules
 651
 652 (defun muse-publish-section-close (depth)
 653   "Seach forward for the closing tag of given DEPTH."
 654   (let (not-end)
 655     (save-excursion
 656       (while (and (setq not-end (re-search-forward
 657                                  (concat "^\\*\\{1," (number-to-string depth)
 658                                          "\\}\\s-+")
 659                                  nil t))
 660                   (get-text-property (match-beginning 0) 'read-only)))
 661       (if not-end
 662           (forward-line 0)
 663         (goto-char (point-max)))
 664       (cond ((not (eq (char-before) ?\n))
 665              (insert "\n\n"))
 666             ((not (eq (char-before (1- (point))) ?\n))
 667              (insert "\n")))
 668       (muse-insert-markup (muse-markup-text 'section-close depth))
 669       (insert "\n"))))
 670
 671 (defun muse-publish-markup-directive (&optional name value)
 672   (unless name (setq name (match-string 1)))
 673   (unless value (setq value (match-string 2)))
 674   (let ((elem (assoc name muse-publishing-directives)))
 675     (if elem
 676         (setcdr elem value)
 677       (setq muse-publishing-directives
 678             (cons (cons name value)
 679                   muse-publishing-directives))))
 680   ;; Make sure we don't ever try to move the point forward (past the
 681   ;; beginning of buffer) while we're still searching for directives.
 682   (setq muse-publishing-last-position nil)
 683   (delete-region (match-beginning 0) (match-end 0)))
 684
 685 (defun muse-publish-markup-anchor ()
 686   (unless (get-text-property (match-end 1) 'noemphasis)
 687     (let ((text (muse-markup-text 'anchor (match-string 2))))
 688       (unless (string= text "")
 689         (save-match-data
 690           (skip-chars-forward (concat muse-regexp-blank "\n"))
 691           (muse-insert-markup text)))
 692       (match-string 1))))
 693
 694 (defun muse-publish-markup-comment ()
 695   (if (null muse-publish-comments-p)
 696       ""
 697     (goto-char (match-end 0))
 698     (muse-insert-markup (muse-markup-text 'comment-end))
 699     (muse-publish-mark-read-only (match-beginning 1) (match-end 1))
 700     (delete-region (match-beginning 0) (match-beginning 1))
 701     (goto-char (match-beginning 0))
 702     (muse-insert-markup (muse-markup-text 'comment-begin))))
 703
 704 (defun muse-publish-markup-tag ()
 705   (let ((tag-info (muse-markup-tag-info (match-string 1))))
 706     (when (and tag-info
 707                (not (get-text-property (match-beginning 0) 'read-only)))
 708       (let ((closed-tag (match-string 3))
 709             (start (match-beginning 0))
 710             (beg (point))
 711             end attrs)
 712         (when (nth 2 tag-info)
 713           (let ((attrstr (match-string 2)))
 714             (while (and attrstr
 715                         (string-match (concat "\\([^"
 716                                               muse-regexp-blank
 717                                               "=\n]+\\)\\(=\"\\"
 718                                               "([^\"]+\\)\"\\)?")
 719                                       attrstr))
 720               (let ((attr (cons (downcase
 721                                  (muse-match-string-no-properties 1 attrstr))
 722                                 (muse-match-string-no-properties 3 attrstr))))
 723                 (setq attrstr (replace-match "" t t attrstr))
 724                 (if attrs
 725                     (nconc attrs (list attr))
 726                   (setq attrs (list attr)))))))
 727         (if (and (cadr tag-info) (not closed-tag))
 728             (if (search-forward (concat "</" (car tag-info) ">") nil t)
 729                 (delete-region (match-beginning 0) (point))
 730               (setq tag-info nil)))
 731         (when tag-info
 732           (setq end (point-marker))
 733           (delete-region start beg)
 734           (goto-char start)
 735           (let ((args (list start end)))
 736             (if (nth 2 tag-info)
 737                 (nconc args (list attrs)))
 738             (apply (nth 3 tag-info) args))))))
 739   nil)
 740
 741 (defun muse-publish-escape-specials (beg end &optional ignore-read-only context)
 742   "Escape specials from BEG to END using style-specific :specials.
 743 If IGNORE-READ-ONLY is non-nil, ignore the read-only property.
 744 CONTEXT is used to figure out what kind of specials to escape.
 745
 746 The following contexts exist in Muse.
 747 'underline  _underlined text_
 748 'literal    =monospaced text= or <code>region</code> (monospaced, escaped)
 749 'emphasis   *emphasized text*
 750 'email      email@example.com
 751 'url        http://example.com
 752 'url-desc   [[...][description of an extended link]]
 753 'example    <example>region</example> (monospaced, block context, escaped)
 754 'verbatim   <verbatim>region</verbatim> (escaped)
 755 'document   normal text"
 756   (let ((specials (muse-style-element :specials nil t)))
 757     (cond ((functionp specials)
 758            (setq specials (funcall specials context)))
 759           ((symbolp specials)
 760            (setq specials (symbol-value specials))))
 761     (save-excursion
 762       (save-restriction
 763         (narrow-to-region beg end)
 764         (goto-char (point-min))
 765         (while (< (point) (point-max))
 766           (if (and (not ignore-read-only)
 767                    (get-text-property (point) 'read-only))
 768               (goto-char (or (next-single-property-change (point) 'read-only)
 769                              (point-max)))
 770             (let ((repl (or (assoc (char-after) specials)
 771                             (assoc (char-after)
 772                                    muse-publish-markup-specials))))
 773               (if (null repl)
 774                   (forward-char 1)
 775                 (delete-char 1)
 776                 (insert-before-markers (cdr repl))))))))))
 777
 778 (defun muse-publish-markup-word ()
 779   (let* ((beg (match-beginning 2))
 780          (end (1- (match-end 2)))
 781          (leader (buffer-substring-no-properties beg end))
 782          open-tag close-tag mark-read-only loc context)
 783     (cond
 784      ((string= leader "_")
 785       (setq context 'underline
 786             open-tag (muse-markup-text 'begin-underline)
 787             close-tag (muse-markup-text 'end-underline)))
 788      ((string= leader "=")
 789       (setq context 'literal
 790             open-tag (muse-markup-text 'begin-literal)
 791             close-tag (muse-markup-text 'end-literal))
 792       (setq mark-read-only t))
 793      (t
 794       (let ((l (length leader)))
 795         (setq context 'emphasis)
 796         (cond
 797          ((= l 1) (setq open-tag (muse-markup-text 'begin-emph)
 798                         close-tag (muse-markup-text 'end-emph)))
 799          ((= l 2) (setq open-tag (muse-markup-text 'begin-more-emph)
 800                         close-tag (muse-markup-text 'end-more-emph)))
 801          ((= l 3) (setq open-tag (muse-markup-text 'begin-most-emph)
 802                         close-tag (muse-markup-text 'end-most-emph)))
 803          (t (setq context nil))))))
 804     (if (and context
 805              (not (get-text-property beg 'noemphasis))
 806              (setq loc (search-forward leader nil t))
 807              (or (eobp) (not (eq (char-syntax (char-after loc)) ?w)))
 808              (not (eq (char-syntax (char-before (point))) ?\ ))
 809              (not (get-text-property (point) 'noemphasis)))
 810         (progn
 811           (replace-match "")
 812           (delete-region beg end)
 813           (setq end (point-marker))
 814           (muse-insert-markup close-tag)
 815           (goto-char beg)
 816           (muse-insert-markup open-tag)
 817           (setq beg (point))
 818           (when mark-read-only
 819             (muse-publish-escape-specials beg end t context)
 820             (muse-publish-mark-read-only beg end)))
 821       (backward-char))
 822     nil))
 823
 824 (defun muse-publish-markup-emdash ()
 825   (delete-region (match-beginning 0) (match-end 0))
 826   (muse-insert-markup (muse-markup-text 'emdash))
 827   (if (eq (char-after) ?\<)
 828       (insert ?\n)))
 829
 830 (defun muse-publish-markup-enddots ()
 831   (unless (get-text-property (match-beginning 0) 'noemphasis)
 832     (delete-region (match-beginning 0) (match-end 0))
 833     (muse-insert-markup (muse-markup-text 'enddots))))
 834
 835 (defun muse-publish-markup-dots ()
 836   (unless (get-text-property (match-beginning 0) 'noemphasis)
 837     (delete-region (match-beginning 0) (match-end 0))
 838     (muse-insert-markup (muse-markup-text 'dots))))
 839
 840 (defun muse-publish-markup-rule ()
 841   (unless (get-text-property (match-beginning 0) 'noemphasis)
 842     (delete-region (match-beginning 0) (match-end 0))
 843     (muse-insert-markup (muse-markup-text 'rule))))
 844
 845 (defun muse-publish-markup-no-break-space ()
 846   (unless (get-text-property (match-beginning 0) 'noemphasis)
 847     (delete-region (match-beginning 0) (match-end 0))
 848     (muse-insert-markup (muse-markup-text 'no-break-space))))
 849
 850 (defun muse-publish-markup-heading ()
 851   (let* ((len (length (match-string 1)))
 852          (start (muse-markup-text
 853                  (cond ((= len 1) 'section)
 854                        ((= len 2) 'subsection)
 855                        ((= len 3) 'subsubsection)
 856                        (t 'section-other))
 857                  len))
 858          (end   (muse-markup-text
 859                  (cond ((= len 1) 'section-end)
 860                        ((= len 2) 'subsection-end)
 861                        ((= len 3) 'subsubsection-end)
 862                        (t 'section-other-end))
 863                  len)))
 864     (delete-region (match-beginning 0) (match-end 0))
 865     (muse-insert-markup start)
 866     (end-of-line)
 867     (when end
 868       (muse-insert-markup end))
 869     (muse-publish-section-close len)))
 870
 871 (defvar muse-publish-footnotes nil)
 872
 873 (defun muse-publish-markup-footnote ()
 874   "Scan ahead and snarf up the footnote body"
 875   (cond
 876    ((get-text-property (match-beginning 0) 'noemphasis)
 877     nil)
 878    ((= (muse-line-beginning-position) (match-beginning 0))
 879     "")
 880    (t
 881     (let ((footnote (save-match-data
 882                       (string-to-number (match-string 1))))
 883           footnotemark)
 884       (delete-region (match-beginning 0) (match-end 0))
 885       (save-excursion
 886         (when (re-search-forward (format "^\\[%d\\]\\s-+" footnote) nil t)
 887           (let* ((start (match-beginning 0))
 888                  (beg (goto-char (match-end 0)))
 889                  (end (save-excursion
 890                         (if (search-forward "\n\n" nil t)
 891                             (copy-marker (match-beginning 0))
 892                           (goto-char (point-max))
 893                           (skip-chars-backward "\n")
 894                           (point-marker)))))
 895             (while (re-search-forward
 896                     (concat "^[" muse-regexp-blank "]+\\([^\n]\\)")
 897                     end t)
 898               (replace-match "\\1" t))
 899             (let ((footnotemark-cmd (muse-markup-text 'footnotemark))
 900                   (footnotemark-end-cmd (muse-markup-text 'footnotemark-end)))
 901               (if (string= "" footnotemark-cmd)
 902                   (setq footnotemark
 903                         (concat (muse-markup-text 'footnote)
 904                                 (buffer-substring-no-properties beg end)
 905                                 (muse-markup-text 'footnote-end)))
 906                 (setq footnotemark (format footnotemark-cmd footnote
 907                                            footnotemark-end-cmd))
 908                 (unless muse-publish-footnotes
 909                   (set (make-local-variable 'muse-publish-footnotes)
 910                        (make-vector 256 nil)))
 911                 (unless (aref muse-publish-footnotes footnote)
 912                   (setq footnotemark
 913                         (concat
 914                          footnotemark
 915                          (concat (format (muse-markup-text 'footnotetext)
 916                                          footnote)
 917                                  (buffer-substring-no-properties beg end)
 918                                  (muse-markup-text 'footnotetext-end))))
 919                   (aset muse-publish-footnotes footnote footnotemark))))
 920             (goto-char end)
 921             (skip-chars-forward "\n")
 922             (delete-region start (point)))))
 923       (muse-insert-markup (or footnotemark footnote))))))
 924
 925 (defun muse-publish-markup-fn-sep ()
 926   (delete-region (match-beginning 0) (match-end 0))
 927   (muse-insert-markup (muse-markup-text 'fn-sep)))
 928
 929 (defun muse-insert-markup-end-list (&rest args)
 930   (let ((beg (point)))
 931     (apply 'insert args)
 932     (add-text-properties beg (point) '(end-list t))
 933     (muse-publish-mark-read-only beg (point))))
 934
 935 (defun muse-publish-surround-dl (indent post-indent)
 936   (let* ((beg-item (muse-markup-text 'begin-dl-item))
 937          (end-item (muse-markup-text 'end-dl-item))
 938          (beg-ddt (muse-markup-text 'begin-ddt)) ;; term
 939          (end-ddt (muse-markup-text 'end-ddt))
 940          (beg-dde (muse-markup-text 'begin-dde)) ;; definition
 941          (end-dde (muse-markup-text 'end-dde))
 942          (continue t)
 943          def-on-same-line beg)
 944     (while continue
 945       ;; envelope this as one term+definitions unit -- HTML does not
 946       ;; need this, but DocBook and Muse's custom XML format do
 947       (muse-insert-markup beg-item)
 948       (when (looking-at muse-dl-term-regexp)
 949         ;; find the term and wrap it with published markup
 950         (setq beg (point))
 951         (goto-char (match-end 1))
 952         (delete-region (point) (match-end 0))
 953         (muse-insert-markup-end-list end-ddt)
 954         ;; if definition is immediately after term, move to next line
 955         (if (eq (char-after) ?\n)
 956             (setq def-on-same-line 0)
 957           (setq def-on-same-line 1)
 958           (insert ?\n))
 959         (save-excursion
 960           (goto-char beg)
 961           (delete-region (point) (match-beginning 1))
 962           (muse-insert-markup beg-ddt)))
 963       (setq beg (point)
 964             ;; move past current item
 965             continue (muse-forward-dl-term indent))
 966       (save-restriction
 967         (narrow-to-region beg (point))
 968         (goto-char (point-min))
 969         ;; publish each definition that we find, defaulting to an
 970         ;; empty definition if none are found
 971         (muse-publish-surround-text beg-dde end-dde #'muse-forward-dl-entry
 972                                     indent post-indent def-on-same-line)
 973         (goto-char (point-max))
 974         (skip-chars-backward (concat muse-regexp-blank "\n"))
 975         (muse-insert-markup-end-list end-item)
 976         (when continue
 977           (goto-char (point-max)))))))
 978
 979 (defun muse-publish-surround-text (beg-tag end-tag move-func &optional indent post-indent determine-indent)
 980   (let ((continue t)
 981         (list-item (format muse-list-item-regexp
 982                            (concat "[" muse-regexp-blank "]*")))
 983         (indent-found nil)
 984         init-indent beg)
 985     (unless indent
 986       (setq indent (concat "[" muse-regexp-blank "]+")))
 987     (if post-indent
 988         (setq post-indent (concat " \\{0," (number-to-string post-indent)
 989                                   "\\}"))
 990       (setq post-indent ""))
 991     (while continue
 992       (muse-insert-markup beg-tag)
 993       (setq beg (point)
 994             ;; move past current item; continue is non-nil if there
 995             ;; are more like items to be processed
 996             continue (funcall move-func indent))
 997       (save-restriction
 998         (when continue
 999           (when determine-indent
1000             (if (= determine-indent 0)
1001                 ;; if the caller doesn't know how much indentation
1002                 ;; to use, figure it out ourselves
1003                 (progn
1004                   (setq indent
1005                         (or (save-match-data
1006                               ;; snarf all but the last whitespace
1007                               ;; character
1008                               (and (looking-at
1009                                     (concat "^\\([" muse-regexp-blank
1010                                             "]+\\)[" muse-regexp-blank "]"))
1011                                    (match-string 1)))
1012                             ""))
1013                   (setq determine-indent nil))
1014               (setq determine-indent (1- determine-indent))))
1015           ;; remove list markup if we encountered another item of the
1016           ;; same type
1017           (replace-match "" t t nil 1))
1018         (narrow-to-region beg (point))
1019         ;; narrow to current item
1020         (goto-char (point-min))
1021         (while (< (point) (point-max))
1022           (when (and (not (looking-at list-item))
1023                      (looking-at (concat indent post-indent)))
1024             ;; if list is not nested, remove indentation
1025             (unless indent-found
1026                 (setq indent (match-string 0)
1027                       indent-found t))
1028             (replace-match ""))
1029           (forward-line 1))
1030         (skip-chars-backward (concat muse-regexp-blank "\n"))
1031         (muse-insert-markup-end-list end-tag)
1032         (when continue
1033           (goto-char (point-max)))))))
1034
1035 (defun muse-publish-markup-list ()
1036   "Markup a list entry.
1037 The reason this function is so funky, is to prevent text properties
1038 like read-only from being inadvertently deleted."
1039   (let* ((str (match-string 1))
1040          (type (muse-list-item-type str))
1041          (indent (buffer-substring (muse-line-beginning-position)
1042                                    (match-beginning 1)))
1043          (post-indent (length str))
1044          (last (match-beginning 0)))
1045     (cond
1046      ((eq type 'ul)
1047       (unless (eq (char-after (match-end 1)) ?-)
1048         (delete-region (match-beginning 0) (match-end 0))
1049         (muse-insert-markup (muse-markup-text 'begin-uli))
1050         (save-excursion
1051           (muse-publish-surround-text
1052            (muse-markup-text 'begin-uli-item)
1053            (muse-markup-text 'end-uli-item)
1054            (lambda (indent)
1055              (muse-forward-list-item 'ul indent))
1056            indent post-indent)
1057           (muse-insert-markup-end-list (muse-markup-text 'end-uli)))
1058         (forward-line 1)))
1059      ((eq type 'ol)
1060       (delete-region (match-beginning 0) (match-end 0))
1061       (muse-insert-markup (muse-markup-text 'begin-oli))
1062       (save-excursion
1063         (muse-publish-surround-text
1064          (muse-markup-text 'begin-oli-item)
1065          (muse-markup-text 'end-oli-item)
1066          (lambda (indent)
1067            (muse-forward-list-item 'ol indent))
1068          indent post-indent)
1069         (muse-insert-markup-end-list (muse-markup-text 'end-oli)))
1070       (forward-line 1))
1071      ((not (string= (match-string 2) ""))
1072       ;; must have an initial term
1073       (goto-char (match-beginning 0))
1074       (muse-insert-markup (muse-markup-text 'begin-dl))
1075       (save-excursion
1076         (muse-publish-surround-dl indent post-indent)
1077         (muse-insert-markup-end-list (muse-markup-text 'end-dl)))
1078       (forward-line 1))))
1079   nil)
1080
1081 (defun muse-publish-markup-quote ()
1082   "Markup a quoted paragraph.
1083 The reason this function is so funky, is to prevent text properties
1084 like read-only from being inadvertently deleted."
1085   (let* ((ws (match-string 1))
1086          (centered (>= (string-width ws) 6))
1087          (begin-elem (if centered 'begin-center 'begin-quote-item))
1088          (end-elem (if centered 'end-center 'end-quote-item)))
1089     (replace-match "" t t nil 1)
1090     (unless centered
1091       (muse-insert-markup (muse-markup-text 'begin-quote)))
1092     (muse-publish-surround-text (muse-markup-text begin-elem)
1093                                 (muse-markup-text end-elem)
1094                                 (function (lambda (indent)
1095                                             (muse-forward-paragraph)
1096                                             nil)))
1097     (unless centered
1098       (muse-insert-markup (muse-markup-text 'end-quote)))))
1099
1100 (defun muse-publish-markup-leading-space (markup-space multiple)
1101   (let (count)
1102     (when (and markup-space
1103                (>= (setq count (skip-chars-forward " ")) 0))
1104       (delete-region (muse-line-beginning-position) (point))
1105       (while (> count 0)
1106         (muse-insert-markup markup-space)
1107         (setq count (- count multiple))))))
1108
1109 (defun muse-publish-markup-verse ()
1110   (let ((leader (match-string 0)))
1111     (goto-char (match-beginning 0))
1112     (muse-insert-markup (muse-markup-text 'begin-verse))
1113     (while (looking-at leader)
1114       (replace-match "")
1115       (muse-publish-markup-leading-space (muse-markup-text 'verse-space) 2)
1116       (let ((beg (point)))
1117         (end-of-line)
1118         (cond
1119          ((bolp)
1120           (let ((text (muse-markup-text 'empty-verse-line)))
1121             (when text (muse-insert-markup text))))
1122          ((save-excursion
1123             (save-match-data
1124               (forward-line 1)
1125               (or (looking-at (concat leader "["
1126                                       muse-regexp-blank
1127                                       "]*$"))
1128                   (not (looking-at leader)))))
1129           (let ((begin-text (muse-markup-text 'begin-last-stanza-line))
1130                 (end-text (muse-markup-text 'end-last-stanza-line)))
1131             (when end-text (muse-insert-markup end-text))
1132             (goto-char beg)
1133             (when begin-text (muse-insert-markup begin-text))
1134             (end-of-line)))
1135          (t
1136           (let ((begin-text (muse-markup-text 'begin-verse-line))
1137                 (end-text (muse-markup-text 'end-verse-line)))
1138             (when end-text (muse-insert-markup end-text))
1139             (goto-char beg)
1140             (when begin-text (muse-insert-markup begin-text))
1141             (end-of-line))))
1142         (forward-line 1))))
1143   (muse-insert-markup (muse-markup-text 'end-verse) ?\n))
1144
1145 (defun muse-publish-table-fields (beg end)
1146   "Parse given region as a table, returning a cons cell.
1147 The car is the length of the longest row.
1148
1149 The cdr is a list of the fields of the table, with the first
1150 element indicating the type of the row:
1151   1: body, 2: header, 3: footer.
1152
1153 The existing region will be removed, except for initial blank lines."
1154   (let ((longest 0)
1155         (left 0)
1156         fields field-list)
1157     (save-restriction
1158       (narrow-to-region beg end)
1159       (goto-char (point-min))
1160       (while (looking-at (concat "^[" muse-regexp-blank "]*$"))
1161         (forward-line 1))
1162       (setq beg (point))
1163       (while (= left 0)
1164         (when (looking-at muse-table-line-regexp)
1165           (setq fields (cons (length (match-string 1))
1166                              (split-string (match-string 0)
1167                                            muse-table-field-regexp))
1168                 field-list (cons fields field-list)
1169                 longest (max (length fields) longest)))
1170         (setq left (forward-line 1))))
1171     (delete-region beg end)
1172     (if (= longest 0)
1173         (cons 0 nil)
1174       (cons (1- longest) (nreverse field-list)))))
1175
1176 (defun muse-publish-markup-table ()
1177   "Style does not support tables.")
1178
1179 (defun muse-publish-escape-specials-in-string (string &optional context)
1180   "Escape specials in STRING using style-specific :specials.
1181 CONTEXT is used to figure out what kind of specials to escape.
1182
1183 See the documentation of the `muse-publish-escape-specials'
1184 function for the list of available contexts."
1185   (unless string
1186     (setq string ""))
1187   (let ((specials (muse-style-element :specials nil t)))
1188     (cond ((functionp specials)
1189            (setq specials (funcall specials context)))
1190           ((symbolp specials)
1191            (setq specials (symbol-value specials))))
1192     (if (functionp specials)
1193         (funcall specials string)
1194       (apply (function concat)
1195              (mapcar
1196               (lambda (ch)
1197                 (let (repl)
1198                   (setq repl (or (assoc ch specials)
1199                                  (assoc ch muse-publish-markup-specials)))
1200                   (if (null repl)
1201                       (char-to-string ch)
1202                     (cdr repl))))
1203               (append string nil))))))
1204
1205 (defun muse-publish-markup-email ()
1206   (let* ((beg (match-end 1))
1207          (addr (buffer-substring-no-properties beg (match-end 0))))
1208     (setq addr (muse-publish-escape-specials-in-string addr 'email))
1209     (goto-char beg)
1210     (delete-region beg (match-end 0))
1211     (if (or (eq (char-before (match-beginning 0)) ?\")
1212             (eq (char-after (match-end 0)) ?\"))
1213         (insert addr)
1214       (insert (format (muse-markup-text 'email-addr) addr addr)))
1215     (muse-publish-mark-read-only beg (point))))
1216
1217 (defun muse-publish-classify-url (target)
1218   "Transform anchors and get published name, if TARGET is a page.
1219 The return value is a cons cell.  The car is the type of link,
1220 the cadr is the page name, and the cddr is the anchor."
1221   (save-match-data
1222     (cond ((or (null target) (string= target ""))
1223            nil)
1224           ((string-match muse-url-regexp target)
1225            (cons 'url (cons target nil)))
1226           ((string-match muse-image-regexp target)
1227            (cons 'image (cons target nil)))
1228           ((string-match muse-file-regexp target)
1229            (cons 'file (cons target nil)))
1230           ((string-match "#" target)
1231            (if (eq (aref target 0) ?\#)
1232               (cons 'anchor-ref (cons nil (substring target 1)))
1233              (cons 'link-and-anchor
1234                    (cons (muse-publish-link-name
1235                           (substring target 0 (match-beginning 0)))
1236                          (substring target (match-end 0))))))
1237           (t
1238            (cons 'link (cons (muse-publish-link-name target) nil))))))
1239
1240 (defun muse-publish-url (url &optional desc explicit)
1241   "Resolve a URL into its final <a href> form."
1242   (let ((orig-url url)
1243         type anchor)
1244     (dolist (transform muse-publish-url-transforms)
1245       (setq url (save-match-data (when url (funcall transform url explicit)))))
1246     (dolist (transform muse-publish-desc-transforms)
1247       (setq desc (save-match-data
1248                    (when desc (funcall transform desc explicit)))))
1249     (when desc
1250       (setq desc (muse-publish-escape-specials-in-string desc 'url-desc)))
1251     (setq orig-url
1252           (muse-publish-escape-specials-in-string orig-url 'url-desc))
1253     (let ((target (muse-publish-classify-url url)))
1254       (setq type (car target)
1255             url (muse-publish-escape-specials-in-string (cadr target) 'url)
1256             anchor (muse-publish-escape-specials-in-string
1257                     (cddr target) 'url)))
1258     (cond ((eq type 'anchor-ref)
1259            (muse-markup-text 'anchor-ref anchor (or desc orig-url)))
1260           ((string= url "")
1261            desc)
1262           ((eq type 'image)
1263            (if desc
1264                (muse-markup-text 'image-with-desc url desc)
1265              (muse-markup-text 'image-link url)))
1266           ((eq type 'link-and-anchor)
1267            (muse-markup-text 'link-and-anchor url anchor
1268                              (or desc orig-url)))
1269           ((and desc (string-match muse-image-regexp desc))
1270            (muse-markup-text 'url-with-image url desc))
1271           ((eq type 'link)
1272            (muse-markup-text 'link url (or desc orig-url)))
1273           (t
1274            (muse-markup-text 'url url (or desc orig-url))))))
1275
1276 (defun muse-publish-insert-url (url &optional desc explicit)
1277   "Resolve a URL into its final <a href> form."
1278   (delete-region (match-beginning 0) (match-end 0))
1279   (let ((text (muse-publish-url url desc explicit)))
1280     (when text
1281       (muse-insert-markup text))))
1282
1283 (defun muse-publish-markup-link ()
1284   (let (desc explicit link)
1285     (setq explicit (save-match-data
1286                      (if (string-match muse-explicit-link-regexp
1287                                        (match-string 0))
1288                          t nil)))
1289     (setq desc (if explicit (match-string 2) (match-string 0)))
1290     (setq link (if explicit
1291                    (muse-handle-explicit-link (match-string 1))
1292                  (muse-handle-implicit-link (match-string 0))))
1293     (when (and link
1294                (or explicit
1295                    (not (or (eq (char-before (match-beginning 0)) ?\")
1296                             (eq (char-after (match-end 0)) ?\")))))
1297       (muse-publish-insert-url link desc explicit))))
1298
1299 (defun muse-publish-markup-url ()
1300   (unless (or (eq (char-before (match-beginning 0)) ?\")
1301               (eq (char-after (match-end 0)) ?\"))
1302     (muse-publish-insert-url (match-string 0))))
1303
1304 ;; Default publishing tags
1305
1306 (defun muse-publish-contents-tag (beg end attrs)
1307   (set (make-local-variable 'muse-publish-generate-contents)
1308        (cons (copy-marker (point) t)
1309              (let ((depth (cdr (assoc "depth" attrs))))
1310                (or (and depth (string-to-number depth)) 2)))))
1311
1312 (defun muse-publish-verse-tag (beg end)
1313   (save-excursion
1314     (save-restriction
1315       (narrow-to-region beg end)
1316       (goto-char (point-min))
1317       (while (eq ?\  (char-syntax (char-after)))
1318         (delete-char 1))
1319       (while (< (point) (point-max))
1320         (insert "> ")
1321         (forward-line))
1322       (if (eq ?\  (char-syntax (char-before)))
1323           (delete-char -1)))))
1324
1325 (defun muse-publish-mark-read-only (beg end)
1326   "Add read-only properties to the given region."
1327   (add-text-properties beg end '(rear-nonsticky (read-only) read-only t))
1328   nil)
1329
1330 (defun muse-publish-mark-noemphasis (&optional beg end)
1331   "Make sure that no emphasis characters are interpreted within
1332 the given region.  If a region is not specified, use the 0th
1333 match data to determine it.
1334
1335 This is usually applied to extended links."
1336   (unless beg (setq beg (match-beginning 0)))
1337   (unless end (setq end (match-end 0)))
1338   (add-text-properties beg end '(noemphasis t))
1339   nil)
1340
1341 (defun muse-publish-quote-tag (beg end)
1342   (save-excursion
1343     (save-restriction
1344       (narrow-to-region beg end)
1345       (muse-insert-markup (muse-markup-text 'begin-quote))
1346       (muse-publish-surround-text (muse-markup-text 'begin-quote-item)
1347                                   (muse-markup-text 'end-quote-item)
1348                                   (function (lambda (indent)
1349                                               (muse-forward-paragraph)
1350                                               (goto-char (match-end 0))
1351                                               (< (point) (point-max)))))
1352       (muse-insert-markup (muse-markup-text 'end-quote)))))
1353
1354 (defun muse-publish-code-tag (beg end)
1355   (muse-publish-escape-specials beg end nil 'literal)
1356   (goto-char beg)
1357   (insert (muse-markup-text 'begin-literal))
1358   (goto-char end)
1359   (insert (muse-markup-text 'end-literal))
1360   (muse-publish-mark-read-only beg (point)))
1361
1362 (defun muse-publish-example-tag (beg end)
1363   (muse-publish-escape-specials beg end nil 'example)
1364   (goto-char beg)
1365   (insert (muse-markup-text 'begin-example))
1366   (goto-char end)
1367   (insert (muse-markup-text 'end-example))
1368   (muse-publish-mark-read-only beg (point)))
1369
1370 (defun muse-publish-verbatim-tag (beg end)
1371   (muse-publish-escape-specials beg end nil 'verbatim)
1372   (muse-publish-mark-read-only beg end))
1373
1374 (defalias 'muse-publish-class-tag 'ignore)
1375
1376 (defun muse-publish-lisp-tag (beg end)
1377   (save-excursion
1378     (let ((str (muse-eval-lisp
1379                 (prog1
1380                     (concat "(progn "
1381                             (buffer-substring-no-properties beg end)
1382                             ")")
1383                   (delete-region beg end)))))
1384       (set-text-properties 0 (length str) nil str)
1385       (insert str))))
1386
1387 (defun muse-publish-command-tag (beg end attrs)
1388   (while (looking-at "\\s-*$")
1389     (forward-line))
1390   (let ((interp (cdr (assoc "interp" attrs))))
1391     (if (null interp)
1392         (shell-command
1393          (prog1
1394              (buffer-substring-no-properties (point) end)
1395            (delete-region beg end)) t)
1396       (shell-command-on-region beg end interp t t))
1397     (muse-publish-mark-read-only beg (point))))
1398
1399 (defun muse-publish-comment-tag (beg end)
1400   (if (null muse-publish-comments-p)
1401       (delete-region beg end)
1402     (goto-char end)
1403     (muse-insert-markup (muse-markup-text 'comment-end))
1404     (muse-publish-mark-read-only beg end)
1405     (goto-char beg)
1406     (muse-insert-markup (muse-markup-text 'comment-begin))))
1407
1408 ;; Miscellaneous helper functions
1409
1410 (defsubst muse-publishing-directive (name)
1411   (cdr (assoc name muse-publishing-directives)))
1412
1413 (defun muse-publish-strip-tags (string)
1414   "Remove all tags from the string."
1415   (while (string-match "<.*?>" string)
1416     (setq string (replace-match "" nil t string)))
1417   string)
1418
1419 (defun muse-publish-markup-type (category default-func)
1420   (let ((rule (muse-find-markup-element :overrides category (muse-style))))
1421     (funcall (or rule default-func))))
1422
1423 (defun muse-published-buffer-contents (buffer)
1424   (with-current-buffer buffer
1425     (goto-char (point-min))
1426     (let ((beg (and (search-forward "Emacs Muse begins here")
1427                     (muse-line-end-position)))
1428           (end (and (search-forward "Emacs Muse ends here")
1429                     (muse-line-beginning-position))))
1430       (buffer-substring-no-properties beg end))))
1431
1432 (defun muse-published-contents (file)
1433   (when (file-readable-p file)
1434     (muse-with-temp-buffer
1435       (insert-file-contents file)
1436       (muse-published-buffer-contents (current-buffer)))))
1437
1438 (defun muse-publish-transform-output
1439   (file temp-file output-path name gen-func &rest cleanup-exts)
1440   "Transform the given TEMP-FILE into the OUTPUT-PATH, using GEN-FUNC."
1441   (setq file (muse-page-name file))
1442   (message "Generating %s output for %s..." name file)
1443   (if (not (funcall gen-func temp-file output-path))
1444       (message "Generating %s from %s...failed" name file)
1445     (message "Generating %s output for %s...done" name file)
1446     (muse-delete-file-if-exists temp-file)
1447     (dolist (ext cleanup-exts)
1448       (muse-delete-file-if-exists
1449        (expand-file-name (concat file ext)
1450                          (file-name-directory output-path))))
1451     (message "Wrote %s" output-path)))
1452
1453 (defun muse-publish-read-only (string)
1454   (let ((end (1- (length string))))
1455     (add-text-properties 0 end
1456                          '(rear-nonsticky (read-only) read-only t)
1457                          string)
1458     string))
1459
1460 (provide 'muse-publish)
1461
1462 ;;; muse-publish.el ends here