lisp/muse-mode.el

   1 ;;; muse-mode.el --- mode for editing Muse files; has font-lock support
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; The Emacs Muse major mode is basically a hyped-up text-mode which
  25 ;; knows a lot more about the apparent structure of the document.
  26
  27 ;;; Contributors:
  28
  29 ;; Andrea Riciputi (ariciputi AT pito DOT com) gave an initial
  30 ;; implementation for tag completion by means of the
  31 ;; `muse-insert-tag' function.
  32
  33 ;;; Code:
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;
  37 ;; Emacs Muse Major Mode
  38 ;;
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (require 'muse)
  42 (require 'muse-regexps)
  43 (require 'muse-project)
  44 (require 'muse-publish)
  45
  46 (autoload 'muse-use-font-lock "muse-colors")
  47
  48 (require 'derived)
  49 (eval-when-compile
  50   (condition-case nil
  51       (require 'pcomplete)              ; load if available
  52     (error nil)))
  53
  54 ;;; Options:
  55
  56 (defgroup muse-mode nil
  57   "Options controlling the behavior of the Muse editing Mode."
  58   :group 'muse)
  59
  60 (defcustom muse-mode-highlight-p t
  61   "If non-nil, highlight the content of Muse buffers."
  62   :type 'boolean
  63   :require 'muse-colors
  64   :group 'muse-mode)
  65
  66 (defcustom muse-mode-auto-p nil
  67   "If non-nil, automagically determine when Muse mode should be activated."
  68   :type 'boolean
  69   :set (function
  70         (lambda (sym value)
  71           (if value
  72               (add-hook 'find-file-hooks 'muse-mode-maybe)
  73             (remove-hook 'find-file-hooks 'muse-mode-maybe))
  74           (set sym value)))
  75   :group 'muse-mode)
  76
  77 (defcustom muse-mode-intangible-links nil
  78   "If non-nil, use the intangible property on links.
  79 This can cause problems with flyspell (and potentially fill-mode),
  80 so only enable this if you don't use either of these."
  81   :type 'boolean
  82   :group 'muse-mode)
  83
  84 (defcustom muse-mode-hook nil
  85   "A hook that is run when Muse mode is entered."
  86   :type 'hook
  87   :options '(flyspell-mode footnote-mode turn-on-auto-fill
  88              highlight-changes-mode)
  89   :set #'(lambda (sym val)
  90            (when (featurep 'muse-wiki)
  91              (add-to-list 'val 'muse-wiki-update-custom-values))
  92            (set sym val))
  93   :group 'muse-mode)
  94
  95 (defvar muse-mode-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map [(control ?c) (control ?a)] 'muse-index)
  98     (define-key map [(control ?c) (control ?b)] 'muse-browse-result)
  99     (define-key map [(control ?c) (control ?c)] 'muse-follow-name-at-point)
 100     (define-key map [(control ?c) (control ?e)] 'muse-edit-link-at-point)
 101     (define-key map [(control ?c) (control ?t)] 'muse-publish-this-file)
 102     (define-key map [(control ?c) (control ?v)] 'muse-follow-name-at-point)
 103
 104     (define-key map [(control ?c) (control ?l)] 'font-lock-mode)
 105
 106     (define-key map [(control ?c) ?=]           'muse-what-changed)
 107
 108     (define-key map [tab] 'muse-next-reference)
 109     (define-key map [(control ?i)] 'muse-next-reference)
 110
 111     (if (featurep 'xemacs)
 112         (progn
 113           (define-key map [(button2)] 'muse-follow-name-at-mouse)
 114           (define-key map [(shift button2)]
 115             'muse-follow-name-at-mouse-other-window))
 116       (define-key map [(shift control ?m)]
 117         'muse-follow-name-at-point-other-window)
 118       (define-key map [mouse-2] 'muse-follow-name-at-mouse)
 119       (define-key map [(shift mouse-2)]
 120         'muse-follow-name-at-mouse-other-window))
 121
 122     (define-key map [(shift tab)] 'muse-previous-reference)
 123     (unless (featurep 'xemacs)
 124       (define-key map [(shift iso-lefttab)] 'muse-previous-reference)
 125       (define-key map [(shift control ?i)] 'muse-previous-reference))
 126
 127     (define-key map [(control ?c) (control ?f)] 'muse-project-find-file)
 128     (define-key map [(control ?c) (control ?p)] 'muse-project-publish)
 129
 130     (define-key map [(control ?c) tab] 'muse-insert-tag)
 131     (define-key map [(control ?c) (control ?i)] 'muse-insert-tag)
 132
 133     (when (featurep 'pcomplete)
 134       (define-key map [(meta tab)] 'pcomplete)
 135       (define-key map [(meta control ?i)] 'pcomplete))
 136
 137     map)
 138   "Keymap used by Emacs Muse mode.")
 139
 140 ;; Code:
 141
 142 ;;;###autoload
 143 (define-derived-mode muse-mode text-mode "Muse"
 144   "Muse is an Emacs mode for authoring and publishing documents.
 145 \\{muse-mode-map}"
 146   ;; Since we're not inheriting from normal-mode, we need to
 147   ;; explicitly run file variables.
 148   (condition-case err
 149       (hack-local-variables)
 150     (error (message "File local-variables error: %s"
 151                     (prin1-to-string err))))
 152   ;; Avoid lock-up caused by use of the 'intangible' text property
 153   ;; with flyspell.
 154   (unless muse-mode-intangible-links
 155     (set (make-local-variable 'inhibit-point-motion-hooks) t))
 156   (setq muse-current-project (muse-project-of-file))
 157   (muse-project-set-variables)
 158   ;; Make sure several variables get updated if the user has changed
 159   ;; them without using the customize interface.
 160   (muse-update-ignored-extensions-regexp 'muse-ignored-extensions
 161                                          muse-ignored-extensions)
 162   (muse-update-url-regexp 'muse-url-protocols muse-url-protocols)
 163   ;; Make fill not split up links
 164   (when (boundp 'fill-nobreak-predicate)
 165     (make-local-variable 'fill-nobreak-predicate)
 166     ;; Work around annoying inconsistency in fill handling between
 167     ;; Emacs 21 and 22.
 168     (if (< emacs-major-version 22)
 169         (setq fill-nobreak-predicate 'muse-mode-fill-nobreak-p)
 170       (add-to-list 'fill-nobreak-predicate
 171                    'muse-mode-fill-nobreak-p)))
 172   ;; Make fill work nicely with item lists
 173   (set (make-local-variable 'adaptive-fill-regexp)
 174        "\\s-+\\(-\\|[0-9]+\\.\\)\\s-+\\|\\[[0-9]+\\]\\s-*\\|\\s-*")
 175   (set (make-local-variable 'paragraph-start)
 176        (concat paragraph-start "\\|\\s-+\\(-\\|[0-9]+\\.\\)\\s-+"
 177                "\\|\\[[0-9]+\\]\\s-*"))
 178   ;; If we're using Emacs21, this makes flyspell work like it should
 179   (setq flyspell-generic-check-word-p 'muse-mode-flyspell-p)
 180   ;; Comment syntax is `; comment'
 181   (set (make-local-variable 'comment-start)
 182        "; ")
 183   (when (featurep 'pcomplete)
 184     ;; If pcomplete is available, set it up
 185     (set (make-local-variable 'pcomplete-default-completion-function)
 186          'muse-mode-completions)
 187     (set (make-local-variable 'pcomplete-command-completion-function)
 188          'muse-mode-completions)
 189     (set (make-local-variable 'pcomplete-parse-arguments-function)
 190          'muse-mode-current-word))
 191   (when muse-mode-highlight-p
 192     (muse-use-font-lock)))
 193
 194 (put 'muse-mode
 195      'flyspell-mode-predicate
 196      'muse-mode-flyspell-p)
 197
 198 (defun muse-mode-fill-nobreak-p ()
 199   "Return nil if we should allow a fill to occur at point.
 200 Otherwise return non-nil.
 201
 202 This is used to keep long explicit links from being mangled by
 203 fill mode."
 204   (save-excursion
 205     (save-match-data
 206       (and (re-search-backward "\\[\\[\\|\\]\\]"
 207                                (line-beginning-position) t)
 208            (string= (or (match-string 0) "")
 209                     "[[")))))
 210
 211 (defun muse-mode-flyspell-p ()
 212   "Return non-nil if we should allow spell-checking to occur at point.
 213 Otherwise return nil.
 214
 215 This is used to keep links from being improperly colorized by flyspell."
 216   (save-match-data
 217     (null (muse-link-at-point))))
 218
 219 (defun muse-mode-choose-mode ()
 220   "Turn the proper Emacs Muse related mode on for this file."
 221   (let ((project (muse-project-of-file)))
 222     (funcall (or (and project (muse-get-keyword :major-mode (cadr project) t))
 223                  'muse-mode))))
 224
 225 (defun muse-mode-maybe ()
 226   "Maybe turn Emacs Muse mode on for this file."
 227   (let ((project (muse-project-of-file)))
 228     (and project
 229          (funcall (or (muse-get-keyword :major-mode (cadr project) t)
 230                       'muse-mode)))))
 231
 232 ;;; Support page name completion using pcomplete
 233
 234 (defun muse-completions ()
 235   "Return a list of possible completions names for this buffer."
 236   (let ((project (muse-project-of-file)))
 237     (if project
 238         (while (pcomplete-here
 239                 (mapcar 'car (muse-project-file-alist project)))))))
 240
 241 (defun muse-current-word ()
 242   (let ((end (point)))
 243     (save-restriction
 244       (save-excursion
 245         (skip-chars-backward (concat "^\\["
 246                                      muse-regexp-space))
 247         (narrow-to-region (point) end))
 248       (pcomplete-parse-buffer-arguments))))
 249
 250 ;;; Navigate/visit links or URLs.  Use TAB, S-TAB and RET (or mouse-2).
 251
 252 (defun muse-link-at-point (&optional pos)
 253   "Return link text if a URL or link is at point."
 254   (let ((case-fold-search nil)
 255         (inhibit-point-motion-hooks t)
 256         (here (or pos (point))))
 257     (when (or (null pos)
 258               (and (char-after pos)
 259                    (not (eq (char-syntax (char-after pos)) ?\ ))))
 260       (save-excursion
 261         (goto-char here)
 262         ;; Check for explicit link here or before point
 263         (if (or (looking-at muse-explicit-link-regexp)
 264                 (and
 265                  (re-search-backward "\\[\\[\\|\\]\\]"
 266                                      (muse-line-beginning-position)
 267                                      t)
 268                  (string= (or (match-string 0) "") "[[")
 269                  (looking-at muse-explicit-link-regexp)))
 270             (progn
 271               (goto-char (match-beginning 1))
 272               (muse-handle-explicit-link))
 273           (goto-char here)
 274           ;; Check for bare URL or other link type
 275           (skip-chars-backward (concat "^'\"<>{}(\n"
 276                                        muse-regexp-space))
 277           (and (looking-at muse-implicit-link-regexp)
 278                (muse-handle-implicit-link)))))))
 279
 280 (defun muse-make-link (link &optional name)
 281   "Return a link to LINK with NAME as the text."
 282   (if (and name
 283            link
 284            (not (string= name ""))
 285            (not (string= link name)))
 286       (concat "[[" (or link "") "][" name "]]")
 287     (concat "[[" (or link "") "]]")))
 288
 289 (defun muse-edit-link-at-point ()
 290   "Edit the current link.
 291 Do not rename the page originally referred to."
 292   (interactive)
 293   (if (muse-link-at-point)
 294       (replace-match
 295        (muse-make-link
 296         (read-string "Link: "
 297                      (muse-match-string-no-properties 1))
 298         (read-string "Text: "
 299                      (muse-match-string-no-properties 2)))
 300        t t)
 301     (error "There is no valid link at point")))
 302
 303 (defun muse-visit-link-default (link &optional other-window anchor)
 304   "Visit the URL or link named by LINK.
 305 If ANCHOR is specified, search for it after opening LINK.
 306
 307 This is the default function to call when visiting links; it is
 308 used by `muse-visit-link' if you have not specified :visit-link
 309 in `muse-project-alist'."
 310   (if (string-match muse-url-regexp link)
 311       (muse-browse-url link)
 312     (let ((base-buffer (get-buffer link)))
 313       (if (and base-buffer (not (buffer-file-name base-buffer)))
 314           ;; If file is temporary (no associated file), just switch to
 315           ;; the buffer
 316           (if other-window
 317               (switch-to-buffer-other-window base-buffer)
 318             (switch-to-buffer base-buffer))
 319         (let ((project (muse-project-of-file)))
 320           (if project
 321               (muse-project-find-file link project
 322                                       (and other-window
 323                                            'find-file-other-window))
 324             (if other-window
 325                 (find-file-other-window link)
 326               (find-file link))))))
 327     (if anchor
 328         (let ((pos (point)))
 329           (goto-char (point-min))
 330           (unless (re-search-forward (concat "^\\W*" (regexp-quote anchor)
 331                                              "\\b")
 332                                      nil t)
 333             (goto-char pos))))))
 334
 335 (defun muse-visit-link (link &optional other-window)
 336   "Visit the URL or link named by LINK."
 337   (let ((visit-link-function
 338          (muse-get-keyword :visit-link (cadr (muse-project-of-file)) t))
 339         anchor)
 340     (if visit-link-function
 341         (funcall visit-link-function link other-window)
 342       (if (string-match "#" link)
 343           (setq anchor (substring link (match-beginning 0))
 344                 link (substring link 0 (match-beginning 0))))
 345       (muse-visit-link-default link other-window anchor))))
 346
 347 (defun muse-browse-result (style &optional other-window)
 348   "Visit the current page's published result."
 349   (interactive (list (muse-publish-get-style) current-prefix-arg))
 350   (setq style (muse-style style))
 351   (let ((result-path
 352          (muse-publish-output-file buffer-file-name
 353                                    (muse-style-element :path style) style)))
 354     (if (not (file-readable-p result-path))
 355         (error "Cannot open output file '%s'" result-path)
 356       (if other-window
 357           (find-file-other-window result-path)
 358         (let ((func (muse-style-element :browser style t)))
 359           (if func
 360               (funcall func result-path)
 361             (message "The %s publishing style does not support browsing."
 362                      style)))))))
 363
 364 (defun muse-follow-name-at-point (&optional other-window)
 365   "Visit the link at point, or insert a newline if none is found."
 366   (interactive "P")
 367   (let ((link (muse-link-at-point)))
 368     (if link
 369         (muse-visit-link link other-window)
 370       (error "There is no valid link at point"))))
 371
 372 (defun muse-follow-name-at-point-other-window ()
 373   "Visit the link at point in other window."
 374   (interactive)
 375   (muse-follow-name-at-point t))
 376
 377 (defun muse-follow-name-at-mouse (event &optional other-window)
 378   "Visit the link at point, or yank text if none is found."
 379   (interactive "eN")
 380   (save-excursion
 381     (cond ((fboundp 'event-window)      ; XEmacs
 382            (set-buffer (window-buffer (event-window event)))
 383            (and (funcall (symbol-function 'event-point) event)
 384                 (goto-char (funcall (symbol-function 'event-point) event))))
 385           ((fboundp 'posn-window)       ; Emacs
 386            (set-buffer (window-buffer (posn-window (event-start event))))
 387            (goto-char (posn-point (event-start event)))))
 388     (let ((link (muse-link-at-point)))
 389       (if link
 390           (muse-visit-link link other-window)
 391         ;; Fall back to normal binding for this event
 392         (call-interactively
 393          (lookup-key (current-global-map) (this-command-keys)))))))
 394
 395 (defun muse-follow-name-at-mouse-other-window (event)
 396   "Visit the link at point"
 397   (interactive "e")
 398   ;; throw away the old window position, since other-window will
 399   ;; change it anyway
 400   (select-window (car (cadr event)))
 401   (muse-follow-name-at-mouse event t))
 402
 403 (defun muse-next-reference ()
 404   "Move forward to next Muse link or URL, cycling if necessary."
 405   (interactive)
 406   (let ((cycled 0) pos)
 407     (save-excursion
 408       (when (memq (get-text-property (point) 'face)
 409                   '(muse-link-face muse-bad-link-face))
 410         (goto-char (or (next-single-property-change (point) 'face)
 411                        (point-max))))
 412       (while (< cycled 2)
 413         (let ((next (point)))
 414           (if (while (and (null pos)
 415                           (setq next
 416                                 (next-single-property-change
 417                                  next 'face)))
 418                 (when (memq (get-text-property next 'face)
 419                             '(muse-link-face muse-bad-link-face))
 420                   (setq pos next)))
 421               (setq cycled 2)
 422             (goto-char (point-min))
 423             (setq cycled (1+ cycled))))))
 424     (if pos
 425         (goto-char pos))))
 426
 427 (defun muse-previous-reference ()
 428   "Move backward to the next Muse link or URL, cycling if necessary.
 429 This function is not entirely accurate, but it's close enough."
 430   (interactive)
 431   (let ((cycled 0) pos)
 432     (save-excursion
 433       (while (< cycled 2)
 434         (let ((prev (point)))
 435           (if (while (and (null pos)
 436                           (setq prev
 437                                 (previous-single-property-change
 438                                  prev 'face)))
 439               (when (memq (get-text-property prev 'face)
 440                           '(muse-link-face muse-bad-link-face))
 441                 (setq pos prev)))
 442               (setq cycled 2)
 443             (goto-char (point-max))
 444             (setq cycled (1+ cycled))))))
 445     (if pos
 446         (goto-char pos))))
 447
 448 (defun muse-what-changed ()
 449   "Show the unsaved changes that have been made to the current file."
 450   (interactive)
 451   (diff-backup buffer-file-name))
 452
 453 ;;; Generate an index of all known Muse pages
 454
 455 (defun muse-generate-index (&optional as-list exclude-private)
 456   "Generate an index of all Muse pages."
 457   (let ((index (muse-index-as-string as-list exclude-private)))
 458     (with-current-buffer (get-buffer-create "*Muse Index*")
 459       (erase-buffer)
 460       (insert index)
 461       (current-buffer))))
 462
 463 (defun muse-index ()
 464   "Display an index of all known Muse pages."
 465   (interactive)
 466   (message "Generating Muse index...")
 467   (let ((project (muse-project)))
 468     (with-current-buffer (muse-generate-index)
 469       (goto-char (point-min))
 470       (muse-mode)
 471       (setq muse-current-project project)
 472       (pop-to-buffer (current-buffer))))
 473   (message "Generating Muse index...done"))
 474
 475 (defun muse-index-as-string (&optional as-list exclude-private exclude-current)
 476   "Generate an index of all Muse pages.
 477 If AS-LIST is non-nil, insert a dash and spaces before each item.
 478 If EXCLUDE-PRIVATE is non-nil, exclude files that have private permissions.
 479 If EXCLUDE-CURRENT is non-nil, exclude the current file from the output."
 480   (let ((files (sort (copy-alist (muse-project-file-alist))
 481                      (function
 482                       (lambda (l r)
 483                         (string-lessp (car l) (car r)))))))
 484     (when (and exclude-current (muse-page-name))
 485       (setq files (delete (assoc (muse-page-name) files) files)))
 486     (muse-with-temp-buffer
 487       (while files
 488         (unless (and exclude-private
 489                      (muse-project-private-p (cdar files)))
 490           (insert (if as-list " - " "") "[[" (caar files) "]]\n"))
 491         (setq files (cdr files)))
 492       (buffer-string))))
 493
 494 ;;; Insert tags interactively on C-c TAB
 495
 496 (defvar muse-tag-history nil
 497   "List of recently-entered tags; used by `muse-insert-tag'.
 498 If you want a tag to start as the default, you may manually set
 499 this variable to a list.")
 500
 501 (defvar muse-custom-tags nil
 502   "Keep track of any new tags entered in `muse-insert-tag'.
 503 If there are (X)HTML tags that you use frequently with that
 504 function, you might want to set this manually.")
 505
 506 (defun muse-insert-tag (tag)
 507   "Insert a tag interactively with a blank line after it."
 508   (interactive
 509    (list
 510     (completing-read
 511      (concat "Tag: "
 512              (when muse-tag-history
 513                (concat "(default: " (car muse-tag-history) ") ")))
 514      (mapcar 'list (nconc (mapcar 'car muse-publish-markup-tags)
 515                           muse-custom-tags))
 516      nil nil nil 'muse-tag-history
 517      (car muse-tag-history))))
 518   (when (equal tag "")
 519     (setq tag (car muse-tag-history)))
 520   (let ((tag-entry (assoc tag muse-publish-markup-tags))
 521         (options ""))
 522     ;; Add to custom list if no entry exists
 523     (unless tag-entry
 524       (add-to-list 'muse-custom-tags tag))
 525     ;; Get option
 526     (when (nth 2 tag-entry)
 527       (setq options (read-string "Option: ")))
 528     (unless (equal options "")
 529       (setq options (concat " " options)))
 530     ;; Insert the tag, closing if necessary
 531     (when tag (insert (concat "<" tag options ">")))
 532     (when (nth 1 tag-entry)
 533       (insert (concat "\n\n</" tag ">\n"))
 534       (forward-line -2))))
 535
 536 (provide 'muse-mode)
 537
 538 ;;; muse-mode.el ends here