share/aclocal/ltdl.m4

   1 ## ltdl.m4 - Configure ltdl for the target system. -*-Autoconf-*-
   2 ## Copyright (C) 1999-2000 Free Software Foundation, Inc.
   3 ##
   4 ## This program is free software; you can redistribute it and/or modify
   5 ## it under the terms of the GNU General Public License as published by
   6 ## the Free Software Foundation; either version 2 of the License, or
   7 ## (at your option) any later version.
   8 ##
   9 ## This program is distributed in the hope that it will be useful, but
  10 ## WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ## General Public License for more details.
  13 ##
  14 ## You should have received a copy of the GNU General Public License
  15 ## along with this program; if not, write to the Free Software
  16 ## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17 ##
  18 ## As a special exception to the GNU General Public License, if you
  19 ## distribute this file as part of a program that contains a
  20 ## configuration script generated by Autoconf, you may include it under
  21 ## the same distribution terms that you use for the rest of that program.
  22
  23 # serial 6 AC_LIB_LTDL
  24
  25 # AC_WITH_LTDL
  26 # ------------
  27 # Clients of libltdl can use this macro to allow the installer to
  28 # choose between a shipped copy of the ltdl sources or a preinstalled
  29 # version of the library.
  30 AC_DEFUN([AC_WITH_LTDL],
  31 [AC_REQUIRE([AC_LIB_LTDL])
  32 AC_SUBST([LIBLTDL])
  33 AC_SUBST([INCLTDL])
  34
  35 # Unless the user asks us to check, assume no installed ltdl exists.
  36 use_installed_libltdl=no
  37
  38 AC_ARG_WITH([included_ltdl],
  39     [  --with-included-ltdl    use the GNU ltdl sources included here])
  40
  41 if test "x$with_included_ltdl" != xyes; then
  42   # We are not being forced to use the included libltdl sources, so
  43   # decide whether there is a useful installed version we can use.
  44   AC_CHECK_HEADER([ltdl.h],
  45       [AC_CHECK_LIB([ltdl], [lt_dlcaller_register],
  46           [with_included_ltdl=no],
  47           [with_included_ltdl=yes])
  48   ])
  49 fi
  50
  51 if test "x$enable_ltdl_install" != xyes; then
  52   # If the user did not specify an installable libltdl, then default
  53   # to a convenience lib.
  54   AC_LIBLTDL_CONVENIENCE
  55 fi
  56
  57 if test "x$with_included_ltdl" = xno; then
  58   # If the included ltdl is not to be used. then Use the
  59   # preinstalled libltdl we found.
  60   AC_DEFINE([HAVE_LTDL], 1,
  61     [Define this if a modern libltdl is already installed])
  62   LIBLTDL=-lltdl
  63 fi
  64
  65 # Report our decision...
  66 AC_MSG_CHECKING([whether to use included libltdl])
  67 AC_MSG_RESULT([$with_included_ltdl])
  68
  69 AC_CONFIG_SUBDIRS([libltdl])
  70 ])# AC_WITH_LTDL
  71
  72
  73 # AC_LIB_LTDL
  74 # -----------
  75 # Perform all the checks necessary for compilation of the ltdl objects
  76 #  -- including compiler checks and header checks.
  77 AC_DEFUN([AC_LIB_LTDL],
  78 [AC_PREREQ(2.50)
  79 AC_REQUIRE([AC_PROG_CC])
  80 AC_REQUIRE([AC_C_CONST])
  81 AC_REQUIRE([AC_HEADER_STDC])
  82 AC_REQUIRE([AC_HEADER_DIRENT])
  83 AC_REQUIRE([_LT_AC_CHECK_DLFCN])
  84 AC_REQUIRE([AC_LTDL_ENABLE_INSTALL])
  85 AC_REQUIRE([AC_LTDL_SHLIBEXT])
  86 AC_REQUIRE([AC_LTDL_SHLIBPATH])
  87 AC_REQUIRE([AC_LTDL_SYSSEARCHPATH])
  88 AC_REQUIRE([AC_LTDL_OBJDIR])
  89 AC_REQUIRE([AC_LTDL_DLPREOPEN])
  90 AC_REQUIRE([AC_LTDL_DLLIB])
  91 AC_REQUIRE([AC_LTDL_SYMBOL_USCORE])
  92 AC_REQUIRE([AC_LTDL_DLSYM_USCORE])
  93 AC_REQUIRE([AC_LTDL_SYS_DLOPEN_DEPLIBS])
  94 AC_REQUIRE([AC_LTDL_FUNC_ARGZ])
  95
  96 AC_CHECK_HEADERS([assert.h ctype.h errno.h malloc.h memory.h stdlib.h \
  97                   stdio.h unistd.h])
  98 AC_CHECK_HEADERS([dl.h sys/dl.h dld.h])
  99 AC_CHECK_HEADERS([string.h strings.h], [break])
 100
 101 AC_CHECK_FUNCS([strchr index], [break])
 102 AC_CHECK_FUNCS([strrchr rindex], [break])
 103 AC_CHECK_FUNCS([memcpy bcopy], [break])
 104 AC_CHECK_FUNCS([memmove strcmp])
 105 AC_CHECK_FUNCS([closedir opendir readdir])
 106 ])# AC_LIB_LTDL
 107
 108
 109 # AC_LTDL_ENABLE_INSTALL
 110 # ----------------------
 111 AC_DEFUN([AC_LTDL_ENABLE_INSTALL],
 112 [AC_ARG_ENABLE([ltdl-install],
 113     [AC_HELP_STRING([--enable-ltdl-install], [install libltdl])])
 114
 115 AM_CONDITIONAL(INSTALL_LTDL, test x"${enable_ltdl_install-no}" != xno)
 116 AM_CONDITIONAL(CONVENIENCE_LTDL, test x"${enable_ltdl_convenience-no}" != xno)
 117 ])])# AC_LTDL_ENABLE_INSTALL
 118
 119
 120 # AC_LTDL_SYS_DLOPEN_DEPLIBS
 121 # --------------------------
 122 AC_DEFUN([AC_LTDL_SYS_DLOPEN_DEPLIBS],
 123 [AC_REQUIRE([AC_CANONICAL_HOST])
 124 AC_CACHE_CHECK([whether deplibs are loaded by dlopen],
 125   [libltdl_cv_sys_dlopen_deplibs],
 126   [# PORTME does your system automatically load deplibs for dlopen?
 127   # or its logical equivalent (e.g. shl_load for HP-UX < 11)
 128   # For now, we just catch OSes we know something about -- in the
 129   # future, we'll try test this programmatically.
 130   libltdl_cv_sys_dlopen_deplibs=unknown
 131   case "$host_os" in
 132   aix3*|aix4.1.*|aix4.2.*)
 133     # Unknown whether this is true for these versions of AIX, but
 134     # we want this `case' here to explicitly catch those versions.
 135     libltdl_cv_sys_dlopen_deplibs=unknown
 136     ;;
 137   aix[[45]]*)
 138     libltdl_cv_sys_dlopen_deplibs=yes
 139     ;;
 140   gnu*)
 141     libltdl_cv_sys_dlopen_deplibs=yes
 142     ;;
 143   hpux10*|hpux11*)
 144     libltdl_cv_sys_dlopen_deplibs=yes
 145     ;;
 146   irix[[12345]]*|irix6.[[01]]*)
 147     # Catch all versions of IRIX before 6.2, and indicate that we don't
 148     # know how it worked for any of those versions.
 149     libltdl_cv_sys_dlopen_deplibs=unknown
 150     ;;
 151   irix*)
 152     # The case above catches anything before 6.2, and it's known that
 153     # at 6.2 and later dlopen does load deplibs.
 154     libltdl_cv_sys_dlopen_deplibs=yes
 155     ;;
 156   linux*)
 157     libltdl_cv_sys_dlopen_deplibs=yes
 158     ;;
 159   netbsd*)
 160     libltdl_cv_sys_dlopen_deplibs=yes
 161     ;;
 162   openbsd*)
 163     libltdl_cv_sys_dlopen_deplibs=yes
 164     ;;
 165   osf[[1234]]*)
 166     # dlopen did load deplibs (at least at 4.x), but until the 5.x series,
 167     # it did *not* use an RPATH in a shared library to find objects the
 168     # library depends on, so we explictly say `no'.
 169     libltdl_cv_sys_dlopen_deplibs=no
 170     ;;
 171   osf5.0|osf5.0a|osf5.1)
 172     # dlopen *does* load deplibs and with the right loader patch applied
 173     # it even uses RPATH in a shared library to search for shared objects
 174     # that the library depends on, but there's no easy way to know if that
 175     # patch is installed.  Since this is the case, all we can really
 176     # say is unknown -- it depends on the patch being installed.  If
 177     # it is, this changes to `yes'.  Without it, it would be `no'.
 178     libltdl_cv_sys_dlopen_deplibs=unknown
 179     ;;
 180   osf*)
 181     # the two cases above should catch all versions of osf <= 5.1.  Read
 182     # the comments above for what we know about them.
 183     # At > 5.1, deplibs are loaded *and* any RPATH in a shared library
 184     # is used to find them so we can finally say `yes'.
 185     libltdl_cv_sys_dlopen_deplibs=yes
 186     ;;
 187   solaris*)
 188     libltdl_cv_sys_dlopen_deplibs=yes
 189     ;;
 190   esac
 191   ])
 192 if test "$libltdl_cv_sys_dlopen_deplibs" != yes; then
 193  AC_DEFINE([LTDL_DLOPEN_DEPLIBS], [1],
 194     [Define if the OS needs help to load dependent libraries for dlopen().])
 195 fi
 196 ])# AC_LTDL_SYS_DLOPEN_DEPLIBS
 197
 198
 199 # AC_LTDL_SHLIBEXT
 200 # ----------------
 201 AC_DEFUN([AC_LTDL_SHLIBEXT],
 202 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 203 AC_CACHE_CHECK([which extension is used for shared libraries],
 204   [libltdl_cv_shlibext],
 205   [ac_last=
 206   for ac_spec in $library_names_spec; do
 207     ac_last="$ac_spec"
 208   done
 209   echo "$ac_last" | [sed 's/\[.*\]//;s/^[^.]*//;s/\$.*$//;s/\.$//'] > conftest
 210   libltdl_cv_shlibext=`cat conftest`
 211   rm -f conftest
 212   ])
 213 if test -n "$libltdl_cv_shlibext"; then
 214   AC_DEFINE_UNQUOTED(LTDL_SHLIB_EXT, "$libltdl_cv_shlibext",
 215     [Define to the extension used for shared libraries, say, ".so".])
 216 fi
 217 ])# AC_LTDL_SHLIBEXT
 218
 219
 220 # AC_LTDL_SHLIBPATH
 221 # -----------------
 222 AC_DEFUN([AC_LTDL_SHLIBPATH],
 223 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 224 AC_CACHE_CHECK([which variable specifies run-time library path],
 225   [libltdl_cv_shlibpath_var], [libltdl_cv_shlibpath_var="$shlibpath_var"])
 226 if test -n "$libltdl_cv_shlibpath_var"; then
 227   AC_DEFINE_UNQUOTED(LTDL_SHLIBPATH_VAR, "$libltdl_cv_shlibpath_var",
 228     [Define to the name of the environment variable that determines the dynamic library search path.])
 229 fi
 230 ])# AC_LTDL_SHLIBPATH
 231
 232
 233 # AC_LTDL_SYSSEARCHPATH
 234 # ---------------------
 235 AC_DEFUN([AC_LTDL_SYSSEARCHPATH],
 236 [AC_REQUIRE([AC_LIBTOOL_SYS_DYNAMIC_LINKER])
 237 AC_CACHE_CHECK([for the default library search path],
 238   [libltdl_cv_sys_search_path],
 239   [libltdl_cv_sys_search_path="$sys_lib_dlsearch_path_spec"])
 240 if test -n "$libltdl_cv_sys_search_path"; then
 241   sys_search_path=
 242   for dir in $libltdl_cv_sys_search_path; do
 243     if test -z "$sys_search_path"; then
 244       sys_search_path="$dir"
 245     else
 246       sys_search_path="$sys_search_path$PATH_SEPARATOR$dir"
 247     fi
 248   done
 249   AC_DEFINE_UNQUOTED(LTDL_SYSSEARCHPATH, "$sys_search_path",
 250     [Define to the system default library search path.])
 251 fi
 252 ])# AC_LTDL_SYSSEARCHPATH
 253
 254
 255 # AC_LTDL_OBJDIR
 256 # --------------
 257 AC_DEFUN([AC_LTDL_OBJDIR],
 258 [AC_CACHE_CHECK([for objdir],
 259   [libltdl_cv_objdir],
 260   [libltdl_cv_objdir="$objdir"
 261   if test -n "$objdir"; then
 262     :
 263   else
 264     rm -f .libs 2>/dev/null
 265     mkdir .libs 2>/dev/null
 266     if test -d .libs; then
 267       libltdl_cv_objdir=.libs
 268     else
 269       # MS-DOS does not allow filenames that begin with a dot.
 270       libltdl_cv_objdir=_libs
 271     fi
 272   rmdir .libs 2>/dev/null
 273   fi
 274   ])
 275 AC_DEFINE_UNQUOTED(LTDL_OBJDIR, "$libltdl_cv_objdir/",
 276   [Define to the sub-directory in which libtool stores uninstalled libraries.])
 277 ])# AC_LTDL_OBJDIR
 278
 279
 280 # AC_LTDL_DLPREOPEN
 281 # -----------------
 282 AC_DEFUN([AC_LTDL_DLPREOPEN],
 283 [AC_REQUIRE([AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE])
 284 AC_CACHE_CHECK([whether libtool supports -dlopen/-dlpreopen],
 285   [libltdl_cv_preloaded_symbols],
 286   [if test -n "$lt_cv_sys_global_symbol_pipe"; then
 287     libltdl_cv_preloaded_symbols=yes
 288   else
 289     libltdl_cv_preloaded_symbols=no
 290   fi
 291   ])
 292 if test x"$libltdl_cv_preloaded_symbols" = xyes; then
 293   AC_DEFINE(HAVE_PRELOADED_SYMBOLS, 1,
 294     [Define if libtool can extract symbol lists from object files.])
 295 fi
 296 ])# AC_LTDL_DLPREOPEN
 297
 298
 299 # AC_LTDL_DLLIB
 300 # -------------
 301 AC_DEFUN([AC_LTDL_DLLIB],
 302 [LIBADD_DL=
 303 AC_SUBST(LIBADD_DL)
 304 AC_LANG_PUSH([C])
 305
 306 AC_CHECK_FUNC([shl_load],
 307       [AC_DEFINE([HAVE_SHL_LOAD], [1],
 308                  [Define if you have the shl_load function.])],
 309   [AC_CHECK_LIB([dld], [shl_load],
 310         [AC_DEFINE([HAVE_SHL_LOAD], [1],
 311                    [Define if you have the shl_load function.])
 312         LIBADD_DL="$LIBADD_DL -ldld"],
 313     [AC_CHECK_LIB([dl], [dlopen],
 314           [AC_DEFINE([HAVE_LIBDL], [1],
 315                      [Define if you have the libdl library or equivalent.])
 316                 LIBADD_DL="-ldl" libltdl_cv_lib_dl_dlopen="yes"],
 317       [AC_TRY_LINK([#if HAVE_DLFCN_H
 318 #  include <dlfcn.h>
 319 #endif
 320       ],
 321         [dlopen(0, 0);],
 322             [AC_DEFINE([HAVE_LIBDL], [1],
 323                              [Define if you have the libdl library or equivalent.]) libltdl_cv_func_dlopen="yes"],
 324         [AC_CHECK_LIB([svld], [dlopen],
 325               [AC_DEFINE([HAVE_LIBDL], [1],
 326                          [Define if you have the libdl library or equivalent.])
 327                     LIBADD_DL="-lsvld" libltdl_cv_func_dlopen="yes"],
 328           [AC_CHECK_LIB([dld], [dld_link],
 329                 [AC_DEFINE([HAVE_DLD], [1],
 330                            [Define if you have the GNU dld library.])
 331                 LIBADD_DL="$LIBADD_DL -ldld"
 332           ])
 333         ])
 334       ])
 335     ])
 336   ])
 337 ])
 338
 339 if test x"$libltdl_cv_func_dlopen" = xyes || test x"$libltdl_cv_lib_dl_dlopen" = xyes
 340 then
 341   lt_save_LIBS="$LIBS"
 342   LIBS="$LIBS $LIBADD_DL"
 343   AC_CHECK_FUNCS([dlerror])
 344   LIBS="$lt_save_LIBS"
 345 fi
 346 AC_LANG_POP
 347 ])# AC_LTDL_DLLIB
 348
 349
 350 # AC_LTDL_SYMBOL_USCORE
 351 # ---------------------
 352 # does the compiler prefix global symbols with an underscore?
 353 AC_DEFUN([AC_LTDL_SYMBOL_USCORE],
 354 [AC_REQUIRE([AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE])
 355 AC_CACHE_CHECK([for _ prefix in compiled symbols],
 356   [ac_cv_sys_symbol_underscore],
 357   [ac_cv_sys_symbol_underscore=no
 358   cat > conftest.$ac_ext <<EOF
 359 void nm_test_func(){}
 360 int main(){nm_test_func;return 0;}
 361 EOF
 362   if AC_TRY_EVAL(ac_compile); then
 363     # Now try to grab the symbols.
 364     ac_nlist=conftest.nm
 365     if AC_TRY_EVAL(NM conftest.$ac_objext \| $lt_cv_sys_global_symbol_pipe \> $ac_nlist) && test -s "$ac_nlist"; then
 366       # See whether the symbols have a leading underscore.
 367       if grep '^. _nm_test_func' "$ac_nlist" >/dev/null; then
 368         ac_cv_sys_symbol_underscore=yes
 369       else
 370         if grep '^. nm_test_func ' "$ac_nlist" >/dev/null; then
 371           :
 372         else
 373           echo "configure: cannot find nm_test_func in $ac_nlist" >&AC_FD_CC
 374         fi
 375       fi
 376     else
 377       echo "configure: cannot run $lt_cv_sys_global_symbol_pipe" >&AC_FD_CC
 378     fi
 379   else
 380     echo "configure: failed program was:" >&AC_FD_CC
 381     cat conftest.c >&AC_FD_CC
 382   fi
 383   rm -rf conftest*
 384   ])
 385 ])# AC_LTDL_SYMBOL_USCORE
 386
 387
 388 # AC_LTDL_DLSYM_USCORE
 389 # --------------------
 390 AC_DEFUN([AC_LTDL_DLSYM_USCORE],
 391 [AC_REQUIRE([AC_LTDL_SYMBOL_USCORE])
 392 if test x"$ac_cv_sys_symbol_underscore" = xyes; then
 393   if test x"$libltdl_cv_func_dlopen" = xyes ||
 394      test x"$libltdl_cv_lib_dl_dlopen" = xyes ; then
 395         AC_CACHE_CHECK([whether we have to add an underscore for dlsym],
 396           [libltdl_cv_need_uscore],
 397           [libltdl_cv_need_uscore=unknown
 398           save_LIBS="$LIBS"
 399           LIBS="$LIBS $LIBADD_DL"
 400           _LT_AC_TRY_DLOPEN_SELF(
 401             [libltdl_cv_need_uscore=no], [libltdl_cv_need_uscore=yes],
 402             [],                          [libltdl_cv_need_uscore=cross])
 403           LIBS="$save_LIBS"
 404         ])
 405   fi
 406 fi
 407
 408 if test x"$libltdl_cv_need_uscore" = xyes; then
 409   AC_DEFINE(NEED_USCORE, 1,
 410     [Define if dlsym() requires a leading underscore in symbol names.])
 411 fi
 412 ])# AC_LTDL_DLSYM_USCORE
 413
 414 # AC_LTDL_FUNC_ARGZ
 415 # -----------------
 416 AC_DEFUN([AC_LTDL_FUNC_ARGZ],
 417 [AC_CHECK_HEADERS([argz.h])
 418
 419 AC_CHECK_TYPES([error_t],
 420   [],
 421   [AC_DEFINE([error_t], [int],
 422     [Define to a type to use for `error_t' if it is not otherwise available.])],
 423   [#if HAVE_ARGZ_H
 424 #  include <argz.h>
 425 #endif])
 426
 427 AC_CHECK_FUNCS([argz_append argz_create_sep argz_insert argz_next argz_stringify])
 428 ])# AC_LTDL_FUNC_ARGZ