mingw/lib/tk8.5/ttk/panedwindow.tcl

   1 #
   2 # $Id: panedwindow.tcl,v 1.4 2007/06/09 21:45:45 jenglish Exp $
   3 #
   4 # Bindings for ttk::panedwindow widget.
   5 #
   6
   7 namespace eval ttk::panedwindow {
   8     variable State
   9     array set State {
  10         pressed 0
  11         pressX  -
  12         pressY  -
  13         sash    -
  14         sashPos -
  15     }
  16 }
  17
  18 ## Bindings:
  19 #
  20 bind TPanedwindow <ButtonPress-1>       { ttk::panedwindow::Press %W %x %y }
  21 bind TPanedwindow <B1-Motion>           { ttk::panedwindow::Drag %W %x %y }
  22 bind TPanedwindow <ButtonRelease-1>     { ttk::panedwindow::Release %W %x %y }
  23
  24 bind TPanedwindow <Motion>              { ttk::panedwindow::SetCursor %W %x %y }
  25 bind TPanedwindow <Enter>               { ttk::panedwindow::SetCursor %W %x %y }
  26 bind TPanedwindow <Leave>               { ttk::panedwindow::ResetCursor %W }
  27 # See <<NOTE-PW-LEAVE-NOTIFYINFERIOR>>
  28 bind TPanedwindow <<EnteredChild>>      { ttk::panedwindow::ResetCursor %W }
  29
  30
  31 ## Sash movement:
  32 #
  33 proc ttk::panedwindow::Press {w x y} {
  34     variable State
  35
  36     set sash [$w identify $x $y]
  37     if {$sash eq ""} {
  38         set State(pressed) 0
  39         return
  40     }
  41     set State(pressed)  1
  42     set State(pressX)   $x
  43     set State(pressY)   $y
  44     set State(sash)     $sash
  45     set State(sashPos)  [$w sashpos $sash]
  46 }
  47
  48 proc ttk::panedwindow::Drag {w x y} {
  49     variable State
  50     if {!$State(pressed)} { return }
  51     switch -- [$w cget -orient] {
  52         horizontal      { set delta [expr {$x - $State(pressX)}] }
  53         vertical        { set delta [expr {$y - $State(pressY)}] }
  54     }
  55     $w sashpos $State(sash) [expr {$State(sashPos) + $delta}]
  56 }
  57
  58 proc ttk::panedwindow::Release {w x y} {
  59     variable State
  60     set State(pressed) 0
  61     SetCursor $w $x $y
  62 }
  63
  64 ## Cursor management:
  65 #
  66 proc ttk::panedwindow::ResetCursor {w} {
  67     variable State
  68     if {!$State(pressed)} {
  69         $w configure -cursor {}
  70     }
  71 }
  72
  73 proc ttk::panedwindow::SetCursor {w x y} {
  74     variable ::ttk::Cursors
  75
  76     if {![llength [$w identify $x $y]]} {
  77         ResetCursor $w
  78     } else {
  79         # Assume we're over a sash.
  80         switch -- [$w cget -orient] {
  81             horizontal  { $w configure -cursor $Cursors(hresize) }
  82             vertical    { $w configure -cursor $Cursors(vresize) }
  83         }
  84     }
  85 }
  86
  87 #*EOF*