lisp/muse-project.el

   1 ;;; muse-project.el --- handle Muse projects
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is not part of GNU Emacs.
   6
   7 ;; This is free software; you can redistribute it and/or modify it under
   8 ;; the terms of the GNU General Public License as published by the Free
   9 ;; Software Foundation; either version 2, or (at your option) any later
  10 ;; version.
  11 ;;
  12 ;; This is distributed in the hope that it will be useful, but WITHOUT
  13 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 ;; for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;;; Code:
  27
  28 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  29 ;;
  30 ;; Muse Project Maintainance
  31 ;;
  32 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  33
  34 (require 'muse)
  35 (require 'muse-publish)
  36 (require 'cus-edit)
  37
  38 (defgroup muse-project nil
  39   "Options controlling the behavior of Muse project handling."
  40   :group 'muse)
  41
  42 (defcustom muse-before-project-publish-hook nil
  43   "A hook run before a project is published.
  44 Each function is passed the project object, a cons with the format
  45   (PROJNAME . SETTINGS)"
  46   :type 'hook
  47   :group 'muse-project)
  48
  49 (defcustom muse-after-project-publish-hook nil
  50   "A hook run after a project is published.
  51 Each function is passed the project object, a cons with the format
  52   (PROJNAME . SETTINGS)"
  53   :type 'hook
  54   :group 'muse-project)
  55
  56 (defvar muse-project-alist-using-customize nil
  57   "Used internally by Muse to indicate whether `muse-project-alist'
  58 has been modified via the customize interface.")
  59 (make-variable-buffer-local 'muse-project-alist-using-customize)
  60
  61 (defmacro with-muse-project (project &rest body)
  62   `(progn
  63      (unless (muse-project ,project)
  64        (error "Can't find project %s" ,project))
  65      (with-temp-buffer
  66        (muse-mode)
  67        (setq muse-current-project (muse-project ,project))
  68        (muse-project-set-variables)
  69        ,@body)))
  70
  71 (put 'with-muse-project 'lisp-indent-function 0)
  72 (put 'with-muse-project 'edebug-form-spec '(sexp body))
  73
  74 (defun muse-project-alist-get (sym)
  75   "Turn `muse-project-alist' into something we can customize easily."
  76   (when (boundp sym)
  77     (setq muse-project-alist-using-customize t)
  78     (let* ((val (copy-alist (symbol-value sym)))
  79            (head val))
  80       (while val
  81         (let ((head (car (cdar val)))
  82               res)
  83           ;; Turn settings of first part into cons cells, symbol->string
  84           (while head
  85             (cond ((stringp (car head))
  86                    (add-to-list 'res (car head) t)
  87                    (setq head (cdr head)))
  88                   ((symbolp (car head))
  89                    (add-to-list 'res (list (symbol-name (car head))
  90                                            (cadr head)) t)
  91                    (setq head (cddr head)))
  92                   (t
  93                    (setq head (cdr head)))))
  94           (setcdr (car val) (cons res (cdr (cdar val)))))
  95         (let ((styles (cdar val)))
  96           ;; Symbol->string in every style
  97           (while (cdr styles)
  98             (let ((head (cadr styles))
  99                   res)
 100               (while (consp head)
 101                 (setq res (plist-put res (symbol-name (car head))
 102                                      (cadr head)))
 103                 (setq head (cddr head)))
 104               (setcdr styles (cons res (cddr styles))))
 105             (setq styles (cdr styles))))
 106         (setq val (cdr val)))
 107       head)))
 108
 109 (defun muse-project-alist-set (sym val)
 110   "Turn customized version of `muse-project-alist' into something
 111 Muse can make use of."
 112   (set sym val)
 113   (when muse-project-alist-using-customize
 114     ;; Make sure the unescaped version is written to .emacs
 115     (put sym 'saved-value (list (custom-quote val)))
 116     ;; Perform unescaping
 117     (while val
 118       (let ((head (car (cdar val)))
 119             res)
 120         ;; Turn cons cells into flat list, string->symbol
 121         (while head
 122           (cond ((stringp (car head))
 123                  (add-to-list 'res (car head) t))
 124                 ((consp (car head))
 125                  (add-to-list 'res (intern (caar head)) t)
 126                  (add-to-list 'res (car (cdar head)) t)))
 127           (setq head (cdr head)))
 128         (setcdr (car val) (cons res (cdr (cdar val)))))
 129       (let ((styles (cdar val)))
 130         ;; String->symbol in every style
 131         (while (cdr styles)
 132           (let ((head (cadr styles))
 133                 res)
 134             (while (consp head)
 135               (setq res (plist-put res (intern (car head))
 136                                    (cadr head)))
 137               (setq head (cddr head)))
 138             (setcdr styles (cons res (cddr styles))))
 139           (setq styles (cdr styles))))
 140       (setq val (cdr val)))))
 141
 142 (define-widget 'muse-project 'default
 143   "A widget that defines a Muse project."
 144   :format "\n%v"
 145   :value-create 'muse-widget-type-value-create
 146   :value-get 'muse-widget-child-value-get
 147   :value-delete 'ignore
 148   :match 'muse-widget-type-match
 149   :type '(cons :format "    %v"
 150                (repeat :tag "Settings" :format "%{%t%}:\n%v%i\n\n"
 151                        (choice
 152                         (string :tag "Directory")
 153                         (list :tag "Book function"
 154                               (const :tag ":book-funcall" ":book-funcall")
 155                               (choice (function)
 156                                       (sexp :tag "Unknown")))
 157                         (list :tag "Book part"
 158                               (const :tag ":book-part" ":book-part")
 159                               (string :tag "Name"))
 160                         (list :tag "Book style"
 161                               (const :tag ":book-style" ":book-style")
 162                               (string :tag "Style"))
 163                         (list :tag "Default file"
 164                               (const :tag ":default" ":default")
 165                               (string :tag "File"))
 166                         (list :tag "End of book"
 167                               (const :tag ":book-end" ":book-end")
 168                               (const t))
 169                         (list :tag "Force publishing"
 170                               (const :tag ":force-publish" ":force-publish")
 171                               (repeat (string :tag "File")))
 172                         (list :tag "Major mode"
 173                               (const :tag ":major-mode" ":major-mode")
 174                               (choice (function :tag "Mode")
 175                                       (sexp :tag "Unknown")))
 176                         (list :tag "New chapter"
 177                               (const :tag ":book-chapter" ":book-chapter")
 178                               (string :tag "Name"))
 179                         (list :tag "No chapters"
 180                               (const :tag ":nochapters" ":nochapters")
 181                               (const t))
 182                         (list :tag "Set variables"
 183                               (const :tag ":set" ":set")
 184                               (repeat (list :inline t
 185                                             (symbol :tag "Variable")
 186                                             (sexp :tag "Setting"))))
 187                         (list :tag "Visit links using"
 188                               (const :tag ":visit-link" ":visit-link")
 189                               (choice (function)
 190                                       (sexp :tag "Unknown")))))
 191                (repeat :tag "Styles" :format "%{%t%}:\n%v%i\n\n"
 192                        (set :tag "Style"
 193                             (list :inline t
 194                                   :tag "Publishing style"
 195                                   (const :tag ":base" ":base")
 196                                   (string :tag "Style"))
 197                             (list :inline t
 198                                   :tag "Base URL"
 199                                   (const :tag ":base-url" ":base-url")
 200                                   (string :tag "URL"))
 201                             (list :inline t
 202                                   :tag "Exclude matching"
 203                                   (const :tag ":exclude" ":exclude")
 204                                   (regexp))
 205                             (list :inline t
 206                                   :tag "Include matching"
 207                                   (const :tag ":include" ":include")
 208                                   (regexp))
 209                             (list :inline t
 210                                   :tag "Timestamps file"
 211                                   (const :tag ":timestamps" ":timestamps")
 212                                   (file))
 213                             (list :inline t
 214                                   :tag "Path"
 215                                   (const :tag ":path" ":path")
 216                                   (string :tag "Path"))))))
 217
 218 (defcustom muse-project-alist nil
 219   "An alist of Muse projects.
 220 A project defines a fileset, and a list of custom attributes for use
 221 when publishing files in that project."
 222   :type '(choice (const :tag "No projects defined." nil)
 223                  (repeat (cons :format "%{%t%}:\n\n%v"
 224                                :tag "Project" :indent 4
 225                                (string :tag "Project name")
 226                                muse-project))
 227                  (sexp :tag "Cannot parse expression"))
 228   :get 'muse-project-alist-get
 229   :set 'muse-project-alist-set
 230   :group 'muse-project)
 231
 232 ;; Make it easier to specify a muse-project-alist entry
 233
 234 (defcustom muse-project-ignore-regexp
 235   (concat "\\`\\(.*\\.?#.*\\|.*,v\\|.*~\\|\\.\\.?\\|,.*\\)\\'\\|"
 236           "/\\(CVS\\|RCS\\|\\.arch-ids\\|{arch}\\|,.*\\)\\(/\\|\\'\\)")
 237   "A regexp matching files to be ignored in Wiki directories.
 238
 239 You should set case-fold-search to nil before using this regexp
 240 in code."
 241   :type 'regexp
 242   :group 'muse-regexp)
 243
 244 (defun muse-project-recurse-directory (base)
 245   "Recusively retrieve all of the directories underneath BASE.
 246 A list of these directories is returned.
 247 Directories starting with \".\" will be ignored, as well as those
 248 which match `muse-project-ignore-regexp'."
 249   (let ((case-fold-search nil)
 250         list dir)
 251     (when (and (file-directory-p base)
 252                (not (string-match muse-project-ignore-regexp base)))
 253       (dolist (file (directory-files base t "^[^.]"))
 254         (when (and (file-directory-p file)
 255                    (not (string-match muse-project-ignore-regexp file)))
 256           (setq dir (file-name-nondirectory file))
 257           (push dir list)
 258           (nconc list (mapcar #'(lambda (item)
 259                                   (concat dir "/" item))
 260                               (muse-project-recurse-directory file)))))
 261       list)))
 262
 263 (defun muse-project-alist-styles (entry-dir output-dir style)
 264   "Return a list of styles to use in a `muse-project-alist' entry.
 265 ENTRY-DIR is the top-level directory of the project.
 266 OUTPUT-DIR is where Muse files are published, keeping directory structure.
 267 STYLE is the publishing style to use.
 268
 269 For an example of the use of this function, see
 270 `examples/mwolson/muse-init.el' from the Muse distribution."
 271   (cons `(:base ,style :path ,(expand-file-name output-dir)
 272                 :include ,(concat "/" (file-name-nondirectory entry-dir)
 273                                   "/[^/]+$"))
 274         (mapcar (lambda (dir);
 275                   `(:base ,style
 276                           :path ,(expand-file-name dir output-dir)
 277                           :include ,(concat "/" dir "/[^/]+$")))
 278                 (muse-project-recurse-directory entry-dir))))
 279
 280 (defun muse-project-alist-dirs (entry-dir)
 281   "Return a list of directories to use in a `muse-project-alist' entry.
 282 ENTRY-DIR is the top-level directory of the project.
 283
 284 For an example of the use of this function, see
 285 `examples/mwolson/muse-init.el' from the Muse distribution."
 286   (cons (expand-file-name entry-dir)
 287         (mapcar (lambda (dir) (expand-file-name dir entry-dir))
 288                 (muse-project-recurse-directory entry-dir))))
 289
 290 ;; Constructing the file-alist
 291
 292 (defvar muse-project-file-alist nil
 293   "This variable is automagically constructed as needed.")
 294
 295 (defvar muse-current-project nil
 296   "Project we are currently visiting.")
 297 (make-variable-buffer-local 'muse-current-project)
 298
 299 (defsubst muse-project (&optional project)
 300   "Resolve the given PROJECT into a full Muse project, if it is a string."
 301   (if (null project)
 302       (or muse-current-project
 303           (muse-project-of-file))
 304     (if (stringp project)
 305         (assoc project muse-project-alist)
 306       (muse-assert (consp project))
 307       project)))
 308
 309 (defsubst muse-project-page-file (page project &optional no-check-p)
 310   "Return a filename if PAGE exists within the given Muse PROJECT."
 311   (setq project (muse-project project))
 312   (cdr (assoc page (muse-project-file-alist project no-check-p))))
 313
 314 (defun muse-project-private-p (file)
 315   "Return non-nil if NAME is a private page with PROJECT."
 316   (unless muse-under-windows-p
 317     (setq file (file-truename file))
 318     (if (file-attributes file)  ; don't publish if no attributes exist
 319         (or (when (eq ?- (aref (nth 8 (file-attributes
 320                                        (file-name-directory file))) 7))
 321               (message (concat
 322                         "The " (file-name-directory file)
 323                         " directory must be readable by others"
 324                         " in order for its contents to be published.")))
 325             (eq ?- (aref (nth 8 (file-attributes file)) 7)))
 326       t)))
 327
 328 (defun muse-project-file-entries (path)
 329   (let* ((names (list t))
 330          (lnames names)
 331          (case-fold-search nil))
 332     (cond
 333      ((file-directory-p path)
 334       (dolist (file (directory-files
 335                      path t (when (and muse-file-extension
 336                                        (not (string= muse-file-extension "")))
 337                               (concat "." muse-file-extension "\\'"))))
 338         (unless (or (string-match muse-project-ignore-regexp file)
 339                     (file-directory-p file))
 340           (setcdr lnames
 341                   (cons (cons (muse-page-name file) file) nil))
 342           (setq lnames (cdr lnames)))))
 343      ((file-readable-p path)
 344       (setcdr lnames
 345               (cons (cons (muse-page-name path) path) nil))
 346       (setq lnames (cdr lnames)))
 347      (t                                 ; regexp
 348       (muse-assert (file-name-directory path))
 349       (dolist (file (directory-files
 350                      (file-name-directory path) t
 351                      (file-name-nondirectory path)))
 352         (unless (string-match muse-project-ignore-regexp file)
 353           (setcdr lnames
 354                   (cons (cons (muse-page-name file) file) nil))
 355           (setq lnames (cdr lnames))))))
 356     (cdr names)))
 357
 358 (defun muse-project-file-alist (&optional project no-check-p)
 359   "Return member filenames for the given Muse PROJECT.
 360 On UNIX, this list is only updated if one of the directories'
 361 contents have changed.  On Windows, it is always reread from
 362 disk."
 363   (setq project (muse-project project))
 364   (let* ((file-alist (assoc (car project) muse-project-file-alist))
 365          (last-mod (cdr (cdr file-alist))))
 366     ;; Determine the last modified of any directory mentioned in the
 367     ;; project's pattern list
 368     (unless (or muse-under-windows-p no-check-p)
 369       (let ((pats (cadr project)))
 370         (while pats
 371           (if (symbolp (car pats))
 372               (setq pats (cddr pats))
 373             (let* ((fnd (file-name-directory (car pats)))
 374                    (dir (cond ((file-directory-p (car pats))
 375                                (car pats))
 376                               ((and (not (file-readable-p (car pats)))
 377                                     fnd
 378                                     (file-directory-p fnd))
 379                                fnd))))
 380               (when dir
 381                 (let ((mod-time (nth 5 (file-attributes dir))))
 382                   (when (or (null last-mod)
 383                             (and mod-time
 384                                  (muse-time-less-p last-mod mod-time)))
 385                     (setq last-mod mod-time)))))
 386             (setq pats (cdr pats))))))
 387     ;; Either return the currently known list, or read it again from
 388     ;; disk
 389     (if (or (and no-check-p (cadr file-alist))
 390             (not (or muse-under-windows-p
 391                      (null (cddr file-alist))
 392                      (null last-mod)
 393                      (muse-time-less-p (cddr file-alist) last-mod))))
 394         (cadr file-alist)
 395       (if file-alist
 396           (setcdr (cdr file-alist) last-mod)
 397         (setq file-alist (cons (car project) (cons nil last-mod))
 398               muse-project-file-alist
 399               (cons file-alist muse-project-file-alist)))
 400       ;; Read in all of the file entries
 401       (save-match-data
 402         (setcar
 403          (cdr file-alist)
 404          (let* ((names (list t))
 405                 (pats (cadr project)))
 406            (while pats
 407              (if (symbolp (car pats))
 408                  (setq pats (cddr pats))
 409                (nconc names (muse-project-file-entries (car pats)))
 410                (setq pats (cdr pats))))
 411            (cdr names)))))))
 412
 413 (defun muse-project-of-file (&optional pathname)
 414   "Determine which project the given PATHNAME relates to.
 415 If PATHNAME is nil, the current buffer's filename is used."
 416   (if (and (null pathname) muse-current-project)
 417       muse-current-project
 418     (unless pathname (setq pathname (muse-current-file)))
 419     (save-match-data
 420       (when (and (stringp pathname)
 421                  (not (string= pathname ""))
 422                  (not (let ((case-fold-search nil))
 423                         (string-match muse-project-ignore-regexp pathname))))
 424         (let* ((file (file-truename pathname))
 425                (dir  (file-name-directory file))
 426                (project-entry muse-project-alist)
 427                found)
 428           (while (and project-entry (not found))
 429             (let ((pats (car (cdar project-entry))))
 430               (while (and pats (not found))
 431                 (if (symbolp (car pats))
 432                     (setq pats (cddr pats))
 433                   (let ((truename (file-truename (car pats))))
 434                     (if (or (string= truename file)
 435                             (string= truename dir)
 436                             (string-match (regexp-quote truename) file))
 437                         (setq found (car project-entry))))
 438                   (setq pats (cdr pats))))
 439               (setq project-entry (cdr project-entry))))
 440           found)))))
 441
 442 (defun muse-read-project (prompt &optional no-check-p no-assume)
 443   "Read a project name from the minibuffer, if it can't be figured
 444   out."
 445   (if (null muse-project-alist)
 446       (error "There are no Muse projects defined; see `muse-project-alist'.")
 447     (or (unless no-check-p
 448           (muse-project-of-file))
 449         (if (and (not no-assume)
 450                  (= 1 (length muse-project-alist)))
 451             (car muse-project-alist)
 452           (assoc (completing-read prompt muse-project-alist)
 453                  muse-project-alist)))))
 454
 455 (defvar muse-project-page-history nil)
 456
 457 (defun muse-read-project-file (project prompt &optional default)
 458   (let ((name (completing-read prompt (muse-project-file-alist project)
 459                                nil nil nil 'muse-project-page-history
 460                                default)))
 461     (cons name (muse-project-page-file name project))))
 462
 463 ;;;###autoload
 464 (defun muse-project-find-file (name project &optional command directory)
 465   "Open the Muse page given by NAME in PROJECT.
 466 If COMMAND is non-nil, it is the function used to visit the file.
 467 If DIRECTORY is non-nil, it is the directory in which the page
 468 will be created if it does not already exist.  Otherwise, the
 469 first directory within the project's fileset is used."
 470   (interactive
 471    (let* ((project (muse-read-project "Find in project: "
 472                                       current-prefix-arg))
 473           (default (muse-get-keyword :default (cadr project)))
 474           (entry (muse-read-project-file
 475                   project (if default
 476                               (format "Find page: (default: %s) "
 477                                       default)
 478                             "Find page: ")
 479                   default)))
 480      (list entry project)))
 481   (setq project (muse-project project))
 482   (let ((project-name (car project)))
 483     (unless (interactive-p)
 484       (setq project (muse-project project)
 485             name (cons name (muse-project-page-file name project))))
 486     ;; If we're given a relative or absolute filename, open it as-is
 487     (if (and (car name)
 488              (save-match-data (string-match muse-file-regexp (car name))))
 489         (setcdr name (car name))
 490       ;; At this point, name is (PAGE . FILE).
 491       (unless (cdr name)
 492         (let ((pats (cadr project)))
 493           (while (and pats (null directory))
 494             (if (symbolp (car pats))
 495                 (setq pats (cddr pats))
 496               (if (file-directory-p (car pats))
 497                   (setq directory (car pats) pats nil)
 498                 (setq pats (cdr pats))))))
 499         (when directory
 500           (let ((filename (expand-file-name
 501                            (if (and muse-file-extension
 502                                     (not (string= muse-file-extension "")))
 503                                (concat (car name) "." muse-file-extension)
 504                              (car name))
 505                            directory)))
 506             (unless (file-exists-p directory)
 507               (make-directory directory t))
 508             (setcdr name filename)))))
 509     ;; Open the file
 510     (if (cdr name)
 511         (funcall (or command 'find-file) (cdr name))
 512       (error "There is no page %s in project %s."
 513              (car name) project-name))))
 514
 515 (defun muse-project-applicable-styles (file styles &optional ignore-regexp)
 516   "Given STYLES, return a list of the ones that are considered for FILE.
 517 The name of a project may be used for STYLES."
 518   (when (stringp styles)
 519     (setq styles (cddr (muse-project styles))))
 520   (when (and file styles)
 521     (let (used-styles)
 522       (dolist (style styles)
 523         (let ((include-regexp (muse-style-element :include style))
 524               (exclude-regexp (muse-style-element :exclude style)))
 525           (when (and (or ignore-regexp
 526                          (and (null include-regexp)
 527                               (null exclude-regexp))
 528                          (if include-regexp
 529                              (string-match include-regexp file)
 530                            (not (string-match exclude-regexp file))))
 531                      (or (not (file-exists-p file))
 532                          (not (muse-project-private-p file))))
 533             (setq used-styles (cons style used-styles)))))
 534       (nreverse used-styles))))
 535
 536 (defun muse-project-publish-file (file styles &optional force ignore-regexp)
 537   (setq styles (muse-project-applicable-styles file styles ignore-regexp))
 538   (let (published)
 539     (dolist (style styles)
 540       (let ((output-dir (muse-style-element :path style)))
 541         ;; ensure the publishing location is available
 542         (unless (file-exists-p output-dir)
 543           (message "Creating publishing directory %s" output-dir)
 544           (make-directory output-dir t))
 545         ;; publish the member file!
 546         (if (muse-publish-file file style output-dir force)
 547             (setq published t))))
 548     published))
 549
 550 (defun muse-project-save-buffers (&optional project)
 551   (setq project (muse-project project))
 552   (map-y-or-n-p
 553    (function
 554     (lambda (buffer)
 555       (and (buffer-modified-p buffer)
 556            (not (buffer-base-buffer buffer))
 557            (or (buffer-file-name buffer)
 558                (progn
 559                  (set-buffer buffer)
 560                  (and buffer-offer-save
 561                       (> (buffer-size) 0))))
 562            (with-current-buffer buffer
 563              (let ((proj (muse-project-of-file)))
 564                (and proj (string= (car proj)
 565                                   (car project)))))
 566            (if (buffer-file-name buffer)
 567                (format "Save file %s? "
 568                        (buffer-file-name buffer))
 569              (format "Save buffer %s? "
 570                      (buffer-name buffer))))))
 571    (function
 572     (lambda (buffer)
 573       (set-buffer buffer)
 574       (save-buffer)))
 575    (buffer-list)
 576    '("buffer" "buffers" "save")
 577    (if (boundp 'save-some-buffers-action-alist)
 578        save-some-buffers-action-alist)))
 579
 580 ;;;###autoload
 581 (defun muse-project-publish (project &optional force)
 582   "Publish the pages of PROJECT that need publishing."
 583   (interactive (list (muse-read-project "Publish project: " nil t)
 584                      current-prefix-arg))
 585   (setq project (muse-project project))
 586   (let ((styles (cddr project))
 587         (muse-current-project project)
 588         published)
 589     ;; determine the style from the project, or else ask
 590     (unless styles
 591       (setq styles (list (muse-publish-get-style))))
 592     ;; prompt to save any buffers related to this project
 593     (muse-project-save-buffers project)
 594     ;; run hook before publishing begins
 595     (run-hook-with-args 'muse-before-project-publish-hook project)
 596     ;; publish all files in the project, for each style; the actual
 597     ;; publishing will only happen if the files are newer than the
 598     ;; last published output, or if the file is listed in
 599     ;; :force-publish.  Files in :force-publish will not trigger the
 600     ;; "All pages need to be published" message.
 601     (let ((forced-files (muse-get-keyword :force-publish (cadr project)))
 602           (file-alist (muse-project-file-alist project)))
 603       (dolist (pair file-alist)
 604         (when (muse-project-publish-file (cdr pair) styles force)
 605           (setq forced-files (delete (car pair) forced-files))
 606           (setq published t)))
 607       (dolist (file forced-files)
 608         (muse-project-publish-file (cdr (assoc file file-alist)) styles t)))
 609     ;; run hook after publishing ends
 610     (run-hook-with-args 'muse-after-project-publish-hook project)
 611     ;; notify the user that everything is now done
 612     (if published
 613         (message "All pages in %s have been published." (car project))
 614       (message "No pages in %s need publishing at this time."
 615                (car project)))))
 616
 617 (defun muse-project-batch-publish ()
 618   "Publish Muse files in batch mode."
 619   (let ((muse-batch-publishing-p t)
 620         force)
 621     (if (string= "--force" (or (car command-line-args-left) ""))
 622         (setq force t
 623               command-line-args-left (cdr command-line-args-left)))
 624     (if command-line-args-left
 625         (dolist (project command-line-args-left)
 626           (message "Publishing project %s ..." project)
 627           (muse-project-publish project force))
 628       (message "No projects specified."))))
 629
 630 (eval-when-compile
 631   (put 'make-local-hook 'byte-compile nil))
 632
 633 (defun muse-project-set-variables ()
 634   "Load project-specific variables."
 635   (let ((vars (muse-get-keyword :set (cadr muse-current-project)))
 636         sym custom-set var)
 637     (while vars
 638       (setq sym (car vars))
 639       (setq custom-set (or (get sym 'custom-set) 'set))
 640       (setq var (if (eq (get sym 'custom-type) 'hook)
 641                     (make-local-hook sym)
 642                   (make-local-variable sym)))
 643       (funcall custom-set var (car (cdr vars)))
 644       (setq vars (cdr (cdr vars))))))
 645
 646 (defun muse-project-delete-output-files (project)
 647   (interactive
 648    (list (muse-read-project "Remove all output files for project: " nil t)))
 649   (setq project (muse-project project))
 650   (let ((file-alist (muse-project-file-alist project))
 651         (styles (cddr project))
 652         output-file path)
 653     (dolist (entry file-alist)
 654       (dolist (style styles)
 655         (setq output-file
 656               (and (setq path (muse-style-element :path style))
 657                    (expand-file-name
 658                     (concat (muse-style-element :prefix style)
 659                             (car entry)
 660                             (or (muse-style-element :osuffix style)
 661                                 (muse-style-element :suffix style)))
 662                     path)))
 663         (if output-file
 664             (muse-delete-file-if-exists output-file))))))
 665
 666 (provide 'muse-project)
 667
 668 ;;; muse-project.el ends here