share/aclocal-1.10/init.m4

   1 # Do all the work for Automake.                             -*- Autoconf -*-
   2
   3 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 # 2005, 2006 Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 # serial 12
  11
  12 # This macro actually does too much.  Some checks are only needed if
  13 # your package does certain things.  But this isn't really a big deal.
  14
  15 # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
  16 # AM_INIT_AUTOMAKE([OPTIONS])
  17 # -----------------------------------------------
  18 # The call with PACKAGE and VERSION arguments is the old style
  19 # call (pre autoconf-2.50), which is being phased out.  PACKAGE
  20 # and VERSION should now be passed to AC_INIT and removed from
  21 # the call to AM_INIT_AUTOMAKE.
  22 # We support both call styles for the transition.  After
  23 # the next Automake release, Autoconf can make the AC_INIT
  24 # arguments mandatory, and then we can depend on a new Autoconf
  25 # release and drop the old call support.
  26 AC_DEFUN([AM_INIT_AUTOMAKE],
  27 [AC_PREREQ([2.60])dnl
  28 dnl Autoconf wants to disallow AM_ names.  We explicitly allow
  29 dnl the ones we care about.
  30 m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
  31 AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
  32 AC_REQUIRE([AC_PROG_INSTALL])dnl
  33 if test "`cd $srcdir && pwd`" != "`pwd`"; then
  34   # Use -I$(srcdir) only when $(srcdir) != ., so that make's output
  35   # is not polluted with repeated "-I."
  36   AC_SUBST([am__isrc], [' -I$(srcdir)'])_AM_SUBST_NOTMAKE([am__isrc])dnl
  37   # test to see if srcdir already configured
  38   if test -f $srcdir/config.status; then
  39     AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
  40   fi
  41 fi
  42
  43 # test whether we have cygpath
  44 if test -z "$CYGPATH_W"; then
  45   if (cygpath --version) >/dev/null 2>/dev/null; then
  46     CYGPATH_W='cygpath -w'
  47   else
  48     CYGPATH_W=echo
  49   fi
  50 fi
  51 AC_SUBST([CYGPATH_W])
  52
  53 # Define the identity of the package.
  54 dnl Distinguish between old-style and new-style calls.
  55 m4_ifval([$2],
  56 [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
  57  AC_SUBST([PACKAGE], [$1])dnl
  58  AC_SUBST([VERSION], [$2])],
  59 [_AM_SET_OPTIONS([$1])dnl
  60 dnl Diagnose old-style AC_INIT with new-style AM_AUTOMAKE_INIT.
  61 m4_if(m4_ifdef([AC_PACKAGE_NAME], 1)m4_ifdef([AC_PACKAGE_VERSION], 1), 11,,
  62   [m4_fatal([AC_INIT should be called with package and version arguments])])dnl
  63  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
  64  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
  65
  66 _AM_IF_OPTION([no-define],,
  67 [AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  68  AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
  69
  70 # Some tools Automake needs.
  71 AC_REQUIRE([AM_SANITY_CHECK])dnl
  72 AC_REQUIRE([AC_ARG_PROGRAM])dnl
  73 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
  74 AM_MISSING_PROG(AUTOCONF, autoconf)
  75 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
  76 AM_MISSING_PROG(AUTOHEADER, autoheader)
  77 AM_MISSING_PROG(MAKEINFO, makeinfo)
  78 AM_PROG_INSTALL_SH
  79 AM_PROG_INSTALL_STRIP
  80 AC_REQUIRE([AM_PROG_MKDIR_P])dnl
  81 # We need awk for the "check" target.  The system "awk" is bad on
  82 # some platforms.
  83 AC_REQUIRE([AC_PROG_AWK])dnl
  84 AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  85 AC_REQUIRE([AM_SET_LEADING_DOT])dnl
  86 _AM_IF_OPTION([tar-ustar], [_AM_PROG_TAR([ustar])],
  87               [_AM_IF_OPTION([tar-pax], [_AM_PROG_TAR([pax])],
  88                              [_AM_PROG_TAR([v7])])])
  89 _AM_IF_OPTION([no-dependencies],,
  90 [AC_PROVIDE_IFELSE([AC_PROG_CC],
  91                   [_AM_DEPENDENCIES(CC)],
  92                   [define([AC_PROG_CC],
  93                           defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
  94 AC_PROVIDE_IFELSE([AC_PROG_CXX],
  95                   [_AM_DEPENDENCIES(CXX)],
  96                   [define([AC_PROG_CXX],
  97                           defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
  98 AC_PROVIDE_IFELSE([AC_PROG_OBJC],
  99                   [_AM_DEPENDENCIES(OBJC)],
 100                   [define([AC_PROG_OBJC],
 101                           defn([AC_PROG_OBJC])[_AM_DEPENDENCIES(OBJC)])])dnl
 102 ])
 103 ])
 104
 105
 106 # When config.status generates a header, we must update the stamp-h file.
 107 # This file resides in the same directory as the config header
 108 # that is generated.  The stamp files are numbered to have different names.
 109
 110 # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
 111 # loop where config.status creates the headers, so we can generate
 112 # our stamp files there.
 113 AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
 114 [# Compute $1's index in $config_headers.
 115 _am_stamp_count=1
 116 for _am_header in $config_headers :; do
 117   case $_am_header in
 118     $1 | $1:* )
 119       break ;;
 120     * )
 121       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
 122   esac
 123 done
 124 echo "timestamp for $1" >`AS_DIRNAME([$1])`/stamp-h[]$_am_stamp_count])