share/aclocal-1.10/tar.m4

   1 # Check how to create a tarball.                            -*- Autoconf -*-
   2
   3 # Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # serial 2
  10
  11 # _AM_PROG_TAR(FORMAT)
  12 # --------------------
  13 # Check how to create a tarball in format FORMAT.
  14 # FORMAT should be one of `v7', `ustar', or `pax'.
  15 #
  16 # Substitute a variable $(am__tar) that is a command
  17 # writing to stdout a FORMAT-tarball containing the directory
  18 # $tardir.
  19 #     tardir=directory && $(am__tar) > result.tar
  20 #
  21 # Substitute a variable $(am__untar) that extract such
  22 # a tarball read from stdin.
  23 #     $(am__untar) < result.tar
  24 AC_DEFUN([_AM_PROG_TAR],
  25 [# Always define AMTAR for backward compatibility.
  26 AM_MISSING_PROG([AMTAR], [tar])
  27 m4_if([$1], [v7],
  28      [am__tar='${AMTAR} chof - "$$tardir"'; am__untar='${AMTAR} xf -'],
  29      [m4_case([$1], [ustar],, [pax],,
  30               [m4_fatal([Unknown tar format])])
  31 AC_MSG_CHECKING([how to create a $1 tar archive])
  32 # Loop over all known methods to create a tar archive until one works.
  33 _am_tools='gnutar m4_if([$1], [ustar], [plaintar]) pax cpio none'
  34 _am_tools=${am_cv_prog_tar_$1-$_am_tools}
  35 # Do not fold the above two line into one, because Tru64 sh and
  36 # Solaris sh will not grok spaces in the rhs of `-'.
  37 for _am_tool in $_am_tools
  38 do
  39   case $_am_tool in
  40   gnutar)
  41     for _am_tar in tar gnutar gtar;
  42     do
  43       AM_RUN_LOG([$_am_tar --version]) && break
  44     done
  45     am__tar="$_am_tar --format=m4_if([$1], [pax], [posix], [$1]) -chf - "'"$$tardir"'
  46     am__tar_="$_am_tar --format=m4_if([$1], [pax], [posix], [$1]) -chf - "'"$tardir"'
  47     am__untar="$_am_tar -xf -"
  48     ;;
  49   plaintar)
  50     # Must skip GNU tar: if it does not support --format= it doesn't create
  51     # ustar tarball either.
  52     (tar --version) >/dev/null 2>&1 && continue
  53     am__tar='tar chf - "$$tardir"'
  54     am__tar_='tar chf - "$tardir"'
  55     am__untar='tar xf -'
  56     ;;
  57   pax)
  58     am__tar='pax -L -x $1 -w "$$tardir"'
  59     am__tar_='pax -L -x $1 -w "$tardir"'
  60     am__untar='pax -r'
  61     ;;
  62   cpio)
  63     am__tar='find "$$tardir" -print | cpio -o -H $1 -L'
  64     am__tar_='find "$tardir" -print | cpio -o -H $1 -L'
  65     am__untar='cpio -i -H $1 -d'
  66     ;;
  67   none)
  68     am__tar=false
  69     am__tar_=false
  70     am__untar=false
  71     ;;
  72   esac
  73
  74   # If the value was cached, stop now.  We just wanted to have am__tar
  75   # and am__untar set.
  76   test -n "${am_cv_prog_tar_$1}" && break
  77
  78   # tar/untar a dummy directory, and stop if the command works
  79   rm -rf conftest.dir
  80   mkdir conftest.dir
  81   echo GrepMe > conftest.dir/file
  82   AM_RUN_LOG([tardir=conftest.dir && eval $am__tar_ >conftest.tar])
  83   rm -rf conftest.dir
  84   if test -s conftest.tar; then
  85     AM_RUN_LOG([$am__untar <conftest.tar])
  86     grep GrepMe conftest.dir/file >/dev/null 2>&1 && break
  87   fi
  88 done
  89 rm -rf conftest.dir
  90
  91 AC_CACHE_VAL([am_cv_prog_tar_$1], [am_cv_prog_tar_$1=$_am_tool])
  92 AC_MSG_RESULT([$am_cv_prog_tar_$1])])
  93 AC_SUBST([am__tar])
  94 AC_SUBST([am__untar])
  95 ]) # _AM_PROG_TAR