share/guile/1.6.0/oop/goops/composite-slot.scm

   1 ;;; installed-scm-file
   2
   3 ;;;;    Copyright (C) 1999, 2000, 2001 Free Software Foundation, Inc.
   4 ;;;;
   5 ;;;; This program is free software; you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation; either version 2, or (at your option)
   8 ;;;; any later version.
   9 ;;;;
  10 ;;;; This program is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with this software; see the file COPYING.  If not, write to
  17 ;;;; the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
  18 ;;;; Boston, MA 02111-1307 USA
  19 ;;;;
  20 ;;;; As a special exception, the Free Software Foundation gives permission
  21 ;;;; for additional uses of the text contained in its release of GUILE.
  22 ;;;;
  23 ;;;; The exception is that, if you link the GUILE library with other files
  24 ;;;; to produce an executable, this does not by itself cause the
  25 ;;;; resulting executable to be covered by the GNU General Public License.
  26 ;;;; Your use of that executable is in no way restricted on account of
  27 ;;;; linking the GUILE library code into it.
  28 ;;;;
  29 ;;;; This exception does not however invalidate any other reasons why
  30 ;;;; the executable file might be covered by the GNU General Public License.
  31 ;;;;
  32 ;;;; This exception applies only to the code released by the
  33 ;;;; Free Software Foundation under the name GUILE.  If you copy
  34 ;;;; code from other Free Software Foundation releases into a copy of
  35 ;;;; GUILE, as the General Public License permits, the exception does
  36 ;;;; not apply to the code that you add in this way.  To avoid misleading
  37 ;;;; anyone as to the status of such modified files, you must delete
  38 ;;;; this exception notice from them.
  39 ;;;;
  40 ;;;; If you write modifications of your own for GUILE, it is your choice
  41 ;;;; whether to permit this exception to apply to your modifications.
  42 ;;;; If you do not wish that, delete this exception notice.
  43 ;;;;
  44 \f
  45
  46 ;;;; This software is a derivative work of other copyrighted softwares; the
  47 ;;;; copyright notices of these softwares are placed in the file COPYRIGHTS
  48 ;;;;
  49 ;;;; This file is based upon composite-slot.stklos from the STk
  50 ;;;; distribution by Erick Gallesio <eg@unice.fr>.
  51 ;;;;
  52
  53 (define-module (oop goops composite-slot)
  54   :use-module (oop goops)
  55   :export (<composite-class>))
  56
  57 ;;;
  58 ;;; (define-class CLASS SUPERS
  59 ;;;   ...
  60 ;;;   (OBJECT ...)
  61 ;;;   ...
  62 ;;;   (SLOT #:allocation #:propagated
  63 ;;;         #:propagate-to '(PROPAGATION ...))
  64 ;;;   ...
  65 ;;;   #:metaclass <composite-class>)
  66 ;;;
  67 ;;; PROPAGATION ::= OBJECT | (OBJECT TARGETSLOT)
  68 ;;;
  69 ;;; The slot SLOT will be propagated to the slot TARGETSLOT in the object
  70 ;;; stored in slot OBJECT.  If TARGETSLOT is omitted, assume that the target
  71 ;;; slot is named SLOT.
  72 ;;;
  73
  74 (define-class <composite-class> (<class>))
  75
  76 (define-method (compute-get-n-set (class <composite-class>) slot)
  77   (if (eq? (slot-definition-allocation slot) #:propagated)
  78       (compute-propagated-get-n-set slot)
  79       (next-method)))
  80
  81 (define (compute-propagated-get-n-set s)
  82   (let ((prop           (get-keyword #:propagate-to (cdr s) #f))
  83         (s-name         (slot-definition-name s)))
  84
  85     (if (not prop)
  86         (goops-error "Propagation not specified for slot ~S" s-name))
  87     (if (not (pair? prop))
  88         (goops-error "Bad propagation list for slot ~S" s-name))
  89
  90     (let ((objects (map (lambda (p) (if (pair? p) (car p) p)) prop))
  91           (slots (map (lambda (p) (if (pair? p) (cadr p) s-name)) prop)))
  92       (let ((first-object (car objects))
  93             (first-slot (car slots)))
  94         (list
  95          ;; The getter
  96          (lambda (o)
  97            (slot-ref (slot-ref o first-object) first-slot))
  98
  99          ;; The setter
 100          (if (null? (cdr objects))
 101              (lambda (o v)
 102                (slot-set! (slot-ref o first-object) first-slot v))
 103              (lambda (o v)
 104                (for-each (lambda (object slot)
 105                            (slot-set! (slot-ref o object) slot v))
 106                          objects
 107                          slots))))))))