share/WinGit/install.iss

   1 #define APP_NAME     'Git'
   2 #define APP_VERSION  '%APPVERSION%'
   3 #define APP_URL      'http://code.google.com/p/msysgit/'
   4 #define APP_BUILTINS 'etc\fileList-builtins.txt'
   5
   6 [Setup]
   7 ; Compiler-related
   8 InternalCompressLevel=max
   9 OutputBaseFilename={#emit APP_NAME+'-'+APP_VERSION}
  10 OutputDir=%OUTPUTDIR%
  11 SolidCompression=yes
  12
  13 ; Installer-related
  14 AllowNoIcons=yes
  15 AppName={#emit APP_NAME}
  16 AppPublisherURL={#emit APP_URL}
  17 AppVersion={#emit APP_VERSION}
  18 AppVerName={#emit APP_NAME+' '+APP_VERSION}
  19 ChangesEnvironment=yes
  20 DefaultDirName={pf}\{#emit APP_NAME}
  21 DefaultGroupName={#emit APP_NAME}
  22 DisableReadyPage=yes
  23 LicenseFile=gpl-2.0.rtf
  24 PrivilegesRequired=none
  25 UninstallDisplayIcon=etc\git.ico
  26
  27 ; Cosmetic
  28 SetupIconFile=etc\git.ico
  29 WizardSmallImageFile=git.bmp
  30
  31 [Tasks]
  32 Name: quicklaunchicon; Description: "Create a &Quick Launch icon"; GroupDescription: "Additional icons:"; Flags: checkedonce
  33 Name: desktopicon; Description: "Create a &Desktop icon"; GroupDescription: "Additional icons:"; Flags: checkedonce
  34 Name: shellextension; Description: "Add ""Git Ba&sh Here"""; GroupDescription: "Windows Explorer integration:"; Flags: checkedonce
  35 Name: guiextension; Description: "Add ""Git &GUI Here"""; GroupDescription: "Windows Explorer integration:"; Flags: checkedonce
  36
  37 [Files]
  38 Source: "*"; DestDir: "{app}"; Excludes: "\*.bmp, gpl-2.0.txt, \install.*, \tmp.*, \bin\*install*"; Flags: recursesubdirs
  39
  40 [Icons]
  41 Name: "{group}\Git GUI"; Filename: "{app}\bin\wish.exe"; Parameters: """{app}\bin\git-gui"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"
  42 Name: "{group}\Git Bash"; Filename: "{syswow64}\cmd.exe"; Parameters: "/c """"{app}\bin\sh.exe"" --login -i"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"
  43 Name: "{group}\Uninstall Git"; Filename: "{uninstallexe}"
  44 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\Git Bash"; Filename: "{syswow64}\cmd.exe"; Parameters: "/c """"{app}\bin\sh.exe"" --login -i"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"; Tasks: quicklaunchicon
  45 Name: "{code:GetShellFolder|desktop}\Git Bash"; Filename: "{syswow64}\cmd.exe"; Parameters: "/c """"{app}\bin\sh.exe"" --login -i"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"; Tasks: desktopicon
  46
  47 [Messages]
  48 BeveledLabel={#emit APP_URL}
  49
  50 [UninstallDelete]
  51 Type: files; Name: "{app}\bin\git-*.exe"
  52 Type: dirifempty; Name: "{app}\home\{username}"
  53 Type: dirifempty; Name: "{app}\home"
  54
  55 [Code]
  56 {
  57     Helper methods
  58 }
  59
  60 function GetShellFolder(Param:string):string;
  61 begin
  62     if IsAdminLoggedOn then begin
  63         Param:='{common'+Param+'}';
  64     end else begin
  65         Param:='{user'+Param+'}';
  66     end;
  67     Result:=ExpandConstant(Param);
  68 end;
  69
  70 function CreateHardLink(lpFileName,lpExistingFileName:string;lpSecurityAttributes:Integer):Boolean;
  71 external 'CreateHardLinkA@Kernel32.dll';
  72
  73 function GetEnvStrings(VarName:string;AllUsers:Boolean):TArrayOfString;
  74 var
  75     Path:string;
  76     i:Longint;
  77     p:Integer;
  78 begin
  79     Path:='';
  80
  81     // See http://www.jrsoftware.org/isfaq.php#env
  82     if AllUsers then begin
  83         RegQueryStringValue(HKEY_LOCAL_MACHINE,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment',VarName,Path);
  84     end else begin
  85         RegQueryStringValue(HKEY_CURRENT_USER,'Environment',VarName,Path);
  86     end;
  87
  88     // Make sure we have at least one semicolon.
  89     Path:=Path+';';
  90
  91     // Split the directories in PATH into an array of strings.
  92     i:=0;
  93     SetArrayLength(Result,0);
  94
  95     p:=Pos(';',Path);
  96     while p>0 do begin
  97         SetArrayLength(Result,i+1);
  98         if p>1 then begin
  99             Result[i]:=Copy(Path,1,p-1);
 100             i:=i+1;
 101         end;
 102         Path:=Copy(Path,p+1,Length(Path));
 103         p:=Pos(';',Path);
 104     end;
 105 end;
 106
 107 function SetEnvStrings(VarName:string;AllUsers,DeleteIfEmpty:Boolean;DirStrings:TArrayOfString):Boolean;
 108 var
 109     Path,KeyName:string;
 110     i:Longint;
 111 begin
 112     // Merge all non-empty directory strings into a PATH variable.
 113     Path:='';
 114     for i:=0 to GetArrayLength(DirStrings)-1 do begin
 115         if Length(DirStrings[i])>0 then begin
 116             if Length(Path)>0 then begin
 117                 Path:=Path+';'+DirStrings[i];
 118             end else begin
 119                 Path:=DirStrings[i];
 120             end;
 121         end;
 122     end;
 123
 124     // See http://www.jrsoftware.org/isfaq.php#env
 125     if AllUsers then begin
 126         KeyName:='SYSTEM\CurrentControlSet\Control\Session Manager\Environment';
 127         if DeleteIfEmpty and (Length(Path)=0) then begin
 128             Result:=(not RegValueExists(HKEY_LOCAL_MACHINE,KeyName,VarName))
 129                       or RegDeleteValue(HKEY_LOCAL_MACHINE,KeyName,VarName);
 130         end else begin
 131             Result:=RegWriteStringValue(HKEY_LOCAL_MACHINE,KeyName,VarName,Path);
 132         end;
 133     end else begin
 134         KeyName:='Environment';
 135         if DeleteIfEmpty and (Length(Path)=0) then begin
 136             Result:=(not RegValueExists(HKEY_CURRENT_USER,KeyName,VarName))
 137                       or RegDeleteValue(HKEY_CURRENT_USER,KeyName,VarName);
 138         end else begin
 139             Result:=RegWriteStringValue(HKEY_CURRENT_USER,KeyName,VarName,Path);
 140         end;
 141     end;
 142 end;
 143
 144 {
 145     Installer code
 146 }
 147
 148 var
 149     EnvPage:TWizardPage;
 150     RdbGitBash,RdbGitCmd,RdbGitCmdTools:TRadioButton;
 151
 152 procedure InitializeWizard;
 153 var
 154     LblGitBash,LblGitCmd,LblGitCmdTools,LblGitCmdToolsWarn:TLabel;
 155 begin
 156     // Create a custom page for modifying the environment.
 157     EnvPage:=CreateCustomPage(
 158         wpSelectTasks,
 159         'Adjusting your PATH environment',
 160         'How would you like to use Git from the command line?'
 161     );
 162
 163     // 1st choice
 164     RdbGitBash:=TRadioButton.Create(EnvPage);
 165     with RdbGitBash do begin
 166       Parent:=EnvPage.Surface;
 167       Caption:='Use Git Bash only';
 168       Left:=ScaleX(4);
 169       Top:=ScaleY(8);
 170       Width:=ScaleX(129);
 171       Height:=ScaleY(17);
 172       Font.Style:=[fsBold];
 173       TabOrder:=0;
 174       Checked:=True;
 175     end;
 176     LblGitBash:=TLabel.Create(EnvPage);
 177     with LblGitBash do begin
 178         Parent:=EnvPage.Surface;
 179         Caption:=
 180             'This is the most conservative choice if you are concerned about the' + #13 +
 181             'stability of your system. Your PATH will not be modified.';
 182         Left:=ScaleX(28);
 183         Top:=ScaleY(32);
 184         Width:=ScaleX(324);
 185         Height:=ScaleY(26);
 186     end;
 187
 188     // 2nd choice
 189     RdbGitCmd:=TRadioButton.Create(EnvPage);
 190     with RdbGitCmd do begin
 191       Parent:=EnvPage.Surface;
 192       Caption:='Run Git from the Windows Command Prompt';
 193       Left:=ScaleX(4);
 194       Top:=ScaleY(76);
 195       Width:=ScaleX(281);
 196       Height:=ScaleY(17);
 197       Font.Style:=[fsBold];
 198       TabOrder:=1;
 199     end;
 200     LblGitCmd:=TLabel.Create(EnvPage);
 201     with LblGitCmd do begin
 202         Parent:=EnvPage.Surface;
 203         Caption:=
 204             'This option is considered safe and no conflicts with other tools are' + #13 +
 205             'known. Only Git will be added to your PATH.';
 206         Left:=ScaleX(28);
 207         Top:=ScaleY(100);
 208         Width:=ScaleX(316);
 209         Height:=ScaleY(26);
 210     end;
 211
 212     // 3rd choice
 213     RdbGitCmdTools:=TRadioButton.Create(EnvPage);
 214     with RdbGitCmdTools do begin
 215       Parent:=EnvPage.Surface;
 216       Caption:='Run Git and included Unix tools from the Windows Command Prompt';
 217       Left:=ScaleX(4);
 218       Top:=ScaleY(152);
 219       Width:=ScaleX(405);
 220       Height:=ScaleY(17);
 221       Font.Style:=[fsBold];
 222       TabOrder:=2;
 223     end;
 224     LblGitCmdTools:=TLabel.Create(EnvPage);
 225     with LblGitCmdTools do begin
 226         Parent:=EnvPage.Surface;
 227         Caption:='Both Git and the Unix tools will be added to your PATH.';
 228         Left:=ScaleX(28);
 229         Top:=ScaleY(176);
 230         Width:=ScaleX(280);
 231         Height:=ScaleY(13);
 232     end;
 233     LblGitCmdToolsWarn:=TLabel.Create(EnvPage);
 234     with LblGitCmdToolsWarn do begin
 235         Parent:=EnvPage.Surface;
 236         Caption:=
 237             'Warning: This will override Windows tools like find.exe and' + #13 +
 238             'sort.exe. Select this option only if you understand the implications.';
 239         Left:=ScaleX(28);
 240         Top:=ScaleY(192);
 241         Width:=ScaleX(376);
 242         Height:=ScaleY(26);
 243         Font.Color:=255;
 244         Font.Style:=[fsBold];
 245     end;
 246 end;
 247
 248 procedure CurStepChanged(CurStep:TSetupStep);
 249 var
 250     AppDir,FileName,Cmd:string;
 251     BuiltIns,EnvPath,EnvHome:TArrayOfString;
 252     Count,i:Longint;
 253     IsNTFS:Boolean;
 254     RootKey:Integer;
 255 begin
 256     if CurStep<>ssPostInstall then begin
 257         Exit;
 258     end;
 259
 260     AppDir:=ExpandConstant('{app}');
 261
 262     {
 263         Create the built-ins
 264     }
 265
 266     // Load the built-ins from a text file.
 267     FileName:=ExpandConstant('{app}\'+'{#emit APP_BUILTINS}');
 268     if not LoadStringsFromFile(FileName,BuiltIns) then begin
 269         MsgBox('Unable to read file "{#emit APP_BUILTINS}".',mbError,MB_OK);
 270         Exit;
 271     end;
 272
 273     // Check if we are running on NTFS.
 274     IsNTFS:=False;
 275     if SetNTFSCompression(AppDir+'\bin\git.exe',true) then begin
 276         IsNTFS:=SetNTFSCompression(AppDir+'\bin\git.exe',false);
 277     end;
 278
 279     Count:=GetArrayLength(BuiltIns)-1;
 280
 281     // Map the built-ins to git.exe.
 282     if IsNTFS then begin
 283         for i:=0 to Count do begin
 284             FileName:=AppDir+'\'+BuiltIns[i];
 285
 286             // On non-NTFS partitions, create hard links.
 287             CreateHardLink(FileName,AppDir+'\bin\git.exe',0);
 288         end;
 289     end else begin
 290         for i:=0 to GetArrayLength(BuiltIns)-1 do begin
 291             FileName:=AppDir+'\'+BuiltIns[i];
 292
 293             // On non-NTFS partitions, copy simply the files.
 294             FileCopy(AppDir+'\bin\git.exe',FileName,false);
 295         end;
 296     end;
 297
 298     {
 299         Modify the environment
 300
 301         This must happen no later than ssPostInstall to make
 302         "ChangesEnvironment=yes" not happend before the change!
 303     }
 304
 305     // Get the current user's directories in PATH.
 306     EnvPath:=GetEnvStrings('PATH',IsAdminLoggedOn);
 307
 308     // First, remove the installation directory from PATH in any case.
 309     for i:=0 to GetArrayLength(EnvPath)-1 do begin
 310         if Pos(AppDir,EnvPath[i])=1 then begin
 311             EnvPath[i]:='';
 312         end;
 313     end;
 314
 315     // Delete HOME if a previous installation modified it.
 316     EnvHome:=GetEnvStrings('HOME',IsAdminLoggedOn);
 317     if (GetArrayLength(EnvHome)=1) and
 318        (CompareStr(EnvHome[0],GetIniString('Environment','HOME','',AppDir+'\setup.ini'))=0) then begin
 319         if not SetEnvStrings('HOME',IsAdminLoggedOn,True,[]) then begin
 320             MsgBox('Unable to reset HOME prior to install.',mbError,MB_OK);
 321         end;
 322     end;
 323
 324     // Modify the PATH variable as requested by the user.
 325     if RdbGitCmd.Checked or RdbGitCmdTools.Checked then begin
 326         i:=GetArrayLength(EnvPath);
 327         SetArrayLength(EnvPath,i+1);
 328
 329         // List \cmd before \bin so \cmd has higher priority and programs in
 330         // there will be called in favor of those in \bin.
 331         EnvPath[i]:=ExpandConstant('{app}\cmd');
 332
 333         if RdbGitCmdTools.Checked then begin
 334             SetArrayLength(EnvPath,i+2);
 335             EnvPath[i+1]:=ExpandConstant('{app}\bin');
 336
 337             // Set HOME for the Windows Command Prompt.
 338             EnvHome:=GetEnvStrings('HOME',IsAdminLoggedOn);
 339             i:=GetArrayLength(EnvHome);
 340             if (i=0) or ((i=1) and (Length(EnvHome[0])=0)) then begin
 341                 SetArrayLength(EnvHome,1);
 342                 EnvHome[0]:=ExpandConstant('{%USERPROFILE}');
 343                 SetEnvStrings('HOME',IsAdminLoggedOn,True,EnvHome);
 344
 345                 // Mark that we have changed HOME.
 346                 SetIniString('Environment','HOME',EnvHome[0],AppDir+'\setup.ini');
 347             end;
 348         end;
 349     end;
 350
 351     // Set the current user's directories in PATH.
 352     SetEnvStrings('PATH',IsAdminLoggedOn,True,EnvPath);
 353
 354     {
 355         Create the Windows Explorer shell extensions
 356     }
 357
 358     if IsAdminLoggedOn then begin
 359         RootKey:=HKEY_LOCAL_MACHINE;
 360     end else begin
 361         RootKey:=HKEY_CURRENT_USER;
 362     end;
 363
 364     if IsTaskSelected('shellextension') then begin
 365         Cmd:=ExpandConstant('"{syswow64}\cmd.exe"');
 366         RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_shell','','Git Ba&sh Here');
 367         RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_shell\command','',Cmd+' /c "pushd "%1" && "'+AppDir+'\bin\sh.exe" --login -i"');
 368     end;
 369
 370     if IsTaskSelected('guiextension') then begin
 371         RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_gui','','Git &GUI Here');
 372         RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_gui\command','','"'+AppDir+'\bin\wish.exe" "'+AppDir+'\bin\git-gui" "--working-dir" "%1"');
 373     end;
 374 end;
 375
 376 {
 377     Uninstaller code
 378 }
 379
 380 function InitializeUninstall:Boolean;
 381 begin
 382     Result:=DeleteFile(ExpandConstant('{app}')+'\bin\ssh-agent.exe');
 383     if not Result then begin
 384         MsgBox('Please stop all ssh-agent processes and run uninstall again.',mbError,MB_OK);
 385     end;
 386 end;
 387
 388 procedure CurUninstallStepChanged(CurUninstallStep:TUninstallStep);
 389 var
 390     AppDir,Command:string;
 391     EnvPath,EnvHome:TArrayOfString;
 392     i:Longint;
 393     RootKey:Integer;
 394 begin
 395     if CurUninstallStep<>usUninstall then begin
 396         Exit;
 397     end;
 398
 399     {
 400         Modify the environment
 401
 402         This must happen no later than usUninstall to make
 403         "ChangesEnvironment=yes" not happend before the change!
 404     }
 405
 406     AppDir:=ExpandConstant('{app}');
 407
 408     // Get the current user's directories in PATH.
 409     EnvPath:=GetEnvStrings('PATH',IsAdminLoggedOn);
 410
 411     // Remove the installation directory from PATH in any case, even if it
 412     // was not added by the installer.
 413     for i:=0 to GetArrayLength(EnvPath)-1 do begin
 414         if Pos(AppDir,EnvPath[i])=1 then begin
 415             EnvPath[i]:='';
 416         end;
 417     end;
 418
 419     // Reset the current user's directories in PATH.
 420     if not SetEnvStrings('PATH',IsAdminLoggedOn,True,EnvPath) then begin
 421         MsgBox('Unable to revert any possible changes to PATH.',mbError,MB_OK);
 422     end;
 423
 424     // Reset the current user's HOME if we modified it.
 425     EnvHome:=GetEnvStrings('HOME',IsAdminLoggedOn);
 426     if (GetArrayLength(EnvHome)=1) and
 427        (CompareStr(EnvHome[0],GetIniString('Environment','HOME','',AppDir+'\setup.ini'))=0) then begin
 428         if not SetEnvStrings('HOME',IsAdminLoggedOn,True,[]) then begin
 429             MsgBox('Unable to revert any possible changes to HOME.',mbError,MB_OK);
 430         end;
 431     end;
 432     DeleteFile(AppDir+'\setup.ini');
 433
 434     {
 435         Delete the Windows Explorer shell extensions
 436     }
 437
 438     if IsAdminLoggedOn then begin
 439         RootKey:=HKEY_LOCAL_MACHINE;
 440     end else begin
 441         RootKey:=HKEY_CURRENT_USER;
 442     end;
 443
 444     Command:='';
 445     RegQueryStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_shell\command','',Command);
 446     if Pos(AppDir,Command)>0 then begin
 447         RegDeleteKeyIncludingSubkeys(RootKey,'SOFTWARE\Classes\Directory\shell\git_shell');
 448     end;
 449
 450     Command:='';
 451     RegQueryStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_gui\command','',Command);
 452     if Pos(AppDir,Command)>0 then begin
 453         RegDeleteKeyIncludingSubkeys(RootKey,'SOFTWARE\Classes\Directory\shell\git_gui');
 454     end;
 455 end;