share/vim/vim73/indent/vim.vim

   1 " Vim indent file
   2 " Language:     Vim script
   3 " Maintainer:   Bram Moolenaar <Bram@vim.org>
   4 " Last Change:  2005 Jul 06
   5
   6 " Only load this indent file when no other was loaded.
   7 if exists("b:did_indent")
   8   finish
   9 endif
  10 let b:did_indent = 1
  11
  12 setlocal indentexpr=GetVimIndent()
  13 setlocal indentkeys+==end,=else,=cat,=fina,=END,0\\
  14
  15 " Only define the function once.
  16 if exists("*GetVimIndent")
  17   finish
  18 endif
  19
  20 function GetVimIndent()
  21   " Find a non-blank line above the current line.
  22   let lnum = prevnonblank(v:lnum - 1)
  23
  24   " If the current line doesn't start with '\' and below a line that starts
  25   " with '\', use the indent of the line above it.
  26   if getline(v:lnum) !~ '^\s*\\'
  27     while lnum > 0 && getline(lnum) =~ '^\s*\\'
  28       let lnum = lnum - 1
  29     endwhile
  30   endif
  31
  32   " At the start of the file use zero indent.
  33   if lnum == 0
  34     return 0
  35   endif
  36
  37   " Add a 'shiftwidth' after :if, :while, :try, :catch, :finally, :function
  38   " and :else.  Add it three times for a line that starts with '\' after
  39   " a line that doesn't (or g:vim_indent_cont if it exists).
  40   let ind = indent(lnum)
  41   if getline(v:lnum) =~ '^\s*\\' && v:lnum > 1 && getline(lnum) !~ '^\s*\\'
  42     if exists("g:vim_indent_cont")
  43       let ind = ind + g:vim_indent_cont
  44     else
  45       let ind = ind + &sw * 3
  46     endif
  47   elseif getline(lnum) =~ '\(^\||\)\s*\(if\|wh\%[ile]\|for\|try\|cat\%[ch]\|fina\%[lly]\|fu\%[nction]\|el\%[seif]\)\>'
  48     let ind = ind + &sw
  49   elseif getline(lnum) =~ '^\s*aug\%[roup]' && getline(lnum) !~ '^\s*aug\%[roup]\s*!\=\s\+END'
  50     let ind = ind + &sw
  51   endif
  52
  53   " If the previous line contains an "end" after a pipe, but not in an ":au"
  54   " command.  And not when there is a backslash before the pipe.
  55   " And when syntax HL is enabled avoid a match inside a string.
  56   let line = getline(lnum)
  57   let i = match(line, '[^\\]|\s*\(ene\@!\)')
  58   if i > 0 && line !~ '^\s*au\%[tocmd]'
  59     if !has('syntax_items') || synIDattr(synID(lnum, i + 2, 1), "name") !~ '\(Comment\|String\)$'
  60       let ind = ind - &sw
  61     endif
  62   endif
  63
  64
  65   " Subtract a 'shiftwidth' on a :endif, :endwhile, :catch, :finally, :endtry,
  66   " :endfun, :else and :augroup END.
  67   if getline(v:lnum) =~ '^\s*\(ene\@!\|cat\|fina\|el\|aug\%[roup]\s*!\=\s\+END\)'
  68     let ind = ind - &sw
  69   endif
  70
  71   return ind
  72 endfunction
  73
  74 " vim:sw=2