share/vim/vim72/ftplugin/aspvbs.vim

   1 " Vim filetype plugin file
   2 " Language:     aspvbs
   3 " Maintainer:   Dan Sharp <dwsharp at hotmail dot com>
   4 " Last Changed: 2004 Jun 28
   5 " URL:          http://mywebpage.netscape.com/sharppeople/vim/ftplugin
   6
   7 if exists("b:did_ftplugin") | finish | endif
   8
   9 " Make sure the continuation lines below do not cause problems in
  10 " compatibility mode.
  11 let s:save_cpo = &cpo
  12 set cpo-=C
  13
  14 " Define some defaults in case the included ftplugins don't set them.
  15 let s:undo_ftplugin = ""
  16 let s:browsefilter = "HTML Files (*.html, *.htm)\t*.htm*\n" .
  17             \        "All Files (*.*)\t*.*\n"
  18 let s:match_words = ""
  19
  20 runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
  21 let b:did_ftplugin = 1
  22
  23 " Override our defaults if these were set by an included ftplugin.
  24 if exists("b:undo_ftplugin")
  25     let s:undo_ftplugin = b:undo_ftplugin
  26 endif
  27 if exists("b:browsefilter")
  28     let s:browsefilter = b:browsefilter
  29 endif
  30 if exists("b:match_words")
  31     let s:match_words = b:match_words
  32 endif
  33
  34 " ASP:  Active Server Pages (with Visual Basic Script)
  35 " thanks to Gontran BAERTS
  36 if exists("loaded_matchit")
  37   let s:notend = '\%(\<end\s\+\)\@<!'
  38   let b:match_ignorecase = 1
  39   let b:match_words =
  40   \ s:notend . '\<if\>\%(.\{-}then\s\+\w\)\@!:\<elseif\>:^\s*\<else\>:\<end\s\+\<if\>,' .
  41   \ s:notend . '\<select\s\+case\>:\<case\>:\<case\s\+else\>:\<end\s\+select\>,' .
  42   \ '^\s*\<sub\>:\<end\s\+sub\>,' .
  43   \ '^\s*\<function\>:\<end\s\+function\>,' .
  44   \ '\<class\>:\<end\s\+class\>,' .
  45   \ '^\s*\<do\>:\<loop\>,' .
  46   \ '^\s*\<for\>:\<next\>,' .
  47   \ '\<while\>:\<wend\>,' .
  48   \ s:match_words
  49 endif
  50
  51 " Change the :browse e filter to primarily show ASP-related files.
  52 if has("gui_win32")
  53     let  b:browsefilter="ASP Files (*.asp)\t*.asp\n" . s:browsefilter
  54 endif
  55
  56 let b:undo_ftplugin = "unlet! b:match_words b:match_ignorecase b:browsefilter | " . s:undo_ftplugin
  57
  58 " Restore the saved compatibility options.
  59 let &cpo = s:save_cpo