share/autoconf/autoconf/specific.m4

   1 # This file is part of Autoconf.                        -*- Autoconf -*-
   2 # Macros that test for specific, unclassified, features.
   3 #
   4 # Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
   5 # 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21 #
  22 # As a special exception, the Free Software Foundation gives unlimited
  23 # permission to copy, distribute and modify the configure scripts that
  24 # are the output of Autoconf.  You need not follow the terms of the GNU
  25 # General Public License when using or distributing such scripts, even
  26 # though portions of the text of Autoconf appear in them.  The GNU
  27 # General Public License (GPL) does govern all other use of the material
  28 # that constitutes the Autoconf program.
  29 #
  30 # Certain portions of the Autoconf source text are designed to be copied
  31 # (in certain cases, depending on the input) into the output of
  32 # Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 # source text consists of comments plus executable code that decides which
  34 # of the data portions to output in any given case.  We call these
  35 # comments and executable code the "non-data" portions.  Autoconf never
  36 # copies any of the non-data portions into its output.
  37 #
  38 # This special exception to the GPL applies to versions of Autoconf
  39 # released by the Free Software Foundation.  When you make and
  40 # distribute a modified version of Autoconf, you may extend this special
  41 # exception to the GPL to apply to your modified version as well, *unless*
  42 # your modified version has the potential to copy into its output some
  43 # of the text that was the non-data portion of the version that you started
  44 # with.  (In other words, unless your change moves or copies text from
  45 # the non-data portions to the data portions.)  If your modification has
  46 # such potential, you must delete any notice of this special exception
  47 # to the GPL from your modified version.
  48 #
  49 # Written by David MacKenzie, with help from
  50 # Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 # Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53
  54 ## ------------------------- ##
  55 ## Checks for declarations.  ##
  56 ## ------------------------- ##
  57
  58
  59 # AC_DECL_SYS_SIGLIST
  60 # -------------------
  61 AN_IDENTIFIER([sys_siglist],     [AC_CHECK_DECLS([sys_siglist])])
  62 AU_DEFUN([AC_DECL_SYS_SIGLIST],
  63 [AC_CHECK_DECLS([sys_siglist],,,
  64 [#include <signal.h>
  65 /* NetBSD declares sys_siglist in unistd.h.  */
  66 #ifdef HAVE_UNISTD_H
  67 # include <unistd.h>
  68 #endif
  69 ])
  70 ])# AC_DECL_SYS_SIGLIST
  71
  72
  73
  74
  75 ## -------------------------------------- ##
  76 ## Checks for operating system services.  ##
  77 ## -------------------------------------- ##
  78
  79
  80 # AC_SYS_INTERPRETER
  81 # ------------------
  82 AC_DEFUN([AC_SYS_INTERPRETER],
  83 [AC_CACHE_CHECK(whether @%:@! works in shell scripts, ac_cv_sys_interpreter,
  84 [echo '#! /bin/cat
  85 exit 69
  86 ' >conftest
  87 chmod u+x conftest
  88 (SHELL=/bin/sh; export SHELL; ./conftest >/dev/null 2>&1)
  89 if test $? -ne 69; then
  90    ac_cv_sys_interpreter=yes
  91 else
  92    ac_cv_sys_interpreter=no
  93 fi
  94 rm -f conftest])
  95 interpval=$ac_cv_sys_interpreter
  96 ])
  97
  98
  99 AU_DEFUN([AC_HAVE_POUNDBANG],
 100 [AC_SYS_INTERPRETER],
 101 [Remove this warning when you adjust your code to use
 102 `AC_SYS_INTERPRETER'.])
 103
 104
 105 AU_DEFUN([AC_ARG_ARRAY], [],
 106 [$0 is no longer implemented: don't do unportable things
 107 with arguments. Remove this warning when you adjust your code.])
 108
 109
 110 # _AC_SYS_LARGEFILE_TEST_INCLUDES
 111 # -------------------------------
 112 m4_define([_AC_SYS_LARGEFILE_TEST_INCLUDES],
 113 [@%:@include <sys/types.h>
 114  /* Check that off_t can represent 2**63 - 1 correctly.
 115     We can't simply define LARGE_OFF_T to be 9223372036854775807,
 116     since some C++ compilers masquerading as C compilers
 117     incorrectly reject 9223372036854775807.  */
 118 @%:@define LARGE_OFF_T (((off_t) 1 << 62) - 1 + ((off_t) 1 << 62))
 119   int off_t_is_large[[(LARGE_OFF_T % 2147483629 == 721
 120                        && LARGE_OFF_T % 2147483647 == 1)
 121                       ? 1 : -1]];[]dnl
 122 ])
 123
 124
 125 # _AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE,
 126 #                               CACHE-VAR,
 127 #                               DESCRIPTION,
 128 #                               PROLOGUE, [FUNCTION-BODY])
 129 # ----------------------------------------------------------
 130 m4_define([_AC_SYS_LARGEFILE_MACRO_VALUE],
 131 [AC_CACHE_CHECK([for $1 value needed for large files], [$3],
 132 [while :; do
 133   m4_ifval([$6], [AC_LINK_IFELSE], [AC_COMPILE_IFELSE])(
 134     [AC_LANG_PROGRAM([$5], [$6])],
 135     [$3=no; break])
 136   m4_ifval([$6], [AC_LINK_IFELSE], [AC_COMPILE_IFELSE])(
 137     [AC_LANG_PROGRAM([@%:@define $1 $2
 138 $5], [$6])],
 139     [$3=$2; break])
 140   $3=unknown
 141   break
 142 done])
 143 case $$3 in #(
 144   no | unknown) ;;
 145   *) AC_DEFINE_UNQUOTED([$1], [$$3], [$4]);;
 146 esac
 147 rm -f conftest*[]dnl
 148 ])# _AC_SYS_LARGEFILE_MACRO_VALUE
 149
 150
 151 # AC_SYS_LARGEFILE
 152 # ----------------
 153 # By default, many hosts won't let programs access large files;
 154 # one must use special compiler options to get large-file access to work.
 155 # For more details about this brain damage please see:
 156 # http://www.unix-systems.org/version2/whatsnew/lfs20mar.html
 157 AC_DEFUN([AC_SYS_LARGEFILE],
 158 [AC_ARG_ENABLE(largefile,
 159                [  --disable-largefile     omit support for large files])
 160 if test "$enable_largefile" != no; then
 161
 162   AC_CACHE_CHECK([for special C compiler options needed for large files],
 163     ac_cv_sys_largefile_CC,
 164     [ac_cv_sys_largefile_CC=no
 165      if test "$GCC" != yes; then
 166        ac_save_CC=$CC
 167        while :; do
 168          # IRIX 6.2 and later do not support large files by default,
 169          # so use the C compiler's -n32 option if that helps.
 170          AC_LANG_CONFTEST([AC_LANG_PROGRAM([_AC_SYS_LARGEFILE_TEST_INCLUDES])])
 171          AC_COMPILE_IFELSE([], [break])
 172          CC="$CC -n32"
 173          AC_COMPILE_IFELSE([], [ac_cv_sys_largefile_CC=' -n32'; break])
 174          break
 175        done
 176        CC=$ac_save_CC
 177        rm -f conftest.$ac_ext
 178     fi])
 179   if test "$ac_cv_sys_largefile_CC" != no; then
 180     CC=$CC$ac_cv_sys_largefile_CC
 181   fi
 182
 183   _AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
 184     ac_cv_sys_file_offset_bits,
 185     [Number of bits in a file offset, on hosts where this is settable.],
 186     [_AC_SYS_LARGEFILE_TEST_INCLUDES])
 187   if test $ac_cv_sys_file_offset_bits = unknown; then
 188     _AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
 189       ac_cv_sys_large_files,
 190       [Define for large files, on AIX-style hosts.],
 191       [_AC_SYS_LARGEFILE_TEST_INCLUDES])
 192   fi
 193 fi
 194 ])# AC_SYS_LARGEFILE
 195
 196
 197 # AC_SYS_LONG_FILE_NAMES
 198 # ----------------------
 199 # Security: use a temporary directory as the most portable way of
 200 # creating files in /tmp securely.  Removing them leaves a race
 201 # condition, set -C is not portably guaranteed to use O_EXCL, so still
 202 # leaves a race, and not all systems have the `mktemp' utility.  We
 203 # still test for existence first in case of broken systems where the
 204 # mkdir succeeds even when the directory exists.  Broken systems may
 205 # retain a race, but they probably have other security problems
 206 # anyway; this should be secure on well-behaved systems.  In any case,
 207 # use of `mktemp' is probably inappropriate here since it would fail in
 208 # attempting to create different file names differing after the 14th
 209 # character on file systems without long file names.
 210 AC_DEFUN([AC_SYS_LONG_FILE_NAMES],
 211 [AC_CACHE_CHECK(for long file names, ac_cv_sys_long_file_names,
 212 [ac_cv_sys_long_file_names=yes
 213 # Test for long file names in all the places we know might matter:
 214 #      .                the current directory, where building will happen
 215 #      $prefix/lib      where we will be installing things
 216 #      $exec_prefix/lib likewise
 217 #      $TMPDIR          if set, where it might want to write temporary files
 218 #      /tmp             where it might want to write temporary files
 219 #      /var/tmp         likewise
 220 #      /usr/tmp         likewise
 221 for ac_dir in . "$TMPDIR" /tmp /var/tmp /usr/tmp "$prefix/lib" "$exec_prefix/lib"; do
 222   # Skip $TMPDIR if it is empty or bogus, and skip $exec_prefix/lib
 223   # in the usual case where exec_prefix is '${prefix}'.
 224   case $ac_dir in #(
 225     . | /* | ?:[[\\/]]*) ;; #(
 226     *) continue;;
 227   esac
 228   test -w "$ac_dir/." || continue # It is less confusing to not echo anything here.
 229   ac_xdir=$ac_dir/cf$$
 230   (umask 077 && mkdir "$ac_xdir" 2>/dev/null) || continue
 231   ac_tf1=$ac_xdir/conftest9012345
 232   ac_tf2=$ac_xdir/conftest9012346
 233   touch "$ac_tf1" 2>/dev/null && test -f "$ac_tf1" && test ! -f "$ac_tf2" ||
 234     ac_cv_sys_long_file_names=no
 235   rm -f -r "$ac_xdir" 2>/dev/null
 236   test $ac_cv_sys_long_file_names = no && break
 237 done])
 238 if test $ac_cv_sys_long_file_names = yes; then
 239   AC_DEFINE(HAVE_LONG_FILE_NAMES, 1,
 240             [Define to 1 if you support file names longer than 14 characters.])
 241 fi
 242 ])
 243
 244
 245 # AC_SYS_RESTARTABLE_SYSCALLS
 246 # ---------------------------
 247 # If the system automatically restarts a system call that is
 248 # interrupted by a signal, define `HAVE_RESTARTABLE_SYSCALLS'.
 249 AC_DEFUN([AC_SYS_RESTARTABLE_SYSCALLS],
 250 [AC_DIAGNOSE([obsolete],
 251 [$0: AC_SYS_RESTARTABLE_SYSCALLS is useful only when supporting very
 252 old systems that lack `sigaction' and `SA_RESTART'.  Don't bother with
 253 this macro unless you need to support very old systems like 4.2BSD and
 254 SVR3.])dnl
 255 AC_REQUIRE([AC_HEADER_SYS_WAIT])dnl
 256 AC_CACHE_CHECK(for restartable system calls, ac_cv_sys_restartable_syscalls,
 257 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 258 [/* Exit 0 (true) if wait returns something other than -1,
 259    i.e. the pid of the child, which means that wait was restarted
 260    after getting the signal.  */
 261
 262 AC_INCLUDES_DEFAULT
 263 #include <signal.h>
 264 #ifdef HAVE_SYS_WAIT_H
 265 # include <sys/wait.h>
 266 #endif
 267
 268 /* Some platforms explicitly require an extern "C" signal handler
 269    when using C++. */
 270 #ifdef __cplusplus
 271 extern "C" void ucatch (int dummy) { }
 272 #else
 273 void ucatch (dummy) int dummy; { }
 274 #endif
 275
 276 int
 277 main ()
 278 {
 279   int i = fork (), status;
 280
 281   if (i == 0)
 282     {
 283       sleep (3);
 284       kill (getppid (), SIGINT);
 285       sleep (3);
 286       return 0;
 287     }
 288
 289   signal (SIGINT, ucatch);
 290
 291   status = wait (&i);
 292   if (status == -1)
 293     wait (&i);
 294
 295   return status == -1;
 296 }])],
 297                [ac_cv_sys_restartable_syscalls=yes],
 298                [ac_cv_sys_restartable_syscalls=no])])
 299 if test $ac_cv_sys_restartable_syscalls = yes; then
 300   AC_DEFINE(HAVE_RESTARTABLE_SYSCALLS, 1,
 301             [Define to 1 if system calls automatically restart after
 302              interruption by a signal.])
 303 fi
 304 ])# AC_SYS_RESTARTABLE_SYSCALLS
 305
 306
 307 # AC_SYS_POSIX_TERMIOS
 308 # --------------------
 309 AC_DEFUN([AC_SYS_POSIX_TERMIOS],
 310 [AC_CACHE_CHECK([POSIX termios], ac_cv_sys_posix_termios,
 311 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 312 #include <unistd.h>
 313 #include <termios.h>
 314 ]],
 315              [/* SunOS 4.0.3 has termios.h but not the library calls.  */
 316    tcgetattr(0, 0);])],
 317              ac_cv_sys_posix_termios=yes,
 318              ac_cv_sys_posix_termios=no)])
 319 ])# AC_SYS_POSIX_TERMIOS
 320
 321
 322
 323
 324 ## ------------------------------------ ##
 325 ## Checks for not-quite-Unix variants.  ##
 326 ## ------------------------------------ ##
 327
 328
 329 # AC_GNU_SOURCE
 330 # --------------
 331 AC_DEFUN([AC_GNU_SOURCE],
 332 [AH_VERBATIM([_GNU_SOURCE],
 333 [/* Enable GNU extensions on systems that have them.  */
 334 #ifndef _GNU_SOURCE
 335 # undef _GNU_SOURCE
 336 #endif])dnl
 337 AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 338 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 339 AC_DEFINE([_GNU_SOURCE])
 340 ])
 341
 342
 343 # AC_CYGWIN
 344 # ---------
 345 # Check for Cygwin.  This is a way to set the right value for
 346 # EXEEXT.
 347 AU_DEFUN([AC_CYGWIN],
 348 [AC_CANONICAL_HOST
 349 case $host_os in
 350   *cygwin* ) CYGWIN=yes;;
 351          * ) CYGWIN=no;;
 352 esac
 353 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 354 matches *cygwin*])# AC_CYGWIN
 355
 356
 357 # AC_EMXOS2
 358 # ---------
 359 # Check for EMX on OS/2.  This is another way to set the right value
 360 # for EXEEXT.
 361 AU_DEFUN([AC_EMXOS2],
 362 [AC_CANONICAL_HOST
 363 case $host_os in
 364   *emx* ) EMXOS2=yes;;
 365       * ) EMXOS2=no;;
 366 esac
 367 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 368 matches *emx*])# AC_EMXOS2
 369
 370
 371 # AC_MINGW32
 372 # ----------
 373 # Check for mingw32.  This is another way to set the right value for
 374 # EXEEXT.
 375 AU_DEFUN([AC_MINGW32],
 376 [AC_CANONICAL_HOST
 377 case $host_os in
 378   *mingw32* ) MINGW32=yes;;
 379           * ) MINGW32=no;;
 380 esac
 381 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 382 matches *mingw32*])# AC_MINGW32
 383
 384
 385 # AC_USE_SYSTEM_EXTENSIONS
 386 # ------------------------
 387 # Enable extensions on systems that normally disable them,
 388 # typically due to standards-conformance issues.
 389 AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS],
 390 [
 391   AC_BEFORE([$0], [AC_COMPILE_IFELSE])
 392   AC_BEFORE([$0], [AC_RUN_IFELSE])
 393
 394   AC_REQUIRE([AC_GNU_SOURCE])
 395   AC_REQUIRE([AC_AIX])
 396   AC_REQUIRE([AC_MINIX])
 397
 398   AH_VERBATIM([__EXTENSIONS__],
 399 [/* Enable extensions on Solaris.  */
 400 #ifndef __EXTENSIONS__
 401 # undef __EXTENSIONS__
 402 #endif
 403 #ifndef _POSIX_PTHREAD_SEMANTICS
 404 # undef _POSIX_PTHREAD_SEMANTICS
 405 #endif
 406 #ifndef _TANDEM_SOURCE
 407 # undef _TANDEM_SOURCE
 408 #endif])
 409   AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
 410     [ac_cv_safe_to_define___extensions__],
 411     [AC_COMPILE_IFELSE(
 412        [AC_LANG_PROGRAM([
 413 #         define __EXTENSIONS__ 1
 414           AC_INCLUDES_DEFAULT])],
 415        [ac_cv_safe_to_define___extensions__=yes],
 416        [ac_cv_safe_to_define___extensions__=no])])
 417   test $ac_cv_safe_to_define___extensions__ = yes &&
 418     AC_DEFINE([__EXTENSIONS__])
 419   AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
 420   AC_DEFINE([_TANDEM_SOURCE])
 421 ])
 422
 423
 424
 425
 426 ## -------------------------- ##
 427 ## Checks for UNIX variants.  ##
 428 ## -------------------------- ##
 429
 430
 431 # These are kludges which should be replaced by a single POSIX check.
 432 # They aren't cached, to discourage their use.
 433
 434 # AC_AIX
 435 # ------
 436 AC_DEFUN([AC_AIX],
 437 [AH_VERBATIM([_ALL_SOURCE],
 438 [/* Define to 1 if on AIX 3.
 439    System headers sometimes define this.
 440    We just want to avoid a redefinition error message.  */
 441 @%:@ifndef _ALL_SOURCE
 442 @%:@ undef _ALL_SOURCE
 443 @%:@endif])dnl
 444 AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 445 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 446 AC_MSG_CHECKING([for AIX])
 447 AC_EGREP_CPP(yes,
 448 [#ifdef _AIX
 449   yes
 450 #endif
 451 ],
 452 [AC_MSG_RESULT([yes])
 453 AC_DEFINE(_ALL_SOURCE)],
 454 [AC_MSG_RESULT([no])])
 455 ])# AC_AIX
 456
 457
 458 # AC_MINIX
 459 # --------
 460 AC_DEFUN([AC_MINIX],
 461 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 462 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 463 AC_CHECK_HEADER(minix/config.h, MINIX=yes, MINIX=)
 464 if test "$MINIX" = yes; then
 465   AC_DEFINE(_POSIX_SOURCE, 1,
 466             [Define to 1 if you need to in order for `stat' and other things to
 467              work.])
 468   AC_DEFINE(_POSIX_1_SOURCE, 2,
 469             [Define to 2 if the system does not provide POSIX.1 features except
 470              with this defined.])
 471   AC_DEFINE(_MINIX, 1,
 472             [Define to 1 if on MINIX.])
 473 fi
 474 ])# AC_MINIX
 475
 476
 477 # AC_ISC_POSIX
 478 # ------------
 479 AC_DEFUN([AC_ISC_POSIX], [AC_SEARCH_LIBS(strerror, cposix)])
 480
 481
 482 # AC_XENIX_DIR
 483 # ------------
 484 AU_DEFUN([AC_XENIX_DIR],
 485 [AC_MSG_CHECKING([for Xenix])
 486 AC_EGREP_CPP(yes,
 487 [#if defined M_XENIX && ! defined M_UNIX
 488   yes
 489 @%:@endif],
 490              [AC_MSG_RESULT([yes]); XENIX=yes],
 491              [AC_MSG_RESULT([no]); XENIX=])
 492
 493 AC_HEADER_DIRENT[]dnl
 494 ],
 495 [You shouldn't need to depend upon XENIX.  Remove the
 496 `AC_MSG_CHECKING', `AC_EGREP_CPP', and this warning if this part
 497 of the test is useless.])
 498
 499
 500 # AC_DYNIX_SEQ
 501 # ------------
 502 AU_DEFUN([AC_DYNIX_SEQ], [AC_FUNC_GETMNTENT])
 503
 504
 505 # AC_IRIX_SUN
 506 # -----------
 507 AU_DEFUN([AC_IRIX_SUN],
 508 [AC_FUNC_GETMNTENT
 509 AC_CHECK_LIB(sun, getpwnam)])
 510
 511
 512 # AC_SCO_INTL
 513 # -----------
 514 AU_DEFUN([AC_SCO_INTL], [AC_FUNC_STRFTIME])